Wolfram 语言与系统参考资料中心

CensoredDistribution

CensoredDistribution[{x_min,x_max},dist]

表示的分布值来自于 dist，并且被删截为位于 x_min 和 x_max 之间.

CensoredDistribution[{{x_min,x_max},{y_min,y_max},…},dist]

表示的分布值来自于多变量分布 dist，并且被删截为位于 x_min 和 x_max、y_min 和 y_max 等之间.

背景

CensoredDistribution[{x_min,x_max},dist] 表示一个从区间内所有的单变量分布中提取的对数据建模的统计分布，并且对于总等于（相应的，对于总等于）. 术语未删截、左删截、右删截和双删截分别描述 {x_min,x_max} 是 {-∞,∞}、{x_min,∞}、{-∞,x_max} 和 {x_min,x_max} 形式的单变量删截，其中单变量 dist 可以是连续的（如 NormalDistribution、 GammaDistribution 或 BetaDistribution）或离散的（如 PoissonDistribution、 BinomialDistribution 或 BernoulliDistribution）并可以（分别通过 TransformedDistribution、 CensoredDistribution 和 TruncatedDistribution）作为已知分布的变形、删截或截断定义.
类似地，多变量的 CensoredDistribution[{{,},{,},… ,{,}},dist] 表示从多变量分布 dist 中提取的向量的分布，其中第个成分位于区间中. 正如单变量的情况，多变量 dist 可以使连续的（如 MultinormalDistribution）或离散的（ MultivariateHypergeometricDistribution），也可以（分别通过 CopulaDistribution 和 ProductDistribution）作为一只分布的耦合或乘积定义.
当对只知道部分数值的数据（即那些只含有部分观测或精度受限的数据的数据集）进行建模时可用删截分布，而对含有删截值的数据集的分析可以追溯到18世纪 Daniel Bernoulli 对天花的研究. 这样的数据在医药和心理学等领域中是比较普遍的，在不时需要未发现世纪故障时做出失效预测的可靠性和制造业中也相对普遍. 删截分布也是生存分析中的常用工具，以及为分析这样的数据集而存在的各种专业统计工具（如删失回归）.
根据定义， CensoredDistribution[{x_min,x_max},dist] 等价于 TransformedDistribution[f,xdist]，其中 f 由 Piecewise[{{x_min,x<=x_min},{x,x_min<x<x_max},{x_max,x>=x_max}}] 给出. CensoredDistribution 常与 TruncatedDistribution 混淆，但这两者有本质上的区别，删截将概率置于删截区间最后，而截尾将概率分布在截尾区间上.

范例

打开所有单元关闭所有单元

基本范例 (2)

定义一个左删截离散分布：

Wolfram Language code: 𝒟 = CensoredDistribution[{5, ∞}, 𝒹 = BinomialDistribution[10, .6]];

概率密度函数：

Wolfram Language code: DiscretePlot[{PDF[𝒹, x], PDF[𝒟, x]}//Evaluate, {x, 0, 12}, ExtentSize -> 1 / 2, PlotLegends -> {"𝒹", "𝒟"}]

定义一个右删截连续分布：

Wolfram Language code: 𝒟 = CensoredDistribution[{-∞, 2}, 𝒩 = NormalDistribution[1, 2]];

累积分布函数：

Wolfram Language code:

Plot[CDF[First[#], x]//Evaluate, {x, -4, 7}, Exclusions -> None, Filling -> Axis, PlotLabel -> Last[#]]& /@ {{𝒟, "𝒟"}, {𝒩, "𝒩"}}

范围 (26)

基本用途 (9)

为一元离散分布定义不同的删截类型：

Wolfram Language code:

LeftCensored𝒟 = CensoredDistribution[{5, ∞}, PoissonDistribution[7]];
RightCensored𝒟 = CensoredDistribution[{-∞, 9}, PoissonDistribution[7]];
DoubleCensored𝒟 = CensoredDistribution[{5, 9}, PoissonDistribution[7]];

Wolfram Language code:

Table[DiscretePlot[{PDF[m, x], PDF[PoissonDistribution[7], x]}//Evaluate, {x, 0, 13}, ExtentSize -> 0.5], {m, {LeftCensored𝒟, RightCensored𝒟, DoubleCensored𝒟}}]

为一元连续分布定义不同的删截类型：

Wolfram Language code:

LeftCensored𝒟 = CensoredDistribution[{-1, ∞}, NormalDistribution[]];
RightCensored𝒟 = CensoredDistribution[{-∞, 1}, NormalDistribution[]];
DoubleCensored𝒟 = CensoredDistribution[{-1, 1}, NormalDistribution[]];

Wolfram Language code:

Table[Plot[{CDF[m, x], CDF[NormalDistribution[], x]}, {x, -3, 3}, Filling -> Axis, Exclusions -> None], {m, {LeftCensored𝒟, RightCensored𝒟, DoubleCensored𝒟}}]

定义一个右删截离散分布：

Wolfram Language code: 𝒟 = CensoredDistribution[{0, 9}, 𝒹 = BinomialDistribution[12, .7]];

比较概率密度函数：

Wolfram Language code: DiscretePlot[{PDF[𝒹, x], PDF[𝒟, x]}, {x, 3, 13}, ExtentSize -> 1 / 2, PlotLegends -> {"𝒹", "𝒟"}]

求删截分布在9处的概率：

Wolfram Language code: PDF[𝒟, 9]

与原分布得到不小于9的值的概率比较：

Wolfram Language code: Probability[x ≥ 9, x𝒹]

对一个连续分布进行删截：

Wolfram Language code: 𝒟 = CensoredDistribution[{-1, ∞}, NormalDistribution[]];

Wolfram Language code: CDF[𝒟, x]

使用直方图并绘制原密度函数，以得到点概率的视图：

Wolfram Language code:

Show[Histogram[RandomVariate[𝒟, 10 ^ 3], {-3, 3, .2}, "PDF"], Plot[PDF[NormalDistribution[], x], {x, -3, 3}, PlotStyle -> Thick]]

在一点处删截的分布：

Wolfram Language code: 𝒟1 = CensoredDistribution[{2, 2}, BinomialDistribution[3, .4]];

Wolfram Language code: PDF[𝒟1, x]

Wolfram Language code: 𝒟2 = CensoredDistribution[{2, 2}, ParetoDistribution[1, 1 / 3]];

Wolfram Language code: CDF[𝒟2, x]

一个多元连续分布的删截：

Wolfram Language code: 𝒟 = CensoredDistribution[{{1 / 3, 1 / 2}, {2 / 5, 4 / 5}}, DirichletDistribution[{1, 3, 2}]];

计算该分布的一个表达式的期望：

Wolfram Language code: NExpectation[x ^ 2 + y, {x, y}𝒟]

一个多元离散分布的删截：

Wolfram Language code: 𝒟 = CensoredDistribution[{{2, 10}, {4, 12}, {3, 19}}, MultinomialDistribution[20, {1 / 3, 1 / 2, 1 / 6}]];

计算分布的均值：

Wolfram Language code: Mean[𝒟]//N

与从分布中随机抽样得到的结果进行比较：

Wolfram Language code: data = RandomVariate[𝒟, 10 ^ 4];

Wolfram Language code: Mean[data]//N

定义一个双删截分布：

Wolfram Language code: 𝒟 = CensoredDistribution[{1.2, 2}, 𝒹 = TriangularDistribution[{0, 4}]];

累积分布函数：

Wolfram Language code:

Plot[{CDF[𝒹, x], CDF[𝒟, x]}//Evaluate, {x, 0, 5 / 2}, PlotStyle -> {Automatic, Thick}, Filling -> {2 -> Axis}, Exclusions -> None, PlotLegends -> {"𝒹", "𝒟"}]

删截分布的均值与方差：

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

Moment 具有符号式阶数的解析式：

Wolfram Language code: Moment[𝒟, r]

估计删截区间：

Wolfram Language code: data = RandomVariate[CensoredDistribution[{2, 7}, PoissonDistribution[5]], 10 ^ 2];

Wolfram Language code: edist = EstimatedDistribution[data, CensoredDistribution[{a, b}, PoissonDistribution[5]]]

参数分布 (5)

定义一个右删截连续分布：

Wolfram Language code: 𝒟 = CensoredDistribution[{0, 1 / 2}, BetaDistribution[2, 3]];

累积分布函数：

Wolfram Language code: CDF[𝒟, x]

绘制随机样本的直方图. 尖峰对应于 PDF 的 DiracDelta 部分：

Wolfram Language code:

Show[Histogram[RandomVariate[𝒟, 10 ^ 3], Automatic, "PDF"], Plot[PDF[𝒟, x]//Evaluate, {x, 0, 1}, PlotStyle -> Thick, Exclusions -> None]]

定义一个删截的 GeometricDistribution：

Wolfram Language code: 𝒟 = CensoredDistribution[{2, 5}, 𝒹 = GeometricDistribution[.2]];

比较概率密度函数：

Wolfram Language code: DiscretePlot[{PDF[𝒹, x], PDF[𝒟, x]}//Evaluate, {x, 0, 10}, ExtentSize -> 1 / 2, PlotLegends -> {"𝒹", "𝒟"}]

Wolfram Language code: PDF[𝒟, x]

在删截点处的概率密度函数值等于下面的概率：

Wolfram Language code: {Probability[x ≤ 2, x𝒹], PDF[𝒟, 2]}

Wolfram Language code: {Probability[x ≥ 5, x𝒹], PDF[𝒟, 5]}

定义一个双删截 GammaDistribution：

Wolfram Language code: 𝒟 = CensoredDistribution[{2, 4}, GammaDistribution[2, 1]];

求母函数：

Wolfram Language code: CharacteristicFunction[𝒟, t]//FullSimplify

Wolfram Language code: MomentGeneratingFunction[𝒟, t]//FullSimplify

Wolfram Language code: CumulantGeneratingFunction[𝒟, t]//FullSimplify

Wolfram Language code: FactorialMomentGeneratingFunction[𝒟, t]//FullSimplify

定义一个右删截 PoissonDistribution：

Wolfram Language code: 𝒟 = CensoredDistribution[{-∞, 7}, 𝒫 = PoissonDistribution[5]];

比较 HazardFunction：

Wolfram Language code: DiscretePlot[{HazardFunction[𝒫, x], HazardFunction[𝒟, x]}, {x, 0, 9}, PlotRange -> All, ExtentSize -> 1 / 2]

定义一个二维删截 DirichletDistribution：

Wolfram Language code: 𝒟 = CensoredDistribution[{{1 / 3, 1 / 2}, {1 / 3, 3 / 5}}, 𝒹 = DirichletDistribution[{3, 2, 4}]];

比较累积分布函数：

Wolfram Language code:

Plot3D[CDF[#, {x, y}]//Evaluate, {x, -1 / 10, 3 / 4}, {y, -1 / 10, 4 / 5}, PlotRange -> All, AxesLabel -> Automatic, Exclusions -> None]&  /@ {𝒹, 𝒟}

删截分布的均值与方差：

Wolfram Language code: Mean[𝒟]

Wolfram Language code: Variance[𝒟]

计算概率与期望：

Wolfram Language code: NProbability[2 / 5 < x < 23 / 50 && y > 2 / 5, {x, y}𝒟]

Wolfram Language code: NExpectation[x ^ 3 + y ^ 3, {x, y}𝒟]

非参数分布 (3)

定义一个删截的 EmpiricalDistribution：

Wolfram Language code:

ed = EmpiricalDistribution[RandomVariate[WeibullDistribution[2, 3], 15]];
𝒟 = CensoredDistribution[{0, 2}, ed];

比较累积分布函数：

Wolfram Language code:

Plot[{CDF[ed, x], CDF[𝒟, x]}, {x, 0, 6}, Filling -> Axis, PlotStyle -> {Automatic, Thick}, Exclusions -> None, PlotLegends -> {"ed", "𝒟"}]

定义一个删截的 HistogramDistribution：

Wolfram Language code:

hd = HistogramDistribution[RandomVariate[PoissonDistribution[6], 10 ^ 3]];
𝒟 = CensoredDistribution[{0, 6}, hd];

比较累积分布函数：

Wolfram Language code:

Plot[{CDF[hd, x], CDF[𝒟, x]}, {x, 0, 12}, Filling -> Axis, Exclusions -> None, PlotStyle -> {Automatic, Thick}, PlotLegends -> {"hd", "𝒟"}]

定义一个删截的 SmoothKernelDistribution：

Wolfram Language code:

skd = SmoothKernelDistribution[RandomVariate[LaplaceDistribution[0, 2], 10 ^ 3]];
𝒟 = CensoredDistribution[{-1, 1}, skd];

比较累积分布函数：

Wolfram Language code:

Plot[{CDF[skd, x], CDF[𝒟, x]}, {x, -3, 3}, Filling -> Axis, PlotStyle -> {Automatic, Thick}, Exclusions -> None, PlotLegends -> {"skd", "𝒟"}]

导出分布 (9)

定义一个删截 ParameterMixtureDistribution：

Wolfram Language code:

ℳ = ParameterMixtureDistribution[GammaDistribution[1 / 2, β], βUniformDistribution[{1, 2}]];
𝒟 = CensoredDistribution[{0, 1}, ℳ];

累积分布函数：

Wolfram Language code: CDF[𝒟, x]

Wolfram Language code:

Plot[CDF[First[#], x]//Evaluate, {x, 0, 2}, Filling -> Axis, Exclusions -> None, PlotLabel -> Last[#]]& /@ {{ℳ, "ℳ"}, {𝒟, "𝒟"}}

定义一个删截 MixtureDistribution：

Wolfram Language code:

ℳ = MixtureDistribution[{1, 2}, {NormalDistribution[-1, 3], NormalDistribution[1, 2]}];
𝒟 = CensoredDistribution[{-2, 2}, ℳ];

累积分布函数：

Wolfram Language code: CDF[𝒟, x]

Wolfram Language code:

Plot[Evaluate[CDF[First[#], x]], {x, -3, 3}, Filling -> Axis, Exclusions -> None, PlotLabel -> Last[#]]& /@ {{ℳ, "ℳ"}, {𝒟, "𝒟"}}

定义一个删截 OrderDistribution：

Wolfram Language code:

𝒫 = OrderDistribution[{BinomialDistribution[10, 0.6], 4}, 1];
𝒟 = CensoredDistribution[{4, ∞}, 𝒫];

概率密度函数：

Wolfram Language code: DiscretePlot[{PDF[𝒫, x], PDF[𝒟, x]}, {x, 0, 10}, ExtentSize -> 1 / 2, PlotLegends -> {"𝒫", "𝒟"}]

比较均值：

Wolfram Language code: {Mean[𝒟], Mean[𝒫]}

定义一个删截 CensoredDistribution：

Wolfram Language code:

𝒞 = CensoredDistribution[{-∞, 9}, 𝒫 = PoissonDistribution[7]];
𝒟 = CensoredDistribution[{6, ∞}, 𝒞];

概率密度函数：

Wolfram Language code:

DiscretePlot[Evaluate[PDF[First[#], x]], {x, 0, 15}, ExtentSize -> 1 / 2, PlotLabel -> Last[#]]& /@ {{𝒫, "𝒫"}, {𝒞, "𝒞"}, {𝒟, "𝒟"}}

Wolfram Language code: PDF[𝒟, x]

与双删截泊松分布比较：

Wolfram Language code: PDF[CensoredDistribution[{6, 9}, PoissonDistribution[7]], x]

Wolfram Language code: % - %%

定义一个删截 TruncatedDistribution：

Wolfram Language code:

𝒯 = TruncatedDistribution[{-∞, 1}, 𝒩 = NormalDistribution[0, 2]];
𝒟 = CensoredDistribution[{-1, ∞}, 𝒯];

比较累积分布函数：

Wolfram Language code:

Plot[Evaluate[CDF[First[#], x]], {x, -3, 3}, Filling -> Axis, Exclusions -> None, PlotLabel -> Last[#]]& /@ {{𝒩, "𝒩"}, {𝒯, "𝒯"}, {𝒟, "𝒟"}}

定义一个删截 TransformedDistribution：

Wolfram Language code:

𝒯 = TransformedDistribution[u + 1, uBenfordDistribution[10]];
𝒟 = CensoredDistribution[{3, 6}, 𝒯];

累积分布函数：

Wolfram Language code: CDF[𝒟, x]

定义一个删截 MarginalDistribution：

Wolfram Language code:

ℳ = MarginalDistribution[NegativeMultinomialDistribution[3, {1 / 3, 1 / 3, 1 / 6}], 1];
𝒟 = CensoredDistribution[{3, 10}, ℳ];

概率密度函数：

Wolfram Language code: pdf = PDF[𝒟, x]

与边缘分布的概率密度函数比较：

Wolfram Language code: DiscretePlot[{PDF[ℳ, x], pdf}, {x, 0, 15}, ExtentSize -> 1 / 2, PlotLegends -> {"ℳ", "𝒟"}]

定义一个删截 ProductDistribution：

Wolfram Language code:

𝒫 = ProductDistribution[PoissonDistribution[8], PoissonDistribution[9]];
𝒟 = CensoredDistribution[{{-∞, 12}, {5, ∞}}, 𝒫];

利用随机样本制作密度函数的视图：

Wolfram Language code: Histogram3D[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"]

QuantityDistribution 的删截估值为 QuantityDistribution：

Wolfram Language code:

𝒟 = CensoredDistribution[{-∞, Quantity[75, "Miles"/"Hours"]}, QuantityDistribution[NormalDistribution[70, 8], "mph"]]

计算平均速度：

Wolfram Language code: Mean[𝒟]//N

应用 (4)

一家保险公司在留用水平处购买再保险. 假定索赔服从对数正态分布，求保险公司支付额随机变量的矩：

Wolfram Language code: Refine[Moment[CensoredDistribution[{0, M}, LogNormalDistribution[μ, σ]], n], M > 0 && σ > 0]

求再保险公司支付随机变量的矩：

Wolfram Language code: Refine[Moment[CensoredDistribution[{M, Infinity}, LogNormalDistribution[μ, σ]], n], M > 0 && σ > 0]

一个组件的生命期服从 RayleighDistribution. 使用小时时间，对组件进行检测，如果在这段时间内组件没有失效，那么假定这个组件的生命期恰好是小时. 求满足至少有 5% 的被检测组件的生命期长于的条件下，检测的时间长度：

Wolfram Language code: component𝒟 = RayleighDistribution[Quantity[3, "Hours"]]

Wolfram Language code: Solve[CDF[component𝒟, n] == 95 / 100, n]

Wolfram Language code: N[%]

对于，求检测的生命期分布：

Wolfram Language code: test𝒟 = CensoredDistribution[{Quantity[0, "Hours"], Quantity[7.35, "Hours"]}, component𝒟];

比较删截分布与实际生命期分布：

Wolfram Language code:

Plot[{CDF[component𝒟, Quantity[x, "Hours"]], CDF[test𝒟, Quantity[x, "Hours"]]}, {x, 0, 10}, Filling -> 1 -> {2}, Epilog -> {Dashed, Line[{{7.35, 0}, {7.35, 1}}]}, PlotLegends -> {"component𝒟", "test𝒟"}, AxesLabel -> {"h"}]

比较平均生命期：

Wolfram Language code: Mean /@ {component𝒟, test𝒟}//N

一名高尔夫初学者要使球进入一个四杆洞所需的击球次数服从均值为 8 的一个 PoissonDistribution 分布. 假定在这个高尔夫球场上，在第10次击球后，这名选手就把球捡起来，求在一个四杆洞中球入洞次数的分布：

Wolfram Language code: 𝒟 = TransformedDistribution[u + 1, uCensoredDistribution[{0, 9}, PoissonDistribution[8]]];

概率密度函数：

Wolfram Language code: DiscretePlot[Evaluate[PDF[𝒟, x]], {x, 0, 11}, ExtentSize -> 1 / 2]

Wolfram Language code: PDF[𝒟, x]

在高尔夫球场内，一个4杆洞所需的平均击球次数：

Wolfram Language code: Mean[𝒟]//N

求要使球入洞，这名选手需要的击球次数超过4次的概率：

Wolfram Language code: NProbability[x > 4, x𝒟]

美国成年男性的体重服从均值为 191 磅、标准差为 70 磅的正态分布. 假定每个浴室磅秤的上限为 300 磅，求当使用普通浴室磅秤测量时得到的体重分布：

Wolfram Language code:

𝒟 = CensoredDistribution[{Quantity[0, "Pounds"], Quantity[300, "Pounds"]}, 𝒹 = NormalDistribution[Quantity[191, "Pounds"], Quantity[70, "Pounds"]]];

累积分布函数：

Wolfram Language code: Plot[Evaluate[CDF[𝒟, Quantity[x, "Pounds"]]], {x, 0, 350}, Filling -> Axis, Exclusions -> None, AxesLabel -> {"lbs"}]

利用一个随机样本，将密度函数可视化表示：

Wolfram Language code: Histogram[RandomVariate[𝒟, 10 ^ 5], Automatic, "PDF", AxesLabel -> Automatic]

求平均体重：

Wolfram Language code: Mean[𝒟]//N

求体重至少为 200 磅的概率：

Wolfram Language code: NProbability[x ≥ Quantity[200, "Pounds"], x𝒟]

求体重恰好位于磅秤上限或者高于这个上限的概率：

Wolfram Language code: Probability[x ≥ Quantity[300, "Pounds"], x𝒟]//N

与未删截分布进行比较：

Wolfram Language code: Probability[x ≥ Quantity[300, "Pounds"], x𝒹]//N

属性和关系 (4)

CensoredDistribution 是 TransformedDistribution 的一种特殊情况：

Wolfram Language code:

𝒟1 = CensoredDistribution[{2, 3}, NormalDistribution[]];
𝒟2 = TransformedDistribution[Piecewise[{{2, u ≤ 2}, {u, 2 ≤ u ≤ 3}, {3, u > 3}}], uNormalDistribution[]];

Wolfram Language code: CDF[𝒟1, x]

Wolfram Language code: CDF[𝒟2, x]

Wolfram Language code: % - %%//FullSimplify

对于一个离散分布，比较删截与截断：

Wolfram Language code:

𝒞 = CensoredDistribution[{4, 9}, 𝒫 = PoissonDistribution[7]];
𝒯 = TruncatedDistribution[{4, 9}, 𝒫];

在删截的情况下，来自外部的权值位于删截区间的两端：

Wolfram Language code: DiscretePlot[{PDF[𝒫, x], PDF[𝒞, x]}, {x, 0, 12}, ExtentSize -> 1 / 2, PlotLegends -> {"𝒫", "𝒞"}]

在截断的情况下，来自外部的权重在截断区间中均匀分布：

Wolfram Language code: DiscretePlot[{PDF[𝒫, x], PDF[𝒯, x]}, {x, 0, 12}, ExtentSize -> 1 / 2, PlotLegends -> {"𝒫", "𝒯"}]

对于一个连续分布，比较删截与截断：

Wolfram Language code:

𝒞 = CensoredDistribution[{1 / 2, ∞}, 𝒩 = NormalDistribution[0, 1 / 2]];
𝒯 = TruncatedDistribution[{1 / 2, ∞}, 𝒩];

在删截的情况下，概率位于删截区间的一端：

Wolfram Language code: Plot[{CDF[𝒩, x], CDF[𝒞, x]}, {x, -2, 3}, Filling -> Axis, PlotLegends -> {"𝒩", "𝒞"}]

在截断的情况下，概率分布在截断区间上：

Wolfram Language code: Plot[{CDF[𝒩, x], CDF[𝒯, x]}, {x, -2, 3}, Filling -> Axis, PlotLegends -> {"𝒩", "𝒯"}]

一个连续分布的删截可能会导致一个既不连续又不离散的混合分布：

Wolfram Language code:

cont𝒟 = LogisticDistribution[];
cens𝒟 = CensoredDistribution[{-1, 1}, cont𝒟]

该混合型删截分布的 CDF 在删截点不连续：

Wolfram Language code: cdf = CDF[cens𝒟, x]

可视化该累积分布函数：

Wolfram Language code:

ticks = {{-1, -0.5, 0, 0.5, 1}, {0, {CDF[cont𝒟, -1], HoldForm[F[-1 + ϵ]]}, 0.5, {CDF[cont𝒟, 1], HoldForm[F[1 - ϵ]]}, 1}};
Plot[{cdf, Style[CDF[cont𝒟, x], DotDashed]}, {x, -1.75, 1.75}, Ticks -> ticks, ExclusionsStyle -> {Directive[Dotted, Red], PointSize[Medium]}, PlotLegends -> {"censored 𝒟", "underlying continuous 𝒟"}]

删截分布的概率密度函数没有定义， PDF 返回未估值：

Wolfram Language code: PDF[cens𝒟, x]

CDF 的微分结果是一个不能积分成 1 的函数：

Wolfram Language code: D[cdf, x]

Wolfram Language code: NIntegrate[D[cdf, x], {x, -∞, ∞}]

概率密度估计函数样本在样本量增大时不收敛：

Wolfram Language code:

Table[Labeled[Histogram[RandomVariate[cens𝒟, 10 ^ k], "Scott", "PDF", ImageSize -> Small], Row[{Text@"Sample size", ":", HoldForm[10] ^ k//TraditionalForm}]], {k, {3, 6}}]

将其与潜在连续分布的直方图比较，估计函数收敛：

Wolfram Language code:

Table[Labeled[Histogram[RandomVariate[cont𝒟, 10 ^ k], "Scott", "PDF", ImageSize -> Small], Row[{Text@"Sample size", ":", HoldForm[10] ^ k//TraditionalForm}]], {k, {3, 6}}]

可能存在的问题 (1)

连续分布的删截可能导致一个既不连续又不离散的混合分布：

Wolfram Language code:

cont𝒟 = NormalDistribution[];
cens𝒟 = CensoredDistribution[{-1, 1}, cont𝒟]

该混合型删截分布的 PDF 无定义： »

Wolfram Language code: PDF[cens𝒟, x]

完全支持混合型分布的计算. 计算特殊矩：

Wolfram Language code: {Mean[cens𝒟], Variance[cens𝒟], Skewness[cens𝒟], Kurtosis[cens𝒟]}

估计一个删截分布：

Wolfram Language code: sample = RandomVariate[cens𝒟, 10 ^ 4];

Wolfram Language code: EstimatedDistribution[sample, CensoredDistribution[{min, max}, NormalDistribution[μ, σ]]]

混合型分布可以理解为连续分布和离散分部的混合：

Wolfram Language code: ProbabilityDistribution[{CDF, CDF[cens𝒟, x]}, {x, -Infinity, Infinity}]//FullSimplify

Top

	{-∞,x_max}	从上端删截，右删截
	{x_min,∞}	从下端删截，左删截
	{x_min,x_max}	双面删截，区间删截
	{-∞,∞},None	无删截

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

CensoredDistribution

更多信息

背景

范例

基本范例 (2)

范围 (26)

基本用途 (9)

参数分布 (5)

非参数分布 (3)

导出分布 (9)

应用 (4)

属性和关系 (4)

可能存在的问题 (1)

文本

CMS

APA

BibTeX

BibLaTeX

CensoredDistribution

更多信息

背景

范例

基本范例 (2)

范围 (26)

基本用途 (9)

参数分布 (5)

非参数分布 (3)

导出分布 (9)

应用 (4)

属性和关系 (4)

可能存在的问题 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX