Wolfram言語＆システムドキュメントセンター

Table

Table[expr,n]

expr の n 個のコピーのリストを作成する．

Table[expr,{i,i_max}]

i が1から i_maxまでの場合の expr の値のリストを作成する．

Table[expr,{i,i_min,i_max}]

i=i_min から開始する．

Table[expr,{i,i_min,i_max,di}]

di をステップとして使用する．

Table[expr,{i,{i₁,i₂,…}}]

連続する値 i₁, i₂, …を使用する．

Table[expr,{i,i_min,i_max},{j,j_min,j_max},…]

ネストしたリストを与える．i に対応するリストが最も外側になる． »

Table

Table[expr,n]

expr の n 個のコピーのリストを作成する．

Table[expr,{i,i_max}]

i が1から i_maxまでの場合の expr の値のリストを作成する．

Table[expr,{i,i_min,i_max}]

i=i_min から開始する．

Table[expr,{i,i_min,i_max,di}]

di をステップとして使用する．

Table[expr,{i,{i₁,i₂,…}}]

連続する値 i₁, i₂, …を使用する．

Table[expr,{i,i_min,i_max},{j,j_min,j_max},…]

ネストしたリストを与える．i に対応するリストが最も外側になる． »

詳細

Tableを使ってベクトル，行列，テンソル，その他の配列を構築することができる．
Tableは，標準的なWolfram言語の反復の指定を使用する．
Tableは非標準的な方法でその引数を評価する．
Table[expr,spec]は，まず spec を評価し，次に指定された変数を局所化し，続いてこれに連続的に値を割り当てる．割当てのたびに expr が評価される．
Tableは，Blockを使って実質的には値や変数を局所化する．
Table[expr,spec₁,spec₂]は，実質的にTable[Table[expr,spec₂],spec₁]と等価である．
Parallelize[Table[expr,iter]]またはParallelTable[expr,iter]はTable[expr,iter]をすべてのサブカーネルで並列に計算する． »

例題

すべて開くすべて閉じる

例 (6)

最初の10個の二乗の表：

Wolfram Language code: Table[i ^ 2, {i, 10}]

ステップ2で0から20までのの表：

Wolfram Language code: Table[f[i], {i, 0, 20, 2}]

10個ののリスト：

Wolfram Language code: Table[x, 10]

4×3行列を作る：

Wolfram Language code: Table[10i + j, {i, 4}, {j, 3}]

Wolfram Language code: MatrixForm[%]

表をプロットする：

Wolfram Language code: ListPlot[Table[Prime[i], {i, 50}]]

表を列に並べ替える：

Wolfram Language code: Column[Table[Prime[i], {i, 5}]]

スコープ (6)

表の指標は後ろ向きにも付けられる：

Wolfram Language code: Table[f[i], {i, 10, -5, -2}]

三角配列を作る：

Wolfram Language code: Table[10i + j, {i, 5}, {j, i}]

Wolfram Language code: TableForm[%]

3×2×4配列，あるいはテンソルを作る：

Wolfram Language code: Table[100i + 10j + k, {i, 3}, {j, 2}, {k, 4}]

既存のリスト上で反復させる：

Wolfram Language code: Table[Sqrt[x], {x, {1, 4, 9, 16}}]

既存のリストから配列を作る：

Wolfram Language code: Table[j ^ (1 / i), {i, {1, 2, 4}}, {j, {1, 4, 9}}]

Tableは，式を毎回別に評価する：

Wolfram Language code: Table[RandomInteger[10], 20]

一般化と拡張 (3)

表の指標に記号を使うことができる：

Wolfram Language code: Table[2 ^ x + x, {x, a, a + 5n, n}]

変数は記号でなくともよい：

Wolfram Language code: Table[a[x]!, {a[x], 6}]

Wolfram Language code: Table[x[1] ^ 2 + x[2] ^ 2, {x[1], 3}, {x[2], 3}]

ParallelTableはTableを並列に計算する：

Wolfram Language code: ParallelTable[PrimeQ[2 ^ i - 1], {i, 10}]

Tableは，事実上ParallelTableを使って自動的に並列化できる：

Wolfram Language code: Parallelize[Table[PrimeQ[2 ^ i - 1], {i, 10}]]

アプリケーション (4)

グラフィックスの表を作る：

Wolfram Language code: Table[Plot[BesselJ[n, x], {x, 0, 10}], {n, 4}]

多角形の角を生成する：

Wolfram Language code: Graphics[Polygon[Table[{Sin[2 n Pi / 5], Cos[2 n Pi / 5]}, {n, 0, 5}]]]

パスカルの三角形を作る：

Wolfram Language code: Column[Table[Binomial[i, j], {i, 0, 8}, {j, 0, i}], Center]

10ポイントから20ポイントまでのフォントサイズを比較する：

Wolfram Language code: Table[Style["text", s], {s, 10, 20}]

特性と関係 (13)

表の表示 (5)

ListPlot，ListLinePlotおよびこれらに類似した関数を使って数値の表を可視化する：

Wolfram Language code: ListLinePlot[Table[DigitCount[n, 2, 1], {n, 128}]]

Gridを使って二次元の表をフォーマットする：

Wolfram Language code: Grid[Table[{i, Prime[i]}, {i, 10}]]

二次元の数値表はArrayPlotまたはMatrixPlotで可視化できる：

Wolfram Language code: ArrayPlot[Table[GCD[i, j], {i, 10}, {j, 10}]]

表を生成している間に，表の指標の値を出力する：

Wolfram Language code: Table[Print[i];i ^ i ^ i, {i, 3}]

臨時のセルに表示することで値をモニターする：

Wolfram Language code: Monitor[Table[Pause[1];i ^ i ^ i, {i, 3}], i]

他の関数との関係 (5)

Rangeは表の反復子の値の文字列を与える：

Wolfram Language code: Range[1, 10, 2]

Wolfram Language code: Table[i, {i, 1, 10, 2}]

DoはTableと同じ式の列を評価するが，それを返すことはしない：

Wolfram Language code: Do[Print[i ^ i], {i, 3}]

Wolfram Language code: Table[i ^ i, {i, 3}]

Sumは実質的にPlusをTableの結果に適用する：

Wolfram Language code: Sum[x ^ i, {i, 3}]

Wolfram Language code: Table[x ^ i, {i, 3}]

Arrayは連続する整数上で反復する：

Wolfram Language code: Array[#1 ^ #2&, {3, 4}]

Wolfram Language code: Array[Function[{x, y}, x ^ y], {3, 4}]

Wolfram Language code: Table[x ^ y, {x, 3}, {y, 4}]

Mapは関数をリスト中の連続する要素に適用する：

Wolfram Language code: list = RandomInteger[9, 10]

Wolfram Language code: Map[Last[IntegerDigits[#, 2]]&, list]

Tableはリスト中の連続する要素を式に置き換えることができる：

Wolfram Language code: Table[Last[IntegerDigits[x, 2]], {x, list}]

ネストした表 (1)

複数の反復指定を使うことはTable関数をネストさせることに等しい：

Wolfram Language code: Table[i + j, {i, 3}, {j, i}]

Wolfram Language code: Table[Table[i + j, {j, i}], {i, 3}]

プログラムに基づいた表の構築 (2)

表のためのパラメータをフィードする：

Wolfram Language code: Table[i - j, {i, #1}, {j, #2}]&@@{4, 5}

Wolfram Language code: Table[i - j, ##]&@@{{i, 4}, {j, 5}}

Applyを使って完全な反復子の指定をTableにスプライスする：

Wolfram Language code: Table[{i[j], j + 1}, {j, 3}]

Wolfram Language code: Apply[Table[x, ##]&, %]

Withを使うと単一の反復子指定が挿入できる：

Wolfram Language code: With[{s = {i, 5}}, Table[i ^ 2, s]]

考えられる問題 (6)

ある種の刻み幅では，Tableの出力が与えられた上限を含まないことがある：

Wolfram Language code: Table[x, {x, 0, 10, 3}]

Tableでは反復子の指定は明示的に行う必要がある：

Wolfram Language code:

p = {x, 5};
Table[x ^ 2, p]

リストを早いうちに強制的に評価すると問題は解決する：

Wolfram Language code: Table[x ^ 2, Evaluate[p]]

あるいは，Withを使って p をリスト形式で代替することもできる：

Wolfram Language code: With[{p = {x, 5}}, Table[x ^ 2, p]]

Tableは通常各ステップで再評価する：

Wolfram Language code: Table[RandomReal[], {5}]

Wolfram Language code: Table[Evaluate[RandomReal[]], {5}]

Plotにフィードする前に表を強制的に評価するためにEvaluate を使う必要がある：

Wolfram Language code: Plot[Evaluate[Table[BesselJ[n, x], {n, 5}]], {x, 0, 15}]

次と比較する：

Wolfram Language code: Plot[Table[BesselJ[n, x], {n, 5}], {x, 0, 15}]

Table変数の値はホールドされた式の内側では置換されない：

Wolfram Language code: Table[Hold[i], {i, 5}]

Withを使って値を挿入する：

Wolfram Language code: Table[With[{i = i}, Hold[i]], {i, 5}]

Gridのようなラッパーをフォーマットすると，もはやリストではない式が返される：

Wolfram Language code: Grid[Table[i j, {i, 4}, {j, 4}]]

Wolfram Language code: x + %

Wolfram Language code: InputForm[%]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Table

詳細

例題

例 (6)

スコープ (6)

一般化と拡張 (3)

アプリケーション (4)