WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

LevyDistribution[μ,σ]

位置母数 μ，分散パラメータ σ のレヴィ(Lévy)分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

LevyDistribution

LevyDistribution[μ,σ]

位置母数 μ，分散パラメータ σ のレヴィ(Lévy)分布を表す．

詳細

予備知識

  • LevyDistribution[μ,σ]は，区間でサポートされ，実数 μ（「位置母数」と呼ばれる）および正の実数 σ（「分散母数」と呼ばれる）でパラメータ化された統計分布を表す．レヴィ分布の確率密度関数(PDF)は，大体において単一の「峰」（最大値）を持つ単峰性であるが，その全体的な形状（高さ， の線近くでの集中度，最大値の水平位置）は μ と σ の値で決定される．これに加え，PDFの裾部は，PDFが の大きい値について指数的というよりむしろ代数的に現象するという意味で「太い」（この現象は分布のSurvivalFunctionを分析することで数量的に正確にできる）．レヴィ分布は，レヴィ分布に従う独立した確率変数の任意の線形結合が再びレヴィ分布に従うという意味でいわゆる安定分布(StableDistribution)であり，安定分布のある種の部分集合を説明するために使われる，より一般的な用語の「パレート・レヴィ分布」および「レヴィ(α)安定分布」と混同してはならない．
  • レヴィ分布はフランス人の数学者Paul Lévyに因んで名付けられた．レヴィ分布の歴史は（1920年代にレヴィによってはじめて詳しく説明された）他の安定分布のより一般的なクラスと切り離すことはできないが，簡約されたレヴィ分布のPDFについては，1919年にオランダ人の天文学者Holtsmarkによって重力場のランダム振動についての叙述の一部としてなはじめて書かれている．安定分布族は，当初は現実世界への応用が欠けているとして数学者や確率論の研究者に無視されたが，ブラウン運動（いわゆるレヴィフライト）を含むさまざまな概念の分析に用いられ，現在では金融工学や数理ファイナンスの分野の重要なツールとなっている．さらに，レヴィ分布は，地球磁気学，素粒子物理学，暗号学，信号解析，生物学のような分野における数多くの重要な現象の説明に使われている．
  • RandomVariateを使って，レヴィ分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,LevyDistribution[μ,σ]]（より簡略な表記では xLevyDistribution[μ,σ]）を使って，確率変数 x がレヴィ分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • レヴィ分布の確率密度関数および累積分布関数は，PDF[LevyDistribution[μ,σ],x]およびCDF[LevyDistribution[μ,σ],x]を使って得られる．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．しかし，LevyDistributionは裾部が長いため， 番目の原点の周りのモーメントと中心モーメント（平均と分散を含む）はすべての についてであり，そのモーメント母関数(MomentGeneratingFunction)はIndeterminateである．
  • DistributionFitTestを使って，与えられたデータ集合がレヴィ分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリックレヴィ分布を推定することが，FindDistributionParametersを使ってデータをレヴィ分布にフィットすることができる．ProbabilityPlotを使って記号レヴィ分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号レヴィ分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換されたレヴィ分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってレヴィ分布を含む高次元分布を構築することが，ProductDistributionを使ってレヴィ分布を含む独立成分分布の結合分布を計算することができる．
  • LevyDistributionは他の多くの分布と密接な関係がある．例えば，LevyDistributionはStableDistributionの一つの例である（LevyDistribution[μ,σ]は厳密にStableDistribution[0,1/2,1,μ+σ,σ]である）．したがって，CauchyDistribution，LandauDistribution，NormalDistribution等の他の安定分布に関連している．LevyDistributionは，InverseGammaDistributionとPearsonDistribution両方の特殊ケースであり，（TransformedDistributionを介して）NormalDistributionの変換として得ることができる．LevyDistributionは，HalfNormalDistribution，ChiSquareDistribution，GammaDistribution，InverseGaussianDistributionとも関連している．

例題

すべて開く すべて閉じる

例  (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[LevyDistribution[1, σ], x], {σ, {1 / 2, 1, 2}}]//Evaluate, {x, 1.1, 3}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Table[PDF[LevyDistribution[μ, 1.5], x], {μ, {-1 / 2, 1, 2}}]//Evaluate, {x, -1, 5}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: PDF[LevyDistribution[μ, σ], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[LevyDistribution[1, σ], x], {σ, {1 / 2, 1, 2}}]//Evaluate, {x, 1.1, 3}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Table[CDF[LevyDistribution[μ, 1.5], x], {μ, {-1 / 2, 1, 2}}]//Evaluate, {x, -1, 5}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: CDF[LevyDistribution[μ, σ], x]

レヴィ分布の平均と分散は無限大である：

Wolfram Language code: Mean[LevyDistribution[μ, σ]]
Wolfram Language code: Variance[LevyDistribution[μ, σ]]

中央値：

Wolfram Language code: Median[LevyDistribution[μ, σ]]

スコープ  (6)

レヴィ分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[LevyDistribution[1, 2], 10 ^ 4];

これのヒストグラムを確率密度関数と比較する：

Wolfram Language code: Show[ Histogram[data, {1, 10, 0.5}, "PDF"], Plot[PDF[TruncatedDistribution[{1, 10}, LevyDistribution[1, 2]], x], {x, 1.1, 10}, PlotStyle -> Thick, PlotRange -> All]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[LevyDistribution[1, 3], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, LevyDistribution[μ, σ]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, {1, 20, 1}, "PDF"], Plot[PDF[TruncatedDistribution[{1, 20}, edist], x], {x, 1, 20}, PlotStyle -> Thick]]

次数 のモーメントは存在しない：

Wolfram Language code: Moment[LevyDistribution[μ, σ], r]

次数 については一般化されたモーメントが存在する：

Wolfram Language code: Expectation[x ^ r, xLevyDistribution[0, 1], Assumptions -> r < 1 / 2]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[LevyDistribution[μ, 2], x], {μ, {-1, 2, 3}}]//Evaluate, {x, -2, 10}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[LevyDistribution[2, σ], x], {σ, {1, 2, 3}}]//Evaluate, {x, 2.1, 6}, Filling -> Axis]
Wolfram Language code: HazardFunction[LevyDistribution[μ, σ], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[LevyDistribution[1, σ], q], {σ, {0.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Quantile[LevyDistribution[μ, σ], q]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: geomMagneticReversalTime𝒟 = LevyDistribution[["0.01 millenia"], ["200 millenia"]]

四分位数を求める：

Wolfram Language code: Quartiles[geomMagneticReversalTime𝒟]

アプリケーション  (1)

ファンデルワールス(van der Waals)スペクトル断片の半値幅を求める：

Wolfram Language code: profile[ω_] = PDF[LevyDistribution[0, 1], ω]
Wolfram Language code: Plot[profile[ω], {ω, 0.1, 5}, Filling -> Axis]

最大値の位置を計算する：

Wolfram Language code: ω0 = ArgMax[profile[ω], ω]

半値の点について解く：

Wolfram Language code: ω /. NSolve[profile[ω] == profile[ω0] / 2, ω, Reals]

幅を求める：

Wolfram Language code: Differences[%]

放出される粒子の周波数はモードよりも大きい確率が高い：

Wolfram Language code: NProbability[ω > ω0, ωLevyDistribution[0, 1]]

特性と関係  (7)

レヴィ分布は平行移動と正の因子によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[a * u + b, uLevyDistribution[μ, σ]]

レヴィ分布は加算の下では閉じている：

Wolfram Language code: TransformedDistribution[x + y, {xLevyDistribution[Subscript[μ, 1], Subscript[σ, 1]], yLevyDistribution[Subscript[μ, 2], Subscript[σ, 2]]}]

他の分布との関係：

LevyDistribution[0,σ]はInverseGammaDistributionの特殊ケースである：

Wolfram Language code: PDF[LevyDistribution[0, σ], x]
Wolfram Language code: PDF[InverseGammaDistribution[1 / 2, σ / 2], x]
Wolfram Language code: Simplify[% - %%]

レヴィ分布はタイプ5のPearsonDistributionの特殊ケースである：

Wolfram Language code: PDF[PearsonDistribution[5, 1, -μ - (σ/3), (2/3), -(4/3)μ, (2/3)μ^2], x]//FullSimplify
Wolfram Language code: PDF[LevyDistribution[μ, σ], x]//PowerExpand
Wolfram Language code: Simplify[% - %%]

レヴィ分布はNormalDistributionを変換したものである：

Wolfram Language code: TransformedDistribution[u ^ -2, uNormalDistribution[]]

平均とスケールとともに：

Wolfram Language code: TransformedDistribution[(u - μ) ^ -2, uNormalDistribution[μ, σ]]

レヴィ分布はStableDistributionである：

Wolfram Language code: PDF[LevyDistribution[μ, σ], x]
Wolfram Language code: PDF[StableDistribution[0, 1 / 2, 1, μ + σ, σ], x]
Wolfram Language code: % - %%//FullSimplify

考えられる問題  (2)

LevyDistributionは μ が実数ではない場合は定義されない：

Wolfram Language code: Mean[LevyDistribution[I, 5]]

LevyDistributionは σ が正の実数でなければ定義されない：

Wolfram Language code: Mean[LevyDistribution[0, -5]]

記号出力に有効ではないパラメータを代入すると無意味な結果になる：

Wolfram Language code: CDF[LevyDistribution[μ, σ], 1] /. {μ -> 0, σ -> 1 + I}
Wolfram Language code: N[%]

おもしろい例題  (1)

累積分布関数の等高線を持つ μ のさまざまな値についての確率密度関数：

Wolfram Language code: dist = LevyDistribution[μ, 1.5];cdf = Function[{x, μ}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, -3.5, 20}, {μ, -3, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotPoints -> 50, PlotRange -> {0, 0.4}], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2008), LevyDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/LevyDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2008), LevyDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/LevyDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2008. "LevyDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/LevyDistribution.html.

APA

Wolfram Language. (2008). LevyDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LevyDistribution.html

BibTeX

@misc{reference.wolfram_2026_levydistribution, author="Wolfram Research", title="{LevyDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/LevyDistribution.html}", note=[Accessed: 02-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_levydistribution, organization={Wolfram Research}, title={LevyDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/LevyDistribution.html}, note=[Accessed: 02-November-2026]}