Wolfram 语言与系统参考资料中心

CauchyDistribution

CauchyDistribution[a,b]

表示定位参数为 a、尺度参数为 b 的柯西分布.

CauchyDistribution[]

表示定位参数为0、尺度参数为1的柯西分布.

背景

CauchyDistribution[a,b] 表示了一个定义在实数集上的，有两个参数 a 和 b 的连续统计分布，称为柯西分布，其中在实数上取值的 a 被称为“位置参数”而 b 是一个正的“比例参数”. 柯西分布的概率密度函数（PDF）是连续的，单峰的，且关于点对称. PDF 的高度和宽度会根据参数 b 而有所不同，当 b 的值接近零时对应的 PDF 更高更陡. 此外，该分布 PDF 的尾部较“胖”，意思是说当值较大时 PDF 的衰减是代数的而不是指数的.（这一行为可通过研究分布的 SurvivalFunction 做精确的定量分析.）柯西分布有时也被称为洛伦兹分布或 Breit–Wigner 分布.
对现在被称为柯西分布的研究可以追溯到十七世纪皮埃尔·德·费马的工作. 当这一分布于 1950 年代和奥古斯丁·路易·柯西联系在一起时——差不多在它诞生一个半世纪之后，它已经为现有的概率论作出了丰富多彩的贡献. 最初，柯西分布是作为当时许多被广泛接受的结果和概念的新奇反例而被研究的. 如今，它是一个独立的已确立的分布并在各种领域有着广泛的应用. 例如，柯西分布与某些分子的布朗运动有着天然的联系，也是在非相对论的上下文中描述共振能线图的分布. 柯西分布也可对诸如风险分析、机械和电气理论、及体质人类学等领域的许多现象建模.
RandomVariate 可被用于给出柯西分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,CauchyDistribution[a,b]]，更简洁的写法是 xCauchyDistribution[a,b]，可被用于声明随机变量 x 是柯西分布的. 这样一个声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
概率密度函数和累积分布函数可用 PDF[CauchyDistribution[a,b],x] 和 CDF[CauchyDistribution[a,b],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算. 请注意因为柯西分布的胖尾部，这些量中有一些可能不存在.
DistributionFitTest 可被用于测试给定的数据集是否与柯西分布一致，EstimatedDistribution 可被用于根据给定数据估算柯西参数化分布，而 FindDistributionParameters 可拟合数据和柯西分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号柯西分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号柯西分布的分位数的图线.
TransformedDistribution 可被用于表示转换的柯西分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了柯西分布的高维分布，而 ProductDistribution 可被用于计算包括柯西分布在内的，若干个独立分量的联合分布.
柯西分布和许多其它分布有关. 例如 CauchyDistribution[0,1] 和 StudentTDistribution[1] 的 PDF 完全相同. CauchyDistribution 可被看成是 NormalDistribution 和 UniformDistribution 通过 TransformedDistribution 变换得到. 它也是 PearsonDistribution 和 HyperbolicDistribution 的极限情形，意思是说当 ϵ 趋向于零时（）PearsonDistribution[4,1,-a,(1+ϵ)/2,-a,(a²+b²)/2] 的 PDF 恰好和 CauchyDistribution[a, b] 的 PDF 相同，当 α 趋向于零时 HyperbolicDistribution[-1/2, α, 0, δ, μ] 的 PDF 恰好等于 CauchyDistribution[μ, δ] 的 PDF. CauchyDistribution 还和 PearsonDistribution、ParetoDistribution 及 StableDistribution 有关.

范例

打开所有单元关闭所有单元

基本范例 (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[CauchyDistribution[a, 2], x], {a, {-2, 0, 3}}]//Evaluate, {x, -8, 8}, Filling -> Axis]

Wolfram Language code: PDF[CauchyDistribution[a, b], x]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[CauchyDistribution[a, 2], x], {a, {-2, 0, 3}}]//Evaluate, {x, -8, 8}, Filling -> Axis]

Wolfram Language code: CDF[CauchyDistribution[a, b], x]

柯西分布的均值和方差是不确定的:

Wolfram Language code: Mean[CauchyDistribution[a, b]]

Wolfram Language code: Variance[CauchyDistribution[a, b]]

中位数：

Wolfram Language code: Median[CauchyDistribution[a, b]]

范围 (6)

生成一个柯西分布的伪随机数的范例：

Wolfram Language code: data = RandomVariate[CauchyDistribution[3, 2.5], 10 ^ 4];

比较直方图和概率密度函数：

Wolfram Language code:

Show[Histogram[data, {-18, 20, 1}, PDF], Plot[PDF[TruncatedDistribution[{-18, 20}, CauchyDistribution[3, 2.5]], x], {x, -18, 20}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[CauchyDistribution[2, 3], 2 * 10 ^ 3];

从样本数据中估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, CauchyDistribution[a, b]]

比较样本的密度直方图和所估计分布的概率密度函数：

Wolfram Language code:

Show[Histogram[sample, {-10, 15, 1}, PDF], Plot[PDF[TruncatedDistribution[{-10, 15}, edist], x], {x, -10, 15}, PlotStyle -> Thick]]

高阶距是不确定的：

Wolfram Language code: Skewness[CauchyDistribution[a, b]]

Wolfram Language code: Kurtosis[CauchyDistribution[a, b]]

Wolfram Language code: Moment[CauchyDistribution[a, b], r]

风险函数：

Wolfram Language code: Plot[Table[HazardFunction[CauchyDistribution[a, 3], x], {a, {-5, 5, 10}}]//Evaluate, {x, -10, 20}, Filling -> Axis]

Wolfram Language code: Plot[Table[HazardFunction[CauchyDistribution[3, b], x], {b, {5, 10, 20}}]//Evaluate, {x, -10, 20}, Filling -> Axis]

Wolfram Language code: HazardFunction[CauchyDistribution[a, b], x]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[CauchyDistribution[a, 3.5], q], {a, {1, 10, 20}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Plot[Table[Quantile[CauchyDistribution[3.5, b], q], {b, {1, 10, 20}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[CauchyDistribution[a, b], q]

在参数中持续使用 Quantity 生成 QuantityDistribution：

Wolfram Language code: δλ𝒟 = CauchyDistribution[Quantity[0, "Nanometers"], Quantity[78, "Nanometers"]]

求四分位数：

Wolfram Language code: Quartiles[δλ𝒟]//N

应用 (1)

一个钟摆悬挂在距原点高处. 它与纵轴所成的角度在到之间均匀分布. 求该钟摆与纵轴的水平距离的分布 [MathWorld]：

Wolfram Language code: 𝒟 = TransformedDistribution[b Tan[θ], θUniformDistribution[{-π / 2, π / 2}]];

Wolfram Language code: PDF[𝒟, x]//FullSimplify[#, b > 0]&

如下所示，这是一个 CauchyDistribution：

Wolfram Language code: FullSimplify[% - PDF[CauchyDistribution[0, b], x], x ≠ 0]

求钟摆与纵轴之间的距离至少为的概率：

Wolfram Language code: Probability[x ≥ b / 2 || x ≤ -b / 2, xCauchyDistribution[0, b]]

Wolfram Language code: N[%]

假定，求在概率密度函数图形下方与此概率相等的面积：

Wolfram Language code: dist = CauchyDistribution[Quantity[0, "Centimeters"], Quantity[1, "Centimeters"]];

Wolfram Language code:

Plot[{PDF[dist, Quantity[x, "Centimeters"]], ConditionalExpression[PDF[dist, Quantity[x, "Centimeters"]], Abs[x] > 1 / 2]}, {x, -3, 3}, Filling -> {2 -> Axis}, AxesLabel -> {"cm"}]

属性和关系 (13)

柯西分布在平移和缩放一个正因子的情况下是闭合的：

Wolfram Language code: TransformedDistribution[k u + loc, u CauchyDistribution[a, b]]

使用任意参数：

Wolfram Language code: TransformedDistribution[k u + loc, u CauchyDistribution[a, b]]

在某些转换下，柯西分布是闭合的：

Wolfram Language code: 𝒟 = TransformedDistribution[2 u / (1 - u ^ 2), uCauchyDistribution[0, 1]];

Wolfram Language code: PDF[𝒟, x]//FullSimplify[#, x∈Reals]&

Wolfram Language code: PDF[CauchyDistribution[0, 1], x]

Wolfram Language code: FullSimplify[% - %%]

几个柯西分布的变量之和服从柯西分布：

Wolfram Language code: TransformedDistribution[u + v, {uCauchyDistribution[a1, b1], vCauchyDistribution[a2, b2]}]

基于特征函数的证明：

Wolfram Language code: CharacteristicFunction[CauchyDistribution[a1, b1], t]CharacteristicFunction[CauchyDistribution[a2, b2], t]

Wolfram Language code: CharacteristicFunction[CauchyDistribution[a1 + a2, b1 + b2], t]

Wolfram Language code: FullSimplify[% - %%]

中心在 0 的柯西分布的逆也是一个柯西分布：

Wolfram Language code: 𝒟 = TransformedDistribution[1 / u, uCauchyDistribution[0, b]];

Wolfram Language code: PDF[𝒟, x]

Wolfram Language code: PDF[CauchyDistribution[0, 1 / b], x]

Wolfram Language code: FullSimplify[% - %%, x ≠ 0]

与其它分布的关系：

当时，CauchyDistribution[0,1] 等价于 StudentTDistribution：

Wolfram Language code: PDF[CauchyDistribution[0, 1], x]

Wolfram Language code: PDF[StudentTDistribution[1], x]

Wolfram Language code: % - %%

两个正态分布变量的比率服从 CauchyDistribution：

Wolfram Language code: TransformedDistribution[u / v, {u, v}ProductDistribution[{NormalDistribution[], 2}]]

如果是均匀分布的，那么服从 CauchyDistribution：

Wolfram Language code: 𝒟 = TransformedDistribution[Tan[π (u - 1 / 2)], uUniformDistribution[{0, 1}]];

Wolfram Language code: PDF[𝒟, x]//PiecewiseExpand//FullSimplify[#, x∈Reals]&

Wolfram Language code: PDF[CauchyDistribution[0, 1], x]

Wolfram Language code: Simplify[% - %%]

柯西分布是第4类 PearsonDistribution 的一个极限情况：

Wolfram Language code: Limit[PDF[PearsonDistribution[4, 1, -a, (1 + ϵ/2), -a, (a^2 + b^2/2)], x], ϵ -> 0]//FullSimplify[#, b > 0]&

Wolfram Language code: PDF[CauchyDistribution[a, b], x]//FullSimplify[#, b > 0]&

Wolfram Language code: % - %%

CauchyDistribution 是第7类 PearsonDistribution 的一个特例：

Wolfram Language code: PDF[PearsonDistribution[7, 2, -2a, 1, -2a, a^2 + b^2], x]//FullSimplify[#, b > 0]&

Wolfram Language code: PDF[CauchyDistribution[a, b], x]//FullSimplify[#, b > 0]&

Wolfram Language code: %% - %//FullSimplify

柯西分布是一个 StableDistribution：

Wolfram Language code: PDF[CauchyDistribution[0, 1], x]

Wolfram Language code: PDF[StableDistribution[0, 1, 0, 0, 1], x]

Wolfram Language code: % - %%

在和的情况下，CauchyDistribution 是 HyperbolicDistribution 在时的一个奇异极限：

Wolfram Language code: Limit[PDF[HyperbolicDistribution[-1 / 2, α, 0, δ, μ], x], α -> 0]//FullSimplify

Wolfram Language code: PDF[CauchyDistribution[μ, δ], x]

Wolfram Language code: FullSimplify[% - %%]

CauchyDistribution 的 LogLikelihood 函数可能有多个局部最大值：

Wolfram Language code:

data = {-1, 3, 7, -11, 10 ^ 2};
llk[m_] := LogLikelihood[CauchyDistribution[m, 1], data];

求出似然函数的极值：

Wolfram Language code: roots = m /. N[Solve[llk'[m] == 0, m, Reals]]

选择似然函数的最大值，并求出相应的值：

Wolfram Language code: maxs = Select[roots, Function[m, llk''[m] < 0]]

Wolfram Language code: vals = llk /@ maxs

把似然函数可视化为一个定位参数的函数：

Wolfram Language code:

epilog = MapThread[{HalfLine[{#1, #2}, {0, -1}]}&, {maxs, vals}];
Plot[llk[m], {m, Min[maxs] - 2, Max[maxs] + 2}, Epilog -> {DotDashed, epilog}, PlotTheme -> "Detailed", Filling -> Axis]

可能存在的问题 (2)

当 a 是非实数时，CauchyDistribution 没有定义：

Wolfram Language code: Mean[CauchyDistribution[3 + I, 2]]

当 b 是非正数时，CauchyDistribution 没有定义：

Wolfram Language code: Mean[CauchyDistribution[0, -1]]

将无效参数代入符号式输出，结果没有意义：

Wolfram Language code: PDF[CauchyDistribution[a, b], x] /. {a -> I, b -> 3}

巧妙范例 (1)

在不同 a 值时，带有累积分布函数等值线的概率密度函数：

Wolfram Language code:

cdf = Function[{x, a}, Evaluate[CDF[CauchyDistribution[a, 2], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[CauchyDistribution[a, 2], x], {x, -10, 10}, {a, -2, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 35, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> {0, 0.16}], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

CauchyDistribution

更多信息

背景

范例

基本范例 (4)

范围 (6)

应用 (1)

属性和关系 (13)

可能存在的问题 (2)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

CauchyDistribution

更多信息

背景

范例

基本范例 (4)

范围 (6)

应用 (1)

属性和关系 (13)

可能存在的问题 (2)

巧妙范例 (1)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX