DiscreteAsymptotic
DiscreteAsymptotic
DiscreteAsymptotic[expr,n∞]
n が整数上で無限大に近付くときの expr についての漸近近似を与える．
DiscreteAsymptotic[expr,{n,∞,m}]
expr についての漸近級数近似を次数 m まで与える．
詳細とオプション
- DiscreteAsymptoticは，主に，厳密解が求まらない問題を解くため，あるいは計算，比較，解釈等のためにより簡単な答を得るために使われる．そのような場合，漸近近似はしばしば該当する問題を簡約したり解いたりするために十分な情報を与える．
- DiscreteAsymptotic[expr,n∞]は，expr についての漸近展開における最高次の項を計算する．SeriesTermGoalを使うとより多くの項が指定できる．
- 式 expr は任意の数列
，Sumで指定される総和，Productで指定される積，SeriesCoefficientで指定される数列，RSolveValue等で指定される差分方程式等でよい． - 厳密結果が g[x]で x0における次数 n の漸近近似が gn[x]であれば，xx0のときにAsymptoticLess[g[x]-gn[x],gn[x]-gn-1[x],xx0]または g[x]-gn[x]∈o[gn[x]-gn-1[x]]である．
- 漸近近似 gn[x]はしばしば総和 gn[x]
αkϕk[x]として与えられる．{ϕ1[x],…,ϕn[x]}は xx0のときの漸近尺度 ϕ1[x]≻ϕ2[x]≻⋯>ϕn[x]である．こうすると，xx0のとき AsymptoticLess[g[x]-gn[x],ϕn[x],xx0]または g[x]-gn[x]∈o[ϕn[x]]となる． - 次は，よく含まれる漸近尺度である．
-
xx0のとき，テイラー(Taylor)スケール 
xx0のとき，ローラン(Laurent)スケール 
x±∞のとき，ローランスケール 
xx0のとき，ピュイゾー(Puiseux)スケール - 漸近近似を表すために使われる尺度は問題から自動的に推測される．多くの場合，より珍しい尺度を含めることができる．
- 次は，使用可能なオプションである．
-
AccuracyGoal Automatic 目標確度 Assumptions $Assumptions パラメータについての仮定 GenerateConditions Automatic パラメータについての条件を含む答を生成するかどうか GeneratedParameters None 生成されたパラメータにどのように命名するか Method Automatic 使用するメソッド PerformanceGoal $PerformanceGoal パフォーマンスのどの面について最適化するか PrecisionGoal Automatic 目標精度 SeriesTermGoal Automatic 近似における項数 WorkingPrecision Automatic 内部計算の精度 - GenerateConditionsにデフォルト設定のAutomaticを使うと，Asymptoticからの結果には，一般に，パラメータについての条件が含まれない．GenerateConditionsをTrueにするとパラメータについての条件を含む答が得られることが多い．
- PerformanceGoalの可能な設定には，$PerformanceGoal，"Quality" ，"Speed"がある．このオプションを"Quality"に設定すると，DiscreteAsymptoticはより多くの問題を解いたりより簡単な答を生成したりするようになるが，かかる時間が長くなりメモリ消費量も大きくなる可能性がある．
- WorkingPrecision，AccuracyGoal，PrecisionGoalにデフォルト設定のAutomaticを使うと，たとえ入力精度が無限でも，DiscreteAsymptoticはより低い精度で漸近近似を返すかもしれない．
例題
すべて開く すべて閉じる例 (4)
がInfinityに近付くときの 
の最高次の漸近項を求める：
DiscreteAsymptotic[n!, n -> ∞]Table[{n!, N[%], n! / N[%]}, {n, 1, 21, 4}]//TableFormSeriesTermGoalを使って展開からより多くの項を得る：
DiscreteAsymptotic[n!, n -> ∞, SeriesTermGoal -> 3]genfun = (1/2 - E^z);DiscreteAsymptoticを適用して漸近近似を計算する：
asy = DiscreteAsymptotic[SeriesCoefficient[genfun, {z, 0, n}], n -> ∞]Table[asy, {n, 0, 20, 5}]//NTable[SeriesCoefficient[genfun, {z, 0, n}], {n, 0, 20, 5}]//NDiscreteAsymptotic[Inactive[Sum][Binomial[n, k] ^ 2, {k, 0, n}], n -> ∞]AsymptoticSumを使って同じ結果を得る：
AsymptoticSum[Binomial[n, k] ^ 2, {k, 0, n}, n -> ∞]dr = DifferenceRoot[Function[{y, n}, {y[n + 1] - n ^ 2 y[n] == 0, y[1] == 1}]][n];DiscreteAsymptotic[dr, n -> ∞]AsymptoticRSolveValueを使って同じ結果を得る：
AsymptoticRSolveValue[{y[n + 1] - n ^ 2 * y[n] == 0, y[1] == 1}, y[n], n -> ∞]スコープ (19)
初等級数 (8)
DiscreteAsymptotic[n ^ 4 + 5n ^ 3 + 3n - 11, n -> ∞]DiscretePlot[{n ^ 4 + 5n ^ 3 + 3n - 11, n ^ 4}, {n, 1, 20}]DiscreteAsymptotic[(3n ^ 2 + 5) / (4n ^ 2 + 11), n -> ∞]DiscreteAsymptotic[(3n ^ 3 + 5) / (4n ^ 2 + 11), n -> ∞]DiscreteAsymptotic[(3n + 5) / (4n ^ 2 + 11), n -> ∞]DiscreteAsymptotic[2 ^ n, n -> ∞]DiscreteAsymptotic[2 ^ n + 3 ^ (-n), n -> ∞]DiscreteAsymptotic[n ^ 2 2 ^ n, n -> ∞]DiscreteAsymptotic[(n ^ 2 + 3n)2 ^ n, n -> ∞]DiscreteAsymptotic[(n ^ 2 / (3n ^ 2 + 1))2 ^ n, n -> ∞]DiscreteAsymptotic[(n ^ 2 / (3n ^ 3 + 1))2 ^ n, n -> ∞]DiscreteAsymptotic[(5n ^ 4 / (3n ^ 3 + 1))2 ^ n, n -> ∞]DiscreteAsymptotic[Sinh[n], n -> ∞]DiscreteAsymptotic[ArcSinh[n], n -> ∞]DiscreteAsymptotic[Log[n], n -> ∞]DiscreteAsymptotic[(5n ^ 2 / (3n ^ 3 + 1))Log[n], n -> ∞]DiscreteAsymptotic[(5n ^ 4 / (3n ^ 3 + 1))Log[n], n -> ∞]DiscreteAsymptotic[2 ^ n / (1 + 2 ^ n), n -> ∞]DiscreteAsymptotic[4 ^ n / (1 + 2 ^ n), n -> ∞]DiscreteAsymptotic[2 ^ n / (1 + 4 ^ n), n -> ∞]DiscreteAsymptotic[QPolyGamma[2, n], n -> ∞]特殊数列 (6)
がInfinityに近付くときの，Fibonacciについての最高次の漸近項を求める：
DiscreteAsymptotic[Fibonacci[n], n -> ∞]Table[{Fibonacci[n], N[%]}, {n, 1, 21, 4}]//TableFormPochhammerについての最高次の漸近項：
DiscreteAsymptotic[Pochhammer[a, n], n -> ∞]DiscreteAsymptotic[FactorialPower[a, n], n -> ∞]DiscreteAsymptotic[Binomial[n, k], n -> ∞]HarmonicNumberの最高次の漸近項：
DiscreteAsymptotic[HarmonicNumber[n], n -> ∞]DiscreteAsymptotic[PolyGamma[n], n -> ∞]Zeta：
DiscreteAsymptotic[Zeta[n], n -> ∞]StirlingS1の最高次の漸近項：
DiscreteAsymptotic[StirlingS1[n, 2], n -> ∞]DiscreteAsymptotic[StirlingS2[n, 2], n -> ∞]
% /. {n -> 200.`20}//NStirlingS2[200, 2]//NBellBについての最高次の漸近項：
DiscreteAsymptotic[BellB[n], n -> ∞]
% /. {n -> 1400.`20}//NBellB[1400]//NBernoulliBについての最高次の漸近項：
DiscreteAsymptotic[BernoulliB[2n], n -> ∞]DiscreteAsymptotic[EulerE[2n], n -> ∞]総和と総和変換 (3)
DiscreteAsymptotic[Inactive[Sum][1 / (k ^ 2 + a), {k, 0, Infinity}], a -> 0]AsymptoticSumを使って同じ結果を得る：
AsymptoticSum[1 / (k ^ 2 + a), {k, 0, Infinity}, a -> 0]フィボナッチ(Fibonacci)数列についての漸近近似を，数列の母関数を使って計算する：
DiscreteAsymptotic[Inactive[SeriesCoefficient][-(z / (-1 + z + z ^ 2)), {z, 0, n}],
n -> ∞]% /. {n -> 2000.}Fibonacci[2000]//NDiscreteAsymptotic[Inactive[InverseZTransform][1 / (z * (-6 + 6 * z ^ 2 + z ^ 3)), z, n], n -> ∞]差分方程式 (2)
dr = DifferenceRoot[Function[{, }, {-(n * []) + [1 + ] == 0, [1] == 1}]][n];DiscreteAsymptotic[dr, n -> Infinity]AsymptoticRSolveValueを使って同じ結果を得る：
AsymptoticRSolveValue[{y[n + 1] - n * y[n] == 0, y[1] == 1}, y[n], n -> ∞]DiscreteAsymptotic[Inactive[RSolveValue][{n ^ 4y[n + 2] == 2n ^ 3(n - 1) y[n + 1] - (n ^ 4 - 2n ^ 3 - 1)y[n], y[1] == 1., y[2] == 3}, y[n], n],
n -> ∞, SeriesTermGoal -> 7]オプション (1)
SeriesTermGoal (1)
デフォルトで，DiscreteAsymptoticは漸近展開における最高次の項を返す：
DiscreteAsymptotic[n!, n -> ∞]DiscreteAsymptotic[n!, n -> ∞, SeriesTermGoal -> 1]SeriesTermGoalを使って展開からより多くの項を得る：
DiscreteAsymptotic[n!, n -> ∞, SeriesTermGoal -> 3]DiscreteAsymptotic[n!, {n, ∞, 3}]アプリケーション (3)
がInfinityに近付くときのPrimeの最高次の漸近項を求める：
DiscreteAsymptotic[Prime[n], n -> ∞]DiscretePlot[{Prime[n], %}, {n, 100, 1000, 10}, PlotLegends -> {Prime[n], n Log[n]}]{Prime[1000], 1000 Log[1000.]}
がInfinityに近付くとき，数列とその最高次の漸近項の比は1に近付く：
DiscreteLimit[Prime[n] / (n Log[n]), n -> ∞]DiscreteAsymptotic[Sum[Binomial[n, k] ^ 3, {k, 0., n}], n -> ∞]
% /. {n -> 1000.}Sum[Binomial[1000, k] ^ 3, {k, 0, 1000}]//Nアペリー(Apéry)数列について最高次の漸近項を計算する．これは，次の2階線形差分方程式を満足する：
apeqn = (n + 2) ^ 3 u[n + 2] - (34 n ^ 3 + 153 n ^ 2 + 231 n + 117)u[n + 1] + (n + 1) ^ 3 u[n] == 0;sol[n_] = DiscreteAsymptotic[Inactive[RSolveValue][apeqn, u[n], n], n -> Infinity]
に値を割り当てる：tsol[n_] := Sum[Binomial[n, k] ^ 2 Binomial[n + k, k] ^ 2, {k, 0, n}]Solve[sol[1000] == tsol[1000], C[2]]//N[#, 20]&//Chopsol[10000] /. %[[1]] //N[#, 20]&tsol[10000]//N特性と関係 (2)
DiscreteAsymptoticからの結果は数列と漸近的に等しい：
DiscreteAsymptotic[(n ^ 2 + 3) / (5n ^ 3 + 11), n -> ∞]AsymptoticEquivalentを使って結果を確かめる：
AsymptoticEquivalent[(n ^ 2 + 3) / (5n ^ 3 + 11), 1 / (5n), n -> ∞]DiscreteAsymptoticは，
の大きい値についての数列の挙動を説明する：
DiscreteAsymptotic[2 ^ n / (1 + 4 ^ n), n -> ∞]% /. {n -> 500.}DiscreteLimitは，Infinityにおける数列の挙動を説明する：
DiscreteLimit[2 ^ n / (1 + 4 ^ n), n -> ∞]
Wolfram Research (2020), DiscreteAsymptotic, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteAsymptotic.html.
テキスト
Wolfram Research (2020), DiscreteAsymptotic, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteAsymptotic.html.
CMS
Wolfram Language. 2020. "DiscreteAsymptotic." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteAsymptotic.html.
APA
Wolfram Language. (2020). DiscreteAsymptotic. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DiscreteAsymptotic.html