Quantity
Quantity
詳細
- Quantity[m,u]の単位 u は，"Meters"のような文字列として，あるいは"Meters"/"Seconds"^2のような単位のベキの積として与えることができる．
- サポートされる単位にはNIST Special Publication 811で指定されているすべての単位が含まれる．
- Quantityは温度を"DegreesCelsius"のような単位で，温度差を"DegreesCelsiusDifference"のような単位で表す．Quantity演算操作はこれを体系的に区別する．
- Quantity操作は"DegreesCelsius"のような単位で表される温度を"DegreesCelsiusDifference"のような単位で表される温度差と体系的に区別する．
- Quantity[unit]は，magnitude が1の正準化されたQuantityを作る．
- Quantity式は
（自由形式言語インターフェース）を使って作ることができる． - Quantityは自動的に未知の単位文字列をその正準形に解析しようと試みる．
- Quantityは属性HoldRestを有し，unit の構造を保持する．
- パーセント等の純粋な数値単位については，Normal[expr]はQuantityオブジェクトを通常の数に変換する．
- QuantityについてのはInformationは，次の特性を含むことがある．
-
"Magnitude" 量の大きさ "Unit" 量と関連付けられた単位 "UnitDimensions" 単位の物理次元 "SIBaseUnits" SI基本単位
例題
すべて開く すべて閉じる例 (4)
Quantityは特定の単位に関連した値を表す：
Quantity[8, "Meters"]
を使って数量と単位を入力する：["30 kilograms"]
で求めることができる：["40 pascals/farad"]Quantity[1, "Feet"]Quantity[1.84, ("Meters" * "Pascals") / "Farads"]Quantity[1, "SpeedOfLight"]["Newtonian gravitational constant"]3 ["magnetic constant"]Quantityは未知の単位文字列を解釈しようと自動的に試みる：
Quantity[1, "foot"]Quantity[19, "fps"]%//InputFormスコープ (7)
Quantity式は比較関数に使うことができる：
["3 feet"] < ["1.1 meter"]Quantity[16, "Ounces"] == Quantity[1, "Pounds"]Select[Range[["10 feet"]], Quantity[1, "Meters"] < # < Quantity[2, "Meters"]&]MixedMagnitudeとMixedUnitの指定を使って混合Quantityを定義する：
Quantity[MixedMagnitude[{5, 10}],
MixedUnit[{"Feet", "Inches"}]]Quantity[MixedMagnitude[{4, 7, 30}],
MixedUnit[{"Days", "Hours", "Minutes"}]]Quantity式はさまざまなリスト操作に使うことができる：
Range[["10 Feet"]]Table[i, {i, Quantity[3, "Ounces"], Quantity[1, "Pounds"]}]Table[i, {i, Quantity[5, "Seconds"], Quantity[1, "Minutes"], Quantity[4, "Seconds"]}]Ordering[{Quantity[3, "Feet"], Quantity[9, "Inches"], Quantity[1, "Meters"]}]多くの数値関数もQuantity式を操作することができる：
Abs[["-3 amps"]]Round[Quantity[3.5, "Feet"]]Round[Quantity[3.6, "Feet"], Quantity[3, "Inches"]]Rationalize[Quantity[14.2, "Inches"]]Rationalize[Quantity[14.2, "Inches"], Quantity[1 / 10, "Meters"]]Rescale[Quantity[1.8, "Meters"], {Quantity[-10, "Meters"], Quantity[10, "Meters"]}]整数関数もまたQuantity式を操作することができる：
Divisible[["8 ft"], Quantity[2, "Inches"]]Mod[Quantity[8, "Feet"], Quantity[3, "Feet"]]Re[Quantity[9. + 3.I, "Feet"]]Im[Quantity[9. + 3.I, "Feet"]]Norm[Quantity[-2 + I, "Pounds"]]Normalは，次元のないQuantity式に対しては，基本的な値を返す：
Normal[Quantity[10, "Percent"]]UnitDimensions["PartsPerMillion"]Normal[Quantity[8, "PartsPerMillion"]]N[Quantity[3 / 8, "Feet"]]Nは，物理定数を含め，Quantity式に関連付けられた単位を変換しない：
N[Quantity[1, "GravitationalConstant"], 20]UnitConvertを使って物理定数のSI値を求めることができる：
UnitConvert[%]アプリケーション (2)
FormulaDataをQuantityオブジェクトと使って地球と太陽の脱出速度を求める：
FormulaData["EscapeVelocity", {"m" -> Quantity[1, "EarthMass"], "r" -> Quantity[1, "EarthMeanRadius"]}]FormulaData["EscapeVelocity", {"m" -> Quantity[1, "SolarMass"], "r" -> Quantity[1, "SolarRadius"]}]FormulaDataをQuantityオブジェクトと使って，温度が5000Kのときの黒体のスペクトル放射輝度を波長の関数として可視化する：
equation = FormulaData[{"PlanckRadiationLaw", "Wavelength"},
{"T" -> Quantity[5000, "Kelvins"], "λ" -> Quantity[wl, "Micrometers"]}
][[2, 2]];Plot[equation, {wl, 0.1, 5}, AxesLabel -> {"Wavelength [μm]", "Spectral radiance [W SuperscriptBox[sr, -1]SuperscriptBox[m, -3]]"}]特性と関係 (15)
単位は文字列として，あるいは文字列の積として与えることができる：
Quantity[1, "Yards"]Quantity[1.7, "Newtons" * "Meters" / "Seconds"]Quantity[1.7, "Kilograms" * "Meters" ^ 2 / "Seconds" ^ 2]IndependentUnit指定も使うことができる：
Quantity[7, IndependentUnit["myUnit"]]Quantity[3, IndependentUnit["myUnit1"] / IndependentUnit["myUnit2"] ^ 2]単位には，単位の倍数や約数からなる接頭辞を使うことができる：
Quantity[1.7, "Decigrams"]Quantity[3.9, "Megaparsecs"]Quantityは，1引数の形では自動的にマグニチュード1に設定される：
Quantity["Candelas"]Quantity["Moles"]Quantityの第1引数はQuantityオブジェクトでもよい．この場合は単位が乗算される：
Quantity[Quantity[4, "Meters"], "Seconds" ^ (-1)]Quantity[Quantity[4, "Radians"], IndependentUnit["myUnit"]]Quantityオブジェクトに互換単位を足すと，結果の単位が発見的手法で決定される：
qa = Quantity[1, "Teslas"];
qb = Quantity[100, "Gauss"];
CompatibleUnitQ[qa, qb]qa + qbQuantityオブジェクトと互換単位の積は，結果の単位を発見的手法で決定する：
qa = Quantity[1, "Kilometers"];
qb = Quantity[3000, "Meters"];
CompatibleUnitQ[qa, qb]qa * qb摂氏や華氏のような非絶対スケールによる温度の減算は温度差を生じる：
temp1 = Quantity[20, "DegreesCelsius"];
temp2 = Quantity[15, "DegreesCelsius"];diff = temp1 - temp2diff//InputFormtemp2 + diff%//InputForm温度の乗法や除法を含む操作は自動的にケルビンに変換されることがある：
temp = Quantity[0, "DegreesFahrenheit"]1 / temp1 / UnitConvert[temp, "Kelvins"]Quantityは，その単位指定をリストに縫い込む：
Quantity[{1, 2, 3, {4, 5, {6}}}, "Hertz"]正準形の単位文字列は常に複数であるが，単位表記では単位の単数系が厳密に反映される：
Quantity[1, "Foot"]%//InputFormQuantity[1, "Foot"]//ToStringQuantityはHoldRestなので，次元が等しい複数の単位文字列を受容することができる：
Quantity[3.5, "Feet" / "Meters"]Quantity[12, "Meters" / "Meters"]数量が掛け合された場合，結果の単位は自動的には簡約されない：
qa = Quantity[1, "Newtons"];
qb = Quantity[10, "Meters"];
qa * qbUnitSimplifyを使って単位のより簡略な形を得る：
UnitSimplify[%]UnitConvertを使って混合形式のQuantity式を非混合形式のQuantity式に正規化する：
q = Quantity[MixedMagnitude[{6, 3, 17, 45}], MixedUnit[{"Weeks", "Days", "Hours", "Minutes"}]]UnitConvert[q]UnitConvert[q, "Minutes"]QuantityArrayを使って共通単位のQuantityオブジェクトの矩形配列を説明する：
qa = QuantityArray[{{1, 2}, {3, 4}, {5, 6}}, {"Meters", "Meters" / "Seconds"}]Normalは構造化配列をQuantityオブジェクトの同等の通常配列に変換する：
Normal[qa]% == qa考えられる問題 (2)
Quantityは未知の単位文字列を正準形の単位として自動的に解釈しようとする：
Quantity[1, "ft"]Quantity[1, "s"]Quantity[1, "ft" / "s"]
Quantity[1, "ft/s"]単位の中にはInterval式を含むものがある．その場合は，比較しても評価されずに戻されることがある：
UnitConvert[Quantity[1, "AcademicTrimesters"], "Days"]Quantity[10, "Weeks"] > Quantity[1, "AcademicTrimesters"]Quantity[1, "AcademicTrimesters"] / Quantity[10, "Weeks"]
An Elementary Introduction to the Wolfram Language
Wolfram Research (2012), Quantity, Wolfram言語関数， https://reference.wolfram.com/language/ref/Quantity.html （2022年に更新）.
テキスト
Wolfram Research (2012), Quantity, Wolfram言語関数， https://reference.wolfram.com/language/ref/Quantity.html （2022年に更新）.
CMS
Wolfram Language. 2012. "Quantity." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/Quantity.html.
APA
Wolfram Language. (2012). Quantity. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Quantity.html