Wolfram 语言与系统参考资料中心

Quantile

Quantile[data,p]

给出估计的 data 的第 p 分位数 .

Quantile[data,{p₁,p₂,…}]

给出分位数列表 p₁,p₂,….

Quantile[data,p,{{a,b},{c,d}}]

使用参数 a、b、c、d 指定的分位数定义.

Quantile[dist,p]

给出分布 dist 的分位数.

范例

打开所有单元关闭所有单元

基本范例 (7)

找出一个列表中的中间值：

Wolfram Language code: Quantile[{1, 2, 3, 4, 5, 6, 7}, 1 / 2]

求列表的 20% 和 80% 分位数：

Wolfram Language code: Quantile[{1, 2, 3, 4, 5, 6, 7}, {0.2, 0.8}]

列表的最高分位数：

Wolfram Language code: Quantile[Range[100], .99]

日期列表的分位数：

Wolfram Language code: RandomDate[4]

Wolfram Language code: Quantile[%, .3]

正态分布的 q 分位数：

Wolfram Language code: Quantile[NormalDistribution[μ, σ], q]

连续单元分布的分位数函数：

Wolfram Language code: Plot[Table[Quantile[BetaDistribution[1 / 2, β], q], {β, {1 / 4, 1 / 2, 1}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

离散单元分布的分位数函数：

Wolfram Language code: 𝒟 = PoissonDistribution[5];

Wolfram Language code: DiscretePlot[Quantile[𝒟, p], {p, CDF[𝒟, Range[0, 10]]}, ExtentSize -> Left, ExtentMarkers -> {"Empty", "Filled"}]

范围 (33)

基本用法 (7)

Quantile 适用于任何实数：

Wolfram Language code: Quantile[{E, Pi, Sqrt[2], Sqrt[3]}, 1 / 4]

获取任意精度的结果：

Wolfram Language code: Quantile[N[{5, 10, 4, 25, 2, 1}, 30], 2 / 3]

用其他参数化计算结果：

Wolfram Language code: Quantile[{5, 10, 4, 25, 2, 1}, 1 / 5]

Wolfram Language code: Quantile[{5, 10, 4, 25, 2, 1}, 1 / 5, {{1 / 2, 0}, {0, 1}}]

求 WeightedData 的分位数：

Wolfram Language code: Quantile[WeightedData[{1, 2, 3}, {3, 7, 4}], 0.4]

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: Quantile[WeightedData[data, weights], 0.4]

求 EventData 的分位数：

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: Quantile[EventData[e, ci], 0.4]

求 TimeSeries 的分位数：

Wolfram Language code:

Quantile[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.], 0.4]

分位数只取决于值：

Wolfram Language code:

Quantile[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]["Values"], 0.4]

求含有量的数据的分位数：

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]

Wolfram Language code: Quantile[data, 0.3]

数组数据 (6)

求每一列元素的分位数：

Wolfram Language code: Quantile[{{1, 2Pi}, {2, Pi}, {3, 3Pi}}, 1 / 3]

求每一列元素的多个分位数：

Wolfram Language code: Quantile[{{1, 2Pi}, {2, Pi}, {3, 3Pi}}, {1 / 3, 4 / 5}]

张量的分位数给出第一级的列的分位数：

Wolfram Language code: Quantile[RandomReal[1, {10, 4, 3}], .2]

计算大型向量或矩阵的分位数：

Wolfram Language code: Quantile[RandomReal[1, 10 ^ 6], 1 / 10]

Wolfram Language code: Quantile[RandomReal[1, {10 ^ 5, 5}], 1 / 10]

当输入为 Association 时，Quantile 只作用于值：

Wolfram Language code:

mat = RandomReal[1, {3, 2}];
assoc = AssociationThread[Range[3], mat]

Wolfram Language code: Quantile[assoc, .3]

计算 SparseArray 的分位数：

Wolfram Language code: sp = SparseArray[{{i_, i_} :> i, {i_, j_} /; j == i + 1 :> i - 1}, {100, 10}]

Wolfram Language code: Quantile[sp, 99 / 100]

求 QuantityArray 的分位数：

Wolfram Language code: data = QuantityArray[RandomReal[1, 6], "Pounds"]

Wolfram Language code: Quantile[data, .1]

图像和音频数据 (2)

按通道计算的 RGB 图像的 30% 分位数：

Wolfram Language code: Quantile[[image], .3]

灰度图的强度值的 30% 分位数：

Wolfram Language code: Quantile[[image], .3]

所有通道的幅值的 30% 分位数：

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]

Wolfram Language code: Quantile[a, .3]

日期和时间 (5)

计算日期的分位数：

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];

Wolfram Language code: DateHistogram[dates]

Wolfram Language code: Quantile[dates, .9]

计算日期的加权分位数：

Wolfram Language code: dates = RandomDate[4]

Wolfram Language code: weights = {1, 1, 1, 3};

Wolfram Language code: Quantile[WeightedData[dates, weights], .1]

计算以不同的日历给出的日期的分位数：

Wolfram Language code:

dates = {DateObject[{2024, 2, 29}, CalendarType -> "Jewish"], 
	DateObject[{1024, 8, 23}, CalendarType -> "Julian"], DateObject[{1524, 1, 1}, CalendarType -> "Islamic"], DateObject[{6024, 1, 15}, CalendarType -> "Julian"]}

Wolfram Language code: TimelinePlot[dates, ImageSize -> Medium]

以输入的一种日历格式给出分位数：

Wolfram Language code: Quantile[dates, .3]

Wolfram Language code: %["CalendarType"]

计算时间的分位数：

Wolfram Language code: times = RandomTime[3, TimeZone -> "America/Chicago"]

Wolfram Language code: Quantile[times, .3]

计算以不同的时区规范给出的时间的分位数：

Wolfram Language code: times = {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}

Wolfram Language code: Quantile[times, .2]

Wolfram Language code: DateValue[%, "TimeZone"]

参数分布 (5)

获得确切的数值解：

Wolfram Language code: Quantile[WeibullDistribution[2, 5], 1 / 4]

Wolfram Language code: Quantile[NegativeBinomialDistribution[20, 1 / 3], 1 / 5]

获得机器精度的结果：

Wolfram Language code: Quantile[WeibullDistribution[2, 5], 0.4]

获得连续分布任何精度的结果：

Wolfram Language code: Quantile[WeibullDistribution[2, 5], N[1 / 4, 25]]

获得分位数的符号表达式：

Wolfram Language code: Quantile[ChiSquareDistribution[ν], x]

Quantile 依次作用于列表的每个元素：

Wolfram Language code: Quantile[NormalDistribution[], {0.0, 0.2, 0.3}]

非参数分布 (2)

非参数分布的 Quantile：

Wolfram Language code: r = RandomVariate[NormalDistribution[], 10 ^ 2];

Wolfram Language code: Quantile[HistogramDistribution[r], 0.2]

Wolfram Language code: Quantile[SmoothKernelDistribution[r], 0.2]

Wolfram Language code: Quantile[KernelMixtureDistribution[r], 0.2]

Wolfram Language code: Quantile[SurvivalDistribution[r], 0.2]

Wolfram Language code: Quantile[EmpiricalDistribution[r], 0.2]

与底层参数分布比较值：

Wolfram Language code: Quantile[NormalDistribution[], 0.2]

为直方图分布绘制分位数：

Wolfram Language code:

Plot[Quantile[HistogramDistribution[RandomVariate[NormalDistribution[], 10 ^ 3]], q]//Evaluate, {q, 0, 1}, Filling -> Axis, Exclusions -> None]

导出分布 (4)

截断分布的 Quantile：

Wolfram Language code: Quantile[TruncatedDistribution[{2, 4}, ExponentialDistribution[1]], q]

Wolfram Language code: Plot[{Quantile[ExponentialDistribution[1], q], %}, {q, 0, 1}, Filling -> Axis]

指数分布的二次变换：

Wolfram Language code: Quantile[TransformedDistribution[x ^ 2, xExponentialDistribution[2]], q]

删截分布：

Wolfram Language code: Quantile[CensoredDistribution[{-2, 4}, CauchyDistribution[0, 1]], q]

含有量的分布的分位数：

Wolfram Language code: Quantile[RayleighDistribution[Quantity[502., "Newtons"]], Quantity[96, "Percent"]]

Wolfram Language code: Quantile[HistogramDistribution[QuantityArray[RandomReal[{2, 5}, 1000], "Grams"]], Quantity[96, "Percent"]]

随机过程 (2)

随机过程的四分位函数：

Wolfram Language code: Quantile[WienerProcess[μ, σ][t], q]

Wolfram Language code: Plot[Evaluate[% /. {μ -> 3, σ -> 1, q -> 1 / 20}], {t, 0, 1}]

求某些时间 t=0.5 处，TemporalData 的四分位数：

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 100]

Wolfram Language code: Quantile[td[0.5], 0.4]

求所有的模拟和相应的四分位函数：

Wolfram Language code:

Show[ListLinePlot[td, PlotStyle -> Directive[Opacity[0.3], Thin]], Plot[Quantile[td[t], 0.4], {t, 0, 10}, PlotStyle -> Thick]]

应用 (7)

间隔均匀的个分位数组将数值划分为个尺寸相同的组：

Wolfram Language code: 𝒟 = NormalDistribution[3, 1];

计算一组分位数：

Wolfram Language code: q = Quantile[𝒟, {0, 0.2, 0.4, 0.6, 0.8, 1}]//N

Wolfram Language code: Length[q]

根据分位数的数值将概率密度函数绘制为5个区：

Wolfram Language code:

Plot[PDF[𝒟, x], {x, 0, 6}, Filling -> Axis, Epilog -> {Orange, Apply[Sequence, Table[Line[{{q[[i]], 0}, {q[[i]], PDF[𝒟, q[[i]]]}}], {i, 2, 5}]]}]

将分位数作为网格函数使用：

Wolfram Language code:

Plot[PDF[𝒟, x], {x, 0, 6}, Ticks -> {Automatic, None}, MeshFunctions -> {#1&}, Mesh -> {Quantile[𝒟, Range[0.2, 0.8, 0.2]]}, MeshStyle -> Red, MeshShading -> ColorData[97, "ColorList"], PlotStyle -> Thick]

绘制列表的第 q 分位数的曲线：

Wolfram Language code: data = RandomVariate[BinomialDistribution[10, 0.5], 40];

Wolfram Language code: Plot[Quantile[data, q], {q, 0, 1}, PlotRange -> {0, 10}]

绘制线性内插分位数的曲线：

Wolfram Language code: Plot[Quantile[data, q, {{1 / 2, 0}, {0, 1}}], {q, 0, 1}]

使用四分位数计算期望值:

Wolfram Language code: dist = TukeyLambdaDistribution[1 / 3];

Wolfram Language code: Integrate[(UnitStep[2x + 1] /. {x -> Quantile[dist, p]}), {p, 0, 1}]

在 Expectation 中使用该方法:

Wolfram Language code: Expectation[UnitStep[2x + 1], xTukeyLambdaDistribution[1 / 3], Method -> "Quantile"]

通过非均匀分布的分位数函数转化均匀分布，生成非均匀分布的随机数：

Wolfram Language code: Q[p_] = Refine[Quantile[NormalDistribution[3, 1], p], 0 ≤ p ≤ 1]

Wolfram Language code: data = RandomVariate[TransformedDistribution[Q[p], pUniformDistribution[]], 10000];

比较样本的直方图和期待分布的概率密度函数：

Wolfram Language code:

Show[
	Histogram[data, 30, "PDF"], 
	Plot[PDF[NormalDistribution[3, 1], x], {x, -9, 9}, PlotStyle -> Thick]]

计算某些数据的平移四分位数：

Wolfram Language code:

data = TemporalData[TimeSeries, {{{0., 0.046491782116164254, 0.08903630113726002, 0.10513552796891892, 
    0.15836877340214242, 0.16762760021154957, 0.22262040271007824, 0.09229029166541514, 
    0.01638158916750626, -0.028243805037334938, 0.212763528740 ... 352256143162, 0.5558410175472224, 0.5068911071028394, 
    0.500082375411682}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

使用长度为 .1 的窗：

Wolfram Language code: mq = MovingMap[Quantile[#, 1 / 3]&, data, .1];

Wolfram Language code: ListLinePlot[{data, mq}]

计算随机过程路径集合切片的选择分位数：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

选择一些切片时间：

Wolfram Language code: times = Range[0, 1, .1];

Wolfram Language code:

q1 = Map[{#, Quantile[data[#], .1]}&, times];
q3 = Map[{#, Quantile[data[#], .3]}&, times];
q7 = Map[{#, Quantile[data[#], .7]}&, times];

在这些路径上绘制分位数图线：

Wolfram Language code:

Show[ListPlot[data], ListLinePlot[{q1, q3, q7}, PlotStyle -> {{Blue, Dotted}, {Blue, Dashed}, Blue}, PlotLegends -> LineLegend[{"q1", "q3", "q7"}, LegendLayout -> "ReversedColumn"]]]

计算一个班级孩子们的身高的分位数：

Wolfram Language code:

heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147, 
	        150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];

Wolfram Language code: ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic]

Wolfram Language code: qs = Quantile[heights, {0.1, 0.5, 0.9}]

Wolfram Language code:

n = Length[heights];
ListPlot[Join[{heights}, Table[{{0, q}, {n, q}}, {q, qs}]], Joined -> {False, True, True, True}, Filling -> {1 -> 0}, AxesLabel -> Automatic, PlotLegends -> {"heights", "q = 0.1", "q = 0.5", "q = 0.9"} ]

属性和关系 (9)

使用 Quantile 求解分布的分位数：

Wolfram Language code: Quantile[ExponentialDistribution[λ], {1 / 4, 1 / 2, 3 / 4}]

直接计算分位数：

Wolfram Language code: Quartiles[ExponentialDistribution[λ]]

Wolfram Language code: % - %%

在默认参数下，Quantile 总是返回列表框中的一个元素：

Wolfram Language code: Quantile[{1, 2, 3, 4}, 1 / 2]

Quartiles 给出列表的线性内插 Quantile 值：

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: Quantile[data, {1 / 4, 1 / 2, 3 / 4}, {{1 / 2, 0}, {0, 1}}]

Wolfram Language code: Quartiles[data]

InterquartileRange 是列表的线性内插 Quantile 值的差值：

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code:

{q1, q2} = Quantile[data, {3 / 4, 1 / 4}, {{1 / 2, 0}, {0, 1}}];
q1 - q2

Wolfram Language code: InterquartileRange[data]

QuartileDeviation 是列表的线性内插 Quantile 值的差值的一半：

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code:

{q1, q2} = Quantile[data, {3 / 4, 1 / 4}, {{1 / 2, 0}, {0, 1}}];
(q1 - q2) / 2

Wolfram Language code: QuartileDeviation[data]

QuartileSkewness 把线性内插 Quantile 值法作为偏差量的测量方法：

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code:

{q1, q2, q3} = Quantile[data, {1 / 4, 1 / 2, 3 / 4}, {{1 / 2, 0}, {0, 1}}];
(q1 - 2q2 + q3) / (q3 - q1)

Wolfram Language code: QuartileSkewness[data]

Quantile 对于分布数来说和 InverseCDF 等效：

Wolfram Language code: Quantile[ParetoDistribution[k, α], q]

Wolfram Language code: InverseCDF[ParetoDistribution[k, α], q]

QuantilePlot 绘制列表或者分布的四分位数图线：

Wolfram Language code:

dist = ExponentialDistribution[2];
data = RandomVariate[dist, 10 ^ 3];

Wolfram Language code: {QuantilePlot[data], QuantilePlot[dist]}

BoxWhiskerChart 显示数据的特定四分位数：

Wolfram Language code: BoxWhiskerChart[RandomVariate[NormalDistribution[0, 1], 100]]

可能存在的问题 (4)

如果对数据进行计算，p 可以是 0 到 1 之间的任意数字：

Wolfram Language code: Quantile[{1, 4, 8, 3, 2, 0, 8}, p]

Wolfram Language code: Quantile[{1, 4, 8, 3, 2, 0, 8}, 3]

对于某些分布，可能存在符号解析式：

Wolfram Language code: Quantile[NormalDistribution[μ, σ], p]

对于某些分布不存在符号闭合形式：

Wolfram Language code: Quantile[StableDistribution[0, 1.8, -0.5, 1, 2], p]

但可以进行数值计算：

Wolfram Language code: Quantile[StableDistribution[0, 1.8, -0.5, 1, 2], 0.3]

把无效的值带入符号输出，得出的结果没有意义：

Wolfram Language code: Quantile[CauchyDistribution[2, 3], p] /. {p -> 1. + I}

作为参数代入，则不进行计算：

Wolfram Language code: Quantile[CauchyDistribution[2, 3], 1. + I]

通过 Quantile 计算的数据的四分位数与通过 Quartiles 计算的结果并不总是一致：

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: Quantile[data, {1 / 4, 1 / 2, 3 / 4}]

直接计算分位数：

Wolfram Language code: Quartiles[data]

Wolfram Language code: %% - %

指定 Quantile 中的线性插值参数：

Wolfram Language code: Quantile[data, {1 / 4, 1 / 2, 3 / 4}, {{1 / 2, 0}, {0, 1}}]

Wolfram Language code: %%% - %

巧妙范例 (1)

在 20、100 和 300 个样本时的 Quantile 估计值分布：

Wolfram Language code: Quantile[ExponentialDistribution[0.9], 0.7]

Wolfram Language code:

SmoothHistogram[Table[Quantile[RandomVariate[ExponentialDistribution[0.9], {s, 1000}], 0.7], {s, {20, 100, 300}}], Filling -> Axis, PlotLegends -> {20, 100, 300}, PlotRange -> {{0, 3}, Automatic}]

Top

	{{0,0},{1,0}}	逆经验 CDF（默认）
	{{0,0},{0,1}}	线性插值（California 法）
	{{1/2,0},{0,0}}	编号最接近 p n 的元素
	{{1/2,0},{0,1}}	线性插值（水文学法）
	{{0,1},{0,1}}	基于均值的估计（Weibull 法）
	{{1,-1},{0,1}}	基于众数的估计
	{{1/3,1/3},{0,1}}	基于中位数的估计
	{{3/8,1/4},{0,1}}	正态分布估计

	Association	数值（键被忽略） »
	SparseArray	数组，相当于 Normal[data] »
	QuantityArray	量组成的数组 »
	WeightedData	基于 EmpiricalDistribution »
	EventData	基于 SurvivalDistribution »
	TimeSeries, TemporalData, …	向量或数值组成的数组（忽略时间戳） »
	Image,Image3D	RGB 通道的值或灰度的强度值 »
	Audio	所有通道的幅值 »
	DateObject, TimeObject	日期列表或时间列表 »

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Quantile

更多信息

范例

基本范例 (7)

范围 (33)

基本用法 (7)

数组数据 (6)

图像和音频数据 (2)

日期和时间 (5)

参数分布 (5)

非参数分布 (2)

导出分布 (4)

随机过程 (2)

应用 (7)

属性和关系 (9)

可能存在的问题 (4)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Quantile

更多信息

范例

基本范例 (7)

范围 (33)

基本用法 (7)

数组数据 (6)

图像和音频数据 (2)

日期和时间 (5)

参数分布 (5)

非参数分布 (2)

导出分布 (4)

随机过程 (2)

应用 (7)

属性和关系 (9)

可能存在的问题 (4)

巧妙范例 (1)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX