DiscreteAsymptotic
DiscreteAsymptotic
DiscreteAsymptotic[expr,n∞]
给出 n 趋近于无限大整数时 expr 的渐近逼近.
DiscreteAsymptotic[expr,{n,∞,m}]
给出 expr 的 m 阶渐近级数近似式.
更多信息和选项
- DiscreteAsymptotic 通常用于求解无法找到精确解的问题，或者为计算、比较和解释寻求更简单的答案. 在这种情况下，渐近逼近通常会提供足够的信息来简化或解决应用问题.
- DiscreteAsymptotic[expr,n∞] 计算 expr 渐近展开式的首项. 用 SeriesTermGoal 可指定更多项.
- 表达式 expr 可为任何序列
、由 Sum 指定的和、由 Product 指定的积、由 SeriesCoefficient 指定的序列、由 RSolveValue 指定的差分方程等. - 如果精确结果为 g[x]， x0 处的 n 阶渐近逼近为 gn[x]，则当 xx0 时，AsymptoticLess[g[x]-gn[x],gn[x]-gn-1[x],xx0] 或 g[x]-gn[x]∈o[gn[x]-gn-1[x]].
- 渐近逼近 gn[x] 经常以和 gn[x]
αkϕk[x] 的形式给出，其中 {ϕ1[x],…,ϕn[x]} 为 xx0 时的渐近尺度 ϕ1[x]≻ϕ2[x]≻⋯>ϕn[x]. 当 xx0 时，AsymptoticLess[g[x]-gn[x],ϕn[x],xx0] 或 g[x]-gn[x]∈o[ϕn[x]]. - 常见的渐近尺度包括：
-
Taylor 尺度，当 xx0 时 
Laurent 尺度，当 xx0 时 
Laurent 尺度，当 x±∞ 时 
Puiseux 尺度，当 xx0 时 - 用于表示渐近逼近的尺度是从问题中自动推断出来的，通常可以包含更多的奇异尺度.
- 可以给出以下选项：
-
AccuracyGoal Automatic 追求的绝对准确度 Assumptions $Assumptions 对参数的设定 GenerateConditions Automatic 是否给出与参数的条件有关的答案 GeneratedParameters None 怎样命名生成的参数 Method Automatic 所用的方法 PerformanceGoal $PerformanceGoal 优化目标 PrecisionGoal Automatic 追求的精度 SeriesTermGoal Automatic 近似式的项数 WorkingPrecision Automatic 内部计算使用的精度 - 当 GenerateConditions 采用默认设置 Automatic 时，DiscreteAsymptotic 返回的结果中通常不包含参数的条件. 通过将 GenerateConditions 设为 True 可返回包含参数条件的答案.
- PerformanceGoal 的可能设置包括 $PerformanceGoal、"Quality" 和 "Speed". 当设置为 "Quality" 时，DiscreteAsymptotic 通常可以解出更多的问题或者产生更简单的结果，但是可能会耗费更多的时间和内存.
- 当 WorkingPrecision、AccuracyGoal 和 PrecisionGoal 采用默认设置 Automatic 时，DiscreteAsymptotic 可能返回精度较低的渐近逼近，即使输入具有无限精度.
范例
打开所有单元 关闭所有单元基本范例 (4)
求 
趋近于 Infinity 时 
的渐近逼近的首项：
DiscreteAsymptotic[n!, n -> ∞]Table[{n!, N[%], n! / N[%]}, {n, 1, 21, 4}]//TableForm用 SeriesTermGoal 获取展开式更多的项：
DiscreteAsymptotic[n!, n -> ∞, SeriesTermGoal -> 3]genfun = (1/2 - E^z);应用 DiscreteAsymptotic，计算渐近逼近：
asy = DiscreteAsymptotic[SeriesCoefficient[genfun, {z, 0, n}], n -> ∞]Table[asy, {n, 0, 20, 5}]//NTable[SeriesCoefficient[genfun, {z, 0, n}], {n, 0, 20, 5}]//NDiscreteAsymptotic[Inactive[Sum][Binomial[n, k] ^ 2, {k, 0, n}], n -> ∞]用 AsymptoticSum 获取相同的结果：
AsymptoticSum[Binomial[n, k] ^ 2, {k, 0, n}, n -> ∞]dr = DifferenceRoot[Function[{y, n}, {y[n + 1] - n ^ 2 y[n] == 0, y[1] == 1}]][n];DiscreteAsymptotic[dr, n -> ∞]用 AsymptoticRSolveValue 获取相同的结果：
AsymptoticRSolveValue[{y[n + 1] - n ^ 2 * y[n] == 0, y[1] == 1}, y[n], n -> ∞]范围 (19)
基本序列 (8)
DiscreteAsymptotic[n ^ 4 + 5n ^ 3 + 3n - 11, n -> ∞]DiscretePlot[{n ^ 4 + 5n ^ 3 + 3n - 11, n ^ 4}, {n, 1, 20}]DiscreteAsymptotic[(3n ^ 2 + 5) / (4n ^ 2 + 11), n -> ∞]DiscreteAsymptotic[(3n ^ 3 + 5) / (4n ^ 2 + 11), n -> ∞]DiscreteAsymptotic[(3n + 5) / (4n ^ 2 + 11), n -> ∞]DiscreteAsymptotic[2 ^ n, n -> ∞]DiscreteAsymptotic[2 ^ n + 3 ^ (-n), n -> ∞]DiscreteAsymptotic[n ^ 2 2 ^ n, n -> ∞]DiscreteAsymptotic[(n ^ 2 + 3n)2 ^ n, n -> ∞]DiscreteAsymptotic[(n ^ 2 / (3n ^ 2 + 1))2 ^ n, n -> ∞]DiscreteAsymptotic[(n ^ 2 / (3n ^ 3 + 1))2 ^ n, n -> ∞]DiscreteAsymptotic[(5n ^ 4 / (3n ^ 3 + 1))2 ^ n, n -> ∞]DiscreteAsymptotic[Sinh[n], n -> ∞]DiscreteAsymptotic[ArcSinh[n], n -> ∞]DiscreteAsymptotic[Log[n], n -> ∞]DiscreteAsymptotic[(5n ^ 2 / (3n ^ 3 + 1))Log[n], n -> ∞]DiscreteAsymptotic[(5n ^ 4 / (3n ^ 3 + 1))Log[n], n -> ∞]DiscreteAsymptotic[2 ^ n / (1 + 2 ^ n), n -> ∞]DiscreteAsymptotic[4 ^ n / (1 + 2 ^ n), n -> ∞]DiscreteAsymptotic[2 ^ n / (1 + 4 ^ n), n -> ∞]DiscreteAsymptotic[QPolyGamma[2, n], n -> ∞]特殊序列 (6)
求 
趋近于 Infinity 时 Fibonacci 的渐近逼近的首项：
DiscreteAsymptotic[Fibonacci[n], n -> ∞]Table[{Fibonacci[n], N[%]}, {n, 1, 21, 4}]//TableFormPochhammer 的渐近逼近的首项：
DiscreteAsymptotic[Pochhammer[a, n], n -> ∞]DiscreteAsymptotic[FactorialPower[a, n], n -> ∞]DiscreteAsymptotic[Binomial[n, k], n -> ∞]HarmonicNumber 的渐近逼近的首项：
DiscreteAsymptotic[HarmonicNumber[n], n -> ∞]DiscreteAsymptotic[PolyGamma[n], n -> ∞]Zeta：
DiscreteAsymptotic[Zeta[n], n -> ∞]StirlingS1 的渐近逼近的首项：
DiscreteAsymptotic[StirlingS1[n, 2], n -> ∞]DiscreteAsymptotic[StirlingS2[n, 2], n -> ∞]
% /. {n -> 200.`20}//NStirlingS2[200, 2]//NBellB 的渐近逼近的首项：
DiscreteAsymptotic[BellB[n], n -> ∞]
% /. {n -> 1400.`20}//NBellB[1400]//NBernoulliB 的渐近逼近的首项：
DiscreteAsymptotic[BernoulliB[2n], n -> ∞]DiscreteAsymptotic[EulerE[2n], n -> ∞]和与求和变换 (3)
DiscreteAsymptotic[Inactive[Sum][1 / (k ^ 2 + a), {k, 0, Infinity}], a -> 0]用 AsymptoticSum 获取同样的结果：
AsymptoticSum[1 / (k ^ 2 + a), {k, 0, Infinity}, a -> 0]DiscreteAsymptotic[Inactive[SeriesCoefficient][-(z / (-1 + z + z ^ 2)), {z, 0, n}],
n -> ∞]% /. {n -> 2000.}Fibonacci[2000]//NDiscreteAsymptotic[Inactive[InverseZTransform][1 / (z * (-6 + 6 * z ^ 2 + z ^ 3)), z, n], n -> ∞]差分方程 (2)
dr = DifferenceRoot[Function[{, }, {-(n * []) + [1 + ] == 0, [1] == 1}]][n];DiscreteAsymptotic[dr, n -> Infinity]用 AsymptoticRSolveValue 获取同样的结果：
AsymptoticRSolveValue[{y[n + 1] - n * y[n] == 0, y[1] == 1}, y[n], n -> ∞]DiscreteAsymptotic[Inactive[RSolveValue][{n ^ 4y[n + 2] == 2n ^ 3(n - 1) y[n + 1] - (n ^ 4 - 2n ^ 3 - 1)y[n], y[1] == 1., y[2] == 3}, y[n], n],
n -> ∞, SeriesTermGoal -> 7]选项 (1)
SeriesTermGoal (1)
默认情况下，DiscreteAsymptotic 返回渐近展开式的首项：
DiscreteAsymptotic[n!, n -> ∞]DiscreteAsymptotic[n!, n -> ∞, SeriesTermGoal -> 1]用 SeriesTermGoal 获取更多项：
DiscreteAsymptotic[n!, n -> ∞, SeriesTermGoal -> 3]DiscreteAsymptotic[n!, {n, ∞, 3}]应用 (3)
求 
趋近于 Infinity 时 Prime 的渐近逼近的首项：
DiscreteAsymptotic[Prime[n], n -> ∞]DiscretePlot[{Prime[n], %}, {n, 100, 1000, 10}, PlotLegends -> {Prime[n], n Log[n]}]{Prime[1000], 1000 Log[1000.]}序列的值与渐近逼近的首项的比在 
趋近于 Infinity 时趋近于 1：
DiscreteLimit[Prime[n] / (n Log[n]), n -> ∞]DiscreteAsymptotic[Sum[Binomial[n, k] ^ 3, {k, 0., n}], n -> ∞]
% /. {n -> 1000.}Sum[Binomial[1000, k] ^ 3, {k, 0, 1000}]//N计算 Apéry 序列的渐近逼近的首项，它满足以下线性二阶差分方程：
apeqn = (n + 2) ^ 3 u[n + 2] - (34 n ^ 3 + 153 n ^ 2 + 231 n + 117)u[n + 1] + (n + 1) ^ 3 u[n] == 0;sol[n_] = DiscreteAsymptotic[Inactive[RSolveValue][apeqn, u[n], n], n -> Infinity]
赋值：tsol[n_] := Sum[Binomial[n, k] ^ 2 Binomial[n + k, k] ^ 2, {k, 0, n}]Solve[sol[1000] == tsol[1000], C[2]]//N[#, 20]&//Chopsol[10000] /. %[[1]] //N[#, 20]&tsol[10000]//N属性和关系 (2)
The result from DiscreteAsymptotic 的结果渐近等价于序列：
DiscreteAsymptotic[(n ^ 2 + 3) / (5n ^ 3 + 11), n -> ∞]用 AsymptoticEquivalent 来验证结果：
AsymptoticEquivalent[(n ^ 2 + 3) / (5n ^ 3 + 11), 1 / (5n), n -> ∞]DiscreteAsymptotic 描述 
取较大值时序列的行为：
DiscreteAsymptotic[2 ^ n / (1 + 4 ^ n), n -> ∞]% /. {n -> 500.}DiscreteLimit 描述序列在 Infinity 处的行为：
DiscreteLimit[2 ^ n / (1 + 4 ^ n), n -> ∞]
Wolfram Research (2020)，DiscreteAsymptotic，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteAsymptotic.html.
文本
Wolfram Research (2020)，DiscreteAsymptotic，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteAsymptotic.html.
CMS
Wolfram 语言. 2020. "DiscreteAsymptotic." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteAsymptotic.html.
APA
Wolfram 语言. (2020). DiscreteAsymptotic. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiscreteAsymptotic.html 年