WOLFRAM

Wolfram 语言与系统参考资料中心

ExpGammaDistribution[κ,θ,μ]

表示形状参数为 κ、尺度参数为 θ 以及定位参数为 μ 的指数伽玛分布.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ExpGammaDistribution

ExpGammaDistribution[κ,θ,μ]

表示形状参数为 κ、尺度参数为 θ 以及定位参数为 μ 的指数伽玛分布.

更多信息

背景

范例

打开所有单元 关闭所有单元

基本范例  (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[ExpGammaDistribution[κ, 2, 1], x], {κ, {.25, 1, 2}}]//Evaluate, {x, -4, 6}, Filling -> Axis]
Wolfram Language code: PDF[ExpGammaDistribution[κ, θ, μ], x]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[ExpGammaDistribution[κ, 2, 1], x], {κ, {.25, 1, 2}}]//Evaluate, {x, -4, 6}, Filling -> Axis]
Wolfram Language code: CDF[ExpGammaDistribution[κ, θ, μ], x]

均值和方差：

Wolfram Language code: Mean[ExpGammaDistribution[κ, θ, μ]]
Wolfram Language code: Variance[ExpGammaDistribution[κ, θ, μ]]

中位数：

Wolfram Language code: Median[ExpGammaDistribution[κ, θ, μ]]

范围  (8)

生成服从指数伽玛分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[ExpGammaDistribution[3, 2, 1], 10 ^ 4];

比较其直方图与概率密度函数：

Wolfram Language code: Show[ Histogram[data, 20, "PDF"], Plot[PDF[ExpGammaDistribution[3, 2, 1], x], {x, -2, 6}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[ExpGammaDistribution[.5, 3, 1], 10 ^ 3];

从样本数据中估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, ExpGammaDistribution[k, θ, μ]]

比较样本的密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, -30, 10}, PlotStyle -> Thick]]

偏度取决于形状参数 κ：

Wolfram Language code: Plot[Skewness[ExpGammaDistribution[κ, θ, μ]], {κ, 0, 10}]
Wolfram Language code: Skewness[ExpGammaDistribution[κ, θ, μ]]

极限值：

Wolfram Language code: Limit[Skewness[ExpGammaDistribution[κ, θ, μ]], κ -> 0, Direction -> -1]
Wolfram Language code: Limit[Skewness[ExpGammaDistribution[κ, θ, μ]], κ -> ∞]

峰度取决于形状参数 κ：

Wolfram Language code: Plot[Kurtosis[ExpGammaDistribution[κ, θ, μ]], {κ, 0, 10}]
Wolfram Language code: Kurtosis[ExpGammaDistribution[κ, θ, μ]]

极限值：

Wolfram Language code: Limit[Kurtosis[ExpGammaDistribution[κ, θ, μ]], κ -> 0, Direction -> -1]
Wolfram Language code: Limit[Kurtosis[ExpGammaDistribution[κ, θ, μ]], κ -> ∞]

以参数的函数形式表示不同矩的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[ExpGammaDistribution[κ, θ, μ], k]//FullSimplify, {k, 3}], M]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[ExpGammaDistribution[κ, θ, μ], k]//Together, {k, 3}], CM]

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[ExpGammaDistribution[κ, θ, μ], k]//FullSimplify, {k, 3}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Cumulant[ExpGammaDistribution[κ, θ, μ], k], {k, 3}], C]

具有符号式阶数的解析式：

Wolfram Language code: Cumulant[ExpGammaDistribution[κ, θ, μ], r]

风险函数：

Wolfram Language code: Plot[Table[HazardFunction[ExpGammaDistribution[κ, 3, -1], x], {κ, {1, 10, 15}}]//Evaluate, {x, -1, 10}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[ExpGammaDistribution[3, θ, -1], x], {θ, {6, 10, 15}}]//Evaluate, {x, -1, 10}, Filling -> Axis]
Wolfram Language code: HazardFunction[ExpGammaDistribution[κ, θ, μ], x]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[ExpGammaDistribution[κ, 0.5, -1], q], {κ, {0.5, 1, 3}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Quantile[ExpGammaDistribution[κ, θ, μ], q]

持续在参数中使用 Quantity 会生成分布 QuantityDistribution：

Wolfram Language code: gusts𝒟 = ExpGammaDistribution[2.3, Quantity[65, "kmph"], Quantity[8, "kmph"]]

求风速中位数：

Wolfram Language code: Median[gusts𝒟]

应用  (1)

ExpGammaDistribution 可用于模拟月最大风速. 麻省波士顿从 1950 年 1 月至 2009 年 12 月记录的月最大风速（km/h）：

Wolfram Language code: maxWinds = TemporalData[TimeSeries, {{StructuredArray[QuantityArray, {720}, StructuredArray`StructuredData[QuantityArray, {66.6, 55.8, 55.8, 51.84, 50.04, 50.04, 42.48, 38.88, 66.6, 44.64, 96.48, 55.8, 48.24, 72.36, 55.8, 53.64, 53.64, 44.64, 4 ... 2.48, 46.44, 51.84, 48.24, 46.44, 37.08, 46.44, 46.44, 48.24, 59.4}, "Kilometers"/"Hours", {{1}}]]}, {{1, 720, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 314.1];
Wolfram Language code: maxWinds["FirstValue"]

用分布拟合数据：

Wolfram Language code: edist = EstimatedDistribution[maxWinds, ExpGammaDistribution[κ, θ, μ]]

比较数据的直方图与估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[maxWinds, Automatic, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "Kilometers" / "Hours"]], {x, 0, 100}, PlotStyle -> Thick, PlotRange -> All]]

求每月最大风速超过 50 千米/小时的概率：

Wolfram Language code: Probability[x > Quantity[50, "Miles"/"Hours"], xedist]

求平均每月最大风速：

Wolfram Language code: Mean[edist]

模拟 30 个月的最大风速：

Wolfram Language code: ListPlot[{RandomVariate[edist, 30], {{0, Mean[edist]}, {30, Mean[edist]}}}, Filling -> Axis, Joined -> {False, True}, AxesLabel -> Automatic]

属性和关系  (6)

当平移并且使用一个正因子为比例进行缩放时，新生成的分布仍然是指数伽玛分布：

Wolfram Language code: TransformedDistribution[a * u + loc, uExpGammaDistribution[κ, θ, μ]]

与其它分布的关系：

ExpGammaDistribution 是 GammaDistribution 的一个变换：

Wolfram Language code: 𝒟 = TransformedDistribution[θ Log[u], uGammaDistribution[κ, 1], Assumptions -> θ > 0];
Wolfram Language code: PDF[𝒟, x]//FullSimplify[#, x∈Reals && θ > 0]&
Wolfram Language code: PDF[ExpGammaDistribution[κ, θ, 0], x]
Wolfram Language code: % - %%

GumbelDistribution 是 ExpGammaDistribution 的一个特例：

Wolfram Language code: PDF[ExpGammaDistribution[1, b, a], x]
Wolfram Language code: PDF[GumbelDistribution[a, b], x]
Wolfram Language code: FullSimplify[% - %%]

指数伽玛分布 ExpGammaDistribution 是 MinStableDistribution 的一个特例：

Wolfram Language code: PDF[MinStableDistribution[μ, σ, 0], x]
Wolfram Language code: PDF[ExpGammaDistribution[1, σ, μ], x]
Wolfram Language code: FullSimplify[% - %%]

MoyalDistribution 是 ExpGammaDistribution 的一个变换：

Wolfram Language code: 𝒟 = TransformedDistribution[-u, uExpGammaDistribution[1 / 2, σ, -μ + σ * Log[2]]];
Wolfram Language code: PDF[𝒟, x]//Simplify
Wolfram Language code: PDF[MoyalDistribution[μ, σ], x]
Wolfram Language code: % - %%//Simplify

巧妙范例  (1)

在 CDF 等高线下，不同 κ 数值的概率密度函数：

Wolfram Language code: cdf = Function[{x, κ}, Evaluate[CDF[ExpGammaDistribution[κ, 2, 1], x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[ExpGammaDistribution[κ, 2, 1], x], {x, -2, 5}, {κ, 0.2, 4}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010)，ExpGammaDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExpGammaDistribution.html （更新于 2016 年）.

文本

Wolfram Research (2010)，ExpGammaDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExpGammaDistribution.html （更新于 2016 年）.

CMS

Wolfram 语言. 2010. "ExpGammaDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/ExpGammaDistribution.html.

APA

Wolfram 语言. (2010). ExpGammaDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ExpGammaDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_expgammadistribution, author="Wolfram Research", title="{ExpGammaDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ExpGammaDistribution.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_expgammadistribution, organization={Wolfram Research}, title={ExpGammaDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/ExpGammaDistribution.html}, note=[Accessed: 16-September-2026]}