WOLFRAM

Wolfram 语言与系统参考资料中心

RegionDisjoint[reg1,reg2]

如果区域 reg1 和 reg2 是不相交的，返回 True.

RegionDisjoint[reg1,reg2,reg3,…]

如果区域 reg1、reg2、reg3、… 两两不相交，返回 True.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用途  
基本区域  
公式区域  
网格区域  
导出区域  
选项  
Assumptions  
GenerateConditions  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

RegionDisjoint

RegionDisjoint[reg1,reg2]

如果区域 reg1 和 reg2 是不相交的，返回 True.

RegionDisjoint[reg1,reg2,reg3,…]

如果区域 reg1、reg2、reg3、… 两两不相交，返回 True.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

检测两个区域是否不相交：

Wolfram Language code: Subscript[ℛ, 1] = Triangle[]; Subscript[ℛ, 2] = Disk[{1, 1}, 1 / 2];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

可视化：

Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

产生区域不相交的条件：

Wolfram Language code: Subscript[ℛ, 1] = Annulus[]; Subscript[ℛ, 2] = ImplicitRegion[Subsuperscript[r, 1, 2] ≤ x^2 + y^2 ≤ Subsuperscript[r, 2, 2], {x, y}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

范围  (17)

基本用途  (5)

显示两个区域是不相交的：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[]; Subscript[ℛ, 2] = Disk[{2, 2}, 1];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

可视化：

Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

显示两个相交区域：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[]; Subscript[ℛ, 2] = Disk[];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

求使得区域不相交的条件：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{x, y}]; Subscript[ℛ, 2] = Annulus[];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

显示多个两两不相交的区域：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{-2, 1}]; Subscript[ℛ, 2] = Disk[]; Subscript[ℛ, 3] = Disk[{2, 1}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], Subscript[ℛ, 3]]
Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Blue, Subscript[ℛ, 3]}}]

显示多个不是两两不相交的区域：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{-1, 1}]; Subscript[ℛ, 2] = Disk[]; Subscript[ℛ, 3] = Disk[{2, 1}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], Subscript[ℛ, 3]]
Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Blue, Subscript[ℛ, 3]}}]

基本区域  (4)

含有 Line 和 Interval 的 中的区域：

Wolfram Language code: RegionDisjoint[Line[{{0}, {1}}], Interval[{2, 4}]]

Point：

Wolfram Language code: RegionDisjoint[Point[{2}], Interval[{1, 3}]]

Ball：

Wolfram Language code: RegionDisjoint[Ball[1], Interval[{2, 3}]]

InfiniteLine:

Wolfram Language code: RegionDisjoint[InfiniteLine[{0}, {1}], InfiniteLine[{-3}, {1}]]

含有 Point 的 中的区域：

Wolfram Language code: Subscript[ℛ, 1] = Point[RandomReal[1, {10, 2}]]; Subscript[ℛ, 2] = Point[RandomReal[1, {10, 2}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics[{{Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

Line：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{0, 0}, {1, 1}}]; Subscript[ℛ, 2] = Line[RandomReal[1, {10, 2}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics[{{Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

Polygon：

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{1, 1 / 2}, {0, 3 / 2}, {-1 / 2, 1 / 2}, {0, 11 / 10}}]; Subscript[ℛ, 2] = Triangle[];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

Disk 和 Ellipsoid：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Ellipsoid[{1, 0}, {3, 2}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Rectangle 和 RegularPolygon：

Wolfram Language code: RegionDisjoint[Rectangle[{x, y}], RegularPolygon[4]]

含有 Point 的 中的区域：

Wolfram Language code: Subscript[ℛ, 1] = Point[RandomReal[1, {10, 3}]]; Subscript[ℛ, 2] = Point[RandomReal[1, {10, 3}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Line:

Wolfram Language code: Subscript[ℛ, 1] = Line[RandomReal[1, {10, 3}]]; Subscript[ℛ, 2] = Line[RandomReal[1, {10, 3}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Polygon:

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{1, 0, 1}, {0, 1, 2}, {1, 1, 1}, {2, 0, 0}}]; Subscript[ℛ, 2] = Triangle[{{0, 0, -1}, {2, -1, 1}, {2, 2, 1}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Graphics3D[{{Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}, Boxed -> False]

Cuboid 和 Hexahedron：

Wolfram Language code: Subscript[ℛ, 1] = Cuboid[]; Subscript[ℛ, 2] = Hexahedron[{{0, 0, 0}, {1, 0, 0}, {2, 1, 0}, {1, 1, 0}, {0, 0, 1}, {1, 0, 1}, {2, 1, 1}, {1, 1, 1}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Ball 和 Ellipsoid：

Wolfram Language code: Subscript[ℛ, 1] = Ball[3]; Subscript[ℛ, 2] = Ellipsoid[{1, 1, 2}, {3, 2, 1}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Tetrahedron 和 Simplex：

Wolfram Language code: Subscript[ℛ, 1] = Tetrahedron[]; Subscript[ℛ, 2] = Simplex[{{1, 0, 1}, {1, 0, 0}, {0, 0, 1}, {1, 1, 1}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

含有 中的 Cuboid 和 Parallelepiped 的 中的区域：

Wolfram Language code: Subscript[ℛ, 1] = Cuboid[{0, 0, 0, 0}, {1, 1, 1, 1}]; Subscript[ℛ, 2] = Parallelepiped[{-1, -1, -1, -1}, -IdentityMatrix[4]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

中的 Ellipsoid 和 Ball：

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[Table[1, 10], Table[i, {i, 10}]]; Subscript[ℛ, 2] = Ball[10];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

公式区域  (4)

隐式区域：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[1 / 2 ≤ x^2 + y^2 ≤ 1, {x, y}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 == 9, {x, y}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

参数化区域：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{2x y, x - y}, {{x, 0, 1}, {y, 0, 1}}]; Subscript[ℛ, 2] = ParametricRegion[{r Cos[θ] + 1, r Sin[θ]}, {{r, 0, 2}, {θ, 0, 2π}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

比较两个公式区域：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[(x - 2)^4 + (y - 2)^4 + (z - 2)^4 ≤ 1, {x, y, z}]; Subscript[ℛ, 2] = ParametricRegion[{ρSqrt[4 - u^2]Cos[θ], ρSqrt[4 - u^2]Sin[θ], ρ u}, {{ρ, 0, 1}, {θ, 0, 2π}, {u, -2, 2}}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

非常数公式区域：

Wolfram Language code: RegionDisjoint[Annulus[], ImplicitRegion[Subsuperscript[r, 1, 2] ≤ x^2 + y^2 ≤ Subsuperscript[r, 2, 2], {x, y}]]

网格区域  (3)

比较 中的 MeshRegion：

Wolfram Language code: Subscript[ℛ, 1] = MeshRegion[{{0}, {2}}, Line[{1, 2}]]; Subscript[ℛ, 2] = MeshRegion[{{1}, {3}}, Line[{1, 2}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

中的：

Wolfram Language code: Subscript[ℛ, 1] = DiscretizeGraphics[Annulus[]]; Subscript[ℛ, 2] = DiscretizeGraphics[Disk[{1 / 3, 0}, 1 / 4]];
Wolfram Language code: Show[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

中的：

Wolfram Language code: Subscript[ℛ, 1] = DiscretizeGraphics[Ball[]]; Subscript[ℛ, 2] = DiscretizeGraphics[Cuboid[{1, 1, 1}]];
Wolfram Language code: Show[Subscript[ℛ, 2], Subscript[ℛ, 1]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

比较 中的 BoundaryMeshRegion：

Wolfram Language code: Subscript[ℛ, 1] = BoundaryMeshRegion[{{0}, {2}}, Point[{1, 2}]]; Subscript[ℛ, 2] = BoundaryMeshRegion[{{1}, {3}}, Point[{1, 2}]];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

中的：

Wolfram Language code: Subscript[ℛ, 1] = BoundaryDiscretizeGraphics[Annulus[]]; Subscript[ℛ, 2] = BoundaryDiscretizeGraphics[Disk[{1 / 3, 0}, 1 / 4]];
Wolfram Language code: Show[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

中的：

Wolfram Language code: Subscript[ℛ, 1] = BoundaryDiscretizeGraphics[Ball[]]; Subscript[ℛ, 2] = BoundaryDiscretizeGraphics[Cuboid[{1, 1, 1}]];
Wolfram Language code: Show[Subscript[ℛ, 2], Subscript[ℛ, 1]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

比较 MeshRegion 与 中的 BoundaryMeshRegion：

Wolfram Language code: Subscript[ℛ, 1] = DelaunayMesh[RandomReal[{-2, 0}, {25, 2}]]; Subscript[ℛ, 2] = ConvexHullMesh[RandomReal[{0, 2}, {25, 2}]];
Wolfram Language code: Show[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

中的：

Wolfram Language code: Subscript[ℛ, 1] = DelaunayMesh[RandomReal[{-1, 1}, {25, 3}]]; Subscript[ℛ, 2] = ConvexHullMesh[RandomReal[{0, 1}, {25, 3}]];
Wolfram Language code: Show[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

导出区域  (1)

比较 BooleanRegion：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[{2, 0}]; Subscript[ℛ, 2] = BooleanRegion[Xnor, {Disk[], Disk[{2, 0}, 2]}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

选项  (2)

Assumptions  (1)

求同心圆盘和圆环不相交的半径：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = ImplicitRegion[Subsuperscript[r, 1, 2] ≤ x^2 + y^2 ≤ Subsuperscript[r, 2, 2], {x, y}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

只求正的半径：

Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], Assumptions -> 0 < Subscript[r, 1] < Subscript[r, 2]]

GenerateConditions  (1)

什么情况下单位圆盘与一个隐式定义的圆环不相交：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = ImplicitRegion[Subscript[r, 1] ≤ x^2 + y^2 ≤ Subscript[r, 2], {x, y}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

显示结果有效的条件：

Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], GenerateConditions -> True]

明确允许退化的情形：

Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2], Assumptions -> Subscript[r, 1]∈Reals]

应用  (6)

通过模拟布封的投针问题估计 的值：

Wolfram Language code: d = 0.2;n = 1000;
Wolfram Language code: lines = MeshRegion[ Join@@Table[{{-1 - d, y}, {1 + d, y}}, {y, -1 - d, 1 + d, d}], Line[Partition[Range[2Floor[2 / d + 3]], 2]] ];

创建长度为 的随机摆放的线段：

Wolfram Language code: needles = Table[Line[{pt, RandomPoint[Circle[pt, d]]}], {pt, RandomReal[{-1, 1}, {n, 2}]}];

选取与网格线重叠的线段：

Wolfram Language code: overlap = Select[needles, !RegionDisjoint[lines, #]&];

显示重叠的线段（红色）：

Wolfram Language code: Show[lines, Graphics[{Red, overlap, StandardGray, Complement[needles, overlap]}]]

估计 的值：

Wolfram Language code: N[(2n/Length[overlap])]

检测一个物体和一组墙面之间相碰触的情况：

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "MeshRegion"];
Wolfram Language code: w1 = Hyperplane[{1, 0, 0}, 0.39]; w2 = Hyperplane[{1, 0, 0}, -0.45];

把不与牛相碰的墙涂成绿色，否则为红色：

Wolfram Language code: wallColor[reg_] := If[RegionDisjoint[cow, reg], Green, Red]
Wolfram Language code: Show[cow, Graphics3D[{{wallColor[w1], w1}, {wallColor[w2], w2}}], PlotRangePadding -> .04]

给出与法国接壤的所有国家：

Wolfram Language code: c = Entity["Country", "France"]; p = c["Polygon"] /. GeoPosition -> Identity;

每个国家的外形：

Wolfram Language code: all = EntityValue["Country", "Polygon", "EntityAssociation"] /. GeoPosition -> Identity;

选择国家的外形与法国的外形非不相交的国家：

Wolfram Language code: DeleteCases[Keys[Select[all, !RegionDisjoint[p, #]&]], c]//Sort

验证结果：

Wolfram Language code: c["BorderingCountries"]

在地图上查看这些国家：

Wolfram Language code: GeoGraphics[{EdgeForm[Black], GeoStyling[LightGray], Polygon[%], GeoStyling[Red], Polygon[c]}]

给出并显示一个单位矩形与一个圆环不相交的位置：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[{x, y}]; Subscript[ℛ, 2] = Annulus[{0, 0}, {1, 2}];
Wolfram Language code: cond = RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionPlot[cond, {x, -4, 3}, {y, -4, 3}, Epilog -> {Red, Opacity[0.1], Subscript[ℛ, 2]}]

在一个区域外进行随机行走：

Wolfram Language code: ℛ = Annulus[{0, 0}, {1 / 2, 1}, {π / 12, 23π / 12}];

定义一个函数，按随机方向行走，但始终处于区域之外：

Wolfram Language code: walkPoint[pt_, r_, reg_] := Block[{npt = RandomPoint[Sphere[pt, r]]}, While[!RegionDisjoint[Line[{pt, npt}], reg], npt = RandomPoint[Sphere[pt, r]] ]; npt ]

从一个初始点出发，模拟随机行走：

Wolfram Language code: start = {0, 0};
Wolfram Language code: path = NestList[walkPoint[#, 0.1, ℛ]&, start, 500];

显示行走路线：

Wolfram Language code: Graphics[{{Green, ℛ}, {Line[path]}, {Red, Point[start]}}]

创建一个网络，如果美国的两个州接壤，就用网络把它们连接起来：

Wolfram Language code: usa = EntityClass["AdministrativeDivision", "ContinentalUSStates"];
Wolfram Language code: polys = EntityValue[usa, "Polygon", "EntityAssociation"] /. {GeoPosition -> Identity, {x_Real, y_} :> {y, x}};

如果 RegionDisjoint 返回 False，则两个州接壤：

Wolfram Language code: statesBorderQ[loc1_, loc2_] := loc1 =!= loc2 && !RegionDisjoint[polys[loc1], polys[loc2]]
Wolfram Language code: g = RelationGraph[statesBorderQ, Keys[polys]]

把该网络叠置在美国地图上：

Wolfram Language code: coords = EntityValue[usa, "Coordinates"];
Wolfram Language code: g = Graph[g, VertexCoordinates -> Reverse /@ coords, EdgeStyle -> Directive[{Red, Thick}], Prolog -> {EdgeForm[Thin], LightGreen, Values[polys]}, PlotRange -> RegionBounds[RegionUnion@@Values[polys]]]

最大的断裂存在于缅因州和最西边的那些州之间：

Wolfram Language code: GraphPeriphery[g]

找出并突出显示从缅因州到加利福尼亚州的路径：

Wolfram Language code: path = FindShortestPath[g, Entity["AdministrativeDivision", {"Maine", "UnitedStates"}], Entity["AdministrativeDivision", {"California", "UnitedStates"}]];
Wolfram Language code: HighlightGraph[g, Style[PathGraph[path], Blue]]

属性和关系  (4)

区域和它的补总是不相交的：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: RegionDisjoint[ℛ, BooleanRegion[Not, {ℛ}]]

不相交区域没有共同点：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Rectangle[{2, 0}];
Wolfram Language code: Resolve[Exists[{x, y}, {x, y}∈Subscript[ℛ, 1]∧{x, y}∈Subscript[ℛ, 2]]]
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]

对于非空区域，当 RegionDisjoint 返回 True 时，RegionEqual 和 RegionWithin 返回 False：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Disk[{2, 1}];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: RegionWithin[Subscript[ℛ, 1], Subscript[ℛ, 2]]

用 FindInstance 找出位于两个区域相交部分的点：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[]; Subscript[ℛ, 2] = Parallelogram[];
Wolfram Language code: RegionDisjoint[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: pts = {x, y} /. FindInstance[{x, y}∈Subscript[ℛ, 1]∧{x, y}∈Subscript[ℛ, 2], {x, y}, 100];
Wolfram Language code: Graphics[{Point[pts], Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

用 RandomPoint 找出位于两个区域相交部分的均匀采样点：

Wolfram Language code: pts = RandomPoint[BooleanRegion[#1∧#2&, {Subscript[ℛ, 1], Subscript[ℛ, 2]}], 100];
Wolfram Language code: Graphics[{Point[pts], Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

用 Reduce 来找出两个区域重叠的部分：

Wolfram Language code: Reduce[{x, y}∈Subscript[ℛ, 1]∧{x, y}∈Subscript[ℛ, 2], {x, y}]
Wolfram Language code: RegionPlot[%, {x, -1, 3}, {y, -3 / 2, 5 / 2}, PlotPoints -> 60]

巧妙范例  (1)

生成由随机放置的、不相交的球构成的场景：

Wolfram Language code: randomBall[dim_] := Ball[{RandomReal[{0, 10}, dim]}, {RandomReal[{1 / 4, 1}]}]
Wolfram Language code: appendDisjointBall[dim_][reg : Ball[pts_, rs_]] := Block[{ball = randomBall[dim]}, While[!RegionDisjoint[ball, reg], ball = randomBall[dim] ]; Ball[Join[pts, #1], Join[rs, #2]]&@@ball ]
Wolfram Language code: disjointBalls[n_, dim_] := Nest[appendDisjointBall[dim], randomBall[dim], n - 1]

二维：

Wolfram Language code: n = 40; scene2D = disjointBalls[n, 2];
Wolfram Language code: Graphics[{EdgeForm[StandardGray], Thread[{RandomColor[Hue[_], n], Thread[scene2D]}]}]

三维：

Wolfram Language code: n = 100; scene3D = disjointBalls[n, 3];
Wolfram Language code: Graphics3D[Thread[{RandomColor[Hue[_], n], Thread[scene3D]}], Lighting -> "Neutral"]
Wolfram Research (2017)，RegionDisjoint，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RegionDisjoint.html.

文本

Wolfram Research (2017)，RegionDisjoint，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RegionDisjoint.html.

CMS

Wolfram 语言. 2017. "RegionDisjoint." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/RegionDisjoint.html.

APA

Wolfram 语言. (2017). RegionDisjoint. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/RegionDisjoint.html 年

BibTeX

@misc{reference.wolfram_2026_regiondisjoint, author="Wolfram Research", title="{RegionDisjoint}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/RegionDisjoint.html}", note=[Accessed: 01-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_regiondisjoint, organization={Wolfram Research}, title={RegionDisjoint}, year={2017}, url={https://reference.wolfram.com/language/ref/RegionDisjoint.html}, note=[Accessed: 01-September-2026]}