WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

RegionDisjoint[reg1,reg2]

領域 reg1と reg2が互いに素である場合にTrueを返す．

RegionDisjoint[reg1,reg2,reg3,…]

領域 reg1，reg2，reg3，…がペアごとに互いに素である場合にTrueを返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
基本的な領域  
数式定義領域  
メッシュ領域  
派生領域  
オプション  
Assumptions  
GenerateConditions  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

RegionDisjoint

RegionDisjoint[reg1,reg2]

領域 reg1と reg2が互いに素である場合にTrueを返す．

RegionDisjoint[reg1,reg2,reg3,…]

領域 reg1，reg2，reg3，…がペアごとに互いに素である場合にTrueを返す．

詳細とオプション

  • 領域 reg1と reg2は，reg1と reg2の両方に属する点がない場合は互いに素である．
  • すべての regiがパラメータを含まない領域である，つまりConstantRegionQ[regi]がTrueであれば，その領域は点集合であり，一般にTrueかFalseが返される．
  • regiの中にパラメータに依存するものがある，つまりConstantRegionQ[regi]がFalseであれば，regiは領域の族を表し，RegionDisjointは領域が互いに素であるようなパラメータの条件を計算しようとする．
  • 次は使用可能なオプションである．
  • Assumptions $Assumptionsパラメータについて行う仮定
    GenerateConditions Falseパラメータについての条件を生成するかどうか

例題

すべて開く すべて閉じる

例  (2)

2つの領域が互いに素かどうかを判定する：

Wolfram Language code: Subscript[ℛ, 1] = Triangle[]; Subscript[ℛ, 2] = Disk[{1, 1}, 1 / 2];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

2領域を可視化する：

Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

領域が互いに素になる条件を生成する：

Wolfram Language code: Subscript[ℛ, 1] = Annulus[]; Subscript[ℛ, 2] = ImplicitRegion[Subsuperscript[r, 1, 2] ≤ x^2 + y^2 ≤ Subsuperscript[r, 2, 2], {x, y}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

スコープ  (17)

基本的な用法  (5)

2つの領域が互いに素であることを示す：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[]; Subscript[ℛ, 2] = Disk[{2, 2}, 1];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

2領域を可視化する：

Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

2つの領域が交わっていることを示す：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[]; Subscript[ℛ, 2] = Disk[];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

領域が互いに素になる条件を求める：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{x, y}]; Subscript[ℛ, 2] = Annulus[];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

複数の領域がペアごとに互いに素であることを示す：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{-2, 1}]; Subscript[ℛ, 2] = Disk[]; Subscript[ℛ, 3] = Disk[{2, 1}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], Subscript[ℛ, 3]]
Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Blue, Subscript[ℛ, 3]}}]

複数の領域がペアごとに互いに素ではないことを示す：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{-1, 1}]; Subscript[ℛ, 2] = Disk[]; Subscript[ℛ, 3] = Disk[{2, 1}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], Subscript[ℛ, 3]]
Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Blue, Subscript[ℛ, 3]}}]

基本的な領域  (4)

LineとIntervalを含む内の領域：

Wolfram Language code: RegionDisjoint[Line[{{0}, {1}}], Interval[{2, 4}]]

Point：

Wolfram Language code: RegionDisjoint[Point[{2}], Interval[{1, 3}]]

Ball：

Wolfram Language code: RegionDisjoint[Ball[1], Interval[{2, 3}]]

InfiniteLine：

Wolfram Language code: RegionDisjoint[InfiniteLine[{0}, {1}], InfiniteLine[{-3}, {1}]]

Pointを含む内の領域：

Wolfram Language code: Subscript[ℛ, 1] = Point[RandomReal[1, {10, 2}]]; Subscript[ℛ, 2] = Point[RandomReal[1, {10, 2}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics[{{Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

Line：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{0, 0}, {1, 1}}]; Subscript[ℛ, 2] = Line[RandomReal[1, {10, 2}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics[{{Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

Polygon：

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{1, 1 / 2}, {0, 3 / 2}, {-1 / 2, 1 / 2}, {0, 11 / 10}}]; Subscript[ℛ, 2] = Triangle[];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

DiskとEllipsoid：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Ellipsoid[{1, 0}, {3, 2}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

RectangleとRegularPolygon：

Wolfram Language code: RegionDisjoint[Rectangle[{x, y}], RegularPolygon[4]]

Pointを含む内の領域：

Wolfram Language code: Subscript[ℛ, 1] = Point[RandomReal[1, {10, 3}]]; Subscript[ℛ, 2] = Point[RandomReal[1, {10, 3}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Line：

Wolfram Language code: Subscript[ℛ, 1] = Line[RandomReal[1, {10, 3}]]; Subscript[ℛ, 2] = Line[RandomReal[1, {10, 3}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Polygon：

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{1, 0, 1}, {0, 1, 2}, {1, 1, 1}, {2, 0, 0}}]; Subscript[ℛ, 2] = Triangle[{{0, 0, -1}, {2, -1, 1}, {2, 2, 1}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics3D[{{Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}, Boxed -> False]

CuboidとHexahedron：

Wolfram Language code: Subscript[ℛ, 1] = Cuboid[]; Subscript[ℛ, 2] = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

BallとEllipsoid：

Wolfram Language code: Subscript[ℛ, 1] = Ball[3]; Subscript[ℛ, 2] = Ellipsoid[{1, 1, 2}, {3, 2, 1}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

TetrahedronとSimplex：

Wolfram Language code: Subscript[ℛ, 1] = Tetrahedron[]; Subscript[ℛ, 2] = Simplex[{{1, 0, 1}, {1, 0, 0}, {0, 0, 1}, {1, 1, 1}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

内のCuboidとParallelepipedを含む内の領域：

Wolfram Language code: Subscript[ℛ, 1] = Cuboid[{0, 0, 0, 0}, {1, 1, 1, 1}]; Subscript[ℛ, 2] = Parallelepiped[{-1, -1, -1, -1}, -IdentityMatrix[4]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

内のEllipsoidとBall：

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[Table[1, 10], Table[i, {i, 10}]]; Subscript[ℛ, 2] = Ball[10];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

数式定義領域  (4)

陰的領域：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[1 / 2 ≤ x^2 + y^2 ≤ 1, {x, y}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 == 9, {x, y}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

パラメトリック領域：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{2x y, x - y}, {{x, 0, 1}, {y, 0, 1}}]; Subscript[ℛ, 2] = ParametricRegion[{r Cos[θ] + 1, r Sin[θ]}, {{r, 0, 2}, {θ, 0, 2π}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

2つの数式定義領域を比較する：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[(x - 2)^4 + (y - 2)^4 + (z - 2)^4 ≤ 1, {x, y, z}]; Subscript[ℛ, 2] = ParametricRegion[{ρSqrt[4 - u^2]Cos[θ], ρSqrt[4 - u^2]Sin[θ], ρ u}, {{ρ, 0, 1}, {θ, 0, 2π}, {u, -2, 2}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

一定ではない数式定義領域：

Wolfram Language code: RegionDisjoint[Annulus[], ImplicitRegion[Subsuperscript[r, 1, 2] ≤ x^2 + y^2 ≤ Subsuperscript[r, 2, 2], {x, y}]]

メッシュ領域  (3)

内のMeshRegionを比較する：

Wolfram Language code: Subscript[ℛ, 1] = MeshRegion[{{0}, {2}}, Line[{1, 2}]]; Subscript[ℛ, 2] = MeshRegion[{{1}, {3}}, Line[{1, 2}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

：

Wolfram Language code: Subscript[ℛ, 1] = DiscretizeGraphics[Annulus[]]; Subscript[ℛ, 2] = DiscretizeGraphics[Disk[{1 / 3, 0}, 1 / 4]];
Wolfram Language code: Show[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

：

Wolfram Language code: Subscript[ℛ, 1] = DiscretizeGraphics[Ball[]]; Subscript[ℛ, 2] = DiscretizeGraphics[Cuboid[{1, 1, 1}]];
Wolfram Language code: Show[Subscript[ℛ, 2], Subscript[ℛ, 1]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

内のBoundaryMeshRegionを比較する：

Wolfram Language code: Subscript[ℛ, 1] = BoundaryMeshRegion[{{0}, {2}}, Point[{1, 2}]]; Subscript[ℛ, 2] = BoundaryMeshRegion[{{1}, {3}}, Point[{1, 2}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

：

Wolfram Language code: Subscript[ℛ, 1] = BoundaryDiscretizeGraphics[Annulus[]]; Subscript[ℛ, 2] = BoundaryDiscretizeGraphics[Disk[{1 / 3, 0}, 1 / 4]];
Wolfram Language code: Show[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

：

Wolfram Language code: Subscript[ℛ, 1] = BoundaryDiscretizeGraphics[Ball[]]; Subscript[ℛ, 2] = BoundaryDiscretizeGraphics[Cuboid[{1, 1, 1}]];
Wolfram Language code: Show[Subscript[ℛ, 2], Subscript[ℛ, 1]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

内のMeshRegionとBoundaryMeshRegionを比較する：

Wolfram Language code: Subscript[ℛ, 1] = DelaunayMesh[RandomReal[{-2, 0}, {25, 2}]]; Subscript[ℛ, 2] = ConvexHullMesh[RandomReal[{0, 2}, {25, 2}]];
Wolfram Language code: Show[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

：

Wolfram Language code: Subscript[ℛ, 1] = DelaunayMesh[RandomReal[{-1, 1}, {25, 3}]]; Subscript[ℛ, 2] = ConvexHullMesh[RandomReal[{0, 1}, {25, 3}]];
Wolfram Language code: Show[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

派生領域  (1)

BooleanRegionを比較する：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[{2, 0}]; Subscript[ℛ, 2] = BooleanRegion[Xnor, {Disk[], Disk[{2, 0}, 2]}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

オプション  (2)

Assumptions  (1)

同心円板とアニュラスが互いに素であるすべての半径を求める：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = ImplicitRegion[Subsuperscript[r, 1, 2] ≤ x^2 + y^2 ≤ Subsuperscript[r, 2, 2], {x, y}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

正の半径だけを求める：

Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], Assumptions -> 0 < Subscript[r, 1] < Subscript[r, 2]]

GenerateConditions  (1)

単位円板が陰的に説明されたアニュラスと互いに素であるときを求める：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = ImplicitRegion[Subscript[r, 1] ≤ x^2 + y^2 ≤ Subscript[r, 2], {x, y}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

結果が有効である条件を示す：

Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], GenerateConditions -> True]

退化した形を明示的に許可する：

Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], Assumptions -> Subscript[r, 1]∈Reals]

アプリケーション  (6)

ビュフォン(Buffon)の針の問題のシミュレーションを行うことで を推定する：

Wolfram Language code: d = 0.2;n = 1000;
Wolfram Language code: lines = MeshRegion[ Join@@Table[{{-1 - d, y}, {1 + d, y}}, {y, -1 - d, 1 + d, d}], Line[Partition[Range[2Floor[2 / d + 3]], 2]] ];

長さ で方向がバラバラの線分を作る：

Wolfram Language code: needles = Table[Line[{pt, RandomPoint[Circle[pt, d]]}], {pt, RandomReal[{-1, 1}, {n, 2}]}];

格子線と重なる線分を選ぶ：

Wolfram Language code: overlap = Select[needles, !RegionDisjoint[lines, #]&];

重なっている線分（赤）を可視化する：

Wolfram Language code: Show[lines, Graphics[{Red, overlap, StandardGray, Complement[needles, overlap]}]]

の推定：

Wolfram Language code: N[(2n/Length[overlap])]

物体と壁の集合との間の衝突を検知する：

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "MeshRegion"];
Wolfram Language code: w1 = Hyperplane[{1, 0, 0}, 0.39]; w2 = Hyperplane[{1, 0, 0}, -0.45];

牛と衝突しない壁を緑で，その他の壁を赤で彩色する：

Wolfram Language code: wallColor[reg_] := If[RegionDisjoint[cow, reg], Green, Red]
Wolfram Language code: Show[cow, Graphics3D[{{wallColor[w1], w1}, {wallColor[w2], w2}}], PlotRangePadding -> .04]

フランスと国境を接するすべての国を求める：

Wolfram Language code: c = Entity["Country", "France"]; p = c["Polygon"] /. GeoPosition -> Identity;

各国の多角形：

Wolfram Language code: all = EntityValue["Country", "Polygon", "EntityAssociation"] /. GeoPosition -> Identity;

国の多角形がフランスの多角形と互いに素ではない国を選ぶ：

Wolfram Language code: DeleteCases[Keys[Select[all, !RegionDisjoint[p, #]&]], c]//Sort

結果を確かめる：

Wolfram Language code: c["BorderingCountries"]

これらの国を地図上で見る：

Wolfram Language code: GeoGraphics[{EdgeForm[Black], GeoStyling[LightGray], Polygon[%], GeoStyling[Red], Polygon[c]}]

単位正方形がアニュラスと互いに素であるすべての位置を求める：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[{x, y}]; Subscript[ℛ, 2] = Annulus[{0, 0}, {1, 2}];
Wolfram Language code: cond = RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionPlot[cond, {x, -4, 3}, {y, -4, 3}, Epilog -> {Red, Opacity[0.1], Subscript[ℛ, 2]}]

領域外でランダムウォークを行う：

Wolfram Language code: ℛ = Annulus[{0, 0}, {1 / 2, 1}, {π / 12, 23π / 12}];

領域外で点をランダムな方向に動かす関数を定義する：

Wolfram Language code: walkPoint[pt_, r_, reg_] := Block[{npt = RandomPoint[Sphere[pt, r]]}, While[!RegionDisjoint[Line[{pt, npt}], reg], npt = RandomPoint[Sphere[pt, r]] ]; npt ]

初期点からのランダムウォークのシミュレーションを行う：

Wolfram Language code: start = {0, 0};
Wolfram Language code: path = NestList[walkPoint[#, 0.1, ℛ]&, start, 500];

このウォークを可視化する：

Wolfram Language code: Graphics[{{Green, ℛ}, {Line[path]}, {Red, Point[start]}}]

アメリカ合衆国の州境を接する各州を接続するネットワークを作る：

Wolfram Language code: usa = EntityClass["AdministrativeDivision", "ContinentalUSStates"];
Wolfram Language code: polys = EntityValue[usa, "Polygon", "EntityAssociation"] /. {GeoPosition -> Identity, {x_Real, y_} :> {y, x}};

RegionDisjointがFalseを返すときは，2つの州の多角形が接している：

Wolfram Language code: statesBorderQ[loc1_, loc2_] := loc1 =!= loc2 && !RegionDisjoint[polys[loc1], polys[loc2]]
Wolfram Language code: g = RelationGraph[statesBorderQ, Keys[polys]]

このネットワークをアメリカ合衆国の地図の上に置く：

Wolfram Language code: coords = EntityValue[usa, "Coordinates"];
Wolfram Language code: g = Graph[g, VertexCoordinates -> Reverse /@ coords, EdgeStyle -> Directive[{Red, Thick}], Prolog -> {EdgeForm[Thin], LightGreen, Values[polys]}, PlotRange -> RegionBounds[RegionUnion@@Values[polys]]]

最も不連続の度合いが大きいのは，メイン州と最西部の各州である：

Wolfram Language code: GraphPeriphery[g]

メイン州からカリフォルニア州までの経路を求め，ハイライトする：

Wolfram Language code: path = FindShortestPath[g, Entity["AdministrativeDivision", {"Maine", "UnitedStates"}], Entity["AdministrativeDivision", {"California", "UnitedStates"}]];
Wolfram Language code: HighlightGraph[g, Style[PathGraph[path], Blue]]

特性と関係  (4)

領域とその補集合は常に互いに素である：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: RegionDisjoint[ℛ, BooleanRegion[Not, {ℛ}]]

互いに素な領域間に共通の点はない：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Rectangle[{2, 0}];
Wolfram Language code: Resolve[Exists[{x, y}, {x, y}∈Subscript[ℛ, 1]∧{x, y}∈Subscript[ℛ, 2]]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

非空の領域について，RegionEqualとRegionWithinは，RegionDisjointがTrueを返すときはFalseを返す：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Disk[{2, 1}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionWithin[Subscript[ℛ, 1], Subscript[ℛ, 2]]

FindInstanceを使って2つの領域の共通部分にある点を求める：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[]; Subscript[ℛ, 2] = Parallelogram[];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: pts = {x, y} /. FindInstance[{x, y}∈Subscript[ℛ, 1]∧{x, y}∈Subscript[ℛ, 2], {x, y}, 100];
Wolfram Language code: Graphics[{Point[pts], Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

RandomPointを使って2つの領域の共通部分にある点の一様サンプリングを求める：

Wolfram Language code: pts = RandomPoint[BooleanRegion[#1∧#2&, {Subscript[ℛ, 1], Subscript[ℛ, 2]}], 100];
Wolfram Language code: Graphics[{Point[pts], Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

Reduceを使って2つの領域が重なる箇所を求める：

Wolfram Language code: Reduce[{x, y}∈Subscript[ℛ, 1]∧{x, y}∈Subscript[ℛ, 2], {x, y}]
Wolfram Language code: RegionPlot[%, {x, -1, 3}, {y, -3 / 2, 5 / 2}, PlotPoints -> 60]

おもしろい例題  (1)

ランダムに置かれた互いに素なボールの場面を作る：

Wolfram Language code: randomBall[dim_] := Ball[{RandomReal[{0, 10}, dim]}, {RandomReal[{1 / 4, 1}]}]
Wolfram Language code: appendDisjointBall[dim_][reg : Ball[pts_, rs_]] := Block[{ball = randomBall[dim]}, While[!RegionDisjoint[ball, reg], ball = randomBall[dim] ]; Ball[Join[pts, #1], Join[rs, #2]]&@@ball ]
Wolfram Language code: disjointBalls[n_, dim_] := Nest[appendDisjointBall[dim], randomBall[dim], n - 1]

2Dで：

Wolfram Language code: n = 40; scene2D = disjointBalls[n, 2];
Wolfram Language code: Graphics[{EdgeForm[StandardGray], Thread[{RandomColor[Hue[_], n], Thread[scene2D]}]}]

3Dで：

Wolfram Language code: n = 100; scene3D = disjointBalls[n, 3];
Wolfram Language code: Graphics3D[Thread[{RandomColor[Hue[_], n], Thread[scene3D]}], Lighting -> "Neutral"]
Wolfram Research (2017), RegionDisjoint, Wolfram言語関数， https://reference.wolfram.com/language/ref/RegionDisjoint.html.

テキスト

Wolfram Research (2017), RegionDisjoint, Wolfram言語関数， https://reference.wolfram.com/language/ref/RegionDisjoint.html.

CMS

Wolfram Language. 2017. "RegionDisjoint." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RegionDisjoint.html.

APA

Wolfram Language. (2017). RegionDisjoint. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RegionDisjoint.html

BibTeX

@misc{reference.wolfram_2026_regiondisjoint, author="Wolfram Research", title="{RegionDisjoint}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/RegionDisjoint.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_regiondisjoint, organization={Wolfram Research}, title={RegionDisjoint}, year={2017}, url={https://reference.wolfram.com/language/ref/RegionDisjoint.html}, note=[Accessed: 04-November-2026]}