WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ExpGammaDistribution[κ,θ,μ]

形状母数 κ，尺度母数 θ，位置母数 μ の指数ガンマ分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

ExpGammaDistribution

ExpGammaDistribution[κ,θ,μ]

形状母数 κ，尺度母数 θ，位置母数 μ の指数ガンマ分布を表す．

詳細

予備知識

  • ExpGammaDistribution[κ,θ,μ]は，実数集合上で定義され，「位置母数」と呼ばれる実数 μ と，それぞれ「形状母数」および「尺度母数」と呼ばれる2つの正の実数 κ および θ によってパラメータ化された連続統計分布を表す．母数 μ は，指数ガンマ分布の確率密度関数(PDF)の「峰」（つまり，絶対最大値）の水平位置を決定する．PDFは常に単峰だが，グラフの全体的な高さと傾きは κ および θ の値で決定される．加えて，PDFの裾部は， の大きい値についてPDFが指数的にではなく代数的に減少するという意味で「厚い」（この動作は分布のSurvivalFunctionを分析することで数量的に正確にできる）．指数ガンマ分布は一般化した極値分布と呼ばれることがあるが，この言葉は数量的に類似した他の多くの確率分布をも指すので注意が必要である．
  • 指数ガンマ分布は，XGammaDistributionである場合は常に をモデル化するように数学的に定義されている．指数ガンマ分布はいわゆる（統計的）極値定理のために重要である．この定理は，独立同分布に従う確率変数のサンプルの最大値は，可能な3つの分布（GumbelDistribution，FrechetDistribution，WeibullDistribution）のうちの1つの分布にのみ収束すると述べている．この3つの関数はどれもExpGammaDistributionの特殊ケースである．これに加え，指数ガンマ分布は科学のさまざまな分野で，気象学における風速や海洋工学における海流速度等を含む数多くの現象のモデル化に使われてきた．
  • RandomVariateを使って指数ガンマ分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,ExpGammaDistribution[κ,θ,μ]]（より簡略すると xExpGammaDistribution[κ,θ,μ]）を使って，確率変数 x が，指数ガンマ分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[ExpGammaDistribution[κ,θ,μ],x]およびCDF[ExpGammaDistribution[κ,θ,μ],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
  • DistributionFitTestを使って，与えられたデータ集合が指数ガンマ分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリック指数ガンマ分布を推定することが，FindDistributionParametersを使ってデータを指数ガンマ分布にフィットすることができる．ProbabilityPlotを使って記号指数ガンマ分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号指数ガンマ分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換された指数ガンマ分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使って指数ガンマ分布を含む高次元分布を構築することが，ProductDistributionを使って指数ガンマ分布を含む独立成分分布の結合分布を計算することができる．
  • 指数ガンマ分布は他の多くの分布と関連がある．定義上，ExpGammaDistribution[κ,θ,0]のCDFは厳密に θ Log[u]のそれであるという意味で，ExpGammaDistributionはGammaDistributionを変換したものである．ただし，uGammaDistribution[κ,1]である．加えて，GumbelDistribution，FrechetDistribution，WeibullDistributionを含む数多くの分布が，より幅の広い「一般化された極値分布」の枠に入るため，定性的にExpGammaDistributionに関連している．この関係は，FrechetDistributionとGumbelDistributionの両方がWeibullDistributionの変換であり，ExpGammaDistribution[1,b,a]が厳密にGumbelDistribution[a,b]であることに注目することによって数量化することができる．ExpGammaDistribution[1,σ,μ]はMinStableDistribution[μ,σ,0]と同じであるのに対し，MoyalDistribution[μ,σ]は確率変数-u の分布として得ることができる．ただし，uExpGammaDistribution[1/2,σ,-μ+σ Log[2]]である．指数ガンマ分布は，ExtremeValueDistribution，ParetoDistribution，LogisticDistribution，MaxStableDistributionとも関連がある．

例題

すべて開く すべて閉じる

例  (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[ExpGammaDistribution[κ, 2, 1], x], {κ, {.25, 1, 2}}]//Evaluate, {x, -4, 6}, Filling -> Axis]
Wolfram Language code: PDF[ExpGammaDistribution[κ, θ, μ], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[ExpGammaDistribution[κ, 2, 1], x], {κ, {.25, 1, 2}}]//Evaluate, {x, -4, 6}, Filling -> Axis]
Wolfram Language code: CDF[ExpGammaDistribution[κ, θ, μ], x]

平均と分散：

Wolfram Language code: Mean[ExpGammaDistribution[κ, θ, μ]]
Wolfram Language code: Variance[ExpGammaDistribution[κ, θ, μ]]

中央値：

Wolfram Language code: Median[ExpGammaDistribution[κ, θ, μ]]

スコープ  (8)

指数ガンマ分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[ExpGammaDistribution[3, 2, 1], 10 ^ 4];

そのヒストグラムを確率密度関数と比較する：

Wolfram Language code: Show[ Histogram[data, 20, "PDF"], Plot[PDF[ExpGammaDistribution[3, 2, 1], x], {x, -2, 6}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[ExpGammaDistribution[.5, 3, 1], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, ExpGammaDistribution[k, θ, μ]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, -30, 10}, PlotStyle -> Thick]]

歪度は形状母数 κ のみに依存する：

Wolfram Language code: Plot[Skewness[ExpGammaDistribution[κ, θ, μ]], {κ, 0, 10}]
Wolfram Language code: Skewness[ExpGammaDistribution[κ, θ, μ]]

極限値：

Wolfram Language code: Limit[Skewness[ExpGammaDistribution[κ, θ, μ]], κ -> 0, Direction -> -1]
Wolfram Language code: Limit[Skewness[ExpGammaDistribution[κ, θ, μ]], κ -> ∞]

尖度は形状母数 κ のみに依存する：

Wolfram Language code: Plot[Kurtosis[ExpGammaDistribution[κ, θ, μ]], {κ, 0, 10}]
Wolfram Language code: Kurtosis[ExpGammaDistribution[κ, θ, μ]]

極限値：

Wolfram Language code: Limit[Kurtosis[ExpGammaDistribution[κ, θ, μ]], κ -> 0, Direction -> -1]
Wolfram Language code: Limit[Kurtosis[ExpGammaDistribution[κ, θ, μ]], κ -> ∞]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[ExpGammaDistribution[κ, θ, μ], k]//FullSimplify, {k, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[ExpGammaDistribution[κ, θ, μ], k]//Together, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[ExpGammaDistribution[κ, θ, μ], k]//FullSimplify, {k, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[ExpGammaDistribution[κ, θ, μ], k], {k, 3}], C]

記号次数の閉じた形：

Wolfram Language code: Cumulant[ExpGammaDistribution[κ, θ, μ], r]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[ExpGammaDistribution[κ, 3, -1], x], {κ, {1, 10, 15}}]//Evaluate, {x, -1, 10}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[ExpGammaDistribution[3, θ, -1], x], {θ, {6, 10, 15}}]//Evaluate, {x, -1, 10}, Filling -> Axis]
Wolfram Language code: HazardFunction[ExpGammaDistribution[κ, θ, μ], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[ExpGammaDistribution[κ, 0.5, -1], q], {κ, {0.5, 1, 3}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Quantile[ExpGammaDistribution[κ, θ, μ], q]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: gusts𝒟 = ExpGammaDistribution[2.3, Quantity[65, "kmph"], Quantity[8, "kmph"]]

風速の中央値を求める：

Wolfram Language code: Median[gusts𝒟]

アプリケーション  (1)

ExpGammaDistributionは月ごとの最高風速のモデル化に使うことができる．次は，1950年から2009年までの，マサチューセッツ州ボストンにおける月ごとの最大風速(km/h)の記録である：

Wolfram Language code: maxWinds = TemporalData[TimeSeries, {{StructuredArray[QuantityArray, {720}, StructuredArray`StructuredData[QuantityArray, {66.6, 55.8, 55.8, 51.84, 50.04, 50.04, 42.48, 38.88, 66.6, 44.64, 96.48, 55.8, 48.24, 72.36, 55.8, 53.64, 53.64, 44.64, 4 ... 2.48, 46.44, 51.84, 48.24, 46.44, 37.08, 46.44, 46.44, 48.24, 59.4}, "Kilometers"/"Hours", {{1}}]]}, {{1, 720, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 314.1];
Wolfram Language code: maxWinds["FirstValue"]

分布をデータにフィットする：

Wolfram Language code: edist = EstimatedDistribution[maxWinds, ExpGammaDistribution[κ, θ, μ]]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[maxWinds, Automatic, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "Kilometers" / "Hours"]], {x, 0, 100}, PlotStyle -> Thick, PlotRange -> All]]

月の最大風速が時速50キロを超える確率を求める：

Wolfram Language code: Probability[x > Quantity[50, "Miles"/"Hours"], xedist]

月最大風速の平均を求める：

Wolfram Language code: Mean[edist]

月ごとの最大風速のシミュレーションを30ヶ月分行う：

Wolfram Language code: ListPlot[{RandomVariate[edist, 30], {{0, Mean[edist]}, {30, Mean[edist]}}}, Filling -> Axis, Joined -> {False, True}, AxesLabel -> Automatic]

特性と関係  (6)

指数ガンマ分布は平行移動と正の因子によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[a * u + loc, uExpGammaDistribution[κ, θ, μ]]

その他の分布との関係：

ExpGammaDistributionはGammaDistributionを変換したものである：

Wolfram Language code: 𝒟 = TransformedDistribution[θ Log[u], uGammaDistribution[κ, 1], Assumptions -> θ > 0];
Wolfram Language code: PDF[𝒟, x]//FullSimplify[#, x∈Reals && θ > 0]&
Wolfram Language code: PDF[ExpGammaDistribution[κ, θ, 0], x]
Wolfram Language code: % - %%

GumbelDistributionはExpGammaDistributionの特殊ケースである：

Wolfram Language code: PDF[ExpGammaDistribution[1, b, a], x]
Wolfram Language code: PDF[GumbelDistribution[a, b], x]
Wolfram Language code: FullSimplify[% - %%]

ExpGammaDistributionはMinStableDistributionの特殊ケースである：

Wolfram Language code: PDF[MinStableDistribution[μ, σ, 0], x]
Wolfram Language code: PDF[ExpGammaDistribution[1, σ, μ], x]
Wolfram Language code: FullSimplify[% - %%]

MoyalDistributionはExpGammaDistributionを変換したものである：

Wolfram Language code: 𝒟 = TransformedDistribution[-u, uExpGammaDistribution[1 / 2, σ, -μ + σ * Log[2]]];
Wolfram Language code: PDF[𝒟, x]//Simplify
Wolfram Language code: PDF[MoyalDistribution[μ, σ], x]
Wolfram Language code: % - %%//Simplify

おもしろい例題  (1)

累積分布関数の等高線を持つ κ のさまざまな値についての確率密度関数：

Wolfram Language code: cdf = Function[{x, κ}, Evaluate[CDF[ExpGammaDistribution[κ, 2, 1], x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[ExpGammaDistribution[κ, 2, 1], x], {x, -2, 5}, {κ, 0.2, 4}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010), ExpGammaDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExpGammaDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2010), ExpGammaDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExpGammaDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2010. "ExpGammaDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/ExpGammaDistribution.html.

APA

Wolfram Language. (2010). ExpGammaDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ExpGammaDistribution.html

BibTeX

@misc{reference.wolfram_2026_expgammadistribution, author="Wolfram Research", title="{ExpGammaDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ExpGammaDistribution.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_expgammadistribution, organization={Wolfram Research}, title={ExpGammaDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/ExpGammaDistribution.html}, note=[Accessed: 18-August-2026]}