Wolfram 语言与系统参考资料中心

CompoundPoissonDistribution

CompoundPoissonDistribution[λ,dist]

表示复合泊松分布，其中速率参数为 λ，跳跃尺寸分布为 dist.

背景

CompoundPoissonDistribution[λ,dist] 表示一个离散统计分布，参数为正实数 λ 和单变量分布 dist，后者既可以是离散的，也可以是连续的. 复合泊松分布模拟的是个独立和同分布的随机变量的和，其中，对于所有的，有 X_idist，同时，NPoissonDistribution[λ]. 参数 λ 和 dist 决定了复合泊松分布的概率密度函数（PDF）所拥有的全部特性，包括形状、高度、位置和分布域. 复合泊松分布有其它几种名称，包括 Poisson-停时和、广义泊松分布、多重泊松分布、组合泊松分布、不连贯泊松分布、群集泊松分布、Pollaczek–Geiringer 分布以及泊松幂级数分布.
对复合泊松过程（当时名为 Pollaczek–Geiringer 分布）的研究可回溯至二十世纪三十年代. 在诞生之初，复合泊松分布被设计作为一种工具，用来模拟统计行为中的“稀有事件”，包括事故、疾病和自杀事件. 在随机过程的研究中，研究所谓的 Bernoulli 过程背后的动机也是复合泊松分布，Bernoulli 过程是一个有跳跃的连续时间随机过程，跳跃的大小随机服从指定的分布，跳跃到达的时间服从泊松过程. 最近，诸如复合泊松分布的停时和分布被用于对多种现象建模，包括保险索赔案件的类型/频次、降雨量或降雨频次.
RandomVariate 可用来给出一个或更多机器精度或任意精度（后者可通过设置 WorkingPrecision 选项获得）的复合泊松分布中的伪随机变数. Distributed[x,CompoundPoissonDistribution[λ,dist]]，更简洁的式子为 xCompoundPoissonDistribution[λ,dist] ，可用来断定随机变量 x 服从复合泊松分布. 它也可以被用在诸如 Probability、NProbability、Expectation 和 NExpectation 这样的函数中.
尽管当 dist 为连续分布时，PDF（以及“与 PDF 相关”的量，比如 HazardFunction 和 Likelihood）没有定义，依然可以通过使用 PDF[CompoundPoissonDistribution[λ,dist],x] 和 CDF[CompoundPoissonDistribution[λ,dist],x]，可以得到复合泊松分布的概率密度和累积分布函数. 可以用 Mean、Median、Variance、Moment 和 CentralMoment 来分别计算均值、中位数、方差、原始矩和中心矩. 不管 dist 是连续的或是离散的，这些量都有定义.
可以用 DistributionFitTest 来检测一个数据集是否符合复合泊松分布，根据给定数据，用 EstimatedDistribution 来估计参数化复合泊松分布，而 FindDistributionParameters 则可用来将数据拟合成复合泊松分布. 用 ProbabilityPlot 指令可以产生给定数据的 CDF 与符号式复合泊松分布的 CDF 的比较图，QuantilePlot 则能绘制给定数据的分位数和符号式复合泊松分布的分位数的比较图.
可以用 TransformedDistribution 来表示转换过的复合泊松分布，用 CensoredDistribution 表示截尾后位于上限和下限值之间的数据的分布，而 TruncatedDistribution 则表示删失后位于上限和下限值之间的数据的分布. CopulaDistribution 可用来构建包含复合泊松分布的高维分布，ProductDistribution 可以计算由独立分布为复合泊松分布所得的联合分布.
CompoundPoissonDistribution 与许多其它分布和构建有密切的关系. CompoundPoissonDistribution 是广义化的 PoissonDistribution，因为参数 dist 可以采用任意单变量分布的优势，CompoundPoissonDistribution 和 Wolfram 语言中所有单变量分布都有关系. 更具体的说，CompoundPoissonDistribution 是 CompoundPoissonProcess 的切片分布，因为 CompoundPoissonProcess[λ,dist][t] 简化后就是 CompoundPoissonDistribution[t λ,dist]. 此外，通过不同的 dist 值，Wolfram 语言中的几个分布可由 CompoundPoissonDistribution[λ,dist] 导出，例如，BinomialDistribution（当 dist 为 BernoulliDistribution 时）和 NegativeBinomialDistribution（当 dist 为 LogSeriesDistribution 时）.

范例

打开所有单元关闭所有单元

基本范例 (2)

定义一个复合泊松分布：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[λ, PascalDistribution[n, p]];

均值和方差：

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}//Simplify

模拟一个复合泊松分布：

Wolfram Language code: data = RandomVariate[CompoundPoissonDistribution[4.4, ExponentialDistribution[2]], 10 ^ 4];

Wolfram Language code: Histogram[data, 30, "PDF"]

范围 (7)

对不同更新率，模拟复合泊松分布：

Wolfram Language code: data = Table[RandomVariate[CompoundPoissonDistribution[λ, WeibullDistribution[2, 3]], 10 ^ 4], {λ, {1, 4, 10}}];

Wolfram Language code: Histogram[data, 30, "PDF"]

分布参数估计：

Wolfram Language code: data = RandomVariate[CompoundPoissonDistribution[4.4, ExponentialDistribution[2]], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code:

edist = EstimatedDistribution[data, CompoundPoissonDistribution[λ, ExponentialDistribution[m]], ParameterEstimator -> "MethodOfMoments"]

比较数据直方图和估计分布的样本：

Wolfram Language code: Show[Histogram[{data, RandomVariate[edist, 10 ^ 3]}, 30, "PDF"]]

定义一个复合泊松分布：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[λ, GammaDistribution[a, b]];

偏度：

Wolfram Language code: Skewness[𝒟]//Simplify

峰度：

Wolfram Language code: Kurtosis[𝒟]

定义一个复合泊松分布：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[λ, rdist = NormalDistribution[μ, σ]];

计算累积量：

Wolfram Language code: Table[Cumulant[𝒟, r], {r, 0, 5}]

与奖励分布（reward distribution）比较：

Wolfram Language code: Table[Cumulant[rdist, r], {r, 0, 5}]

与更新分布比较：

Wolfram Language code: Table[Cumulant[PoissonDistribution[λ], r], {r, 0, 5}]

在解析形式下，以参数的函数表示不同的矩：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[λ, BernoulliDistribution[p]];

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[𝒟, k], {k, 5}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[𝒟, k], {k, 5}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[𝒟, k], {k, 5}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[𝒟, k], {k, 5}], C]

CompoundPoissonDistribution 的母函数：

Wolfram Language code: 𝒟 = CompoundPoissonDistribution[3, NormalDistribution[]];

特征函数：

Wolfram Language code: CharacteristicFunction[𝒟, t]

矩母函数：

Wolfram Language code: MomentGeneratingFunction[𝒟, t]

阶乘矩母函数：

Wolfram Language code: FactorialMomentGeneratingFunction[𝒟, t]

累积量母函数：

Wolfram Language code: CumulantGeneratingFunction[𝒟, t]

具有混合跳跃分布的复合泊松分布：

Wolfram Language code:

𝒟 = CompoundPoissonDistribution[25, MixtureDistribution[{10, 15}, 
     {ExponentialDistribution[1], GammaDistribution[2, 1]}]];

分布的均值：

Wolfram Language code: Mean[𝒟]

与模拟得到的数值比较：

Wolfram Language code: Mean[RandomVariate[𝒟, 10 ^ 4]]

应用 (2)

在一个新装修的商店里，购物者按照每小时20个的速率的泊松过程到达. 该商店通过给每个顾客一个礼品促销. 礼品的加载服从形状参数为10，尺度参数为3的韦伯分布. 求在商店开门后12小时时间段内给出的礼品的期望总额：

Wolfram Language code: giftDistribution = CompoundPoissonDistribution[20 * 12, WeibullDistribution[10, 3]];

在就职日给出的礼品的期望总额：

Wolfram Language code: Mean[giftDistribution]//N

该商店在礼品上花费500美元到800美元之间的概率：

Wolfram Language code: gifts = RandomVariate[giftDistribution, 10 ^ 4];

Wolfram Language code: Histogram[gifts, {400, 900, 25}, "PDF"]

Wolfram Language code: Probability[500 < p < 800, pgifts]//N

一种风险的索赔总额服从泊松参数为200的复合泊松分布，个人索赔额分布服从帕累托分布，其中最小值参数为300，形状参数为3，位置参数为0. 保险公司具有保留额度为300美元的超额赔款再保险. 计算再保险公司的索赔总额的均值和方差. 再保险公司的单个索赔服从经过变换的帕累托分布，由于再保险公司只付超出300美元的金额：

Wolfram Language code: individualClaimDistribution = TransformedDistribution[Max[0, x - 300], xParetoDistribution[300, 3, 0]];

索赔总额：

Wolfram Language code: aggregateClaimDistribution = CompoundPoissonDistribution[200, individualClaimDistribution];

Wolfram Language code: Histogram[RandomVariate[aggregateClaimDistribution, 10 ^ 4], {0, 20000, 1000}, "PDF"]

再保险公司索赔总额的均值和方差：

Wolfram Language code: {Mean[aggregateClaimDistribution], Variance[aggregateClaimDistribution]}

属性和关系 (5)

CompoundPoissonDistribution 是 CompoundPoissonProcess 的切片分布：

Wolfram Language code: CompoundPoissonProcess[λ, WeibullDistribution[a, b]][t]

BernoulliDistribution 的 CompoundPoissonDistribution 是 PoissonDistribution：

Wolfram Language code: CompoundPoissonDistribution[μ, BernoulliDistribution[p]]

特殊 BorelTannerDistribution 的 CompoundPoissonDistribution 遵循 PoissonConsulDistribution：

Wolfram Language code: dist = CompoundPoissonDistribution[μ, BorelTannerDistribution[α, 1]];

Borel-Tanner 分布变量的总和遵循 Borel-Tanner 分布，因此切片分布等于参数混合分布：

Wolfram Language code:

pdm = ParameterMixtureDistribution[BorelTannerDistribution[α, n], 
    n  PoissonDistribution[μ]]

比较特征函数：

Wolfram Language code: CharacteristicFunction[dist, x] / CharacteristicFunction[pdm, x]//Simplify

更新率影响峰度：

Wolfram Language code: 𝒟[λ_] = CompoundPoissonDistribution[λ, NormalDistribution[]];

Wolfram Language code: data = Table[RandomVariate[𝒟[λ], 10 ^ 3], {λ, {1, 3, 9}}];

Wolfram Language code: Histogram[#, 20, "PDF"]& /@ data

Wolfram Language code: Kurtosis /@ data

使用不同的奖励分布：

Wolfram Language code: 𝒹[λ_] = CompoundPoissonDistribution[λ, ExponentialDistribution[3]];

Wolfram Language code: sample = Table[RandomVariate[𝒹[λ], 10 ^ 3], {λ, {1, 3, 9}}];

Wolfram Language code: Histogram[#, 20, "PDF"]& /@ sample

Wolfram Language code: Kurtosis /@ sample

CompoundRenewalProcess 的切片，其中更新时间由 ExponentialDistribution 给出：

Wolfram Language code: dist[λ_, t_] := CompoundRenewalProcess[ExponentialDistribution[λ], NormalDistribution[]][t];

创建一个速率为 3 的随机样本，并在 7 处切片：

Wolfram Language code:

SeedRandom[4728];
sample1 = RandomVariate[dist[3, 7], 10 ^ 4];

Wolfram Language code: Histogram[sample1, 30, "PDF"]

与相应的 CompoundPoissonDistribution 的样本进行比较：

Wolfram Language code:

SeedRandom[4728];
sample2 = RandomVariate[CompoundPoissonDistribution[3 * 7, NormalDistribution[]], 10 ^ 4];

Wolfram Language code: Histogram[{sample1, sample2}, 30, "PDF"]

可能存在的问题 (1)

默认的参数估计采用最大似然估计，这可能需要很长的时间：

Wolfram Language code: data = RandomVariate[CompoundPoissonDistribution[4.4, GammaDistribution[4, 2]], 10 ^ 3];

Wolfram Language code: TimeConstrained[EstimatedDistribution[data, CompoundPoissonDistribution[λ, GammaDistribution[a, m]]], 10, $TimedOut]

使用不同的方法：

Wolfram Language code:

EstimatedDistribution[data, CompoundPoissonDistribution[λ, GammaDistribution[a, m]], ParameterEstimator -> "MethodOfMoments"]//AbsoluteTiming

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

CompoundPoissonDistribution

更多信息

背景

范例

基本范例 (2)

范围 (7)

应用 (2)

属性和关系 (5)

可能存在的问题 (1)

文本

CMS

APA

BibTeX

BibLaTeX

CompoundPoissonDistribution

更多信息

背景

范例

基本范例 (2)

范围 (7)

应用 (2)

属性和关系 (5)

可能存在的问题 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX