WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CompoundPoissonDistribution[λ,dist]

比率の母数が λ でジャンプサイズ分布 dist の複合ポアソン(Poisson)分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

CompoundPoissonDistribution

CompoundPoissonDistribution[λ,dist]

比率の母数が λ でジャンプサイズ分布 dist の複合ポアソン(Poisson)分布を表す．

詳細

予備知識

  • CompoundPoissonDistribution[λ,dist]は，正の実数 λ と一変量分布 dist（連続分布でも離散分布でもよい）によってパラメータ化された離散統計分布を表す．複合ポアソン分布は，独立同分布に従う 個の確率変数 の和をモデル化する．ただし，すべての について Xidistであり，NPoissonDistribution[λ]である．母数 λ および dist は，形，高さ，位置，領域を含む，複合ポアソン分布の確率密度関数(PDF)が有するすべての特性を決定する．複合ポアソン分布は，ポアソン中断和，一般化されたポアソン分布，多重ポアソン分布，合成ポアソン分布，断続ポアソン分布，クラスタポアソン分布，Pollaczek–Geiringer分布，ポアソンベキ級数分布等，他のさまざまな名称で参照されることがある．
  • 複合ポアソン過程の研究は，Pollaczek–Geiringer分布の名称で，1930年代から行われている．複合ポアソン分布は，その初期には，事故，疾病，自殺を含む「稀な出来事」の統計動作のモデル化のためのツールとして考案された．確率過程の研究内で，複合ポアソン分布は，いわゆるベルヌーイ過程の開発動機ともなっている．ベルヌーイ過程は，大きさが指定された分布に従ってランダムに分布しているジャンプを持つ連続時間確率過程で，ジャンプはポアソン分布に従って現れる．より近年では，複合ポアソン分布のような中断和分布を使って，保険請求のタイプや頻度，降雨の頻度や量等を含むさまざまな現象のモデル化が行われている．
  • RandomVariateを使って，複合ポアソン分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,CompoundPoissonDistribution[λ,dist]]（より簡略すると xCompoundPoissonDistribution[λ,dist] ）を使って，確率変数 x が複合ポアソン分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[CompoundPoissonDistribution[λ,dist],x] およびCDF[CompoundPoissonDistribution[λ,dist],x]を使って得られることがある．しかし，PDF（およびHazardFunctionやLikelihood等のPDF関連の数量）は，dist が連続分布の場合は定義されない．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができ，離散あるいは連続の dist のついて定義される．
  • DistributionFitTestを使って，与えられたデータ集合が複合ポアソン分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリック複合ポアソン分布を推定することが，FindDistributionParametersを使ってデータを複合ポアソン分布にフィットすることができる．ProbabilityPlotを使って記号複合ポアソン分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号複合ポアソン分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換された複合ポアソン分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使って複合ポアソン分布を含む高次元分布を構築することが，ProductDistributionを使って複合ポアソン分布を含む独立成分分布の結合分布を計算することができる．
  • CompoundPoissonDistributionは他の数多くの統計分布および構造と関連している．CompoundPoissonDistributionはPoissonDistributionを一般化したものである．母数 dist が任意の一変量分布を取れるため，CompoundPoissonDistributionとWolfram言語に含まれるすべての一変量分布との間には，包括的な関係がある．より具体的な意味で，CompoundPoissonDistributionは，CompoundPoissonProcess[λ,dist][t]を簡約するとCompoundPoissonDistribution[t λ,dist]になるという意味で，CompoundPoissonProcessのスライス分布である．さらに，Wolfram言語内のいくつかの分布は，dist のさまざまな値についてCompoundPoissonDistribution[λ,dist]から導くことができる．例として，BinomialDistribution（dist がBernoulliDistributionのとき），NegativeBinomialDistribution（dist がLogSeriesDistributionのとき）等が挙げられる．

例題

すべて開く すべて閉じる

例  (2)

複合ポアソン分布を定義する：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[λ, PascalDistribution[n, p]];

平均と分散：

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}//Simplify

複合ポアソン分布のシミュレーションを行う：

Wolfram Language code: data = RandomVariate[CompoundPoissonDistribution[4.4, ExponentialDistribution[2]], 10 ^ 4];
Wolfram Language code: Histogram[data, 30, "PDF"]

スコープ  (7)

さまざまな更新率で複合ポアソン分布のシミュレーションを行う：

Wolfram Language code: data = Table[RandomVariate[CompoundPoissonDistribution[λ, WeibullDistribution[2, 3]], 10 ^ 4], {λ, {1, 4, 10}}];
Wolfram Language code: Histogram[data, 30, "PDF"]

分布母数推定：

Wolfram Language code: data = RandomVariate[CompoundPoissonDistribution[4.4, ExponentialDistribution[2]], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[data, CompoundPoissonDistribution[λ, ExponentialDistribution[m]], ParameterEstimator -> "MethodOfMoments"]

データのヒストグラムを推定分布からのサンプルと比べる：

Wolfram Language code: Show[Histogram[{data, RandomVariate[edist, 10 ^ 3]}, 30, "PDF"]]

複合ポアソン分布を定義する：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[λ, GammaDistribution[a, b]];

歪度：

Wolfram Language code: Skewness[𝒟]//Simplify

尖度：

Wolfram Language code: Kurtosis[𝒟]

複合ポアソン分布を定義する：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[λ, rdist = NormalDistribution[μ, σ]];

キュムラントを計算する：

Wolfram Language code: Table[Cumulant[𝒟, r], {r, 0, 5}]

報酬分布と比較する：

Wolfram Language code: Table[Cumulant[rdist, r], {r, 0, 5}]

更新分布と比較する：

Wolfram Language code: Table[Cumulant[PoissonDistribution[λ], r], {r, 0, 5}]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]
Wolfram Language code: 𝒟 = CompoundPoissonDistribution[λ, BernoulliDistribution[p]];

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[𝒟, k], {k, 5}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[𝒟, k], {k, 5}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[𝒟, k], {k, 5}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[𝒟, k], {k, 5}], C]

CompoundPoissonDistributionの母関数：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[3, NormalDistribution[]];

特性関数：

Wolfram Language code: CharacteristicFunction[𝒟, t]

モーメント母関数：

Wolfram Language code: MomentGeneratingFunction[𝒟, t]

階乗モーメント母関数：

Wolfram Language code: FactorialMomentGeneratingFunction[𝒟, t]

キュムラント母関数：

Wolfram Language code: CumulantGeneratingFunction[𝒟, t]

混合ジャンプ分布を持つ複合ポアソン分布：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[25, MixtureDistribution[{10, 15}, {ExponentialDistribution[1], GammaDistribution[2, 1]}]];

分布の平均：

Wolfram Language code: Mean[𝒟]

シミュレーションで得られた値と比較する：

Wolfram Language code: Mean[RandomVariate[𝒟, 10 ^ 4]]

アプリケーション  (2)

改装オープンした商店を訪れる顧客数は1時間に20人の割合でポアソン過程に従う．商店はこのイベントを販売促進に利用し，来店者全員に記念品を渡した．記念品の価値は，形状母数が10，尺度母数が3でワイブル分布に従う．改装オープン当日の開店時間12時間で渡された記念品にかかる費用総額の期待値を求める：

Wolfram Language code: giftDistribution = CompoundPoissonDistribution[20 * 12, WeibullDistribution[10, 3]];

改装オープン当日に送られた記念品にかかる費用総額の期待値：

Wolfram Language code: Mean[giftDistribution]//N

店が記念品に500ドルから800ドルまで費やした確率：

Wolfram Language code: gifts = RandomVariate[giftDistribution, 10 ^ 4];
Wolfram Language code: Histogram[gifts, {400, 900, 25}, "PDF"]
Wolfram Language code: Probability[500 < p < 800, pgifts]//N

リスクからの支払い請求総計は，ポアソン母数200の複合ポアソン分布と，個々の請求額の分布（最小値母数300，形状母数3，位置母数0のパレート分布）に従う．保険者は損害再保険の超過分を保持レベル300ドルで発効させた．再保険会社の請求総額の平均と分散を計算する．再保険会社は300ドルを超えた額のみを支払うので，再保険会社への個別の請求は変形パレート分布に従う：

Wolfram Language code: individualClaimDistribution = TransformedDistribution[Max[0, x - 300], xParetoDistribution[300, 3, 0]];

請求総額：

Wolfram Language code: aggregateClaimDistribution = CompoundPoissonDistribution[200, individualClaimDistribution];
Wolfram Language code: Histogram[RandomVariate[aggregateClaimDistribution, 10 ^ 4], {0, 20000, 1000}, "PDF"]

再保険社の請求総額の平均と分散：

Wolfram Language code: {Mean[aggregateClaimDistribution], Variance[aggregateClaimDistribution]}

特性と関係  (5)

CompoundPoissonDistributionはCompoundPoissonProcessのスライス分布である：

Wolfram Language code: CompoundPoissonProcess[λ, WeibullDistribution[a, b]][t]

BernoulliDistributionのCompoundPoissonDistributionはPoissonDistributionである：

Wolfram Language code: CompoundPoissonDistribution[μ, BernoulliDistribution[p]]

特殊BorelTannerDistributionのCompoundPoissonDistributionはPoissonConsulDistributionに従う：

Wolfram Language code: dist = CompoundPoissonDistribution[μ, BorelTannerDistribution[α, 1]];

Borel–Tanner分布の変数の和はBorel–Tanner分布に従うので，スライス分布はパラメータ混合分布に等しい：

Wolfram Language code: pdm = ParameterMixtureDistribution[BorelTannerDistribution[α, n], n  PoissonDistribution[μ]]

特性分布を比較する：

Wolfram Language code: CharacteristicFunction[dist, x] / CharacteristicFunction[pdm, x]//Simplify

更新率は尖度に影響する：

Wolfram Language code: 𝒟[λ_] = CompoundPoissonDistribution[λ, NormalDistribution[]];
Wolfram Language code: data = Table[RandomVariate[𝒟[λ], 10 ^ 3], {λ, {1, 3, 9}}];
Wolfram Language code: Histogram[#, 20, "PDF"]& /@ data
Wolfram Language code: Kurtosis /@ data

別の報酬分布を使う：

Wolfram Language code: 𝒹[λ_] = CompoundPoissonDistribution[λ, ExponentialDistribution[3]];
Wolfram Language code: sample = Table[RandomVariate[𝒹[λ], 10 ^ 3], {λ, {1, 3, 9}}];
Wolfram Language code: Histogram[#, 20, "PDF"]& /@ sample
Wolfram Language code: Kurtosis /@ sample

更新時がExponentialDistributionで与えられるCompoundRenewalProcessのスライス：

Wolfram Language code: dist[λ_, t_] := CompoundRenewalProcess[ExponentialDistribution[λ], NormalDistribution[]][t];

割合3で7におけるスライスについてのランダムなサンプルを作る：

Wolfram Language code: SeedRandom[4728]; sample1 = RandomVariate[dist[3, 7], 10 ^ 4];
Wolfram Language code: Histogram[sample1, 30, "PDF"]

対応するCompoundPoissonDistributionのサンプルと比較する：

Wolfram Language code: SeedRandom[4728]; sample2 = RandomVariate[CompoundPoissonDistribution[3 * 7, NormalDistribution[]], 10 ^ 4];
Wolfram Language code: Histogram[{sample1, sample2}, 30, "PDF"]

考えられる問題  (1)

最尤度を使ったデフォルトの母数推定には時間がかかることがある：

Wolfram Language code: data = RandomVariate[CompoundPoissonDistribution[4.4, GammaDistribution[4, 2]], 10 ^ 3];
Wolfram Language code: TimeConstrained[EstimatedDistribution[data, CompoundPoissonDistribution[λ, GammaDistribution[a, m]]], 10, $TimedOut]

別のメソッドを使う：

Wolfram Language code: EstimatedDistribution[data, CompoundPoissonDistribution[λ, GammaDistribution[a, m]], ParameterEstimator -> "MethodOfMoments"]//AbsoluteTiming
Wolfram Research (2012), CompoundPoissonDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/CompoundPoissonDistribution.html.

テキスト

Wolfram Research (2012), CompoundPoissonDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/CompoundPoissonDistribution.html.

CMS

Wolfram Language. 2012. "CompoundPoissonDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CompoundPoissonDistribution.html.

APA

Wolfram Language. (2012). CompoundPoissonDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CompoundPoissonDistribution.html

BibTeX

@misc{reference.wolfram_2026_compoundpoissondistribution, author="Wolfram Research", title="{CompoundPoissonDistribution}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CompoundPoissonDistribution.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_compoundpoissondistribution, organization={Wolfram Research}, title={CompoundPoissonDistribution}, year={2012}, url={https://reference.wolfram.com/language/ref/CompoundPoissonDistribution.html}, note=[Accessed: 09-August-2026]}