Wolfram 语言与系统参考资料中心

ExpressionGraph

参见
- TreeGraph
- TreeForm
- TreePlot
- AtomQ
相关指南
- 图的构建与表示
- 参见
  - TreeGraph
  - TreeForm
  - TreePlot
  - AtomQ
- 相关指南
  - 图的构建与表示

ExpressionGraph

ExpressionGraph[expr]

给出树状图，显示不同的深度处不同的层级.

ExpressionGraph[expr,n]

只给出到层级 n 的树状图.

ExpressionGraph[expr,n,form]

给出树状图，其中，与 form 匹配的子表达式为叶子.

范例

打开所有单元关闭所有单元

基本范例 (3)

根据符号表达式构建图，以树的形式表示：

Wolfram Language code: ExpressionGraph[a + b ^ 2 + c ^ 3 + d]

将嵌套表达式显示为对称树：

Wolfram Language code: ExpressionGraph[Nest[{#, #}&, x, 4]]

非对称树：

Wolfram Language code: ExpressionGraph[Nest[{{#}, #, #}&, x, 4]]

限制图形对象的深度：

Wolfram Language code: ExpressionGraph[[image], 2]

范围 (5)

ExpressionGraph 适用于格式化符号表达式：

Wolfram Language code: ExpressionGraph[E^n I π]

ExpressionGraph 适用于含有有下标的变量的表达式：

Wolfram Language code: ExpressionGraph[Subscript[x, 1] + Subscript[x, 2]]

嵌套列表：

Wolfram Language code: ExpressionGraph[{1, {2, {3}}}]

图形对象：

Wolfram Language code: ExpressionGraph[[image]]

限制树的深度：

Wolfram Language code: ExpressionGraph[{1, {2, {3}}}, 2]

用 VertexLabels->Automatic 生成有标签的图：

Wolfram Language code: ExpressionGraph[a + b ^ Cos[e + 1] + c ^ 3 + d + Cos[e], VertexLabels -> Automatic]

给出树状图，其中，与 form 匹配的子表达式为叶子：

Wolfram Language code: ExpressionGraph[a + b ^ Cos[e + 1] + c ^ 3 + d + Cos[e], _Cos, VertexLabels -> Automatic]

选项 (82)

AnnotationRules (3)

指定顶点的注释：

Wolfram Language code: ExpressionGraph[a + b + c, AnnotationRules -> {1 -> {VertexLabels -> "hello"}}]

边：

Wolfram Language code: ExpressionGraph[a + b + c, AnnotationRules -> {12 -> {EdgeLabels -> "hello"}}]

图：

Wolfram Language code: ExpressionGraph[a + b + c, AnnotationRules -> {"GraphProperties" -> {"Message" -> "hello"}}]

Wolfram Language code: AnnotationValue[%, "Message"]

DirectedEdges (1)

默认情况下，生成无向图：

Wolfram Language code: ExpressionGraph[a + b + c]

用 DirectedEdges->True 生成有向图：

Wolfram Language code: ExpressionGraph[a + b + c, DirectedEdges -> True]

EdgeLabels (7)

标注边 12：

Wolfram Language code: ExpressionGraph[a + b, EdgeLabels -> {12 -> "Hello"}]

标注所有的边：

Wolfram Language code: el = EdgeList[ExpressionGraph[a + b]]

Wolfram Language code: ExpressionGraph[a + b, EdgeLabels -> Table[el[[i]] -> Subscript["e", i], {i, Length[el]}]]

将任意表达式用作标签：

Wolfram Language code: ExpressionGraph[a + b ^ 2, EdgeLabels -> {12 -> [image], 13 -> [image], 34 -> [image]}]

将 Placed 与符号位置一起使用，以控制在边的什么位置放置标签：

Wolfram Language code:

Table[ExpressionGraph[a + b, EdgeLabels -> {12 -> Placed["■■■", p]}, PlotLabel -> p], {p, {"Start", "Middle", "End"}}]

用明确的坐标放置标签：

Wolfram Language code:

Table[ExpressionGraph[a + b, EdgeLabels -> {12 -> Placed["■■■", p]}, PlotLabel -> p, BaselinePosition -> Bottom], {p, {0, 1 / 4, 1 / 3}}]

改变标签的位置：

Wolfram Language code:

Table[ExpressionGraph[a + b, EdgeLabels -> {12 -> Placed["■■■", {1 / 2, p}]}, PlotLabel -> p, BaselinePosition -> Bottom], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

放置多个标签：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeLabels -> {12 -> Placed[{"lbl1", "lbl2"}, {"Start", "End"}]}]

Wolfram Language code: ExpressionGraph[a + b + c, EdgeLabels -> {12 -> Placed[{"lbl1", "lbl2", "lbl3"}, {"Start", "Middle", "End"}]}]

通过 Tooltip 和 StatusArea 用值进行自动标注：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeLabels -> Placed["Name", Tooltip]]

Wolfram Language code: ExpressionGraph[a + b + c, EdgeLabels -> Placed["Name", StatusArea]]

EdgeShapeFunction (6)

获取 EdgeShapeFunction 的内置设置列表：

Wolfram Language code: ResourceData["EdgeShapeFunction"]

使用简单直线的无向边：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeShapeFunction -> "Line"]

用具有不同标记符号的直线作为边：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, {"BoxLine", "DiamondLine", "DotLine"}}]

使用实箭头的有向边：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, ResourceData["EdgeShapeFunction", "FilledArrow"]}]

线状箭头：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, ResourceData["EdgeShapeFunction", "UnfilledArrow"]}]

空心箭头：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, ResourceData["EdgeShapeFunction", "CarvedArrow"]}]

为个别边指定边函数：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeShapeFunction -> {12 -> "DotLine"}]

与不同的默认边函数组合使用：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeShapeFunction -> {12 -> "BoxLine", "DotLine"}]

通过运行程序绘制边：

Wolfram Language code:

ef[pts_List, e_] := 
	Block[{s = 0.015, g = [image]}, {Arrowheads[{{s, 0.33, g}, {s, 0.67, g}}], Arrow[pts]}]

Wolfram Language code: ExpressionGraph[a + b + c, EdgeShapeFunction -> ef]

EdgeShapeFunction 可与 EdgeStyle 组合使用：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeStyle -> Blue, EdgeShapeFunction -> (Line[#1]&)]

EdgeShapeFunction 比 EdgeStyle 的优先级高：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeStyle -> Blue, EdgeShapeFunction -> ({Red, Line[#1]}&)]

EdgeStyle (2)

为所有的边设置样式：

Wolfram Language code: Table[ExpressionGraph[a + b + c, EdgeStyle -> style], {style, {Gray, Dashed, Thick}}]

为个别的边设置样式：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeStyle -> {12 -> Blue, 13 -> Dashed}]

EdgeWeight (3)

指定所有边的权重：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeWeight -> RandomInteger[5, 2]]

Wolfram Language code: WeightedAdjacencyMatrix[%]//MatrixForm

用任意数值表达式作为权重：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeWeight -> {a, b}]

Wolfram Language code: WeightedAdjacencyMatrix[%]//MatrixForm

指定个别边的权重：

Wolfram Language code: ExpressionGraph[a + b + c, EdgeWeight -> {12 -> 2, 13 -> 4}]

Wolfram Language code: AnnotationValue[{%, 12}, EdgeWeight]

GraphHighlight (3)

突出显示顶点 1：

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> Tiny, GraphHighlight -> {1}]

突出显示边 13：

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> Tiny, GraphHighlight -> {13}]

突出显示边和顶点：

Wolfram Language code: ExpressionGraph[a + b + 1, VertexSize -> Tiny, GraphHighlight -> {1, 2, 12, 13}]

GraphHighlightStyle (2)

获取 GraphHighlightStyle 的内置设置的列表：

Wolfram Language code: ResourceData["GraphHighlightStyle"]

使用 GraphHighlightStyle 的内置设置：

Wolfram Language code:

ExpressionGraph[a + b + c, GraphHighlight -> {1, 13}, VertexSize -> Small, GraphHighlightStyle -> #, PlotLabel -> #]& /@ Select[ResourceData["GraphHighlightStyle"], # =!= Automatic&]

GraphLayout (5)

默认情况下，自动选择布局：

Wolfram Language code: ExpressionGraph[a + b + c, GraphLayout -> Automatic]

指定排布到特殊曲线上：

Wolfram Language code:

Table[ExpressionGraph[a + b ^ 2, GraphLayout -> l, PlotLabel -> Style[l, 10]], {l, {"CircularEmbedding", "SpiralEmbedding"}}]

指定满足最佳标准的布局：

Wolfram Language code:

Table[ExpressionGraph[a + b ^ 2 + c ^ 3 + d, GraphLayout -> l, PlotLabel -> Style[l, 10]], {l, {"SpringEmbedding", "SpringElectricalEmbedding", "HighDimensionalEmbedding"}}]

VertexCoordinates 将覆盖 GraphLayout 的坐标：

Wolfram Language code:

{ExpressionGraph[a + b + c, GraphLayout -> "SpringElectricalEmbedding"], 
	ExpressionGraph[a + b + c, GraphLayout -> "SpringElectricalEmbedding", VertexCoordinates -> Table[{i, i}, {i, 0, 3}]]}

用 AbsoluteOptions 提取用布局算法得出的 VertexCoordinates：

Wolfram Language code: ExpressionGraph[a + b + c]

Wolfram Language code: AbsoluteOptions[%, VertexCoordinates]

PlotTheme (4)

基本主题 (2)

使用常见基本主题：

Wolfram Language code: ExpressionGraph[a + b + c, PlotTheme -> "Business"]

使用单色主题：

Wolfram Language code: ExpressionGraph[a + b + c, PlotTheme -> "Monochrome"]

特色主题 (2)

使用大图主题：

Wolfram Language code: ExpressionGraph[a + b + c, PlotTheme -> "LargeGraph"]

使用传统的示意图主题：

Wolfram Language code: ExpressionGraph[a + b + c, PlotTheme -> "ClassicDiagram"]

VertexCoordinates (2)

默认情况下，自动计算所有顶点的坐标：

Wolfram Language code: ExpressionGraph[a + b + c]

用 AbsoluteOptions 提取所得的顶点坐标：

Wolfram Language code: AbsoluteOptions[%, VertexCoordinates]

指定椭圆形布局函数：

Wolfram Language code: ellipseLayout[n_, {a_, b_}] := Table[{a Cos[2Pi / n u], b Sin[2Pi / n u]}, {u, 1, n}]

Wolfram Language code: Graphics[Point[ellipseLayout[29, {2, 1}]]]

用它来生成图的顶点坐标：

Wolfram Language code: ExpressionGraph[a + b ^ 2 + c ^ 3 + d, VertexCoordinates -> ellipseLayout[9, {2, 1}]]

VertexLabels (13)

用顶点名称作为标签：

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> "Name"]

标注个别顶点：

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> {1 -> "one"}]

标注所有顶点：

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> Table[i -> Subscript[v, i], {i, 3}]]

用任意表达式作为标签：

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> {1 -> **[image]**, 2 -> [image], 3 -> [image]}]

将 Placed 与符号式位置合用，控制标签的放置，包括顶点外的位置：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexSize -> 0.1, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], PlotLabel -> p, ImagePadding -> 20], {p, {Before, After, Below, Above}}]

顶点外的符号式角落位置：

Wolfram Language code: pl = {{Before, Below}, {After, Below}, {Before, Above}, {After, Above}};

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexSize -> 0.1, VertexShapeFunction -> "Square", ImagePadding -> 20, VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], PlotLabel -> p], {p, pl}]

顶点内的符号式位置：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexSize -> 0.25, VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], VertexShapeFunction -> "Square", PlotLabel -> p], {p, {Left, Top, Right, Bottom}}]

顶点内的符号式角落位置：

Wolfram Language code: pl = {{Left, Bottom}, {Right, Bottom}, {Left, Top}, {Right, Top}};

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexSize -> 0.25, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], PlotLabel -> p], {p, pl}]

使用显式坐标指定标签的中心：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexSize -> 0.25, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed[[image], p], {i, 4}], PlotLabel -> p, BaselinePosition -> Bottom], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

将所有标签放在顶点的右上角，并改变标签内的坐标：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexSize -> 0.35, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed[[image], {{1, 1}, p}], {i, 4}], PlotLabel -> p, BaselinePosition -> Bottom], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

放置多个标签：

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> {1 -> Placed[{"lbl1", "lbl2"}, {Above, Below}]}]

可使用任意数量的标签：

Wolfram Language code:

ExpressionGraph[a + b + c, VertexLabels -> {1 -> Placed[{"lbl1", "lbl2", "lbl3", "lbl4"}, {Above, After, Below, Before}]}]

用 Placed 的参数控制格式，包括 Tooltip：

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> Placed["Name", Tooltip]]

或 StatusArea：

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> Placed["Name", StatusArea]]

使用更精细的格式函数：

Wolfram Language code: rotateLabel[lab_] := Rotate[lab, 45Degree]

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> Table[i -> Placed["xxx", Below, rotateLabel], {i, 4}]]

Wolfram Language code: panelLabel[lab_] := Panel[lab, FrameMargins -> 0, Background -> Lighter[Yellow, 0.7]]

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> Table[i -> Placed["xxx", Center, panelLabel], {i, 4}]]

Wolfram Language code: hyperlinkLabel[lab_] := Hyperlink[lab, "http://www.wolfram.com"]

Wolfram Language code: ExpressionGraph[a + b + c, VertexLabels -> Table[i -> Placed["xxx", Center, hyperlinkLabel], {i, 4}]]

VertexShape (5)

使用任意 Graphics、Image 或 Graphics3D 作为顶点的形状：

Wolfram Language code: Table[ExpressionGraph[a + b + c, VertexShape -> s, VertexSize -> Medium], {s, {[image], [image], [image]}}]

指定个别顶点的形状：

Wolfram Language code: ExpressionGraph[a + b + c, VertexShape -> {2 -> [image]}, VertexSize -> Small]

VertexShape 可与 VertexSize 组合使用：

Wolfram Language code: Table[ExpressionGraph[a + b + c, VertexSize -> s, VertexShape -> [image], PlotLabel -> s], {s, {Small, Large}}]

VertexShape 不受 VertexStyle 的影响：

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> 0.2, VertexShape -> [image], VertexStyle -> Blue]

VertexShapeFunction 比 VertexShape 的优先级高：

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> 0.1, VertexShapeFunction -> "Square", VertexShape -> [image]]

VertexShapeFunction (10)

获取 VertexShapeFunction 的内置集合列表：

Wolfram Language code: ResourceData["VertexShapeFunction"]

使用 "Basic" 集合中 VertexShapeFunction 的内置设置：

Wolfram Language code: ResourceData["VertexShapeFunction", "Basic"]

简单的基本形状：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, {"Triangle", "Square", "Rectangle", "Pentagon", "Hexagon", "Octagon"}}]

常见基本形状：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, {"DownTrapezoid", "UpTrapezoid", "Parallelogram", "FiveDown", "Circle", "Diamond", "Star", "Capsule"}}]

使用 "Rounded" 集合中 VertexShapeFunction 的内置设置：

Wolfram Language code: ResourceData["VertexShapeFunction", "Rounded"]

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, ResourceData["VertexShapeFunction", "Rounded"]}]

使用 "Concave" 集合中 VertexShapeFunction 的内置设置：

Wolfram Language code: ResourceData["VertexShapeFunction", "Concave"]

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, ResourceData["VertexShapeFunction", "Concave"]}]

绘制个别顶点：

Wolfram Language code: ExpressionGraph[a + b + c, VertexShapeFunction -> { 1 -> "Square"}, VertexSize -> 0.2]

与默认顶点函数组合使用：

Wolfram Language code: ExpressionGraph[a + b + c, VertexShapeFunction -> { 1 -> "Square", "Triangle"}, VertexSize -> 0.2]

用预定义的图形绘制顶点：

Wolfram Language code: ExpressionGraph[a + b + c, VertexShapeFunction -> (Inset[[image], #]&)]

通过运行程序绘制顶点：

Wolfram Language code:

vf[{xc_, yc_}, name_, {w_, h_}] := 
	Block[{xmin = xc - w, xmax = xc + w, ymin = yc - h, ymax = yc + h}, 
	Polygon[{{xmin, ymin}, {xmax, ymax}, {xmin, ymax}, {xmax, ymin}}]
	];

Wolfram Language code: ExpressionGraph[a + b + c, VertexShapeFunction -> vf, VertexSize -> 0.2]

VertexShapeFunction 可与 VertexStyle 组合使用：

Wolfram Language code: vf1[{xc_, yc_}, name_, {w_, h_}] := Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf1]

VertexShapeFunction 比 VertexStyle 的优先级高：

Wolfram Language code: vf2[{xc_, yc_}, name_, {w_, h_}] := {Red, Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]}

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf2]

VertexShapeFunction 可与 VertexSize 组合使用：

Wolfram Language code: ExpressionGraph[a + b + c, VertexShapeFunction -> "Star", VertexSize -> {1 -> Small, Medium}]

VertexShapeFunction 比 VertexShape 的优先级高：

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> 0.3, VertexShapeFunction -> "Star", VertexShape -> [image]]

VertexSize (8)

默认情况下，自动计算顶点的大小：

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> Automatic]

用符号式顶点大小指定所有顶点的尺寸：

Wolfram Language code: Table[ExpressionGraph[a + b + c, VertexSize -> s, PlotLabel -> s], {s, {Tiny, Small, Medium, Large}}]

用顶点坐标之间的最小距离的比例指定顶点的大小：

Wolfram Language code: Table[ExpressionGraph[a + b + c, VertexSize -> s, PlotLabel -> s], {s, 0.1, 1, 0.3}]

用所有顶点坐标整体对角尺寸的比例指定顶点的大小：

Wolfram Language code: Table[ExpressionGraph[a + b + c, VertexSize -> {"Scaled", s}, PlotLabel -> {"Scaled", s}], {s, 0.1, 1, 0.3}]

指定在方向和方向的大小：

Wolfram Language code: Table[ExpressionGraph[a + b + c, VertexSize -> s, PlotLabel -> s], {s, {{0.1, 0.2}, {0.2, 0.1}}}]

指定个别顶点的大小：

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> {1 -> 0.2, 2 -> 0.3}]

VertexSize 可与 VertexShapeFunction 组合使用：

Wolfram Language code:

Table[ExpressionGraph[a + b + c, VertexSize -> s, VertexShapeFunction -> "Square", PlotLabel -> s], {s, {0.05, 0.1, 0.2}}]

VertexSize 可与 VertexShape 组合使用：

Wolfram Language code: Table[ExpressionGraph[a + b + c, VertexSize -> s, VertexShape -> [image], PlotLabel -> s], {s, {0.1, 0.2, 0.4}}]

VertexStyle (5)

为所有的顶点设置样式：

Wolfram Language code: Table[ExpressionGraph[a + b + c, VertexStyle -> style, VertexSize -> 0.3], {style, {Yellow, EdgeForm[Dashed]}}]

为个别顶点设置样式：

Wolfram Language code: ExpressionGraph[a + b + c, VertexStyle -> {1 -> Blue, 2 -> Red}, VertexSize -> 0.2]

VertexShapeFunction 可与 VertexStyle 组合使用：

Wolfram Language code: vf1[{xc_, yc_}, name_, {w_, h_}] := Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf1]

VertexShapeFunction 比 VertexStyle 的优先级高：

Wolfram Language code: vf2[{xc_, yc_}, name_, {w_, h_}] := {Red, Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]}

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf2]

VertexStyle 可与 BaseStyle 组合使用：

Wolfram Language code: ExpressionGraph[a + b + c, VertexStyle -> LightBlue, BaseStyle -> EdgeForm[Dotted], VertexSize -> 0.2]

VertexStyle 比 BaseStyle 的优先级高：

Wolfram Language code: ExpressionGraph[a + b + c, VertexStyle -> LightBlue, BaseStyle -> Gray, VertexSize -> 0.2]

VertexShape 不受 VertexStyle 的影响：

Wolfram Language code: ExpressionGraph[a + b + c, VertexSize -> 0.2, VertexShape -> [image], VertexStyle -> Blue]

VertexWeight (3)

设置所有顶点的权重：

Wolfram Language code: ExpressionGraph[a + b + c, VertexWeight -> {2, 3, 4, 5}]

Wolfram Language code: AnnotationValue[{%, 1}, VertexWeight]

指定个别顶点的权重：

Wolfram Language code: ExpressionGraph[a + b + c, VertexWeight -> {1 -> 2}]

Wolfram Language code: AnnotationValue[{%, 1}, VertexWeight]

用任意数值表达式作为权重：

Wolfram Language code: ExpressionGraph[a + b + c, VertexWeight -> {a, b, c, d}]

Wolfram Language code: AnnotationValue[{%, 1}, VertexWeight]

应用 (2)

将布尔代数的 Wolfram 公理可视化为树：

Wolfram Language code: ExpressionGraph[f[f[f[p, q], r], f[p, f[f[p, r], p]]] == r]

生成递归编程树：

Wolfram Language code:

F[1] := "f[1]";
F[0] := "f[0]";
F[n_] /; n > 1 := ToString[f[n]][F[n - 1], F[n - 2]]

Wolfram Language code: ExpressionGraph[F[6]]

属性和关系 (5)

用 VertexCount 和 EdgeCount 计算顶点数和边数：

Wolfram Language code: g = ExpressionGraph[a + b ^ 2 + c]

Wolfram Language code: {VertexCount[g], EdgeCount[g]}

用 VertexList 和 EdgeList 以标准顺序列出顶点和边：

Wolfram Language code: g = ExpressionGraph[a + b ^ 2 + c]

Wolfram Language code: {VertexList[g], EdgeList[g]}

从一个图计算 AdjacencyMatrix:

Wolfram Language code: g = ExpressionGraph[Rectangle[]]

Wolfram Language code: AdjacencyMatrix[g]//MatrixForm

FullForm 给出与 ExpressionGraph 类似的线性表达式：

Wolfram Language code: FullForm[1 / (a + b) * x ^ 2]

Wolfram Language code: ExpressionGraph[1 / (a + b) * x ^ 2, VertexLabels -> Automatic]

用 TreeForm 绘制树状图：

Wolfram Language code: TreeForm[1 / (a + b) * x ^ 2]

可能存在的问题 (1)

ExpressionGraph[expr] 可用于对表达式 expr 进行计算：

Wolfram Language code: ExpressionGraph[1 + 1, VertexLabels -> Automatic]

Wolfram Language code: ExpressionGraph[Unevaluated[1 + 1], VertexLabels -> Automatic]

巧妙范例 (2)

完整的二叉树：

Wolfram Language code: Nest[{#, #}&, x, 4]

Wolfram Language code: ExpressionGraph[%]

完整的三叉树：

Wolfram Language code: Nest[{#, #, #}&, x, 3]

Wolfram Language code: ExpressionGraph[%]

RGB 颜色立方体表达式树：

Wolfram Language code: ExpressionGraph[[image]]

Top

AlignmentPoint	Center	在图形内对齐的缺省点
AnnotationRules	{}	图、边和顶点的注释
AspectRatio	Automatic	高与宽的比
Axes	False	是否绘制轴
AxesLabel	None	坐标轴标签
AxesOrigin	Automatic	坐标轴原点
AxesStyle	{}	坐标轴样式指定
Background	None	绘图的背景色
BaselinePosition	Automatic	如何与环绕文本基线对齐
BaseStyle	{}	图形的基本样式指定
ContentSelectable	Automatic	是否允许进行内容选择
CoordinatesToolOptions	Automatic	坐标工具的详细行为
DirectedEdges	Automatic	是否将 Rule 解释为 DirectedEdge
EdgeLabels	None	边的标签和标签放置
EdgeLabelStyle	Automatic	边的标签所使用的样式
EdgeShapeFunction	Automatic	如何生成边的图形表示
EdgeStyle	Automatic	边的样式
EdgeWeight	Automatic	边的权值
Epilog	{}	主图形之后执行的图形指令
FormatType	StandardForm	用于顶点和边标签的格式类型
Frame	False	是否在图形周围放置边框
FrameLabel	None	边框标签
FrameStyle	{}	边框的样式指定
FrameTicks	Automatic	边框刻度
FrameTicksStyle	{}	边框刻度的样式指定
GraphHighlight	{}	要突出显示的图的元素
GraphHighlightStyle	Automatic	突出显示时使用的样式
GraphLayout	Automatic	如何设计顶点和边的布局
GridLines	None	绘制的网格线
GridLinesStyle	{}	网格线的样式指定
ImageMargins	0.	图形周围的边幅
ImagePadding	All	为标签等额外填充内容
ImageSize	Automatic	图形的绝对尺寸
LabelStyle	{}	标签的样式指定
Method	Automatic	使用图形方式的细节
PerformanceGoal	Automatic	优化的目标
PlotLabel	None	图形的一个整体标签
PlotRange	All	图形值的范围
PlotRangeClipping	False	是否在图形范围剪切
PlotRangePadding	Automatic	填充图形值范围的程度
PlotRegion	Automatic	填充的最后显示区域
PlotTheme	$PlotTheme	图的整体主题样式
PreserveImageOptions	Automatic	当显示相同图形的新版本时，是否保存图形选项
Prolog	{}	主图形之前执行的图形指令
RotateLabel	True	是否在边框上旋转 y 标签
Ticks	Automatic	坐标轴标记
TicksStyle	{}	坐标轴标记的样式指定
VertexCoordinates	Automatic	顶点的坐标
VertexLabels	None	顶点的标签和位置
VertexLabelStyle	Automatic	顶点的标签所使用的样式
VertexShape	Automatic	顶点的形状
VertexShapeFunction	Automatic	生成顶点的形状的函数
VertexSize	Medium	顶点的大小
VertexStyle	Automatic	顶点的样式
VertexWeight	Automatic	顶点的权值

ExpressionGraph

更多信息和选项

所有选项的列表

范例

基本范例 (3)

范围 (5)

选项 (82)

AnnotationRules (3)

DirectedEdges (1)

EdgeLabels (7)

EdgeShapeFunction (6)

EdgeStyle (2)

EdgeWeight (3)

GraphHighlight (3)

GraphHighlightStyle (2)

GraphLayout (5)

PlotTheme (4)

基本主题 (2)

特色主题 (2)

VertexCoordinates (2)

VertexLabels (13)

VertexShape (5)

VertexShapeFunction (10)

VertexSize (8)

VertexStyle (5)

VertexWeight (3)

应用 (2)

属性和关系 (5)

可能存在的问题 (1)

巧妙范例 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX