CauchyDistribution

CauchyDistribution[a,b]

位置母数 a，尺度母数 b のコーシー(Cauchy)分布を表す．

CauchyDistribution[]

位置母数0，尺度母数1のコーシー分布を表す．

詳細

CauchyDistributionは，Lorentz分布またはBreit–Wigner分布としても知られている．
コーシー分布における値の確率密度はに比例する． »
CauchyDistributionでは，a は任意の実数，b は任意の正の実数でよい．
CauchyDistributionでは，a と b は単位次元が等しい任意の数量でよい． »
CauchyDistributionは，Mean，CDF，RandomVariate等の関数で使うことができる． »

予備知識

CauchyDistribution[a,b]は，実数集合上で定義され，2つの変数 a および b によってパラメータ化される連続統計分布を表す．ただし，a は実数値の「位置母数」であり，b は正の「尺度母数」である．コーシー分布の確率密度関数(PDF)は連続かつ単峰性であり，点について対称である．PDFの高さと幅は，母数 b によって変わる．b の値が0に近付くと，より高くより急勾配のPDFになる．これに加え，PDFがの大きい値について，指数的と言うよりも代数的に減少するという意味で，PDFの裾部は「厚い」．（この動作は，分布のSurvivalFunctionを分析することで，定量的に厳密にすることができる）．コーシー分布は，ローレンツ分布あるいはBreit–Wigner分布と呼ばれることがある．
現在コーシー分布と呼ばれているものの研究は，17世紀のフェルマの業績まで遡る．この分布は，分布の誕生からおよそ150年後の1850年代にオーギュスタン＝ルイ・コーシーと関連付けられるまでに，すでに，既存の確率理論に豊かでカラフルな貢献をしていた．もともと，コーシー分布は，当時一般に受け入れられていた数多くの結果や概念に対する反例として作用する新しい分布として研究された．今日この分布は，それ自体として確立され，さまざまな分野における数多くの応用がある分布である．例えば，コーシー分布はある種の分子のブラウン運動と自然な結びつきを持ち，非相対的なコンテキストにおける共鳴のエネルギー断面を説明する分布である．コーシー分布は，また，危険分析，力学理論および電気理論，自然人類学を含む数多くの現象のモデル化に使うことができる．
RandomVariateを使って，コーシー分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,CauchyDistribution[a,b]]（より簡略すると xCauchyDistribution[a,b]）を使って，確率変数 x がコーシー分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
確率密度関数および累積分布関数は，PDF[CauchyDistribution[a,b],x]およびCDF[CauchyDistribution[a,b],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．コーシー分布の厚い裾部のために，ここに上げた数量の中には存在しないものがあるかもしれないので注意が必要である．
DistributionFitTestを使って，与えられたデータ集合がコーシー分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからコーシーパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをコーシー分布にフィットすることができる．ProbabilityPlotを使って記号的なコーシー分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号的なコーシー分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
TransformedDistributionを使って変換されたコーシー分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってコーシー分布を含む高次元分布を構築することが，ProductDistributionを使ってコーシー分布を含む独立成分分布の結合分布を計算することができる．
コーシー分布は数多くの他の分布と関連している．例えば，CauchyDistribution[0,1]はStudentTDistribution[1]と厳密に等しいPDFを持つ．CauchyDistributonは，また，TransformedDistributionを介したNormalDistributionおよびUniformDistributionの両方の変換と見ることができ，ϵ がについて0に近付くときのPearsonDistribution[4,1,-a,(1+ϵ)/2,-a,(a²+b²)/2]のPDFが，そして α が0に近付くときのHyperbolicDistribution[-1/2, α, 0, δ, μ]のPDFが，それぞれCauchyDistribution[a, b]およびCauchyDistribution[μ, δ]のPDFと厳密に等しいという意味において，PearsonDistributionおよびHyperbolicDistributionの両方にとっての極限のケースである．CauchyDistributionは，PearsonDistribution，ParetoDistribution，StableDistributionとも関係がある．

例題

すべて開くすべて閉じる

例 (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[CauchyDistribution[a, 2], x], {a, {-2, 0, 3}}]//Evaluate, {x, -8, 8}, Filling -> Axis]

Wolfram Language code: PDF[CauchyDistribution[a, b], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[CauchyDistribution[a, 2], x], {a, {-2, 0, 3}}]//Evaluate, {x, -8, 8}, Filling -> Axis]

Wolfram Language code: CDF[CauchyDistribution[a, b], x]

コーシー分布では平均と分散は不定である：

Wolfram Language code: Mean[CauchyDistribution[a, b]]

Wolfram Language code: Variance[CauchyDistribution[a, b]]

中央値：

Wolfram Language code: Median[CauchyDistribution[a, b]]

スコープ (6)

コーシー分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[CauchyDistribution[3, 2.5], 10 ^ 4];

ヒストグラムと確率密度関数を比較する：

Wolfram Language code:

Show[Histogram[data, {-18, 20, 1}, PDF], Plot[PDF[TruncatedDistribution[{-18, 20}, CauchyDistribution[3, 2.5]], x], {x, -18, 20}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[CauchyDistribution[2, 3], 2 * 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, CauchyDistribution[a, b]]

サンプルの密度ヒストグラムを推定された分布の確率密度関数と比較する：

Wolfram Language code:

Show[Histogram[sample, {-10, 15, 1}, PDF], Plot[PDF[TruncatedDistribution[{-10, 15}, edist], x], {x, -10, 15}, PlotStyle -> Thick]]

高次モーメントは不定である：

Wolfram Language code: Skewness[CauchyDistribution[a, b]]

Wolfram Language code: Kurtosis[CauchyDistribution[a, b]]

Wolfram Language code: Moment[CauchyDistribution[a, b], r]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[CauchyDistribution[a, 3], x], {a, {-5, 5, 10}}]//Evaluate, {x, -10, 20}, Filling -> Axis]

Wolfram Language code: Plot[Table[HazardFunction[CauchyDistribution[3, b], x], {b, {5, 10, 20}}]//Evaluate, {x, -10, 20}, Filling -> Axis]

Wolfram Language code: HazardFunction[CauchyDistribution[a, b], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[CauchyDistribution[a, 3.5], q], {a, {1, 10, 20}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Plot[Table[Quantile[CauchyDistribution[3.5, b], q], {b, {1, 10, 20}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[CauchyDistribution[a, b], q]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: δλ𝒟 = CauchyDistribution[Quantity[0, "Nanometers"], Quantity[78, "Nanometers"]]

四分位数を求める：

Wolfram Language code: Quartiles[δλ𝒟]//N

アプリケーション (1)

振子が原点の上，高さのところに掛っている．この振子と垂直軸によってできる角はからまでで一様分布に従う．振子と垂直軸の間の水平距離を求める[MathWorld]：

Wolfram Language code: 𝒟 = TransformedDistribution[b Tan[θ], θUniformDistribution[{-π / 2, π / 2}]];

Wolfram Language code: PDF[𝒟, x]//FullSimplify[#, b > 0]&

以下で示されるように，これはCauchyDistributionである：

Wolfram Language code: FullSimplify[% - PDF[CauchyDistribution[0, b], x], x ≠ 0]

振子と垂直軸の距離が最短でもになる確率を求める：

Wolfram Language code: Probability[x ≥ b / 2 || x ≤ -b / 2, xCauchyDistribution[0, b]]

Wolfram Language code: N[%]

を仮定し，この確率に等しい確率密度関数プロットの下の部分の面積を求める：

Wolfram Language code: dist = CauchyDistribution[Quantity[0, "Centimeters"], Quantity[1, "Centimeters"]];

Wolfram Language code:

Plot[{PDF[dist, Quantity[x, "Centimeters"]], ConditionalExpression[PDF[dist, Quantity[x, "Centimeters"]], Abs[x] > 1 / 2]}, {x, -3, 3}, Filling -> {2 -> Axis}, AxesLabel -> {"cm"}]

特性と関係 (13)

コーシー分布は平行移動と正の因子によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[k u + loc, u CauchyDistribution[]]

任意のパラメータで：

Wolfram Language code: TransformedDistribution[k u + loc, u CauchyDistribution[a, b]]

コーシー分布はある種の変換下では閉じている：

Wolfram Language code: 𝒟 = TransformedDistribution[2 u / (1 - u ^ 2), uCauchyDistribution[0, 1]];

Wolfram Language code: PDF[𝒟, x]//FullSimplify[#, x∈Reals]&

Wolfram Language code: PDF[CauchyDistribution[0, 1], x]

Wolfram Language code: FullSimplify[% - %%]

コーシー分布に従う変量の総和はコーシー分布に従う：

Wolfram Language code: TransformedDistribution[u + v, {uCauchyDistribution[a1, b1], vCauchyDistribution[a2, b2]}]

特性関数に基づいて証明する：

Wolfram Language code: CharacteristicFunction[CauchyDistribution[a1, b1], t]CharacteristicFunction[CauchyDistribution[a2, b2], t]

Wolfram Language code: CharacteristicFunction[CauchyDistribution[a1 + a2, b1 + b2], t]

Wolfram Language code: FullSimplify[% - %%]

0を中心としたコーシー分布の逆分布もまたコーシー分布である：

Wolfram Language code: 𝒟 = TransformedDistribution[1 / u, uCauchyDistribution[0, b]];

Wolfram Language code: PDF[𝒟, x]

Wolfram Language code: PDF[CauchyDistribution[0, 1 / b], x]

Wolfram Language code: FullSimplify[% - %%, x ≠ 0]

他の分布との関係：

CauchyDistribution[0,1]は，のStudentTDistributionに等しい：

Wolfram Language code: PDF[CauchyDistribution[0, 1], x]

Wolfram Language code: PDF[StudentTDistribution[1], x]

Wolfram Language code: % - %%

正規分布に従う2つの変数の比はCauchyDistributionである：

Wolfram Language code: TransformedDistribution[u / v, {u, v}ProductDistribution[{NormalDistribution[], 2}]]

が一様分布に従う場合，はCauchyDistributionを示す：

Wolfram Language code: 𝒟 = TransformedDistribution[Tan[π (u - 1 / 2)], uUniformDistribution[{0, 1}]];

Wolfram Language code: PDF[𝒟, x]//PiecewiseExpand//FullSimplify[#, x∈Reals]&

Wolfram Language code: PDF[CauchyDistribution[0, 1], x]

Wolfram Language code: Simplify[% - %%]

コーシー分布はタイプ4のピアソン分布(PearsonDistribution)の限定されたケースである：

Wolfram Language code: Limit[PDF[PearsonDistribution[4, 1, -a, (1 + ϵ/2), -a, (a^2 + b^2/2)], x], ϵ -> 0]//FullSimplify[#, b > 0]&

Wolfram Language code: PDF[CauchyDistribution[a, b], x]//FullSimplify[#, b > 0]&

Wolfram Language code: % - %%

CauchyDistributionはタイプ7のPearsonDistributionの特殊ケースである：

Wolfram Language code: PDF[PearsonDistribution[7, 2, -2a, 1, -2a, a^2 + b^2], x]//FullSimplify[#, b > 0]&

Wolfram Language code: PDF[CauchyDistribution[a, b], x]//FullSimplify[#, b > 0]&

Wolfram Language code: %% - %//FullSimplify

コーシー分布はStableDistributionである：

Wolfram Language code: PDF[CauchyDistribution[0, 1], x]

Wolfram Language code: PDF[StableDistribution[0, 1, 0, 0, 1], x]

Wolfram Language code: % - %%

CauchyDistributionは，かつとすると，のときのHyperbolicDistributionの特異極限である：

Wolfram Language code: Limit[PDF[HyperbolicDistribution[-1 / 2, α, 0, δ, μ], x], α -> 0]//FullSimplify

Wolfram Language code: PDF[CauchyDistribution[μ, δ], x]

Wolfram Language code: FullSimplify[% - %%]

CauchyDistributionのLogLikelihood関数は複数の極大値を持つことがある：

Wolfram Language code:

data = {-1, 3, 7, -11, 10 ^ 2};
llk[m_] := LogLikelihood[CauchyDistribution[m, 1], data];

尤度関数の極値を求める：

Wolfram Language code: roots = m /. N[Solve[llk'[m] == 0, m, Reals]]

尤度の極大値を選びその値を求める：

Wolfram Language code: maxs = Select[roots, Function[m, llk''[m] < 0]]

Wolfram Language code: vals = llk /@ maxs

尤度を局所パラメータの関数として可視化する：

Wolfram Language code:

epilog = MapThread[{HalfLine[{#1, #2}, {0, -1}]}&, {maxs, vals}];
Plot[llk[m], {m, Min[maxs] - 2, Max[maxs] + 2}, Epilog -> {DotDashed, epilog}, PlotTheme -> "Detailed", Filling -> Axis]

考えられる問題 (2)

CauchyDistributionは，a が実数ではないときは定義されない：

Wolfram Language code: Mean[CauchyDistribution[3 + I, 2]]

CauchyDistributionは，b が正ではないときは定義されない：

Wolfram Language code: Mean[CauchyDistribution[0, -1]]

記号出力に無効な母数を代入すると意味のない結果が返される：

Wolfram Language code: PDF[CauchyDistribution[a, b], x] /. {a -> I, b -> 3}

おもしろい例題 (1)

累積分布関数の等高線を持つ a のさまざまな値についての確率密度関数：

Wolfram Language code:

cdf = Function[{x, a}, Evaluate[CDF[CauchyDistribution[a, 2], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[CauchyDistribution[a, 2], x], {x, -10, 10}, {a, -2, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 35, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> {0, 0.16}], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

CauchyDistribution

詳細

予備知識

例題

例 (4)

スコープ (6)

アプリケーション (1)

特性と関係 (13)

考えられる問題 (2)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

CauchyDistribution

詳細

予備知識

例題

例 (4)

スコープ (6)

アプリケーション (1)

特性と関係 (13)

考えられる問題 (2)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX