WOLFRAM

Wolfram 语言与系统参考资料中心

Line[{p1,p2,…}]

表示连接点 pi 的线段.

Line[{{p11,p12,…},{p21,…},…}]

表示一组线段.

更多信息和选项
Details and Options Details and Options
背景
范例  
基本范例  
范围  
图形  
规范  
样式  
坐标  
区域  
选项  
VertexColors  
VertexNormals  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Line

Line[{p1,p2,…}]

表示连接点 pi 的线段.

Line[{{p11,p12,…},{p21,…},…}]

表示一组线段.

更多信息和选项

背景

  • Line 是一个图形和几何基元，表示一个几何线段或相连的线段序列（折线）. 在 -维空间中，连接 个点的 Line 的位置由 个子列表组成的变量列表确定，每个子列表包含 个直角坐标值. Line 对象的子列表中的坐标值可以是精确的，也可以是近似值，其中，可以用 RegionEmbeddingDimension 来确定所给 Line 表达式的维度 . 一组线段（或折线）还可以用一个嵌套在单个 Line 基元（“多线段”）中的 -元组表示. Line 对象的坐标值可以是精确的，也可以是近似值.
  • 可以分别使用 Graphics 和 Graphics3D 在二维空间或三维空间显示 Line 对象. 通过使用 GeoGraphics 和 GeoPosition（例如 GeoGraphics[Line[GeoPosition[{{38.9,-77.0},{40.1,-88.3}}]]]），Line 对象还可以用在地图中. 另外，也可用 Line 来定义一个进行某种计算用的区域.
  • 尽管线段自身的维度为 1（见 RegionDimension 函数的结果），粗细为零，但在格式化的图形表达式的缺省输出中，Line 对象被显示为看起来有粗细的一条线，而不是一条一维的数学意义上的线段. 而且在图形可视化中，不管从哪个角度看，距离有多远，图形中的线的尺寸不变. 如果想要改变 Line 对象的样式，可以使用调整粗细的指令，比如 Thickness、AbsoluteThickness、Thick 和 Thin；还有改变线的虚实的指令，比如 Dashing、AbsoluteDashing、Dashed、Dotted 和 DotDashed；指定边和线帽形状的指令，有 EdgeForm 和 CapForm；着色指令，比如 Red，规定透明度的指令 Opacity；以及样式选项 Antialiasing. 此外，可以用 VertexColors 指定多条线段的颜色，而 Graphics3D 中的阴影和模拟光照则可使用 VertexNormals 指令来实现.
  • 我们可以使用 GeometricTransformation 和更具体的转换函数，比如 Translate 和 Rotate，来改变图形输出中 Line 对象所在的坐标系，而保持产生该输出的 Line 表达式不变.
  • 其他图形基元，如 Tube、Arrow、HalfLine 及 InfiniteLine 和样式经过调整的 Line 对象类似. 但是折线仅由直线段组成，如果想要生成光滑的曲线，可以利用 BSplineCurve、BezierCurve 指令产生样条曲线，或者通过插值函数 Interpolation. 有一个和 Line 作为几何区域有关的函数 Interval，它将一对数字作为一个线段在数轴上的端点，并可对它直接进行算术及关系运算.
  • 尽管 Line 基元可以出现在图形和定义几何区域的表达式中，但我们要注意到，在 Wolfram 语言里，其他情况下坐标通常都以列表形式表示. 许多图形函数，包括 Plot、ParametricPlot、ParametricPlot3D 和 ContourPlot，返回的图形表达式中会显式包含 Line 对象.

范例

打开所有单元 关闭所有单元

基本范例  (4)

一个线段基元：

Wolfram Language code: Graphics[Line[{{1, 0}, {2, 1}, {3, 0}, {4, 1}}]]
Wolfram Language code: Graphics3D[Line[{{1, 1, -1}, {2, 2, 1}, {3, 3, -1}, {4, 4, 1}}]]

不同样式的二维线段：

Wolfram Language code: l = Line[{{1, 0}, {2, 1}, {3, 0}, {4, 1}, {5, 0}, {6, 1}}];
Wolfram Language code: {Graphics[{Dashed, l}], Graphics[{Pink, l}], Graphics[{Thick, l}], Graphics[{Thick, Dashed, Pink, l}]}

不同样式的三维线段：

Wolfram Language code: l = Line[{{1, 1, -1}, {2, 2, 1}, {3, 3, -1}, {4, 4, 1}}];
Wolfram Language code: {Graphics3D[{Dashed, l}], Graphics3D[{Pink, l}], Graphics3D[{Thick, l}], Graphics3D[{Thick, Dashed, Pink, l}]}

计算线段的 ArcLength：

Wolfram Language code: ArcLength[Line[{{0, 0}, {1, 1}}]]

几何中心：

Wolfram Language code: RegionCentroid[Line[{{0, 0}, {1, 1}}]]

范围  (24)

图形  (14)

规范  (3)

单个线段：

Wolfram Language code: Graphics[Line[{{0, 0}, {2, 1}}]]

连在一起的多个线段：

Wolfram Language code: Graphics[Line[{{0, 0}, {2, 1}, {4, 0}}]]

多个互不相接的线段：

Wolfram Language code: s = {{0, 0}, {2, 1}, {4, 0}};
Wolfram Language code: Graphics[Line[{s, s + 1}]]

样式  (8)

粗细不同的线：

Wolfram Language code: Table[Graphics[{Thickness[i], Line[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{t, Line[{{0, 0}, {2, 1}}]}], {t, {Thin, Thick}}]

粗细成比例的线：

Wolfram Language code: Table[Graphics[{Thickness[i], Line[{{0, 0}, {2, 1}}]}], {i, {.005, .05, .1}}]

用打印机阵点来规定粗细：

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], Line[{{0, 0}, {2, 1}}]}], {i, {1, 5, 10}}]

虚线：

Wolfram Language code: Table[Graphics[{Dashing[i], Line[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{d, Line[{{0, 0}, {2, 1}}]}], {d, {Dotted, Dashed, DotDashed}}]

不同颜色的线：

Wolfram Language code: Table[Graphics[{c, Line[{{0, 0}, {2, 1}}]}], {c, {Red, Green, Blue, Yellow}}]

可以用 CapForm 来指定线帽的形状：

Wolfram Language code: Table[Graphics[{CapForm[cap], Thickness[.2], Line[{{-1, -1}, {1, 1}}]}, PlotRange -> 1.5, PlotLabel -> cap], {cap, {"Butt", "Round", "Square"}}]
Wolfram Language code: Table[Graphics3D[{CapForm[cap], Thickness[.1], Line[{{-1, -1, -1}, {1, 1, 1}}]}, PlotRange -> 1.5, PlotLabel -> cap], {cap, {"Butt", "Round", "Square"}}]

可以用 JoinForm 指定线段连接处的形状：

Wolfram Language code: Table[Graphics[{JoinForm[j], Thickness[.2], Line[{{-1, -0.5}, {0, 0.5}, {1, -0.5}}]}, PlotRange -> 1.5, PlotLabel -> j], {j, {"Bevel", "Round", "Miter"}}]
Wolfram Language code: Table[Graphics3D[{JoinForm[j], Thickness[.1], Line[{{-1, -1, -1}, {0, 0, 1}, {1, 1, -1}}]}, PlotRange -> 1.5, PlotLabel -> j], {j, {"Bevel", "Round", "Miter"}}]

可以用 VertexColors 指定顶点处的颜色：

Wolfram Language code: Graphics[{Thick, Line[{{0, 0}, {2, 1}}, VertexColors -> {Red, Green}]}]
Wolfram Language code: Graphics3D[{Thick, Line[{{0, 0, 0}, {2, 1, 1}}, VertexColors -> {Red, Green}]}]

对于三维线段，用 VertexNormals 指定顶点法线：

Wolfram Language code: Graphics3D[{Thick, Yellow, Line[{{0, 0, 0}, {2, 1, 1}}, VertexNormals -> {{1, -1, 1}, {-1, 1, -1}}]}]

坐标  (3)

使用 Scaled 的坐标：

Wolfram Language code: Graphics[Line[{Scaled[{0, .2}], Scaled[{1, .8}]}], Frame -> True]
Wolfram Language code: Graphics3D[Line[{Scaled[{0, .2, 0}], Scaled[{1, .8, 1}]}], Axes -> True]

在二维中使用 ImageScaled 的坐标：

Wolfram Language code: Graphics[Line[{ImageScaled[{0, .2}], ImageScaled[{1, .8}]}], Frame -> True]

在二维中使用 Offset 的坐标：

Wolfram Language code: Graphics[Line[{Offset[{10, 20}, {0, 0}], Offset[{-10, -20}, {1, 1}]}], Frame -> True]

区域  (10)

嵌入维度是线段所处空间的维度：

Wolfram Language code: RegionEmbeddingDimension[Line[{{1, 2}, {3, 4}}]]
Wolfram Language code: RegionEmbeddingDimension[Line[{{1, 2, 3}, {4, 5, 6}}]]

几何维度：

Wolfram Language code: RegionDimension[Line[{{1, 2}, {3, 4}}]]
Wolfram Language code: RegionDimension[Line[{{1, 2}, {1, 2}}]]

判断某点是否为该区域的成员：

Wolfram Language code: ℛ = Line[{{1, 2}, {3, 4}}];
Wolfram Language code: {RegionMember[ℛ, {2, 3}], RegionMember[ℛ, {0, 0}]}

获取成为该区域成员的条件：

Wolfram Language code: RegionMember[ℛ, {x, y}]

长度：

Wolfram Language code: ℛ = Line[{{1, 2}, {3, 4}, {5, 2}}];
Wolfram Language code: {RegionMeasure[ℛ], ArcLength[ℛ]}

几何中心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Gray, ℛ}, {Red, Point[c]}}]

到线段的距离：

Wolfram Language code: ℛ = Line[{{1, 2}, {3, 4}, {5, 2}}];
Wolfram Language code: RegionDistance[ℛ, {2, 1}]

图示：

Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -1, 7}, {y, 0, 6}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -1, 7}, {y, 0, 6}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

距线段的有符号距离：

Wolfram Language code: ℛ = Line[{{1, 2}, {3, 4}, {5, 2}}];
Wolfram Language code: SignedRegionDistance[ℛ, {2, 1}]

到一个线段的有符号距离：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 7}, {y, 0, 6}, Mesh -> None]

区域中最近的点：

Wolfram Language code: ℛ = Line[{{1, 2}, {3, 4}, {1, 6}}];
Wolfram Language code: RegionNearest[ℛ, {2, 1}]

最近的点：

Wolfram Language code: pts = Table[{2, 4} + 5 / 2{Cos[k 2 π / 25], Sin[k 2π / 25]}, {k, 0., 24}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{ℛ, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

线段是有界的：

Wolfram Language code: ℛ = Line[{{1, 2}, {3, 4}}];
Wolfram Language code: BoundedRegionQ[ℛ]

获取线段范围：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.2, Yellow], Cuboid@@Transpose[rr]}}]

在多段线上积分：

Wolfram Language code: ℛ = Line[{{1, 2}, {3, 4}, {1, 6}}];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

在多段线上最优化：

Wolfram Language code: ℛ = Line[{{1, 2}, {3, 4}, {1, 6}}];
Wolfram Language code: Minimize[{x y - x, {x, y}∈ℛ}, {x, y}]

在多段线上解方程：

Wolfram Language code: ℛ = Line[{{0, 0}, {1, 1}, {2, 0}}];
Wolfram Language code: Solve[(x - 1)^2 + (y - 1)^2 == 1 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Graphics[{{Thin, ℛ}, {Thin, Circle[{1, 1}]}, {Red, Point[{x, y} /. %]}}, Frame -> True]

选项  (3)

VertexColors  (2)

带有顶点颜色的线段：

Wolfram Language code: Graphics[{Thick, Line[{{0, 0}, {2, 1}}, VertexColors -> {Red, Green}]}]

指定三维线段的顶点颜色：

Wolfram Language code: Graphics3D[{Thick, Line[{{0, 0, 0}, {2, 1, 1}}, VertexColors -> {Red, Green}]}]

VertexNormals  (1)

指定三维线段的顶点法线：

Wolfram Language code: Graphics3D[{Thick, Yellow, Line[{{0, 0, 0}, {2, 1, 1}}, VertexNormals -> {{1, -1, 1}, {-1, 1, -1}}]}]

应用  (6)

含有11个节点的完全图：

Wolfram Language code: p = Tuples[Table[{Cos[t], Sin[t]}, {t, 0, 2Pi, 2Pi / 11}], 2];
Wolfram Language code: Graphics[Line[p]]

二次曲线的切线簇：

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: p = Table[{{a - 2, f'[a]((a - 2) - a) + f[a]}, {a + 2, f'[a]((a + 2) - a) + f[a]}}, {a, -10, 10, .1}];
Wolfram Language code: Graphics[Line[p], PlotRange -> {{-1, 1}, {-1, 1}}]

矢量场：

Wolfram Language code: Graphics[{Table[Line[{{x, y}, {x, y} + {y, x} / 5 - 1}], {x, 0, 10}, {y, 0, 10}]}, AspectRatio -> 1]

在二维格子上随机行走：

Wolfram Language code: Graphics[Line[Accumulate[RandomChoice[{{-1, 0}, {1, 0}, {0, 1}, {0, -1}}, 1000]]]]

在三维格子上随机行走：

Wolfram Language code: Graphics3D[Line[Accumulate[RandomChoice[Join[IdentityMatrix[3], -IdentityMatrix[3]], 500]]]]

用 Line 代替 Polygon 可以获得特殊的渲染效果：

Wolfram Language code: LineRendering[g_] := g /. Polygon[pt_] :> Line[pt, VertexColors -> Automatic, VertexNormals -> Automatic]
Wolfram Language code: Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}, Mesh -> False]//LineRendering
Wolfram Language code: Plot3D[Sin[x y ^ 2], {x, 0, 4}, {y, 0, 2}, ColorFunction -> "TemperatureMap", Mesh -> None, Lighting -> Automatic]//LineRendering

运用一组随机光源：

Wolfram Language code: obj = RevolutionPlot3D[{8 + Cos[t], 2Sin[t]}, {t, 0, 2Pi}, Mesh -> None, PlotStyle -> FaceForm[None], Axes -> False];
Wolfram Language code: Table[Show[obj, Lighting -> ({"Spot", ColorData["SouthwestColors"][RandomReal[]], Scaled[#], {Pi / 4, 100}}&) /@ RandomReal[{-4, 4}, {5, 3}]], {3}]//LineRendering
Wolfram Language code: {ExampleData[{"Geometry3D", "Deimos"}], ExampleData[{"Geometry3D", "Vase"}]}//LineRendering

用线段估算曲线的长度：

Wolfram Language code: f[x_] := Sin[x ^ 2];
Wolfram Language code: lineApprox[f_, n_, xmin_, xmax_] := Module[{vals}, vals = Table[{x, f[x]}, {x, xmin, xmax, (xmax - xmin) / n}];Line@Partition[Riffle[Most@vals, Rest@vals], 2]]
Wolfram Language code: lines = lineApprox[f, 30, -4, 4];
Wolfram Language code: Show[Plot[f[x], {x, -4, 4}], Graphics[lines]]
Wolfram Language code: Integrate[Sqrt[1 + f'[x] ^ 2], {x, -4, 4}]//N
Wolfram Language code: ArcLength[lines]//N

增加线段的数量可以得到更精确的结果：

Wolfram Language code: ArcLength[lineApprox[f, 300, -4, 4]]//N

属性和关系  (4)

可以生成 Line 对象的几个绘图函数：

Wolfram Language code: data = RandomInteger[10, {10}];
Wolfram Language code: ListLinePlot[data]

使用相应指令指定线段的样式：

Wolfram Language code: ListLinePlot[data, PlotStyle -> DotDashed]

对结果进行转换：

Wolfram Language code: % /. Line -> Arrow

上述方法同样适用于三维：

Wolfram Language code: ParametricPlot3D[{Cos[θ], Sin[θ], θ / 4}, {θ, 0, 3Pi}, PlotStyle -> Directive[Thick, Pink]]

显示抽样点：

Wolfram Language code: % /. Line[p_List] :> Point[p]

ImplicitRegion 可用来表示任意 Line 区域：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{0, 0}, {1, 1}}]; Subscript[ℛ, 2] = ImplicitRegion[x == y && 0 ≤ x ≤ 1, {x, y}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion 可用来表示任意 Line 区域：

Wolfram Language code: Subscript[ℛ, 1] = RegionUnion[ParametricRegion[{{1 + t, 2 + t}, 0 ≤ t ≤ 2}, {t}], ParametricRegion[{{3 - t, 4 + t}, 0 ≤ t ≤ 2}, {t}]]; Subscript[ℛ, 2] = Line[{{1, 2}, {3, 4}, {1, 6}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

可能存在的问题  (1)

必须用机器可以表示的数字来指定 Line 对象：

Wolfram Language code: Graphics[Line[{{0, 0}, {10. ^ 500, 10. ^ 500}}]]
Wolfram Language code: MachineNumberQ[10. ^ 500]

巧妙范例  (4)

一组随意排列的直线：

Wolfram Language code: Graphics[Table[{Hue[RandomReal[]], Line[RandomReal[1, {2, 2}]]}, {100}]]
Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Line[RandomReal[1, {2, 3}]]}, {100}]]

加上光源：

Wolfram Language code: Block[{sp = Normalize /@ RandomReal[{-1, 1}, {500, 3}]}, Graphics3D[{Line[sp, VertexNormals -> sp]}]]

生成莫尔条纹：

Wolfram Language code: Graphics[Table[Line[{{{x, 0}, {1 - x, 1}}, {{0, x}, {1, 1 - x}}}], {x, 0, 1, .02}]]

椭圆曲线上的切向量：

Wolfram Language code: With[{f = {Cos[x] + Sin[x], Sin[x]}}, Graphics[Table[{Hue[t / (2Pi), 1, .8], Line[{f, Normalize[D[f, x]] + f}]} /. x -> t, {t, 0, 2Pi, .1}]]]
Wolfram Research (1988)，Line，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Line.html （更新于 2014 年）.

文本

Wolfram Research (1988)，Line，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Line.html （更新于 2014 年）.

CMS

Wolfram 语言. 1988. "Line." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Line.html.

APA

Wolfram 语言. (1988). Line. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Line.html 年

BibTeX

@misc{reference.wolfram_2026_line, author="Wolfram Research", title="{Line}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Line.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_line, organization={Wolfram Research}, title={Line}, year={2014}, url={https://reference.wolfram.com/language/ref/Line.html}, note=[Accessed: 03-November-2026]}