Wolfram言語＆システムドキュメントセンター

LowpassFilter

LowpassFilter[data,ω_c]

カットオフ周波数 ω_cのローパスフィルタをデータ配列に適用する．

LowpassFilter[data,ω_c,n]

長さ n のフィルタカーネルを使う．

LowpassFilter[data,ω_c,n,wfun]

平滑化窓 wfun をフィルタカーネルに適用する．

詳細とオプション

ローパスフィルタは，通常，高周波数のコンテンツをデータから減らすことによるデータの平滑化やノイズ除去に使われる．
LowpassFilterは，窓メソッドで作られた有限インパルス応答(FIR)カーネルを持つデジタル信号をたたみ込む．

data は次のいずれでもよい．

	list	任意階数の数値配列
	tseries	TimeSeriesやTemporalData等の時間データ
	image	任意のImageオブジェクトまたはImage3Dオブジェクト
	audio	AudioオブジェクトまたはSoundオブジェクト
	video	Videoオブジェクト

カットオフ周波数が小さいとより滑らかになることが多い．カーネルが長いほど周波数がよりよく弁別できる． »
LowpassFilter[data,ω_c]はカットオフ周波数 ω_cと入力 data に適したフィルタカーネル長と平滑化窓を使う．
よく使われる平滑化窓 wfun

	BlackmanWindow	Blackman窓で平滑化する
	DirichletWindow	平滑化は行わない
	HammingWindow	ハミング窓で平滑化する（デフォルト）
	{v₁,v₂,…}	値 v_iの窓を使う
	f	からの範囲で f をサンプリングすることで窓を作る

画像や多次元配列に適用された場合，フィルタリングはレベル1から始めて各次元に連続的に適用される．LowpassFilter[data,{ω_c₁,ω_c₂,…}]は次元で周波数 ω_{c_i} を使う．
使用可能なオプション
Padding "Fixed" 使用する充填値

SampleRate Automatic 入力に想定されるサンプルレート
デフォルトで，リストと同様画像にもSampleRate->1が想定される．音声信号と時系列については，サンプルレートは入力データから抽出されるか計算されるかのいずれかである．
SampleRatesr の場合，カットオフ周波数 ω_cは 0からまででなければならない． »

例題

すべて開くすべて閉じる

例 (3)

ノイズの多い矩形波にローパスフィルタをかける：

Wolfram Language code:

data = Table[SquareWave[i / 100], {i, 225}] + RandomReal[{-0.1, 0.1}, 225];
GraphicsRow[ListLinePlot /@ {data, LowpassFilter[data, 0.5]}]

音声にローパスフィルタをかける：

Wolfram Language code: LowpassFilter[\!\(\*AudioBox["![Embedded Audio Player](audio://content-1323j)"]\), Quantity[1000, "Hertz"]]

画像にローパスフィルタをかける：

Wolfram Language code: LowpassFilter[[image], 0.5, 15]//ImageAdjust

スコープ (14)

データ (9)

1Dパルス列にフィルタをかける：

Wolfram Language code:

data = BoxMatrix[5, {41}];
ListLinePlot[{data, LowpassFilter[data, 0.5, 15]}]

2Dパルス列にフィルタをかける：

Wolfram Language code:

data = Table[UnitBox[(n/7), (m/7)], {n, -7, 7}, {m, -7, 7}];
ListPlot3D[data]

Wolfram Language code: LowpassFilter[data, 0.5, 15]//ListPlot3D

TimeSeriesにフィルタをかける：

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, 
    -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, 
    -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, 
    -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];
filtered = LowpassFilter[ts, Quantity[10, "Hertz"]];

Wolfram Language code: ListLinePlot[{ts, filtered}, PlotLegends -> {"original data", "filtered"}]

三角波のAudioオブジェクトを平滑化する：

Wolfram Language code: a = AudioGenerator[{"Triangle", 440}]

Wolfram Language code: AudioPlot[a, PlotRange -> {{0, 0.01}, All}]

低いカットオフ周波数を使ってほとんどの信号高調波を削除する：

Wolfram Language code: AudioPlot[LowpassFilter[a, Quantity[500, "Hertz"]], PlotRange -> {{0, 0.01}, All}]

デュアルトーン多重周波数(DTMF)信号のSoundオブジェクトにローパスフィルタをかける：

Wolfram Language code: s = Sound[SampledSoundList[Table[Sin[2 π 697 t] + Sin[2 π 1209 t], {t, 0., 0.3, 1 / 8000.}], 8000]]

2つのダイアルトーンの中間のカットオフ周波数，長さ99のフィルタ，Blackman窓を使う：

Wolfram Language code: LowpassFilter[s, Quantity[953, "Hertz"], 99, BlackmanWindow]

カラーのハーフトーン画像にローパスフィルタをかける：

Wolfram Language code: LowpassFilter[[image], 0.5]

動画のフレームにフィルタをかける：

Wolfram Language code: LowpassFilter[Video["ExampleData/fish.mp4"], .5]

3D画像のローパスフィルタリング：

Wolfram Language code: LowpassFilter[[image], 0.5]

厳密な精度でフィルタをかける：

Wolfram Language code: LowpassFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, Pi / 2, 3]

パラメータ (5)

数値カットオフ周波数は1秒あたりのラジアン単位の量として解釈される：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-iz4x8)"]\);

Wolfram Language code:

LowpassFilter[a, 2000 π] === LowpassFilter[a, Quantity[2000*Pi, "Radians"/"Seconds"]] === LowpassFilter[a, Quantity[1000, "Hertz"]]

のカットオフ周波数を使ってホワイトノイズ信号にフィルタをかける：

Wolfram Language code:

noise = AudioGenerator["White", 0.2];
Periodogram[noise]

Wolfram Language code: Periodogram[LowpassFilter[noise, Quantity[5000, "Hertz"]]]

より高い周波数値を使う：

Wolfram Language code: Periodogram[LowpassFilter[noise, Quantity[10000, "Hertz"]]]

デフォルトで，フィルタの長さとその周波数弁別はカットオフ周波数に依存する：

Wolfram Language code:

noise = AudioGenerator["White", 0.2];
Periodogram[LowpassFilter[noise, Quantity[2000, "Hertz"]]]

カットオフ周波数を高くすると，より短いフィルタカーネルでより広い遷移帯域となり，周波数識別は劣化する：

Wolfram Language code: Periodogram[LowpassFilter[noise, Quantity[5000, "Hertz"]]]

より長いカーネルを使って周波数弁別を上昇させる：

Wolfram Language code: Periodogram[LowpassFilter[noise, Quantity[5000, "Hertz"], 55]]

別の窓関数を使ってストップバンドの減衰量を変える：

Wolfram Language code:

a = AudioGenerator[Sin[11025 2 π  #^2]&];
Periodogram[LowpassFilter[a, Quantity[10000, "Hertz"], 33, #]& /@ {DirichletWindow, HammingWindow, BlackmanWindow}, PlotLegends -> {"Dirichlet", "Hamming", "Blackman"}]

フィルタ長を伸ばして周波数識別を向上させる：

Wolfram Language code:

a = AudioGenerator[Sin[11025 2 π  #^2]&];
n = 33;
Periodogram[MapThread[LowpassFilter[a, Quantity[10000, "Hertz"], #1, #2]&, {{n, 2n, 3n}, {DirichletWindow, HammingWindow, BlackmanWindow}}], PlotLegends -> {"Dirichlet", "Hamming", "Blackman"}]

調整可能なカイザー(Kaiser)窓を使って減衰の量を変える：

Wolfram Language code:

Periodogram[Table[LowpassFilter[a, Quantity[10000, "Hertz"], 33, KaiserWindow[#, b]&], {b, {3, 5, 7}}], PlotLegends -> {3, 5, 7}]

窓関数を数値リストとして指定する：

Wolfram Language code: Periodogram[LowpassFilter[a, Quantity[10000, "Hertz"], 33, ConstantArray[1, {33}]]]

各次元に異なるカットオフ周波数を使う：

Wolfram Language code: LowpassFilter[[image], {.5, 1.5}]

オプション (4)

Padding (2)

充填を使わないで境界のアーチファクトをなくす：

Wolfram Language code: LowpassFilter[[image], 0.2, Padding -> #]& /@ {Automatic, None}

充填法を変えるとエッジ効果も変わる：

Wolfram Language code:

ramp = Range[21] / 21. + RandomReal[.1, 21];
GraphicsRow@(ListLinePlot[{ramp, LowpassFilter[ramp, 0.5, Padding -> #]}, ...]& /@ {"Fixed", "Periodic", 0})

SampleRate (2)

標準化されたサンプルレートのを仮定して，長さ5のローパスハーフバンドフィルタを使う：

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, π / 2., 5]

サンプルレートを仮定する：

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, 3 π / 2., 5, SampleRate -> 3]

ハーフバンドローパスフィルタを適用してレートでサンプルされた音声にフィルタをかける：

Wolfram Language code:

noise = AudioGenerator["White", 0.2];
sr = QuantityMagnitude@AudioSampleRate[noise]

Wolfram Language code: LowpassFilter[noise, sr π / 2.]//Periodogram

アプリケーション (6)

カットオフ周波数1000Hzを使って音声のノイズを削減する：

Wolfram Language code:

input = ExampleData[{"Audio", "Apollo11ReturnSafely"}];
Spectrogram[input]

Wolfram Language code: LowpassFilter[input, Quantity[1000, "Hertz"]]//Spectrogram

LowpassFilterを使って音声オブジェクトがあまり不快ではなくなるようにする：

Wolfram Language code: cello = \!\(\*AudioBox["![Embedded Audio Player](audio://content-4obok)"]\);

Wolfram Language code: LowpassFilter[cello, Quantity[800, "Hertz"]]

現代の88鍵のピアノでは，55番目の鍵盤(C₅)の基本周波数はおよそ523Hzである．次の音声クリップでLowpassFilterを使ってこの鍵盤の基本周波数を残し，すべてのハーモニックスを削除する：

Wolfram Language code: key55 = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sglcp)"]\);

カットオフ周波数が基本周波数(523Hz)と最初のハーモニックの1046Hzの中間の，長さ59のフィルタを使う：

Wolfram Language code:

f = 1.5 523;
res = LowpassFilter[key55, 2 π f, 59]

2つの音声クリップの周波数のスペクトルを比較する：

Wolfram Language code:

Periodogram[{key55, res}, PlotRange -> All, GridLines -> All, PlotLegends -> {"original", "filtered"}, Epilog -> {Red, InfiniteLine[{{f, 0}, {f, 1}}]}]

画像をぼかす：

Wolfram Language code:

image = [image];
LowpassFilter[image, .5]

干渉縞と高空間周波数を除く：

Wolfram Language code: LowpassFilter[[image], 2]

画像のアンシャープマスク処理：

Wolfram Language code: i = [image];

Wolfram Language code: 2i - LowpassFilter[i, .5]

特性と関係 (8)

カットオフ周波数0を使うと0の数列が返される：

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, 0]

π 以上のカットオフ周波数を使ってオールパスフィルタを作る：

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, π]

LeastSquaresFilterKernelとハミング窓を使ってローパスフィルタを作る：

Wolfram Language code:

n = 5;
ω = 1.;
win = Array[HammingWindow, n, {-1 / 2, 1 / 2}];
ker = Normalize[win LeastSquaresFilterKernel[{"Lowpass", ω}, n], Total]

Wolfram Language code: ListConvolve[ker, {0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, Ceiling[n / 2], 0]

LowpassFilterの結果と比較する：

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, ω, n, win, Padding -> 0]

長さ21のハーフバンドローパスフィルタのインパルス応答：

Wolfram Language code: h = LowpassFilter[ArrayPad[{1}, 10], π / 2., 21]

Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

フィルタの振幅スペクトル：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

平滑化窓なしでの長さ21のハーフバンドローパスフィルタのインパルス応答：

Wolfram Language code: h = LowpassFilter[ArrayPad[{1}, 10], π / 2., 21, None]

Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

フィルタの振幅スペクトル：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

平滑化窓なしの偶数長フィルタのインパルス応答：

Wolfram Language code: h = LowpassFilter[ArrayPad[{1}, 10], π / 2., 20, None]

Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

フィルタの振幅スペクトル：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

ローパスフィルタの周波数識別は長さが伸びると向上する：

Wolfram Language code:

Manipulate[
	ListLinePlot[Abs[Fourier[LowpassFilter[ArrayPad[{1.}, 128], Pi / 2, n, DirichletWindow], FourierParameters -> {1, -1}]][[ ;; 129]], ...], {{n, 21}, 3, 63, 1}]

インパルス応答の長さは，フィルタの帯域幅が減少するにつれて増加する：

Wolfram Language code:

Manipulate[ListPlot[DeleteCases[LowpassFilter[ArrayPad[{1.}, 65], ω, Padding -> 0], 0.], Filling -> 0, Axes -> {True, False}, Ticks -> None], {{ω, 1., "SubscriptBox[ω, c]"}, 0.125, 1.0}]

考えられる問題 (1)

PaddingNoneを使うと，結果として入力より短い出力になる：

Wolfram Language code: LowpassFilter[{0, 0, 0, 1, 0, 0, 0}, 1., 7, Padding -> None]

より長いカーネルを使うと結果が空リストになるかもしれない：

Wolfram Language code: LowpassFilter[{0, 0, 0, 1, 0, 0, 0}, 1., 11, Padding -> None]

インタラクティブな例題 (1)

カットオフ周波数 ω_cを変えることで画像の輪を除去する：

Wolfram Language code:

Manipulate[LowpassFilter[[image], w, Padding -> None], {{w, 1.5, "SubscriptBox[ω, c]"}, 0.25, 1.5}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

LowpassFilter

詳細とオプション

例題

例 (3)

スコープ (14)

データ (9)

パラメータ (5)

オプション (4)

Padding (2)

SampleRate (2)

アプリケーション (6)

特性と関係 (8)

考えられる問題 (1)

インタラクティブな例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

	Padding	"Fixed"	使用する充填値
	SampleRate	Automatic	入力に想定されるサンプルレート

LowpassFilter

詳細とオプション

例題

例 (3)

スコープ (14)

データ (9)

パラメータ (5)

オプション (4)

Padding (2)

SampleRate (2)

アプリケーション (6)

特性と関係 (8)

考えられる問題 (1)

インタラクティブな例題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX