WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BorelTannerDistribution[α,n]

形状母数が α と n のBorel–Tanner分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

BorelTannerDistribution

BorelTannerDistribution[α,n]

形状母数が α と n のBorel–Tanner分布を表す．

詳細

予備知識

  • BorelTannerDistribution[α,n]は，整数値 について定義され，「形状母数」と呼ばれる母数 α および n によって決定された離散統計分布を表す．のとき，n は任意の正の整数であり，これら2つの母数が，平面内の確率密度関数(PDF)の，全体的な形，高さ，水平位置を決定する．Borel–Tanner分布は離散単峰性PDFを持つ．Borel–Tanner分布はTanner-Borel分布，あるいは（金融の領域では）群れのサイズ分布と呼ばれることがある．
  • Borel–Tanner分布の歴史は，フランス人の数学者Félix Borelが値 に対応するPDFの動作を調べた1940年代に始まる．10年後に，BorelのメソッドはJ.C. Tannerによって一般的な正の整数 n に対して適用され，現在の形の分布が生まれた．伝統的に，Borel–Tanner分布は待ち行列理論に基づいており，到着率がポアソン分布に従い，応対時間が一定であると仮定した場合に，そのPDFが，指定された x について，最初に行列がなくなるまでに，始まりの人数 n，トラヒック密度 α である待ち行列の厳密に x 人のメンバーが応対される確率を返す．この分布は，より最近では，高速道路の交通流量，オンラインサーバのトラヒック，既存の金融ポートフォリオと相対的なさまざまな投資行為等を含む，さまざまな現実世界の現象に使用されている．
  • RandomVariateを使ってBorel–Tanner分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,BorelTannerDistribution[α,n]]（より簡略すると xBorelTannerDistribution[α,n]）を使って，確率変数 x がBorel–Tanner分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[BorelTannerDistribution[α,n],x]およびCDF[BorelTannerDistribution[α,n],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．これらの数量はDiscretePlotを使って可視化することができる．
  • DistributionFitTestを使って，与えられたデータ集合がBorel–Tanner分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからBorel–Tannerパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをBorel–Tanner分布にフィットすることができる．ProbabilityPlotを使って記号Borel–Tanner分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号Borel–Tanner分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換されたBorel–Tanner分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってBorel–Tanner分布を含む高次元分布を構築することが，ProductDistributionを使ってBorel–Tanner分布を含む独立成分分布の結合分布を計算することができる．
  • BorelTannerDistributionは，数多くの他の統計分布と関係がある．BorelTannerDistributionは，nPoissonDistribution[μ]であるときは常に，PoissonConsulDistribution[μ,α]がBorelTannerDistribution[α,n]から得られるという意味で，PoissonConsulDistributionとも関連する．BorelTannerDistributionは，また，BinomialDistribution，NegativeBinomialDistribution，LogSeriesDistributionとも関係がある．

例題

すべて開く すべて閉じる

例  (3)

確率質量関数：

Wolfram Language code: DiscretePlot[Table[PDF[BorelTannerDistribution[α, 4], x], {α, {0.4, 0.7, 0.9}}]//Evaluate, {x, 4, 20}, PlotRange -> All, PlotMarkers -> Automatic]
Wolfram Language code: DiscretePlot[Table[PDF[BorelTannerDistribution[.4, n], x], {n, {5, 10, 12}}]//Evaluate, {x, 5, 25}, PlotMarkers -> Automatic]
Wolfram Language code: PDF[BorelTannerDistribution[α, n], x]

累積分布関数：

Wolfram Language code: DiscretePlot[Table[CDF[BorelTannerDistribution[α, 4], x], {α, {0.4, 0.7, 0.9}}]//Evaluate, {x, 4, 20}, ExtentSize -> Right]
Wolfram Language code: DiscretePlot[Table[CDF[BorelTannerDistribution[.4, n], x], {n, {5, 10, 12}}]//Evaluate, {x, 5, 25}, ExtentSize -> Right]

平均と分散：

Wolfram Language code: Mean[BorelTannerDistribution[α, n]]
Wolfram Language code: Variance[BorelTannerDistribution[α, n]]

スコープ  (8)

Borel–Tanner分布から擬似乱数のサンプルを生成する：

Wolfram Language code: sample = RandomVariate[BorelTannerDistribution[0.4, 30], 10 ^ 3];

そのヒストグラムをBorel-Tanner分布の確率密度関数と比較する：

Wolfram Language code: Show[ Histogram[sample, {2}, "PDF"], DiscretePlot[PDF[BorelTannerDistribution[0.4, 30], x], {x, 30, 76}, PlotStyle -> PointSize[Medium]]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[BorelTannerDistribution[.2, 10], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, BorelTannerDistribution[a, b]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, {1}, "PDF"], DiscretePlot[PDF[edist, x], {x, 9, 22}, PlotStyle -> PointSize[Medium]]]

歪度：

Wolfram Language code: Plot[Table[Skewness[BorelTannerDistribution[α, n]], {n, {1, 2, 5, 10}}]//Evaluate, {α, 0, 1}, PlotLegends -> Map[TraditionalForm[n == #]&, {1, 2, 5, 10}]]
Wolfram Language code: Skewness[BorelTannerDistribution[α, n]]

歪度は n とは無関係にその最小値に到達する：

Wolfram Language code: ArgMin[Skewness[BorelTannerDistribution[α, n]], α]

極限値：

Wolfram Language code: Limit[Skewness[BorelTannerDistribution[α, n]], α -> 0, Direction -> -1, Assumptions -> n > 0]
Wolfram Language code: Limit[Skewness[BorelTannerDistribution[α, n]], α -> 1, Direction -> 1, Assumptions -> n > 0]

n が大きいと，分布はより対称になる：

Wolfram Language code: Limit[Skewness[BorelTannerDistribution[α, n]], n -> ∞]

尖度：

Wolfram Language code: Plot[Table[Kurtosis[BorelTannerDistribution[α, n]], {n, {1, 2, 5, 10}}]//Evaluate, {α, 0, 1}, PlotLegends -> Map[TraditionalForm[n == #]&, {1, 2, 5, 10}]]
Wolfram Language code: Kurtosis[BorelTannerDistribution[α, n]]

極限値：

Wolfram Language code: Limit[Kurtosis[BorelTannerDistribution[α, n]], α -> 0, Direction -> -1, Assumptions -> n > 0]
Wolfram Language code: Limit[Kurtosis[BorelTannerDistribution[α, n]], α -> 1, Direction -> 1, Assumptions -> n > 0]

n の値が大きいと，尖度は標準NormalDistributionの尖度に収束する：

Wolfram Language code: Limit[Kurtosis[BorelTannerDistribution[α, n]], n -> ∞]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BorelTannerDistribution[α, n], k]//Together, {k, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BorelTannerDistribution[α, n], k]//Together, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BorelTannerDistribution[α, n], k]//Together, {k, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BorelTannerDistribution[α, n], k]//Simplify, {k, 3}], C]

ハザード関数：

Wolfram Language code: DiscretePlot[Table[HazardFunction[BorelTannerDistribution[α, 20], x], {α, {0.2, 0.3, 0.5}}]//Evaluate, {x, 20, 3 20}, PlotMarkers -> {Automatic, Tiny}]

分位関数：

Wolfram Language code: 𝒟 = BorelTannerDistribution[.7, 10]; points = Table[CDF[𝒟, x], {x, 0, 60, 4}]//N;
Wolfram Language code: DiscretePlot[Quantile[𝒟, p], {p, points}, ExtentSize -> Right, ExtentMarkers -> {"Empty", "Filled"}]

無次元のQuantityを使ってBorelTannerDistributionを定義する：

Wolfram Language code: BorelTannerDistribution[Quantity[86.7, "Percent"], Quantity[10, "Gross"]]

アプリケーション  (2)

BorelTannerDistributionのCDFは右連続関数の例である：

Wolfram Language code: DiscretePlot[CDF[BorelTannerDistribution[.5, 2], x], {x, 0, 10}, ExtentSize -> Right, ExtentMarkers -> {"Filled", "Empty"}]

単位時間に 人の顧客が案内係を訪れるとする．顧客1人あたりの対応時間 は一定である．案内係が仕事を開始する時点で 人の顧客が待っている．待ち行列が空になるまでに対応を受ける顧客数はBorelTannerDistributionに従う：

Wolfram Language code: ℬ𝒯 = BorelTannerDistribution[λ t, n];

待ち行列に人がいなくなるためには積 は1より小さくなくてはならない点に注意のこと：

Wolfram Language code: DistributionParameterAssumptions[ℬ𝒯]

特定の母数についての分布質量関数を示す：

Wolfram Language code: DiscretePlot[PDF[ℬ𝒯 /. {n -> 7, t -> 0.35, λ -> 2}, k], {k, 10, 30}]

待ち行列の人がいなくなるまでに対応される顧客の期待値：

Wolfram Language code: Mean[ℬ𝒯]

上で使った特定の母数について計算する：

Wolfram Language code: % /. {n -> 7, t -> 0.35, λ -> 2}

特性と関係  (3)

共通の母数 α でBorelTannerDistributionに従う確率変量の総和はBorelTannerDistributionにも従う：

Wolfram Language code: TransformedDistribution[x + y, {xBorelTannerDistribution[α, n], yBorelTannerDistribution[α, m]}]

PoissonConsulDistributionはBorelTannerDistributionとPoissonDistributionの母数混合である：

Wolfram Language code: ParameterMixtureDistribution[BorelTannerDistribution[α, n], n  PoissonDistribution[μ]]

のBorelTannerDistributionはボレル分布と呼ばれる：

Wolfram Language code: ℬ = BorelTannerDistribution[α, 1]

確率質量関数：

Wolfram Language code: DiscretePlot[Table[PDF[BorelTannerDistribution[α, 1], x], {α, {0.4, 0.7, 0.9}}]//Evaluate, {x, 4, 30}, PlotRange -> All]

平均と分散：

Wolfram Language code: {Mean[ℬ], Variance[ℬ]}

モーメント母関数：

Wolfram Language code: MomentGeneratingFunction[ℬ, t]

考えられる問題  (1)

モーメント法による推定は無効なパラメータを与えるかもしれない：

Wolfram Language code: sample = RandomVariate[BorelTannerDistribution[.2, 10], 10 ^ 3];
Wolfram Language code: EstimatedDistribution[sample, BorelTannerDistribution[a, b], ParameterEstimator -> "MethodOfMoments"]
Wolfram Language code: DistributionParameterQ[%]

第2パラメータの定義を使って値を指定する：

Wolfram Language code: EstimatedDistribution[sample, BorelTannerDistribution[a, Min[sample]], ParameterEstimator -> "MethodOfMoments"]
Wolfram Language code: DistributionParameterQ[%]
Wolfram Research (2010), BorelTannerDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BorelTannerDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2010), BorelTannerDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BorelTannerDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2010. "BorelTannerDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/BorelTannerDistribution.html.

APA

Wolfram Language. (2010). BorelTannerDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BorelTannerDistribution.html

BibTeX

@misc{reference.wolfram_2026_boreltannerdistribution, author="Wolfram Research", title="{BorelTannerDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/BorelTannerDistribution.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_boreltannerdistribution, organization={Wolfram Research}, title={BorelTannerDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/BorelTannerDistribution.html}, note=[Accessed: 14-August-2026]}