WOLFRAM

Wolfram 语言与系统参考资料中心

BorelTannerDistribution[α,n]

表示形状参数为 α 和 n 的 Borel Tanner 分布.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

BorelTannerDistribution

BorelTannerDistribution[α,n]

表示形状参数为 α 和 n 的 Borel Tanner 分布.

更多信息

背景

  • BorelTannerDistribution[α,n] 表示了一个定义在整数值 上的，由两个被称为“形状参数”的参数 α 和 n 决定的离散统计分布，称为 Borel–Tanner 分布. 这里，，n 为任意正整数，这两个参数一起决定了该分布的概率密度函数在平面上的整体形状，高度及水平位置. Borel–Tanner 分布有离散单峰的 PDF. Borel–Tanner 分布有时候又被称为 Tanner–Borel 分布或（在金融中） 羊群规模分布.
  • Borel–Tanner 分布的历史可以追溯到 1940 年代，当时法国数学家 Félix Borel 研究了当 时的 PDF 的性质. 十年后，J. C. Tanner 采用 Borel 的方法研究了一般正整数 n 的情形，这标志着现在这种形式的分布的形成. 传统上，Borel–Tanner 分布根植于排队论，对给定的 x，其 PDF 返回的是开始有 n 个顾客，交通强度为 α 的队伍在消失前恰好有 x 个顾客得到服务的概率，假设顾客到达服从泊松分布且服务时间为常数. 最近，这个分布被用于对许多真实世界的现象建模，包括高速公路交通流，在线服务器信息流，以及与现存金融投资组合有关的各种投资行为.
  • RandomVariate 可被用于给出 Borel–Tanner 分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,BorelTannerDistribution[α,n]]，更简洁的写法是 xBorelTannerDistribution[α,n]，可被用于声明随机变量 x 是 Borel–Tanner 分布的. 这样一个声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
  • 概率密度函数和累积分布函数可用 PDF[BorelTannerDistribution[α,n],x] 和 CDF[BorelTannerDistribution[α,n],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算. 这些量都可用 DiscretePlot 可视化.
  • DistributionFitTest 可被用于测试给定的数据集是否与 Borel–Tanner 分布一致，EstimatedDistribution 可被用于根据给定数据估算 Borel–Tanner 参数化分布，而 FindDistributionParameters 可拟合数据和 Borel–Tanner 分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号 Borel–Tanner 分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号 Borel–Tanner 分布的分位数的图线.
  • TransformedDistribution 可被用于表示转换的 Borel–Tanner 分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了 Borel–Tanner 分布的高维分布，而 ProductDistribution 可被用于计算包括 Borel–Tanner 分布在内的，若干个独立分量分布的联合分布.
  • BorelTannerDistribution 和许多其它统计分布有关. BorelTannerDistribution 和 PoissonConsulDistribution 有关，意思是说 PoissonConsulDistribution[μ,α] 可以从 BorelTannerDistribution[α,n] 得到，只要 nPoissonDistribution[μ]. BorelTannerDistribution 也和 BinomialDistribution、NegativeBinomialDistribution 和 LogSeriesDistribution 有关.

范例

打开所有单元 关闭所有单元

基本范例  (3)

概率质量函数：

Wolfram Language code: DiscretePlot[Table[PDF[BorelTannerDistribution[α, 4], x], {α, {0.4, 0.7, 0.9}}]//Evaluate, {x, 4, 20}, PlotRange -> All, PlotMarkers -> Automatic]
Wolfram Language code: DiscretePlot[Table[PDF[BorelTannerDistribution[.4, n], x], {n, {5, 10, 12}}]//Evaluate, {x, 5, 25}, PlotMarkers -> Automatic]
Wolfram Language code: PDF[BorelTannerDistribution[α, n], x]

累积分布函数：

Wolfram Language code: DiscretePlot[Table[CDF[BorelTannerDistribution[α, 4], x], {α, {0.4, 0.7, 0.9}}]//Evaluate, {x, 4, 20}, ExtentSize -> Right]
Wolfram Language code: DiscretePlot[Table[CDF[BorelTannerDistribution[.4, n], x], {n, {5, 10, 12}}]//Evaluate, {x, 5, 25}, ExtentSize -> Right]

均值和方差：

Wolfram Language code: Mean[BorelTannerDistribution[α, n]]
Wolfram Language code: Variance[BorelTannerDistribution[α, n]]

范围  (8)

生成一组 Borel Tanner 分布的伪随机数样本：

Wolfram Language code: sample = RandomVariate[BorelTannerDistribution[0.4, 30], 10 ^ 3];

将样本直方图与 Borel Tanner 分布的概率密度函数比较：

Wolfram Language code: Show[ Histogram[sample, {2}, "PDF"], DiscretePlot[PDF[BorelTannerDistribution[0.4, 30], x], {x, 30, 76}, PlotStyle -> PointSize[Medium]]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[BorelTannerDistribution[.2, 10], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, BorelTannerDistribution[a, b]]

比较样本的密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, {1}, "PDF"], DiscretePlot[PDF[edist, x], {x, 9, 22}, PlotStyle -> PointSize[Medium]]]

偏度：

Wolfram Language code: Plot[Table[Skewness[BorelTannerDistribution[α, n]], {n, {1, 2, 5, 10}}]//Evaluate, {α, 0, 1}, PlotLegends -> Map[TraditionalForm[n == #]&, {1, 2, 5, 10}]]
Wolfram Language code: Skewness[BorelTannerDistribution[α, n]]

偏度取得了与 n 无关的最小值：

Wolfram Language code: ArgMin[Skewness[BorelTannerDistribution[α, n]], α]

极限值：

Wolfram Language code: Limit[Skewness[BorelTannerDistribution[α, n]], α -> 0, Direction -> -1, Assumptions -> n > 0]
Wolfram Language code: Limit[Skewness[BorelTannerDistribution[α, n]], α -> 1, Direction -> 1, Assumptions -> n > 0]

对于较大的 n 值，分布变得更加对称：

Wolfram Language code: Limit[Skewness[BorelTannerDistribution[α, n]], n -> ∞]

峰度：

Wolfram Language code: Plot[Table[Kurtosis[BorelTannerDistribution[α, n]], {n, {1, 2, 5, 10}}]//Evaluate, {α, 0, 1}, PlotLegends -> Map[TraditionalForm[n == #]&, {1, 2, 5, 10}]]
Wolfram Language code: Kurtosis[BorelTannerDistribution[α, n]]

极限值：

Wolfram Language code: Limit[Kurtosis[BorelTannerDistribution[α, n]], α -> 0, Direction -> -1, Assumptions -> n > 0]
Wolfram Language code: Limit[Kurtosis[BorelTannerDistribution[α, n]], α -> 1, Direction -> 1, Assumptions -> n > 0]

对于较大的 n 值，峰度收敛为标准 NormalDistribution 的峰度：

Wolfram Language code: Limit[Kurtosis[BorelTannerDistribution[α, n]], n -> ∞]

以参数的函数形式表示不同矩量的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BorelTannerDistribution[α, n], k]//Together, {k, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BorelTannerDistribution[α, n], k]//Together, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BorelTannerDistribution[α, n], k]//Together, {k, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BorelTannerDistribution[α, n], k]//Simplify, {k, 3}], C]

风险函数：

Wolfram Language code: DiscretePlot[Table[HazardFunction[BorelTannerDistribution[α, 20], x], {α, {0.2, 0.3, 0.5}}]//Evaluate, {x, 20, 3 20}, PlotMarkers -> {Automatic, Tiny}]

分位数函数：

Wolfram Language code: 𝒟 = BorelTannerDistribution[.7, 10]; points = Table[CDF[𝒟, x], {x, 0, 60, 4}]//N;
Wolfram Language code: DiscretePlot[Quantile[𝒟, p], {p, points}, ExtentSize -> Right, ExtentMarkers -> {"Empty", "Filled"}]

用无量纲的 Quantity 来定义 BorelTannerDistribution：

Wolfram Language code: BorelTannerDistribution[Quantity[86.7, "Percent"], Quantity[10, "Gross"]]

应用  (2)

BorelTannerDistribution 的 CDF 是右连续函数的一个例子:

Wolfram Language code: DiscretePlot[CDF[BorelTannerDistribution[.5, 2], x], {x, 0, 10}, ExtentSize -> Right, ExtentMarkers -> {"Filled", "Empty"}]

客户以每单位时间速率 到达服务台. 服务每个客户需要固定时间 . 在服务台开始工作的时候，队列包含 个人. 在队列清空之前，所服务过的客户总数服从一个 BorelTannerDistribution：

Wolfram Language code: ℬ𝒯 = BorelTannerDistribution[λ t, n];

注意，乘积 必须少于1，队列才能最终清空：

Wolfram Language code: DistributionParameterAssumptions[ℬ𝒯]

对特定参数，显示分布密度函数：

Wolfram Language code: DiscretePlot[PDF[ℬ𝒯 /. {n -> 7, t -> 0.35, λ -> 2}, k], {k, 10, 30}]

在队列变空之前，预期服务过的客户数目：

Wolfram Language code: Mean[ℬ𝒯]

对上面所用的特定参数进行计算：

Wolfram Language code: % /. {n -> 7, t -> 0.35, λ -> 2}

属性和关系  (3)

具有共同的 α 参数的服从 BorelTannerDistribution 的随机变量的和也服从 BorelTannerDistribution：

Wolfram Language code: TransformedDistribution[x + y, {xBorelTannerDistribution[α, n], yBorelTannerDistribution[α, m]}]

PoissonConsulDistribution 是 BorelTannerDistribution 和 PoissonDistribution 的一个参数混合：

Wolfram Language code: ParameterMixtureDistribution[BorelTannerDistribution[α, n], n  PoissonDistribution[μ]]

当 时，BorelTannerDistribution 被称作 Borel 分布：

Wolfram Language code: ℬ = BorelTannerDistribution[α, 1]

概率质量函数：

Wolfram Language code: DiscretePlot[Table[PDF[BorelTannerDistribution[α, 1], x], {α, {0.4, 0.7, 0.9}}]//Evaluate, {x, 4, 30}, PlotRange -> All]

均值和方差：

Wolfram Language code: {Mean[ℬ], Variance[ℬ]}

矩母函数：

Wolfram Language code: MomentGeneratingFunction[ℬ, t]

可能存在的问题  (1)

通过矩量法进行运算可能会产生无效的参数：

Wolfram Language code: sample = RandomVariate[BorelTannerDistribution[.2, 10], 10 ^ 3];
Wolfram Language code: EstimatedDistribution[sample, BorelTannerDistribution[a, b], ParameterEstimator -> "MethodOfMoments"]
Wolfram Language code: DistributionParameterQ[%]

使用第二个参数的定义来指定其值：

Wolfram Language code: EstimatedDistribution[sample, BorelTannerDistribution[a, Min[sample]], ParameterEstimator -> "MethodOfMoments"]
Wolfram Language code: DistributionParameterQ[%]
Wolfram Research (2010)，BorelTannerDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BorelTannerDistribution.html （更新于 2016 年）.

文本

Wolfram Research (2010)，BorelTannerDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BorelTannerDistribution.html （更新于 2016 年）.

CMS

Wolfram 语言. 2010. "BorelTannerDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/BorelTannerDistribution.html.

APA

Wolfram 语言. (2010). BorelTannerDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BorelTannerDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_boreltannerdistribution, author="Wolfram Research", title="{BorelTannerDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/BorelTannerDistribution.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_boreltannerdistribution, organization={Wolfram Research}, title={BorelTannerDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/BorelTannerDistribution.html}, note=[Accessed: 18-August-2026]}