Wolfram言語＆システムドキュメントセンター

BetaPrimeDistribution

BetaPrimeDistribution[p,q]

形状母数が p と q のベータプライム分布を表す．

BetaPrimeDistribution[p,q,β]

尺度母数が β の一般化されたベータプライム分布を表す．

BetaPrimeDistribution[p,q,α,β]

形状母数が α の一般化された第2種ベータ分布を表す．

詳細

BetaPrimeDistribution[1,q,1,β]はLomax分布としても知られている．
ベータプライム分布中の値の確率密度はのときに比例する．
BetaPrimeDistributionでは，p，q，α，β は任意の正の実数でよい．
BetaPrimeDistributionでは，β は任意の単位次元の数量でよく，p，q，α は無次元量でよい． »
BetaPrimeDistributionは，Mean，CDF，RandomVariate等の関数とともに使うことができる．

予備知識

BetaPrimeDistribution[p,q,α,β]は，区間上で定義され，4つの正の実数 p，q，α，β でパラメータ化された連続統計分布を表す．母数 p，q，α は「形状母数」として知られ，β は「尺度母数」として知られるものである．これらの母数はベータプライム分布の確率密度関数(PDF)の全体的な形を決定する．p，q，α，β の値によって，ベータプライム分布のPDFは，単峰性か潜在的な特異値が領域の下限に近付いていく単調減少になる．加えて，PDFの裾部はPDFが，の大きい値について指数的にではなく代数的に減少するという意味で「厚い」．（この動作は，分布のSurvivalFunctionを分析することで数量的に厳密にできる．）
BetaPrimeDistribution[p,q,α,β]は，一般化された第2種ベータ分布，逆ベータ分布，タイプ6のピアソン分布(PearsonDistribution)と呼ばれることがある．2引数および3引数形のBetaPrimeDistribution[p,q]およびBetaPrimeDistribution[p,q,β]を評価すると，それぞれBetaPrimeDistribution[p,q,1,1]およびBetaPrimeDistribution[p,q,1,β]となる．これらはそれぞれ，標準ベータプライム分布，一般化されたベータプライム分布と呼ばれることがある．
ベイズ解析では，ベータプライム分布は，確率として表現された二項比率についての事前分布として登場している．ベータプライム分布は，現実世界の多くの現象をモデル化することも分かっている．例えば，ベータプライム分布は，証券利益の経験的予測やオプションプライスモデルの開発に役立つことが証明されている．より近年には，保険の損失過程のモデリングに適用されている．他にも，ベータプライム分布の長い裾部は，この分布が個人集団の中で疾病を伝染させやすい動作頻度とそのような疾病の実際の伝染のモデル化に特に適していることを示している．
RandomVariateを使ってたベータプライム分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,BetaPrimeDistribution[p,q,α,β]]（より簡略すると xBetaPrimeDistribution[p,q,α,β]）を使って，確率変数 x がベータプライム分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
確率密度関数および累積分布関数は，PDF[BetaPrimeDistribution[p,q,α,β],x]およびCDF[BetaPrimeDistribution[p,q,α,β],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
DistributionFitTestを使って，与えられたデータ集合がベータプライム分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからベータプライムパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをベータプライム分布にフィットすることができる．ProbabilityPlotを使って記号ベータプライム分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号ベータプライム分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
TransformedDistributionを使って変換されたベータプライム分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってベータプライム分布を含む高次元分布を構築することが，ProductDistributionを使ってベータプライム分布を含む独立成分分布の結合分布を計算することができる．
BetaPrimeDistributionは他の多くの分布と関係がある．例えば，BetaPrimeDistribution[p,q,a,b]は，のときに簡約するとDagumDistribution[p,a,b]になり，で簡約するとSinghMaddalaDistribution[q,a,b] になる．およびではLogLogisticDistribution[a,b]になる．これに加え，2つの母数を持つ形のBetaPrimeDistribution[p,q]はタイプ6のピアソン分布PearsonDistribution[6,1,f/g,1/g,1/g,0]（および）と同じPDFを有し，タイプIIとタイプIVの両ParetoDistributionと関連している．BetaPrimeDistributionのPDFはBetaDistributionのPDFを変換したものであるのに対し，4引数の形BetaPrimeDistribution[p,q,a,1]は，2つの独立確率変数XGammaDistribution[p,1,a,0]および YGammaDistribution[q,1,a,0]の商である．BetaPrimeDistributionは，FRatioDistribution，DirichletDistribution，KumaraswamyDistribution，NoncentralBetaDistribution，PERTDistributionとも関連がある．

例題

すべて開くすべて閉じる

例 (4)

ベータプライム分布の確率密度関数：

Wolfram Language code: Plot[Table[PDF[BetaPrimeDistribution[4, q], x], {q, {1, 2, 3}}]//Evaluate, {x, 0, 8}, PlotRange -> All, Filling -> Axis]

Wolfram Language code:

Plot[Table[PDF[BetaPrimeDistribution[p, 4], x], {p, {1, 1.5, 3}}]//Evaluate, {x, 0, 1.5}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: PDF[BetaPrimeDistribution[p, q], x]

ベータプライム分布の累積分布関数：

Wolfram Language code: Plot[Table[CDF[BetaPrimeDistribution[4, q], x], {q, {1, 2, 3}}]//Evaluate, {x, 0, 8}, PlotRange -> All, Filling -> Axis]

Wolfram Language code:

Plot[Table[CDF[BetaPrimeDistribution[p, 4], x], {p, {1, 1.5, 3}}]//Evaluate, {x, 0, 1.5}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: CDF[BetaPrimeDistribution[p, q], x]

ベータプライム分布の平均と分散：

Wolfram Language code: Mean[BetaPrimeDistribution[p, q]]

Wolfram Language code: Variance[BetaPrimeDistribution[p, q]]

ベータプライム分布の中央値：

Wolfram Language code: Median[BetaPrimeDistribution[p, q]]

スコープ (19)

一般化されたベータプライム分布の確率密度関数：

Wolfram Language code:

Plot[Table[PDF[BetaPrimeDistribution[4, 2, β], x], {β, {1, 2, 4}}]//Evaluate, {x, 0, 8}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: PDF[BetaPrimeDistribution[p, q, β], x]

一般化されたベータプライム分布の累積分布関数：

Wolfram Language code:

Plot[Table[CDF[BetaPrimeDistribution[4, 2, β], x], {β, {1, 2, 4}}]//Evaluate, {x, 0, 8}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: CDF[BetaPrimeDistribution[p, q, β], x]

一般化されたベータプライム分布の平均と分散：

Wolfram Language code: Mean[BetaPrimeDistribution[p, q, β]]

Wolfram Language code: Variance[BetaPrimeDistribution[p, q, β]]

中央値：

Wolfram Language code: Median[BetaPrimeDistribution[p, q, β]]

一般化された第2種ベータ分布の確率密度関数：

Wolfram Language code:

Plot[Table[PDF[BetaPrimeDistribution[4, 2, α, 3], x], {α, {1, 2, 3}}]//Evaluate, {x, 0, 8}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: PDF[BetaPrimeDistribution[p, q, α, β], x]

一般化された第2種ベータ分布の累積分布関数：

Wolfram Language code:

Plot[Table[CDF[BetaPrimeDistribution[4, 2, α, 3], x], {α, {1, 2, 3}}]//Evaluate, {x, 0, 8}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: CDF[BetaPrimeDistribution[p, q, α, β], x]

一般化された第2種ベータ分布の平均と分散：

Wolfram Language code: Mean[BetaPrimeDistribution[p, q, α, β]]

Wolfram Language code: Variance[BetaPrimeDistribution[p, q, α, β]]

中央値：

Wolfram Language code: Median[BetaPrimeDistribution[p, q, α, β]]

ベータプライム分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[BetaPrimeDistribution[3.5, 1.2], 10 ^ 4];

そのヒストグラムを確率密度関数と比較する：

Wolfram Language code:

Show[
	Histogram[data, {0, 10, 0.5}, "PDF"], 
	Plot[PDF[TruncatedDistribution[{0, 10}, BetaPrimeDistribution[3.5, 1.2]], x], {x, 0, 10}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[BetaPrimeDistribution[20, 3], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, BetaPrimeDistribution[p, q]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, {0, 25, 1}, "PDF"], Plot[PDF[edist, x], {x, 0, 25}, PlotStyle -> Thick]]

歪度：

Wolfram Language code:

Plot3D[Skewness[BetaPrimeDistribution[p, q]], {p, 0, 10}, {q, 3, 10}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {2, -1, 0.5}]

一般化された第2種ベータ分布では，歪度は β に依存しない：

Wolfram Language code:

Plot3D[Skewness[BetaPrimeDistribution[p, 2, α, β]], {α, 2, 10}, {p, 0, 10}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {3, -1, 1}]

尖度：

Wolfram Language code:

Plot3D[Kurtosis[BetaPrimeDistribution[p, q]], {p, 0, 10}, {q, 4, 10}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {2, -1, 0.5}]

一般化された第2種ベータ分布では，尖度は β に依存しない：

Wolfram Language code:

Plot3D[Kurtosis[BetaPrimeDistribution[p, 2, α, β]], {α, 2, 10}, {p, 0, 10}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {3, -1, 1}]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BetaPrimeDistribution[p, q], k], {k, 3}], M]

記号次数の閉じた形：

Wolfram Language code: Moment[BetaPrimeDistribution[p, q], r]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BetaPrimeDistribution[p, q], k], {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BetaPrimeDistribution[p, q], k], {k, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BetaPrimeDistribution[p, q], k], {k, 3}], C]

一般化された第2種ベータ分布のさまざまなモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BetaPrimeDistribution[p, q, α, β], k], {k, 3}], M]

記号次数の閉じた形：

Wolfram Language code: Moment[BetaPrimeDistribution[p, q, α, β], r]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BetaPrimeDistribution[p, q, α, β], k]//Together, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BetaPrimeDistribution[p, q, α, β], k], {k, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BetaPrimeDistribution[p, q, α, β], k], {k, 3}], C]

ベータプライム分布のハザード関数：

Wolfram Language code:

Plot[Table[HazardFunction[BetaPrimeDistribution[4, q], x], {q, {0.5, 0.75, 1}}]//Evaluate, {x, 0, 8}, PlotRange -> All, Filling -> Axis]

Wolfram Language code:

Plot[Table[HazardFunction[BetaPrimeDistribution[p, 4], x], {p, {1, 2, 4}}]//Evaluate, {x, 0, 8}, PlotRange -> {0, 3}, Filling -> Axis]

Wolfram Language code: HazardFunction[BetaPrimeDistribution[p, q], x]

一般化されたベータプライム分布のハザード関数：

Wolfram Language code:

Plot[Table[HazardFunction[BetaPrimeDistribution[4, 2, β], x], {β, {0.5, 1, 2}}]//Evaluate, {x, 0, 10}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: HazardFunction[BetaPrimeDistribution[p, q, β], x]

一般化された第2種ベータ分布のハザード関数：

Wolfram Language code:

Plot[Table[HazardFunction[BetaPrimeDistribution[4, 2, α, 3], x], {α, {0.5, 1, 1.5}}]//Evaluate, {x, 0, 10}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: HazardFunction[BetaPrimeDistribution[p, q, α, β], x]

ベータプライム分布の分位関数：

Wolfram Language code: Plot[Table[Quantile[BetaPrimeDistribution[p, 2], z], {p, {1, 3, 5}}]//Evaluate, {z, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[BetaPrimeDistribution[p, q], z]

一般化されたベータプライム分布の分位関数：

Wolfram Language code: Plot[Table[Quantile[BetaPrimeDistribution[1.5, 2, β], z], {β, {1, 3, 5}}]//Evaluate, {z, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[BetaPrimeDistribution[p, q, β], z]

一般化された第2種ベータ分布の分位関数：

Wolfram Language code: Plot[Table[Quantile[BetaPrimeDistribution[1.5, 2, α, 3], z], {α, {1, 3, 5}}]//Evaluate, {z, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[BetaPrimeDistribution[p, q, α, β], z]

パラメータでQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: loss𝒟 = BetaPrimeDistribution[804.44, 2.13, 3.21, Quantity[1, "USDollars"]]

損失の中央値を求める：

Wolfram Language code: Median[loss𝒟]

アプリケーション (2)

BetaPrimeDistributionは損失のモデル化に使用できる：

Wolfram Language code: USHurricaneLoss = ExampleData[{"Statistics", "USHurricaneLoss"}];

Wolfram Language code: ExampleData[{"Statistics", "USHurricaneLoss"}, "Description"]

Wolfram Language code: TableForm[USHurricaneLoss]

明らかな外れ値である最も被害の大きかったハリケーンAndrewを除く：

Wolfram Language code: hurricaneLoss = QuantityArray[Rest[USHurricaneLoss[[All, 4]]], "Mega" * "USDollars"];

一般化されたベータ分布をデータにフィットする：

Wolfram Language code: edist = EstimatedDistribution[hurricaneLoss, BetaPrimeDistribution[p, 2.5, a]]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code:

Show[Histogram[hurricaneLoss, 20, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "MegaUSDollars"]], {x, 100, 7500}, PlotStyle -> Thick, PlotRange -> All]]

ハリケーンによる損失が30億ドルを超える確率を求める：

Wolfram Language code: Probability[x > Quantity[3 * 10 ^ 9, "USDollars"], xedist]

ハリケーンによる損失の平均をUSドルで求める：

Wolfram Language code: UnitConvert[Mean[edist], "USDollars"]

これから来る強力な30のハリケーンで被り得る損失のシミュレーションを，単位を百万USドルとして行う：

Wolfram Language code: ListPlot[RandomVariate[edist, 30], Filling -> Axis, AxesLabel -> Automatic]

BetaPrimeDistributionを使って州ごとの1人あたりの収入をモデル化することができる：

Wolfram Language code: data = ExampleData[{"Statistics", "USStateIncome"}]

通貨単位を加える：

Wolfram Language code:

incomes = MapAt[Quantity[#, "USDollars"]&, data, {All, 2}];
incomeValues = Part[incomes, All, 2];

一般化された第2種ベータ分布をデータにフィットする：

Wolfram Language code:

edistBetaPrime = EstimatedDistribution[incomeValues, BetaPrimeDistribution[p, q, α, β], ParameterEstimator -> {"MaximumLikelihood", Method -> "NMaximize"}]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code:

Show[Histogram[incomeValues, 15, "PDF", AxesLabel -> Automatic], Plot[PDF[edistBetaPrime, Quantity[x, "USDollars"]], {x, 20000, 48000}, PlotStyle -> Thick]]

1人あたりの平均収入を求める：

Wolfram Language code: meanIncome = Mean[edistBetaPrime]

収入が平均値に近い州を求める：

Wolfram Language code: Cases[incomes, {s_, inc_} /; Abs[inc - meanIncome] < Quantity[200, "USDollars"]]

1人あたりの収入の中央値を求める：

Wolfram Language code: medianIncome = Median[edistBetaPrime]

収入が中央値に近い州を求める：

Wolfram Language code: Cases[incomes, {s_, inc_} /; Abs[inc - medianIncome] < Quantity[300, "USDollars"]]

対数尤度値を求める：

Wolfram Language code: LogLikelihood[edistBetaPrime, incomeValues]

特性と関係 (16)

一般化された第2種ベータ分布の累積分布関数に対する母数の影響：

Wolfram Language code:

{ContourPlot[CDF[BetaPrimeDistribution[2, 1.5, α, .4], x], {x, 0, 3}, {α, 1 / 10, 3}, FrameLabel -> Automatic], ContourPlot[CDF[BetaPrimeDistribution[2, 1.5, .6, β], x], {x, 0, 3}, {β, 1 / 10, 3}, FrameLabel -> Automatic]}

BetaPrimeDistributionは正の因子によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[k * u, uBetaPrimeDistribution[p, q]]

Wolfram Language code: TransformedDistribution[k * u, uBetaPrimeDistribution[p, q, β]]

Wolfram Language code: TransformedDistribution[k * u, uBetaPrimeDistribution[p, q, α, β]]

BetaPrimeDistributionは，逆数を取る下では閉じている：

Wolfram Language code: TransformedDistribution[1 / u, uBetaPrimeDistribution[α, β]]

他の分布との関係：

DagumDistributionはBetaPrimeDistributionの特殊ケースである：

Wolfram Language code: PDF[DagumDistribution[p, a, b], x]

Wolfram Language code: PDF[BetaPrimeDistribution[p, 1, a, b], x]//PowerExpand//FullSimplify

Wolfram Language code: Simplify[% - %%, b > 0]

SinghMaddalaDistributionはBetaPrimeDistributionの特殊ケースである：

Wolfram Language code: PDF[SinghMaddalaDistribution[p, a, b], x]

Wolfram Language code: PDF[BetaPrimeDistribution[1, p, a, b], x]//PowerExpand//FullSimplify

Wolfram Language code: Simplify[% - %%, b > 0]

LogLogisticDistributionはBetaPrimeDistributionの特殊ケースである：

Wolfram Language code: PDF[BetaPrimeDistribution[1, 1, γ, σ], x]

Wolfram Language code: PDF[LogLogisticDistribution[γ, σ], x]

Wolfram Language code: FullSimplify[% - %%, σ > 0]

FRatioDistributionはBetaPrimeDistributionの特殊ケースである：

Wolfram Language code: PDF[FRatioDistribution[n, m], x]//PowerExpand

Wolfram Language code: PDF[BetaPrimeDistribution[n / 2, m / 2, m / n], x]//PowerExpand

Wolfram Language code: % - %%//FullSimplify[#, m > 0 && n > 0]&

ベータプライム分布はタイプ6のPearsonDistributionの特殊ケースである：

Wolfram Language code: PDF[PearsonDistribution[6, 1, (1 - p/q + 1), (1/q + 1), (1/q + 1), 0], x]

Wolfram Language code: PDF[BetaPrimeDistribution[p, q], x]

Wolfram Language code: % - %%//FullSimplify

タイプIIのParetoDistributionはBetaPrimeDistributionに関連している：

Wolfram Language code: PDF[BetaPrimeDistribution[1, q, 1, b], x]//FullSimplify//PowerExpand

Wolfram Language code: PDF[ParetoDistribution[b, q, 0], x]//PowerExpand

Wolfram Language code: Simplify[% - %%, x > 0]

タイプIVのParetoDistributionはBetaPrimeDistributionに関連している：

Wolfram Language code: PDF[BetaPrimeDistribution[1, q, a, 1], x]//FullSimplify

Wolfram Language code: PDF[ParetoDistribution[1, q, 1 / a, 0], x]//FullSimplify//PowerExpand

Wolfram Language code: Simplify[% - %%, x > 0]

ベータプライム分布は BetaDistributionを変換して求めることができる：

Wolfram Language code: TransformedDistribution[u / (1 - u), uBetaDistribution[α, β]]

Wolfram Language code: TransformedDistribution[(1 - u) / u, uBetaDistribution[α, β]]

一般化された第2種ベータ分布は，GammaDistributionの2つの独立した確率変数の比の分布である：

Wolfram Language code: TransformedDistribution[u / v, {uGammaDistribution[p, 1, a, 0], vGammaDistribution[q, 1, a, 0]}]

一般化された第2種ベータ分布を簡約するとベータプライム分布になる：

Wolfram Language code: PDF[BetaPrimeDistribution[p, q, 1, 1], x]

Wolfram Language code: PDF[BetaPrimeDistribution[p, q], x]

Wolfram Language code: % - %%

一般化されたベータプライム分布は一般化された第2種ベータ分布の特殊ケースである：

Wolfram Language code: PDF[BetaPrimeDistribution[p, q, 1, β], x]

Wolfram Language code: PDF[BetaPrimeDistribution[p, q, β], x]//PowerExpand

Wolfram Language code: FullSimplify[% - %%, β > 0]

一般化されたベータプライム分布を簡約するとベータプライム分布になる：

Wolfram Language code: PDF[BetaPrimeDistribution[p, q, 1], x]//PowerExpand

Wolfram Language code: PDF[BetaPrimeDistribution[p, q], x]

Wolfram Language code: % - %%

おもしろい例題 (1)

累積分布関数の等高線を持つ q のさまざまな値についての確率密度関数：

Wolfram Language code:

dist = BetaPrimeDistribution[4, q];cdf = Function[{x, q}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[dist, x], {x, 0, 15}, {q, 1, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BetaPrimeDistribution

詳細

予備知識

例題

例 (4)

スコープ (19)

アプリケーション (2)

特性と関係 (16)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

BetaPrimeDistribution

詳細

予備知識

例題

例 (4)

スコープ (19)

アプリケーション (2)

特性と関係 (16)

おもしろい例題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX