WOLFRAM

Wolfram 语言与系统参考资料中心

BubbleHistogram[{{x1,y1},{x2,y2},…}]

绘制值 {xi,yi} 的气泡直方图.

BubbleHistogram[{{x1,y1},{x2,y2},…},bspec]

绘制一个气泡直方图，其分箱由 bspec 指定.

BubbleHistogram[{{x1,y1},{x2,y2},…},bspec,hspec]

绘制一个气泡直方图，其中气泡大小根据规范 hspec 计算.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数据  
表格数据  
演示  
选项  
AspectRatio  
坐标轴  
AxesLabel  
Show More Show More
AxesOrigin  
AxesStyle  
BubbleScale  
BubbleSizes  
ChartElementFunction  
ColorFunction  
ColorFunctionScaling  
ImageSize  
LabelingFunction  
Mesh  
MeshStyle  
Method  
PerformanceGoal  
PlotInteractivity  
Ticks  
TicksStyle  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
历史
按以下格式引用：

BubbleHistogram

BubbleHistogram[{{x1,y1},{x2,y2},…}]

绘制值 {xi,yi} 的气泡直方图.

BubbleHistogram[{{x1,y1},{x2,y2},…},bspec]

绘制一个气泡直方图，其分箱由 bspec 指定.

BubbleHistogram[{{x1,y1},{x2,y2},…},bspec,hspec]

绘制一个气泡直方图，其中气泡大小根据规范 hspec 计算.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

为数据集绘制气泡直方图：

Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 500]]

添加一个图例来说明分类色块的含义：

Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 500], PlotLegends -> Automatic]

绘制数据的概率密度函数：

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 100];
Wolfram Language code: BubbleHistogram[data, Automatic, "PDF"]

累积分布函数：

Wolfram Language code: BubbleHistogram[data, Automatic, "CDF"]

生存函数：

Wolfram Language code: BubbleHistogram[data, Automatic, "SF"]

风险函数：

Wolfram Language code: BubbleHistogram[data, Automatic, "HF"]

累积风险函数：

Wolfram Language code: BubbleHistogram[data, Automatic, "CHF"]

范围  (14)

数据  (8)

指定要使用的箱数：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {200, 2}];
Wolfram Language code: BubbleHistogram[data, 5]

指定要在 x 和 y 中使用的不同分箱数：

Wolfram Language code: BubbleHistogram[data, {3, 5}, Mesh -> True]

指定箱宽：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {200, 2}];
Wolfram Language code: BubbleHistogram[data, {.5}]

指定要在 x 和 y 中使用的不同箱宽：

Wolfram Language code: BubbleHistogram[data, {{.5}, {2}}]

指定分箱定界符：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {200, 2}];
Wolfram Language code: BubbleHistogram[data, {-2, 2, 0.5}]

指定要在 x 和 y 中使用的不同分箱定界符：

Wolfram Language code: BubbleHistogram[data, {{-2, 2, 0.5}, {-3, 3, 1.5}}]

以显式列表的形式指定分箱定界符：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {500, 2}];
Wolfram Language code: BubbleHistogram[data, {{-3, -1, 0, 1, 3}}, Mesh -> All]

指定要在 x 和 y 中使用的不同分箱定界符：

Wolfram Language code: BubbleHistogram[data, {{{-3, -1, 0, 1, 3}}, {{-1, 0, 2, 3}}}, Mesh -> All]

使用不同的自动分箱方法：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {500, 2}];
Wolfram Language code: Table[BubbleHistogram[data, b, PlotLabel -> b], {b, {"Sturges", "Scott", "FreedmanDiaconis", "Wand", "Knuth"}}]

使用对数间隔的分箱：

Wolfram Language code: Table[BubbleHistogram[data, {"Log", b}, PlotLabel -> "Log" <> b], {b, {"Sturges", "Scott", "FreedmanDiaconis", "Wand", "Knuth"}}]

使用不同的高度规范：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {200, 2}];
Wolfram Language code: Table[BubbleHistogram[data, Automatic, h, PlotLabel -> h], {h, {"Count", "PDF", "CDF", "SF", "HF", "CHF"}}]

使用对数高度：

Wolfram Language code: Table[BubbleHistogram[data, Automatic, {"Log", h}, PlotLabel -> "Log" <> h], {h, {"Count", "PDF", "CDF", "SF", "HF", "CHF"}}]

使用一个高度函数，该函数沿 y 方向累加分箱计数：

Wolfram Language code: accumulatedCount[xBins_, yBins_, counts_] := Block[{newCounts, heights}, newCounts = Flatten[Transpose[counts]];heights = 100 Accumulate[newCounts] / Total[newCounts];Transpose[Partition[heights, {Length[xBins]}]]];
Wolfram Language code: BubbleHistogram[RandomReal[NormalDistribution[0, 1], {100, 2}], Automatic, accumulatedCount, ColorFunction -> "FallColors"]

非实数数据将被视为缺失：

Wolfram Language code: BubbleHistogram[{{1, 1}, {2, 2}, {3, 3}, None, {3, 3}, {5, 5}, Missing[], {2, 2}, {1, 1}, foo, {2, 2}, {3, 3}}]

表格数据  (1)

根据不同葡萄酒的 pH 值和酒精值创建一个气泡直方图：

Wolfram Language code: tab = Tabular[ResourceData["Sample Data: Wine Quality"]]
Wolfram Language code: BubbleHistogram[tab -> {"PH", "Alcohol"}, FrameLabel -> {"pH", "alcohol content"}, PlotLegends -> Automatic]

增加箱数以显示更细的粒度：

Wolfram Language code: BubbleHistogram[tab -> {"PH", "Alcohol"}, 15, BubbleSizes -> {0.25, 1}, FrameLabel -> {"pH", "alcohol content"}, PlotLegends -> Automatic]

演示  (5)

添加标签：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {200, 2}];
Wolfram Language code: BubbleHistogram[data, PlotLabel -> "plot label", FrameLabel -> {"xlabel", "ylabel"}]

默认情况下，BubbleHistogram 同时使用颜色和大小来表示计数：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {200, 2}];
Wolfram Language code: BubbleHistogram[data]

仅使用颜色表示计数：

Wolfram Language code: BubbleHistogram[data, BubbleSizes -> {1, 1}, ColorFunction -> "BlueGreenYellow"]

仅使用大小表示计数：

Wolfram Language code: BubbleHistogram[data, ColorFunction -> None, BubbleSizes -> {0.1, 1}]

添加网格线以显示分箱定界符：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {200, 2}];
Wolfram Language code: BubbleHistogram[data, Mesh -> All]

添加图例以显示分箱计数：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {1000, 2}];
Wolfram Language code: BubbleHistogram[data, PlotLegends -> Automatic]

使用绘图主题：

Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], PlotTheme -> "Detailed"]
Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], PlotTheme -> "Minimal"]

选项  (62)

AspectRatio  (3)

默认情况下，BubbleHistogram 使用相同的宽度和高度：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»]]

指定高度与宽度的比率：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], AspectRatio -> 1 / 2]

使用 Automatic 根据数值确定比率：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], AspectRatio -> Automatic]

坐标轴  (4)

默认情况下，BubbleHistogram 使用边框而不是坐标轴：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»]]

使用坐标轴而不是边框：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True]

使用 AxesOrigin 指定坐标轴的相交位置：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Axes -> True, Frame -> False, AxesOrigin -> {0, 0}]

仅开启 轴：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> {True, False}]

仅开启 轴：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> {False, True}]

AxesLabel  (4)

默认情况下不绘制坐标轴标签：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True]

在 轴放置标签：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, AxesLabel -> y]

指定轴标签：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, AxesLabel -> {x, y}]

使用单位作为自动标签：

Wolfram Language code: BubbleHistogram[QuantityArray[IconizedObject[«data»], "Meters"], Frame -> False, Axes -> True, AxesLabel -> Automatic]

AxesOrigin  (2)

坐标轴的位置是自动确定的：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True]

为坐标轴指定明确的原点：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, AxesOrigin -> {0, 0}]

AxesStyle  (4)

更改坐标轴样式：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, AxesStyle -> RGBColor[0.93, 0.27, 0.27]]

指定每个坐标轴的样式：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, AxesStyle -> {{Thick, RGBColor[0.93, 0.27, 0.27]}, {Thick, RGBColor[0.4, 0.6, 1]}}]

刻度线和坐标轴使用不同的样式：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, AxesStyle -> RGBColor[0.14, 0.8, 0.14], TicksStyle -> RGBColor[0.93, 0.27, 0.27]]

标签和坐标轴使用不同的样式：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, AxesStyle -> RGBColor[0.14, 0.8, 0.14], LabelStyle -> RGBColor[0.93, 0.27, 0.27]]

BubbleScale  (2)

默认情况下，气泡的直径与 z 值成正比：

Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], BubbleSizes -> {0.1, 1}, BubbleScale -> "Diameter"]

比较面积比例尺和直径比例尺：

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 100];
Wolfram Language code: Table[BubbleHistogram[data, BubbleSizes -> {0.1, 1}, BubbleScale -> scale, PlotLabel -> scale], {scale, {"Area", "Diameter"}}]

BubbleSizes  (2)

默认情况下，最小的气泡会被缩放到其自身分箱大小的 20%，最大的气泡会被缩放到其自身分箱大小的 100%：

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 100];
Wolfram Language code: BubbleHistogram[data, Mesh -> All]

将最小和最大气泡的相对大小调整到它们各自的分箱大小：

Wolfram Language code: BubbleHistogram[data, BubbleSizes -> {0.1, 0.8}, Mesh -> All]

将气泡大小相对于气泡计数进行反转：

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 100];
Wolfram Language code: BubbleHistogram[data, BubbleSizes -> {1, 0.2}, Mesh -> All]

ChartElementFunction  (3)

获取 ChartElementFunction 的内置设置列表：

Wolfram Language code: ChartElementData["BubbleHistogram"]

如需详细设置，使用 面板 ▶ 图表元素方案：

Wolfram Language code: Table[BubbleHistogram[RandomVariate[NormalDistribution[], {100, 2}], ChartElementFunction -> cf, PlotLabel -> cf], {cf, {"Bubble", "FadingBubble"}}]
Wolfram Language code: Table[BubbleHistogram[RandomVariate[NormalDistribution[], {100, 2}], {1}, ChartElementFunction -> cf, PlotLabel -> cf], {cf, {"GradientBubble", "MarkerBubble", "NoiseBubble", "OscillatingBubble"}}]
Wolfram Language code: Table[BubbleHistogram[RandomVariate[NormalDistribution[], {100, 2}], {1}, ChartElementFunction -> cf, PlotLabel -> cf], {cf, {"SphereBubble", "SquareWaveBubble", "TriangleWaveBubble"}}]

编写自定义 ChartElementFunction：

Wolfram Language code: f[{{xmin_, xmax_}, {ymin_, ymax_}}, _, _] := Rectangle[{xmin, ymin}, {xmax, ymax}, RoundingRadius -> 0.2]
Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[], {100, 2}], {1}, ChartElementFunction -> f]

ColorFunction  (5)

根据气泡计数，按气泡大小着色：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], ColorFunction -> Function[{count}, ColorData["Rainbow"][count]]]

使用命名颜色渐变：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {500, 2}], ColorFunction -> "SolarColors"]

使用亮度：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {500, 2}], ColorFunction -> (Hue[2 / 5, 2 / 3, #]&)]

使用 ColorFunctionScaling->False 获取未缩放的高度值：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {500, 2}], ColorFunction -> (Which[# < 5, RGBColor[1, 0.51, 0.51], 5 ≤ # < 15, RGBColor[0.4, 0.6, 1], True, RGBColor[0.93, 0.27, 0.27]]&), ColorFunctionScaling -> False]

使用 ColorFunction 组合不同的样式效果：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {500, 2}], ColorFunction -> Function[{count}, Directive[ColorData["FuchsiaTones"][1 - count], EdgeForm[Opacity[count]]]]]

ColorFunctionScaling  (2)

默认情况下，使用经缩放的高度值：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], ColorFunction -> Function[{height}, ColorData["Rainbow"][height]]]

使用 ColorFunctionScaling->False 获取未缩放的高度值：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {500, 2}], ColorFunction -> (Which[# < 5, RGBColor[1, 0.51, 0.51], 5 ≤ # < 15, RGBColor[0.4, 0.6, 1], True, RGBColor[0.93, 0.27, 0.27]]&), ColorFunctionScaling -> False]

ImageSize  (6)

使用命名尺寸，如 Tiny、Small、Medium 和 Large：

Wolfram Language code: {BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", ImageSize -> Tiny], BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", ImageSize -> Small]}

指定绘图宽度：

Wolfram Language code: {BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", ImageSize -> 150], BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", AspectRatio -> 1.5, ImageSize -> 150]}

指定绘图高度：

Wolfram Language code: {BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", ImageSize -> {Automatic, 150}], BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

允许宽度和高度达到一定尺寸：

Wolfram Language code: {BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", ImageSize -> UpTo[200]], BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", AspectRatio -> 2, ImageSize -> UpTo[200]]}

指定图形的宽度和高度，必要时添加内边距：

Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", ImageSize -> {200, 300}, Background -> RGBColor[0.4, 0.6, 1]]

宽度和高度均使用最大值：

Wolfram Language code: {BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", ImageSize -> {UpTo[150], UpTo[100]}], BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

将图像大小指定为可用空间的百分比：

Wolfram Language code: Framed[Pane[BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Automatic, "PDF", AspectRatio -> 1 / 3, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> RGBColor[0.4, 0.6, 1]], {200, 100}]]

LabelingFunction  (3)

通过 Tooltip 和 StatusArea 使用值自动标签：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], 5, LabelingFunction -> Automatic]

不添加标签：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], 5, LabelingFunction -> None]

使用 Placed 控制标签位置：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], 5, LabelingFunction -> (Placed[#1, StatusArea]&)]

Mesh  (5)

在箱间插入网格线：

Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Mesh -> Automatic]

插入 15 条行网格线和 5 条列网格线：

Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Mesh -> {15, 5}]

仅在 方向上指定显式网格线：

Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], Mesh -> {None, Range[0, 10]}]

指定网格线的样式：

Wolfram Language code: BubbleHistogram[RandomVariate[BinormalDistribution[.5], 100], {1 / 2}, Mesh -> {None, Table[{i / 2 - 3, Hue[i / 12]}, {i, 0, 12}]}]

使用 MeshAutomatic 在箱间绘制网格：

Wolfram Language code: BubbleHistogram[RandomReal[NormalDistribution[0, 1], {200, 2}], {{{-3, -1, 0, 1, 3}}, {{-1, 0, 2, 3}}}, Mesh -> Automatic]

MeshStyle  (2)

默认网格样式：

Wolfram Language code: BubbleHistogram[RandomReal[NormalDistribution[0, 1], {200, 2}], Mesh -> Automatic]

使网格变成粉色：

Wolfram Language code: BubbleHistogram[RandomReal[NormalDistribution[0, 1], {200, 2}], Mesh -> Automatic, MeshStyle -> RGBColor[1, 0.51, 0.51]]

Method  (4)

在坐标轴上显示每个维度的数据：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], Method -> {"DistributionAxes" -> True}]

使用箱线图来显示数据在每个维度上的分布情况：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], Method -> {"DistributionAxes" -> "BoxWhisker"}]

使用直方图符号：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], Method -> {"DistributionAxes" -> "Histogram"}]

分布轴的颜色会根据图表的颜色函数而改变：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], Method -> {"DistributionAxes" -> "BoxWhisker"}, ColorFunction -> "RustTones"]
Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[0, 1], {200, 2}], Method -> {"DistributionAxes" -> "Histogram"}, ColorFunction -> "DeepSeaColors"]

PerformanceGoal  (1)

生成带有交互式高亮显示的条形图：

Wolfram Language code: data = RandomReal[NormalDistribution[0, 1], {100, 2}];
Wolfram Language code: BubbleHistogram[data, PerformanceGoal -> "Quality"]

通过禁用交互行为来强调性能：

Wolfram Language code: BubbleHistogram[data, PerformanceGoal -> "Speed"]

通常情况下，非交互式图表所需的内存较少：

Wolfram Language code: Table[ByteCount@BubbleHistogram[data, PerformanceGoal -> p], {p, {"Quality", "Speed"}}]

PlotInteractivity  (2)

柱状图数量适中的直方图会自动显示工具提示和鼠标悬停效果：

Wolfram Language code: BubbleHistogram[IconizedObject[«Subscript[data, 1]»]]

关闭所有交互元素：

Wolfram Language code: BubbleHistogram[IconizedObject[«Subscript[data, 1]»], PlotInteractivity -> False]

Ticks  (4)

刻度线自动添加到每个图表中：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True]

使用 TicksNone 可以不绘制任何刻度线：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> None]

在特定位置放置刻度线：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> {{-2, 0, 3}, {-2, 0, 2}}]

在指定位置绘制带有指定标签的刻度线：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> {{{-2, -a}, {0, 0}, {3, b}}, {{-2, -a}, {0, b}, {2, a}}}]

TicksStyle  (4)

指定整体刻度样式，包括刻度标签：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, TicksStyle -> Directive[RGBColor[0.93, 0.27, 0.27], Bold]]

为每个坐标轴指定刻度样式：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, TicksStyle -> {Directive[RGBColor[0.93, 0.27, 0.27], Bold], Directive[RGBColor[0.4, 0.6, 1]]}]

用缩放长度指定刻度线：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> {{{-2, -a, .1}, {0, 0, .2}, {3, b, .45}}, {{-2, -a, .1}, {0, b, .2}, {2, a, .5}}}]

自定义每个刻度的位置、长度、标签和样式：

Wolfram Language code: BubbleHistogram[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> {{{-2, -a, .1, Directive[RGBColor[0.93, 0.27, 0.27]]}, {0, 0, .2, Directive[Thick, RGBColor[0.93, 0.27, 0.27]]}, {3, b, .45, Directive[Thick, Dashed, RGBColor[0.93, 0.27, 0.27]]}}, {{-2, -a, .1, Directive[RGBColor[0.4, 0.6, 1]]}, {0, b, .2, Directive[Thick, RGBColor[0.4, 0.6, 1]]}, {2, a, .5, Directive[Thick, Dashed, RGBColor[0.4, 0.6, 1]]}}}]

应用  (4)

估算乌干达西部火山坑的密度：

Wolfram Language code: volcanoes = ExampleData[{"Statistics", "UgandaVolcanoes"}]; border = Graphics[{EdgeForm[Thick], Opacity[0], Polygon[ExampleData[{"Statistics", "WesternUgandaBorder"}]]}];

火山坑位置：

Wolfram Language code: Show[ListPlot[volcanoes], border, AspectRatio -> 1]

用于标签的缩放函数：

Wolfram Language code: cfs[data_, bspec_, hspec_ : Automatic] := With[{cnts = Union[Flatten@Last[HistogramList[data, bspec, hspec]]]}, N@Transpose[{Rescale[cnts], cnts}] ]

带有缩放图例的估计密度：

Wolfram Language code: Show[BubbleHistogram[volcanoes, 10, ColorFunction -> "SolarColors", PlotLegends -> Automatic], border]

随机过程多元时间切片的气泡直方图：

Wolfram Language code: data = RandomVariate[WienerProcess[3, 4][{7, 10}], 10 ^ 4];
Wolfram Language code: BubbleHistogram[data, 20, "PDF"]

通过绘制二维时间切片的气泡直方图，对 TemporalData 进行分析：

Wolfram Language code: data = TemporalData[«4»];
Wolfram Language code: Table[BubbleHistogram[data["SliceData", {.1, y}], Automatic, "PDF"], {y, .2, 1, .1}]

分析尚佩恩地区两年间的气候变化情况：

Wolfram Language code: data = WeatherData["Champaign", "Temperature", {DateObject[{2022, 1, 1}], DateObject[{2024, 1, 1}]}];

取日期和温度：

Wolfram Language code: datetime = Transpose[{AbsoluteTime /@ data["Times"], Normal[data["Values"]]}];

在 x 和 y 方向上，分别以一个月和 5 摄氏度作为分箱宽度：

Wolfram Language code: bins = {{Table[AbsoluteTime@DateObject[{2022, i, 1}], {i, 24}]}, {Quantity[5, "DegreesCelsius"]}};

结合日期刻度和分箱信息，使用 BubbleHistogram 对数据进行可视化：

Wolfram Language code: BubbleHistogram[datetime, bins, ScalingFunctions -> {"Date", None}, AspectRatio -> 1 / 2, PlotLabel -> "Temperature variations across the year in Champaign" ]

添加刻度、网格、颜色和样式：

Wolfram Language code: frameticks = {{Transpose[{Range[-20, 40, 5], Quantity[Range[-20, 40, 5], "DegreesCelsius"]}], None}, {Table[{AbsoluteTime@DateObject[{2022, 2i - 1}], Rotate[DateObject[{2022, 2i - 1}], 90Degree]}, {i, 12}], None}}; mesh = {Transpose[{Range[-25, 40, 5], Reverse@Table[Blend[{RGBColor[0.93, 0.27, 0.27], RGBColor[0.4, 0.6, 1]}, i / 10], {i, 14}]}], Automatic} ; meshstyle = {Directive[{Opacity[0.9]}], Directive[{GrayLevel[0.7], Opacity[0.4]}]};
Wolfram Language code: BubbleHistogram[datetime, bins, AspectRatio -> 1 / 2, FrameTicks -> frameticks, Mesh -> mesh, MeshStyle -> meshstyle, PlotStyle -> EdgeForm[GrayLevel[0.62]], PlotLabel -> "Temperature variations across the year in Champaign" ]

属性和关系  (4)

BubbleHistogram 根据数据自动确定要使用的分箱：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[], {100, 2}]]

BubbleHistogram 根据 ColorFunction 对高度进行着色：

根据 坐标值进行着色：

Wolfram Language code: BubbleHistogram[RandomVariate[NormalDistribution[], {100, 2}], Automatic, "CDF", ColorFunctionScaling -> False, PlotLegends -> Automatic]

使用 Histogram3D 在三维中可视化数据：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {100, 2}];
Wolfram Language code: {Histogram3D[data], BubbleHistogram[data], DensityHistogram[data]}

使用 DensityHistogram、SmoothDensityHistogram 和 SmoothHistogram3D 将估计分布与数据进行比较：

Wolfram Language code: data = RandomVariate[BinormalDistribution[{2, 2}, {1, 1}, 0.5], 100];
Wolfram Language code: {BubbleHistogram[data], DensityHistogram[data], SmoothDensityHistogram[data], SmoothHistogram3D[data]}

可能存在的问题  (1)

BubbleHistogram 总是将气泡显示为圆形，忽略箱的纵横比：

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 100];
Wolfram Language code: BubbleHistogram[data, {{-3, -1, -0.5, 0, 0.5, 1, 3}}, Mesh -> All]

巧妙范例  (1)

显示 BubbleHistogram 的网格：

Wolfram Language code: PlotGrid[Partition[Table[BubbleHistogram[RandomVariate[BinormalDistribution[ρ], 10 ^ 3], {-3, 3, .25}, ColorFunction -> "SolarColors", PlotLabel -> ρ, ImageSize -> 150, PlotRange -> {{-3, 3}, {-3, 3}}], {ρ, {-.95, -.75, -.5, -.25, 0, .25, .5, .75, .95 }}], 3], ItemSize -> 150]
Wolfram Research (2026)，BubbleHistogram，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BubbleHistogram.html.

文本

Wolfram Research (2026)，BubbleHistogram，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BubbleHistogram.html.

CMS

Wolfram 语言. 2026. "BubbleHistogram." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BubbleHistogram.html.

APA

Wolfram 语言. (2026). BubbleHistogram. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BubbleHistogram.html 年

BibTeX

@misc{reference.wolfram_2026_bubblehistogram, author="Wolfram Research", title="{BubbleHistogram}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/BubbleHistogram.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bubblehistogram, organization={Wolfram Research}, title={BubbleHistogram}, year={2026}, url={https://reference.wolfram.com/language/ref/BubbleHistogram.html}, note=[Accessed: 13-August-2026]}