WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Databin["id"]

Wolfram Data Drop中のデータビンを表す．

Databin["id",n]

データビン中の最初の n 項目を表す．

Databin["id",-n]

データビン中の最も新しい n 項目を表す．

Databin["id",{m,n}]

データビン中の m 個目から n 個目までの項目を表す．負の数は，最後から数えていることを示す．

Databin["id",{m,n,s}]

ステップ s で m 個目から n 個目までの項目を表す．

Databin["id",time]

time で指定された時間量だけ戻った項目を表す．

Databin["id",date]

指定の日付から現在までのデータビン内の項目を表す．

Databin["id",{date1,date2}]

date1から date2までのデータビン内の項目を表す．

Databin["id",range,{"key1","key2",…}]

データビンの各項目のうち，キー keyiがある要素のみを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
関連項目
関連するガイド
関連リンク
履歴
引用書式

Databin

Databin["id"]

Wolfram Data Drop中のデータビンを表す．

Databin["id",n]

データビン中の最初の n 項目を表す．

Databin["id",-n]

データビン中の最も新しい n 項目を表す．

Databin["id",{m,n}]

データビン中の m 個目から n 個目までの項目を表す．負の数は，最後から数えていることを示す．

Databin["id",{m,n,s}]

ステップ s で m 個目から n 個目までの項目を表す．

Databin["id",time]

time で指定された時間量だけ戻った項目を表す．

Databin["id",date]

指定の日付から現在までのデータビン内の項目を表す．

Databin["id",{date1,date2}]

date1から date2までのデータビン内の項目を表す．

Databin["id",range,{"key1","key2",…}]

データビンの各項目のうち，キー keyiがある要素のみを表す．

詳細

  • Databin["id"]では，id は短縮ID，完全なUUID，短縮あるいは長いURLのいずれかである．
  • Wolfram Cloud中のデータビンについての長いURLは，datadrop.wolframcloud.com/databin/ の形である．
  • Databinは，標準的な列指定を使う．
  • Allすべての項目
    n第1項目から第 n 項目まで
    -n最後の n 個の項目
    {n}第 n 項目のみ
    {m,n}第 m 項目から第 n 項目まで（最初と最後を含む）
    {m,n,s}第 m 項目から第 n 項目までをステップ s で
  • Databin["id"]はDatabin["id",All]に等しい．
  • Databin["id",time]では，time はQuantityオブジェクトとして指定される．
  • time の特殊形
  • "Minute"直近の分
    "Hour"直近の時
    "Day"直近の24時間
    "Week"直近の7日間
    "Month"直近の30日間
    "Year"直近の365日間
  • Databin["id",date]では，date はDateObjectを使って指定される．
  • データビンについて次の操作がサポートされている．
  • EventSeries[databin]データビン中のすべてのデータの事象系列
    TimeSeries[databin]データビン中のすべてのデータの時系列
    Dataset[databin]データビン中のタイムスタンプと項目のデータ集合
    Get[databin]データビンの全コンテンツを連想のリストとして
    Normal[databin]データビン中のメタデータなしの項目リスト
    Values[databin]データビン中のタイムスタンプなしの値のリスト
    Keys[databin]データ署名に対応する連想キー
    DateListPlot[databin]データビン中の各キーについての時系列プロット
    Options[databin]データビンのオプションを求める
    SetOptions[databin,…]データビンのオプションをリセットする
    DeleteObject[databin]データビンを永久的に削除する
  • 一般に，TimeSeriesオブジェクトおよびEventSeriesオブジェクトを操作する関数は，Databinオブジェクトに直接適用することができる．例として，Histogram，Mean，TimeSeriesMapが挙げられる．
  • Databin[…][request,…]を使ってデータビンを操作することができる．
  • データビンのコンテンツを取り出す基本的なリクエスト
  • "Latest"メタデータのある，最も新しく加えられた項目
    "Recent"メタデータのある最近の項目
    "TimeInterval"データビン中の項目のタイムスパン
    "Timestamps"データビン中の全項目のタイムスタンプのリスト
    "GeoLocations"データビン中の全項目の地理位置のリスト
    "EventSeries"データビン中のデータの事象系列(EventSeries)
    "TimeSeries"データビン中のデータの時系列(TimeSeries)
    "FullEntries"メタデータのある，データビン中のすべての項目(Get)
    "Entries"メタデータのない，データビン中のすべての項目(Normal)
    "Values"データビンで使われている各キーの値のリスト(Values)
    request,paramsパラメータ params でリクエストする
  • 使用可能なパラメータ params
  • seq列指定 seq によって与えられた項目
    <|key1val1,…|>詳細指定
  • 詳細指定に使用可能な項目
  • "StartIndex"含める最初の項目の指標
    "EndIndex"含める最後の項目の指標
    "StartTime"含める最初の項目の時間
    "EndTime"含める最後の項目の時間
  • データビンにデータを加えることに関連したリクエスト
  • "Add",dataデータビンにデータを加える
    "WebForm"データビンにデータを加えるための，クラウドに配備されたフォーム
  • Databin["id"]["Add",data]はDatabinAdd["id",data]と等価である．
  • Databin["id"]["Add",data,"Authorization"->token]は，承認トークンを含む．このトークンは，データビンが作成されたときに指定されたトークンとマッチしなければならない．
  • Databin["id"]["Add",data,"Timestamp"date]は，データビン項目についてのカスタムのタイムスタンプを含む．
  • データビンの識別操作
  • "ShortID"データビンの短縮ID
    "UUID"データビンの完全なUUID
    "ShortURL"データビンの短縮URL
    "URL"完全UUIDに基づいたデータビンのURL
    "Name"データビンに割り当てられた名前
  • データビンのメタデータリクエスト
  • "Information"データビンについての情報
    "EntryCount"データビン中の項目数
    "Size"データビンのコンテンツサイズ
    "Keys"データビン解釈署名中のキーの名前
    "LatestDate"最新項目が加えられた日付
    "CreationDate"データビンが最初に作られた日付
    "ExpirationDate"データビンが失効する日付
    "Class"データビンの作成に使われたクラス
  • Databin["id"]["Keys"]はKeys[Databin["id"]]と等価である．
  • 項目の追加に関連したデータビンの操作
  • "Interpretation"データビンについての解釈署名
  • データビンのアクセス制御操作
  • "Permissions"データビンについてのパーミッション
    "Owner"データビンの所有者のWolfram ID
    "Administrators"データビンの管理者のWolfram ID
    "Creator"データビンの制作者のWolfram ID
  • データビンのレポート生成操作
  • "Report"ローカルのノートブックとして与えられる，データビンについてのレポート
    "WebReport"クラウドノートブックとして与えられる，データビンについてのレポート
  • データビンについての操作の中にはWolfram Cloudの認証を必要とするものがある．
  • データビンのパーミッションのようなオプションは，Optionsを使って求め，SetOptionsを使って設定することができる．
  • DatabinのInformationは次の特性を含むことがある．
  • "Bin"完全なデータビン識別
    "DataInterpretation"データビンの解釈署名
    "Class"データビンの作成に使われたクラス
    "Owner"データビンの所有者のWolfram ID
    "SourceType"データビンのソース
    "CreationDate"データビンがはじめて作成された日付
    "Creator"データビンの作成者のWolfram ID
    "Permissions"データビンのパーミッション
    "EntryCount"データビン中の項目数
    "LatestTimestamp"最新のタイムスタンプ
    "ExpirationDate"データビンが失効する日付
    "Size"データビンのコンテンツサイズ

例題

すべて開く すべて閉じる

例  (3)

既存の例のデータビンをロードする：

Wolfram Language code: bin = Databin["1qGFQ8v"]

データビンからのデータをプロットする：

Wolfram Language code: DateListPlot[bin]

データビンから時系列を得る：

Wolfram Language code: TimeSeries[bin]

既存のデータビンから最近の3項目をロードする：

Wolfram Language code: Databin["1qGFQ8v", -3]

これら3項目の値を取り出す：

Wolfram Language code: Values[%]

新たなデータビンを作る：

Wolfram Language code: bin = CreateDatabin[]

このデータビンに値を加える：

Wolfram Language code: DatabinAdd[bin, 1234]

データビンから項目を取り出す：

Wolfram Language code: Values[bin]

スコープ  (6)

解釈付きのデータビンを作る：

Wolfram Language code: bin = CreateDatabin["Interpretation" -> {"city" -> "City", "temp" -> Restricted["StructuredQuantity", "DegreesCelsius"]}]

このデータビンに加える：

Wolfram Language code: DatabinAdd[bin, <|"city" -> "nyc", "temp" -> 20.4|>]
Wolfram Language code: DatabinAdd[bin, <|"city" -> "LA", "temp" -> 26.2|>]

このデータビンから値を取り出す：

Wolfram Language code: Values[bin]

このデータビンを削除する：

Wolfram Language code: DeleteObject[bin]

データビンにいくつかの項目を加える：

Wolfram Language code: bin = CreateDatabin[]
Wolfram Language code: Do[DatabinAdd[bin, {"x" -> i, "y" -> RandomReal[]}], {i, 20}]

コンテンツとタイムスタンプがあるデータ集合を取り出す：

Wolfram Language code: Dataset[bin]

データビンを削除する：

Wolfram Language code: DeleteObject[bin]

新たなデータビンを作成する：

Wolfram Language code: bin = CreateDatabin[]

データビンに値を加える：

Wolfram Language code: DatabinAdd[bin, 1234]

別の値を加える：

Wolfram Language code: DatabinAdd[bin, 5678]

Web APIを使ってデータを加える：

Wolfram Language code: URLExecute["https://datadrop.wolframcloud.com/api/v1.0/Add", {"bin" -> bin["UUID"], "Data" -> "91011"}];

データビンからすべての値を取り出す：

Wolfram Language code: Values[bin]

名前付きのデータビンを作成する：

Wolfram Language code: bin = CreateDatabin["Students"]

いくつかの項目を加える：

Wolfram Language code: DatabinUpload[bin, {<|"Name" -> "Braden", "Birthday" -> DateObject[{2010, 2, 4}]|>, <|"Name" -> "Sofia", "Birthday" -> DateObject[{2009, 12, 14}]|>, <|"Name" -> "Erin", "Birthday" -> DateObject[{2009, 9, 8}]|>, <|"Name" -> "Aiden", "Birthday" -> DateObject[{2010, 5, 1}]|>}]

最初の２つの項目のみを含むデータビンの表現を取得する：

Wolfram Language code: firsttwo = Databin[bin, 2]

データを取り出す：

Wolfram Language code: Values[firsttwo]

最も最近の値を取得する：

Wolfram Language code: Values[Databin[bin, -3]]

連続する値を持つ項目を持つデータビンを作成する：

Wolfram Language code: bin = DatabinUpload[CreateDatabin[], 15 + Range[40]]

特定の範囲の項目の表現を取得する：

Wolfram Language code: range = Databin[bin, {3, 10}]

その範囲を取り出す：

Wolfram Language code: Values[range]

刻み幅を指定する：

Wolfram Language code: Values[Databin[bin, {3, 10, 3}]]

Associationのデータ項目のリストを作成する：

Wolfram Language code: entries = Table[<|"a" -> i, "b" -> 100 - 1, "c" -> 2i|>, {i, 20}]

項目をデータビンにアップロードする：

Wolfram Language code: bin = DatabinUpload[CreateDatabin[], entries]

データビンの中の特定のキーの表現を取得する：

Wolfram Language code: abin = Databin[bin, All, "a"]

範囲を取り出す：

Wolfram Language code: Values[abin]

キーのリストを指定する：

Wolfram Language code: acbin = Databin[bin, All, {"a", "c"}]

これらのキーのデータを取り出す：

Wolfram Language code: Values[acbin]

指定のキーの最初の5項目の値だけを取得する：

Wolfram Language code: Values[Databin[bin, 5, {"a", "c"}]]

特性と関係  (3)

Databin式のInformationは完全なビン指定，作成日，その他の詳細を含む：

Wolfram Language code: Information[Databin["1qGFQ8v"]]

Information式から入手可能な特性のリストを得る：

Wolfram Language code: %["Properties"]

DateBoundsを使って指定されたデータビンに関連付けられた最初と最後のタイムスタンプを得る：

Wolfram Language code: bin = Databin["1qGFQ8v"]
Wolfram Language code: DateBounds[bin]

DeleteObjectは，データビンを永久に削除する：

Wolfram Language code: bin = DatabinAdd[CreateDatabin[], <|"event" -> "My First Data Entry"|>]
Wolfram Language code: DeleteObject[bin]

このデータビンはもはや存在しない：

Wolfram Language code: bin["Information"]
Wolfram Research (2014), Databin, Wolfram言語関数， https://reference.wolfram.com/language/ref/Databin.html （2019年に更新）.

テキスト

Wolfram Research (2014), Databin, Wolfram言語関数， https://reference.wolfram.com/language/ref/Databin.html （2019年に更新）.

CMS

Wolfram Language. 2014. "Databin." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Databin.html.

APA

Wolfram Language. (2014). Databin. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Databin.html

BibTeX

@misc{reference.wolfram_2026_databin, author="Wolfram Research", title="{Databin}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Databin.html}", note=[Accessed: 17-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_databin, organization={Wolfram Research}, title={Databin}, year={2019}, url={https://reference.wolfram.com/language/ref/Databin.html}, note=[Accessed: 17-June-2026]}