WOLFRAM

Wolfram 语言与系统参考资料中心

BetaBinomialDistribution[α,β,n]

表示一个 β-二项混合分布，其中 β 分布的参数为 alpha 和 beta，二项试验次数为 n.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

BetaBinomialDistribution

BetaBinomialDistribution[α,β,n]

表示一个 β-二项混合分布，其中 β 分布的参数为 alpha 和 beta，二项试验次数为 n.

更多信息

背景

范例

打开所有单元 关闭所有单元

基本范例  (3)

概率质量函数：

Wolfram Language code: DiscretePlot[Table[PDF[BetaBinomialDistribution[α, .3, 20], x], {α, {0.5, 1, 3}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]
Wolfram Language code: DiscretePlot[Table[PDF[BetaBinomialDistribution[1.2, β, 20], x], {β, {0.5, 2, 3}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]
Wolfram Language code: PDF[BetaBinomialDistribution[α, β, n], x]

累积分布函数：

Wolfram Language code: DiscretePlot[Table[CDF[BetaBinomialDistribution[α, .3, 20], x], {α, {0.5, 1, 3}}]//Evaluate, {x, 0, 20}, ExtentSize -> Right]
Wolfram Language code: DiscretePlot[Table[CDF[BetaBinomialDistribution[1.2, β, 20], x], {β, {0.5, 2, 3}}]//Evaluate, {x, 0, 20}, ExtentSize -> Right]
Wolfram Language code: CDF[BetaBinomialDistribution[α, β, n], x]

均值和方差：

Wolfram Language code: Mean[BetaBinomialDistribution[α, β, n]]
Wolfram Language code: Variance[BetaBinomialDistribution[α, β, n]]

范围  (7)

生成一组服从 β-二项分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[BetaBinomialDistribution[2, 3, 50], 10 ^ 4];

将其直方图与概率密度函数进行比较：

Wolfram Language code: Show[ Histogram[data, {5}, "PDF"], DiscretePlot[PDF[BetaBinomialDistribution[2, 3, 50], x], {x, 0, 50}, PlotStyle -> PointSize[Medium]]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[BetaBinomialDistribution[.5, .3, 30], 10 ^ 3];

假设 n 已知，根据样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, BetaBinomialDistribution[α, β, 30]]

比较样本的密度直方图和所估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, {1}, "PDF"], DiscretePlot[PDF[edist, x], {x, 0, 30}, PlotStyle -> PointSize[Medium]]]

偏度：

Wolfram Language code: Plot3D[Skewness[BetaBinomialDistribution[α, β, 100]], {α, 0, 20}, {β, 0, 20}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {15, -8, 5}]
Wolfram Language code: Skewness[BetaBinomialDistribution[α, β, n]]

峰度：

Wolfram Language code: Plot3D[Kurtosis[BetaBinomialDistribution[α, β, 100]], {α, 0, 20}, {β, 0, 20}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {15, 8, 5}]
Wolfram Language code: Kurtosis[BetaBinomialDistribution[α, β, n]]

以参数的函数形式表示不同矩的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BetaBinomialDistribution[α, β, n], k]//FullSimplify, {k, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BetaBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BetaBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], FM]

具有符号式阶数的解析式：

Wolfram Language code: FactorialMoment[BetaBinomialDistribution[α, β, n], r]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BetaBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], C]

风险函数：

Wolfram Language code: DiscretePlot[Table[HazardFunction[BetaBinomialDistribution[α, .2, 20], x], {α, {0.1, 0.5, 1}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]
Wolfram Language code: DiscretePlot[Table[HazardFunction[BetaBinomialDistribution[0.4, β, 20], x], {β, {0.1, 0.5, 0.7}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]
Wolfram Language code: HazardFunction[BetaBinomialDistribution[α, β, n], x]

分位数函数：

Wolfram Language code: 𝒟 = BetaBinomialDistribution[3, 2, 10]; points = Table[CDF[𝒟, x], {x, 0, 10}]//N;
Wolfram Language code: DiscretePlot[Quantile[𝒟, p], {p, points}, ExtentSize -> Right, ExtentMarkers -> {"Empty", "Filled"}]

应用  (4)

服从一种 β 分布的 100 次试验，成功次数大于50的概率：

Wolfram Language code: 1 - CDF[BetaBinomialDistribution[4, 5, 100], 50]
Wolfram Language code: N[%]

定义负超几何分布：

Wolfram Language code: NegativeHypergeometricDistribution[w_, wtot_, btot_] := BetaBinomialDistribution[w, wtot - w + 1, btot]

一个容器原先装有 个黑球和 个白球，求在容器中抽到第 个白球之前，拿到 个黑球，而不放回去的概率：

Wolfram Language code: Probability[x == b, xNegativeHypergeometricDistribution[w, Subscript[k, w], Subscript[k, b]]]

或者，计算在前 次采样抽取（不放回）中，有 个黑球的情况下，抽到一个白球的概率：

Wolfram Language code: FullSimplify[% == Probability[y == b, yHypergeometricDistribution[w + b - 1, Subscript[k, b], Subscript[k, w] + Subscript[k, b]]]((Subscript[k, w] - w + 1)/Subscript[k, w] + Subscript[k, b] - w - b + 1), 0 < w < Subscript[k, w] && 0 < b < Subscript[k, b] && (w | b | Subscript[k, w] | Subscript[k, b])∈Integers]

定义 Pólya 分布：

Wolfram Language code: PolyaDistribution[p_, α_, n_] := BetaBinomialDistribution[p / α, (1 - p) / α, n]
Wolfram Language code: PDF[PolyaDistribution[p, α, n], k]

产生随机数：

Wolfram Language code: RandomVariate[PolyaDistribution[1 / 3, 10 / 3, 10], 10]

计算概率：

Wolfram Language code: Probability[x ≤ 5, xPolyaDistribution[1 / 3, 10 / 3, 10]]

定义 Pólya-Eggenberg 罐子分布：

Wolfram Language code: PolyaEggenbergDistribution[w_, b_, c_, n_] := BetaBinomialDistribution[w / c, b / c, n]

该分布对从一个罐子中取球的过程进行建模. 假设一个罐子中含有 个白球和 个黑球. 当取出一个球时，它与另外 个同样颜色的球一起放回罐子中. 该分布给出在 次抽取中，取出 个白球的概率：

Wolfram Language code: PDF[PolyaEggenbergDistribution[w, b, c, n], k]

以下求出在10次抽取中白球的数目：

Wolfram Language code: RandomVariate[PolyaEggenbergDistribution[5, 5, 1, 10], 20]

属性和关系  (5)

得到负整数、超出 n 的整数或非整数的概率为零：

Wolfram Language code: PDF[BetaBinomialDistribution[α, β, n], π]

与其它分布的关系：

DiscreteUniformDistribution 是贝塔二项分布的一个特例：

Wolfram Language code: PDF[BetaBinomialDistribution[1, 1, 99], x]//FullSimplify
Wolfram Language code: PDF[DiscreteUniformDistribution[{0, 99}], x]
Wolfram Language code: % - %%//Simplify

对于 和 ，贝塔二项分布具有一个三角形状，但是不是 TriangularDistribution 的离散版本：

Wolfram Language code: DiscretePlot[{PDF[BetaBinomialDistribution[1, 2, 6], x], DifferenceDelta[CDF[TriangularDistribution[{0, 7}, 0], x], x]}//Evaluate, {x, 0, 7}, Filling -> {1 -> {2}}, PlotLegends -> {"BetaBinomial", "floor of Triangular"}]
Wolfram Language code: PDF[BetaBinomialDistribution[1, 2, 6], x]//FullSimplify
Wolfram Language code: FullSimplify[DifferenceDelta[CDF[TriangularDistribution[{0, 7}, 0], x], x], x∈Integers]

确认前面的表达式给出 TemplateBox[{y}, Floor] 的概率密度函数，其中 服从 TriangularDistribution：

Wolfram Language code: Assuming[x∈Integers, FullSimplify[PiecewiseExpand[% == Probability[x ≤ y < x + 1, yTriangularDistribution[{0, 7}, 0]]]]]

BetaBinomialDistribution 是 BinomialDistribution 和 BetaDistribution 的混合：

Wolfram Language code: ParameterMixtureDistribution[BinomialDistribution[n, p], pBetaDistribution[α, β]]

可能存在的问题  (3)

当 α 或 β 为非正数时，BetaBinomialDistribution 没有定义：

Wolfram Language code: Mean[BetaBinomialDistribution[-4, 6.2, 40]]

当 n 不是一个正整数时，BetaBinomialDistribution 没有定义：

Wolfram Language code: Mean[BetaBinomialDistribution[5, 6.2, -10]]

将无效参数代入符号式输出时，所得到的结果没有意义：

Wolfram Language code: Mean[BetaBinomialDistribution[α, β, n]] /. {α -> 3 + I, β -> 7, n -> 23}
Wolfram Research (2007)，BetaBinomialDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetaBinomialDistribution.html.

文本

Wolfram Research (2007)，BetaBinomialDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetaBinomialDistribution.html.

CMS

Wolfram 语言. 2007. "BetaBinomialDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BetaBinomialDistribution.html.

APA

Wolfram 语言. (2007). BetaBinomialDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BetaBinomialDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_betabinomialdistribution, author="Wolfram Research", title="{BetaBinomialDistribution}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/BetaBinomialDistribution.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_betabinomialdistribution, organization={Wolfram Research}, title={BetaBinomialDistribution}, year={2007}, url={https://reference.wolfram.com/language/ref/BetaBinomialDistribution.html}, note=[Accessed: 18-August-2026]}