WOLFRAM

Wolfram 语言与系统参考资料中心

BesselJ[n,z]

给出第一类贝塞尔函数 TemplateBox[{n, z}, BesselJ].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
积分变换  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

BesselJ

BesselJ[n,z]

给出第一类贝塞尔函数 TemplateBox[{n, z}, BesselJ].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值化计算：

Wolfram Language code: BesselJ[0, 5.2]

在实数的子集上绘制 ：

Wolfram Language code: Plot[BesselJ[0, x], {x, 0, 50}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[BesselJ[1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[BesselJ[0, x], {x, 0, 10}]

在 Infinity 的级数展开：

Wolfram Language code: Series[BesselJ[0, x], {x, ∞, 3}]//Normal

范围  (52)

数值运算  (6)

进行数值运算：

Wolfram Language code: BesselJ[0, 4.0]

高精度求值：

Wolfram Language code: N[BesselJ[0, 4], 50]

输出精度与输入精度一致：

Wolfram Language code: BesselJ[0, 4.000000000000000000000000]

对复变量和参量求值：

Wolfram Language code: BesselJ[7 / 3 + I, 4.5 - I]

在高精度条件下高效运行 BesselJ：

Wolfram Language code: BesselJ[0, 4`500]//Timing
Wolfram Language code: BesselJ[0, 4`50000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: BesselJ[Interval[{0.5, 0.6}], Interval[{2.4, 2.5}]]
Wolfram Language code: BesselJ[1 / 2, CenteredInterval[2, 1 / 100]]

或者使用 Around 计算一般情况下的统计区间：

Wolfram Language code: BesselJ[2, Around[2, 0.01]]

逐项计算数组中各个元素的值：

Wolfram Language code: BesselJ[0.5, {{1, 2}, {3, 4}}]

或使用 MatrixFunction 计算矩阵 BesselJ 函数：

Wolfram Language code: MatrixFunction[BesselJ[0.5, #]&, {{1, 2}, {3, 4}}]

特殊值  (3)

对于半整数指数，BesselJ 求解为初等函数：

Wolfram Language code: Table[BesselJ[(2n + 1) / 2, x], {n, 0, 2}]

无穷处的极限值：

Wolfram Language code: Limit[BesselJ[n, x], x -> Infinity]

TemplateBox[{0, x}, BesselJ] 的前三个零点：

Wolfram Language code: Table[BesselJZero[0, x], {x, 3}]//N

用 Solve 求 TemplateBox[{0, x}, BesselJ] 的第一个正零点：

Wolfram Language code: sol = Solve[BesselJ[0, x] == 0 && 0 < x < 3, x]//N

可视化结果：

Wolfram Language code: xzero = x /. First@sol; Plot[BesselJ[0, x], {x, -1, 8}, Epilog -> Style[Point[{xzero, BesselJ[0, xzero]}], Red, PointSize[Large]]]

可视化  (4)

绘制整数 () 和半整数 () 阶数的 BesselJ 函数：

Wolfram Language code: Plot[{BesselJ[0, x], BesselJ[1, x], BesselJ[-1 / 2, x]}, {x, -7, 7}]

绘制半整数阶 BesselJ 函数的实部和虚部：

Wolfram Language code: ReImPlot[{BesselJ[1 / 2, x], BesselJ[3 / 2, x]}, {x, -3, 3}]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[BesselJ[0, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[BesselJ[0, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[BesselJ[-1 / 4, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[BesselJ[-1 / 4, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

函数属性  (12)

是针对所有实数和复数定义的：

Wolfram Language code: FunctionDomain[BesselJ[0, x], x]
Wolfram Language code: FunctionDomain[BesselJ[0, z], z, Complexes]

是针对所有大于 0 的实数定义的：

Wolfram Language code: FunctionDomain[BesselJ[1 / 2, x], x]

其复定义域是除 之外的整个平面：

Wolfram Language code: FunctionDomain[BesselJ[1 / 2, z], z, Complexes]

的近似值域：

Wolfram Language code: FunctionRange[BesselJ[0, x], x, y]//Quiet

的近似值域：

Wolfram Language code: FunctionRange[BesselJ[1, x], x, y]//Quiet

对于整数 ，TemplateBox[{n, z}, BesselJ] 是关于 的奇函数还是偶函数，取决于 是偶数还是奇数：

Wolfram Language code: BesselJ[0, -z]
Wolfram Language code: BesselJ[1, -z]

可将其表示为 TemplateBox[{n, z}, BesselJ]=(-1)^n TemplateBox[{n, {-, z}}, BesselJ]:

Wolfram Language code: FullSimplify[BesselJ[n, z] == (-1)^n BesselJ[n, -z], n∈ℤ]

对于整数 ，TemplateBox[{n, z}, BesselJ] 是 的解析函数：

Wolfram Language code: Table[FunctionAnalytic[BesselJ[n, z], z], {n, -2, 2}]

非整数阶数的函数不是解析函数：

Wolfram Language code: Table[FunctionAnalytic[BesselJ[n, z], z], {n, -(3/2), (3/2)}]

BesselJ 既不是非递增，也不是非递减：

Wolfram Language code: Table[FunctionMonotonicity[BesselJ[n, z], z], {n, 5}]
Wolfram Language code: Table[FunctionMonotonicity[BesselJ[1 / n, z], z], {n, 5}]

BesselJ 不是单射函数：

Wolfram Language code: Table[FunctionInjective[BesselJ[n, z], z], {n, 5}]
Wolfram Language code: Table[FunctionInjective[BesselJ[1 / n, z], z], {n, 5}]
Wolfram Language code: Plot[{BesselJ[1, z], BesselJ[2, z], BesselJ[1 / 3, z], .2}, {z, 0, 15}]

BesselJ 不是满射函数：

Wolfram Language code: Table[FunctionSurjective[BesselJ[n, z], z], {n, 5}]
Wolfram Language code: Table[FunctionSurjective[BesselJ[1 / n, z], z], {n, 5}]
Wolfram Language code: Plot[{BesselJ[1, z], BesselJ[2, z], BesselJ[1 / 3, z], 1}, {z, 0, 15}]

BesselJ 既不是非负，也不是非正：

Wolfram Language code: Table[FunctionSign[BesselJ[n, z], z], {n, 4}]

时，TemplateBox[{n, z}, BesselJ] 有奇点， 为非整数时，可能还包括 ：

Wolfram Language code: FunctionSingularities[BesselJ[n, z], z]//Simplify

其不连续性也是如此：

Wolfram Language code: FunctionDiscontinuities[BesselJ[n, z], z]//Simplify

BesselJ 既不凸，也不凹：

Wolfram Language code: Table[FunctionConvexity[BesselJ[a, z], z], {a, 5}]

TraditionalForm 格式：

Wolfram Language code: BesselJ[n, r]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[BesselJ[n, x], x]

高阶导数：

Wolfram Language code: derivs = Table[D[BesselJ[n, x], {x, k}], {k, 1, 3}]//FullSimplify

绘制整数阶和半整数阶函数的高阶导数：

Wolfram Language code: Plot[Evaluate[derivs /. n -> 0], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]
Wolfram Language code: ReImPlot[Evaluate[derivs /. n -> 1 / 2], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

阶导数的公式：

Wolfram Language code: D[BesselJ[n, x], {x, j}]

积分  (5)

用 Integrate 计算 BesselJ 的不定积分：

Wolfram Language code: Integrate[BesselJ[n, x], x]

含有 BesselJ 的表达式的不定积分：

Wolfram Language code: Integrate[Sin[x] BesselJ[n, x], x]

定积分：

Wolfram Language code: Integrate[BesselJ[n, x], {x, 0, Infinity}]

在以原点为中心的积分区间上的定积分为 0：

Wolfram Language code: Integrate[BesselJ[1, x], {x, -10, 10}]

（被积函数为偶函数）在以原点为中心的积分区间上的定积分：

Wolfram Language code: Integrate[BesselJ[0, x], {x, -10, 10}]

这是半区间上的积分的两倍：

Wolfram Language code: 2 Integrate[BesselJ[0, x], {x, 0, 10}]

级数展开式  (6)

在 处的泰勒展开式：

Wolfram Language code: Series[BesselJ[0, x], {x, 0, 7}]

绘制 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[BesselJ[0, x], {x, 0, m}], {m, 2, 7, 2}]; Plot[{BesselJ[0, x], terms}, {x, -8, 8}, PlotRange -> {All, {-1, 1.5}}]

BesselJ 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[BesselJ[0, x], {x, 0, n}]

在 处的级数展开式：

Wolfram Language code: Series[BesselJ[-1 / 2, x], {x, 0, 7}]

绘制 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[BesselJ[-1 / 2, x], {x, 0, m}], {m, 2, 7, 2}]; Plot[{BesselJ[-1 / 2, x], terms}, {x, 0, 10}, PlotRange -> {All, {-1, 1.5}}]

BesselJ 的渐近逼近：

Wolfram Language code: Series[BesselJ[n, x], {x, ∞, 2}]//Normal

在常点的泰勒展开式：

Wolfram Language code: Series[BesselJ[n, x], {x, x0, 2}]// FullSimplify

BesselJ 可被应用于幂级数：

Wolfram Language code: BesselJ[1 / 3, Log[1 + x] + O[x] ^ 2]

积分变换  (4)

用 FourierTransform 计算傅立叶变换：

Wolfram Language code: FourierTransform[BesselJ[0, t], t, ω]

LaplaceTransform:

Wolfram Language code: LaplaceTransform[BesselJ[n, t], t, s]

HankelTransform:

Wolfram Language code: HankelTransform[BesselY[n, r], r, s ]

MellinTransform:

Wolfram Language code: MellinTransform[BesselJ[n, x], x, s]

函数恒等式和化简  (4)

用 FullSimplify 化简贝塞尔函数：

Wolfram Language code: FullSimplify[x BesselJ[2, x] + x BesselJ[0, x]]

验证恒等式 TemplateBox[{{n, -, 1}, z}, BesselJ] TemplateBox[{{-, n}, z}, BesselJ]+TemplateBox[{{1, -, n}, z}, BesselJ] TemplateBox[{n, z}, BesselJ]=(2 sin(pi n))/(pi z)：

Wolfram Language code: BesselJ[n - 1, z] BesselJ[-n, z] + BesselJ[1 - n, z] BesselJ[n, z] == (2 Sin[n π]/π z)//FullSimplify

递推关系式 z (TemplateBox[{{n, -, 1}, z}, BesselJ] + TemplateBox[{{n, +, 1}, z}, BesselJ])=2 n J_n(z)：

Wolfram Language code: FullSimplify[z (BesselJ[n - 1, z] + BesselJ[n + 1, z]) == 2n BesselJ[n, z]]

对于整数 和任意固定不变的 ，TemplateBox[{{-, n}, z}, BesselJ]=(-1)^n TemplateBox[{n, z}, BesselJ]：

Wolfram Language code: FullSimplify[BesselJ[-n, z] == (-1)^n BesselJ[n, z], n∈ℤ]

函数表示  (5)

用 BesselI 表示：

Wolfram Language code: FullSimplify[(z^n/(I z)^n)BesselI[n, I z]]

级数表示：

Wolfram Language code: Sum[ (-1)^k((x/2))^2k / (k!) ^ 2, {k, 0, ∞}]

积分表示：

Wolfram Language code: Integrate[ Cos[x Cos[2 π t]], {t, 0, 1}, Assumptions -> x > 0]

用 MeijerG 表示：

Wolfram Language code: MeijerGReduce[BesselJ[n, x], x]
Wolfram Language code: Activate[%]

用 DifferenceRoot 表示：

Wolfram Language code: DifferenceRootReduce[BesselJ[k, z], k]

应用  (3)

解贝塞尔微分方程：

Wolfram Language code: DSolve[ x^2y''[x] + x y'[x] + (x - n)(x + n)y[x] == 0, y[x], x]

求解另一个微分方程：

Wolfram Language code: DSolve[(a + x Cot[x]) y[x] + (x + 2 x^2 Cot[x]) Derivative[1][y][x] + x^2 Derivative[2][y][x] == 0, y[x], x]

夫琅禾费衍射 (Fraunhofer diffraction) 是发生在小菲涅尔数 (small Fresnel number) 极限下的衍射类型. 绘制圆形光圈的夫琅禾费衍射图案的强度与衍射角的关系：

Wolfram Language code: Plot[2(BesselJ[1, 20Sin[θ]] / (20Sin[θ])) ^ 2, {θ, 0, π / 3}]

开普勒方程描述了一个物体在椭圆轨道上的运动. 开普勒方程的近似解是截断的傅里叶正弦级数：

Wolfram Language code: aKeplerE[ϵ_, m_] = m + Sum[(2/n)BesselJ[n, n ϵ]Sin[n m], {n, 1, 12}];

精确解：

Wolfram Language code: eKeplerE[ϵ_Real, m_Real] := Block[{x}, x /. FindRoot[x - ϵ Sin[x] == m, {x, m}]]

对不同解之间的差值作图：

Wolfram Language code: Plot[eKeplerE[0.5, m] - aKeplerE[0.5, m], {m, 0, 4Pi}]

属性和关系  (5)

用 FullSimplify 简化贝塞尔函数：

Wolfram Language code: FullSimplify[x BesselJ[2, x] + x BesselJ[0, x]]

Sum 和 Integrate 能够产生 BesselJ：

Wolfram Language code: Sum[ (-1)^kx^2k / (k!) ^ 2, {k, 0, ∞}]
Wolfram Language code: Integrate[ Cos[x Cos[2 π t]], {t, 0, 1}, Assumptions -> x > 0]

求解含有 BesselJ 的表达式的极限：

Wolfram Language code: Limit[(BesselJ[3, x]/Sin[x] - x), x -> 0]

BesselJ 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[BesselJ[n, x], x]

BesselJ 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[BesselJ[n, k], n, x]

可能存在的问题  (1)

对于数值自变量，半整数贝塞尔函数不能自动求值：

Wolfram Language code: BesselJ[11 / 2, 1]

若自变量为符号，则为：

Wolfram Language code: BesselJ[11 / 2, x]

这将致使机器精度求值中存在大误差：

Wolfram Language code: {BesselJ[35 / 2, 1.], BesselJ[35 / 2, x] /. x -> 1.}

巧妙范例  (1)

绘制 TemplateBox[{{1, /, 3}, z}, BesselJ] 的黎曼曲面：

Wolfram Language code: With[{ν = 1 / 3, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[k ν π I] BesselJ[ν, r Exp[I φ]]]}, {k, -1, 1}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.23], Opacity[0.6]]]]
Wolfram Research (1988)，BesselJ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BesselJ.html （更新于 2022 年）.

文本

Wolfram Research (1988)，BesselJ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BesselJ.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "BesselJ." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/BesselJ.html.

APA

Wolfram 语言. (1988). BesselJ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BesselJ.html 年

BibTeX

@misc{reference.wolfram_2026_besselj, author="Wolfram Research", title="{BesselJ}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/BesselJ.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_besselj, organization={Wolfram Research}, title={BesselJ}, year={2022}, url={https://reference.wolfram.com/language/ref/BesselJ.html}, note=[Accessed: 11-August-2026]}