Wolfram 语言与系统参考资料中心

CompleteKaryTree

CompleteKaryTree[n]

给出含有 n 个层的完全二叉树.

CompleteKaryTree[n,k]

给出含有 n 个层的完全 k 叉树.

范例

打开所有单元关闭所有单元

基本范例 (3)

具有五个层的完全二叉树：

Wolfram Language code: CompleteKaryTree[5]

具有三个层的完全三叉树：

Wolfram Language code: CompleteKaryTree[3, 3]

使用有向边：

Wolfram Language code: CompleteKaryTree[3, 3, DirectedEdges -> True]

选项 (79)

AnnotationRules (2)

指定顶点的注释：

Wolfram Language code: CompleteKaryTree[2, 3, AnnotationRules -> {1 -> {VertexLabels -> "hello"}}]

边：

Wolfram Language code: CompleteKaryTree[2, 3, AnnotationRules -> {12 -> {EdgeLabels -> "hello"}}]

DirectedEdges (1)

默认情况下，生成一个无向图：

Wolfram Language code: CompleteKaryTree[2, 3]

使用 DirectedEdges->True 来生成一个有向图：

Wolfram Language code: CompleteKaryTree[2, 3, DirectedEdges -> True]

EdgeLabels (6)

对边 12 添加标签：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeLabels -> {12 -> "Hello"}]

分别对所有边添加标签：

Wolfram Language code: el = EdgeList[CompleteKaryTree[2, 3]]

Wolfram Language code: CompleteKaryTree[2, 3, EdgeLabels -> Table[el[[i]] -> Subscript["e", i], {i, Length[el]}]]

将任意表达式作为标签使用：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeLabels -> {12 -> [image], 13 -> [image], 14 -> [image]}]

使用显式坐标来放置标签：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, EdgeLabels -> {12 -> Placed["■■■", p]}, PlotLabel -> p, BaselinePosition -> Bottom], {p, {0, 1 / 4, 1 / 3}}]

改变标签内的位置：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, EdgeLabels -> {12 -> Placed["■■■", {1 / 2, p}]}, PlotLabel -> p, BaselinePosition -> Bottom], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

放置多个标签：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeLabels -> {31 -> Placed[{"lbl1", "lbl2"}, {"Start", "End"}]}]

Wolfram Language code: CompleteKaryTree[2, 3, EdgeLabels -> {31 -> Placed[{"lbl1", "lbl2", "lbl3"}, {"Start", "Middle", "End"}]}]

通过 Tooltip 和 StatusArea 的值使用自动标签：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeLabels -> Placed["Name", Tooltip]]

Wolfram Language code: CompleteKaryTree[2, 3, EdgeLabels -> Placed["Name", StatusArea]]

EdgeShapeFunction (6)

获取 EdgeShapeFunction 的内置设置列表：

Wolfram Language code: ResourceData["EdgeShapeFunction"]

包含基本线条的无向边：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeShapeFunction -> "Line"]

具有各种符号的边线条：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, {"BoxLine", "DiamondLine", "DotLine"}}]

包含实心箭头的有向边：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, ResourceData["EdgeShapeFunction", "FilledArrow"]}]

线型箭头：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, ResourceData["EdgeShapeFunction", "UnfilledArrow"]}]

开放式箭头：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, ResourceData["EdgeShapeFunction", "CarvedArrow"]}]

对每条边指定一个边函数：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeShapeFunction -> {12 -> "DotLine"}]

与一个不同的默认边函数合用：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeShapeFunction -> {12 -> "BoxLine", "DotLine"}]

通过运行程序，绘制边：

Wolfram Language code:

ef[pts_List, e_] := 
	Block[{s = 0.015, g = [image]}, {Arrowheads[{{s, 0.33, g}, {s, 0.67, g}}], Arrow[pts]}]

Wolfram Language code: CompleteKaryTree[2, 3, EdgeShapeFunction -> ef]

EdgeShapeFunction 可以与 EdgeStyle 合起来使用：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeStyle -> Blue, EdgeShapeFunction -> (Line[#1]&)]

EdgeShapeFunction 具有比 EdgeStyle 更高的优先级：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeStyle -> Blue, EdgeShapeFunction -> ({Red, Line[#1]}&)]

EdgeStyle (2)

对边进行样式化处理：

Wolfram Language code: Table[CompleteKaryTree[2, 3, EdgeStyle -> style, PlotLabel -> style], {style, {Gray, Dashed, Thick}}]

对单条边进行样式化处理：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeStyle -> {12 -> Blue, 14 -> Dashed}]

EdgeWeight (2)

指定所有边的权值：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeWeight -> RandomInteger[5, 3]]

Wolfram Language code: WeightedAdjacencyMatrix[%]//MatrixForm

将任意数值表达式作为权值使用：

Wolfram Language code: CompleteKaryTree[2, 3, EdgeWeight -> {a, b, c}]

Wolfram Language code: WeightedAdjacencyMatrix[%]//MatrixForm

GraphLayout (5)

默认情况下，自动选择布局：

Wolfram Language code: CompleteKaryTree[2, 3, GraphLayout -> Automatic]

指定在特殊曲线上的布局：

Wolfram Language code: Table[CompleteKaryTree[5, 3, GraphLayout -> l, PlotLabel -> l], {l, {"CircularEmbedding", "SpiralEmbedding"}}]

指定满足最优化标准的布局：

Wolfram Language code:

Table[CompleteKaryTree[5, 3, GraphLayout -> l, PlotLabel -> l], {l, {"SpringEmbedding", "SpringElectricalEmbedding", "HighDimensionalEmbedding"}}]

VertexCoordinates 覆盖 GraphLayout 坐标：

Wolfram Language code:

{CompleteKaryTree[2, 3, GraphLayout -> "SpringElectricalEmbedding"], 
	CompleteKaryTree[2, 3, GraphLayout -> "SpringElectricalEmbedding", VertexCoordinates -> Table[{i, i}, {i, 0, 3}]]}

通过一个布局算法，利用 AbsoluteOptions 提取 VertexCoordinates：

Wolfram Language code: CompleteKaryTree[2, 3]

Wolfram Language code: AbsoluteOptions[%, VertexCoordinates]

GraphHighlight (3)

突出显示顶点 1：

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> Tiny, GraphHighlight -> {1}]

突出显示边 13：

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> Tiny, GraphHighlight -> {13}]

突出显示顶点和边：

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> Tiny, GraphHighlight -> {1, 2, 13, 14}]

GraphHighlightStyle (2)

获取 GraphHighlightStyle 的默认设置列表：

Wolfram Language code: ResourceData["GraphHighlightStyle"]

使用 GraphHighlightStyle 的内置设置：

Wolfram Language code:

CompleteKaryTree[2, 3, GraphHighlight -> {1, 12}, VertexSize -> Small, GraphHighlightStyle -> #, PlotLabel -> #]& /@ Select[ResourceData["GraphHighlightStyle"], # =!= Automatic&]

PlotTheme (4)

基本主题 (2)

使用普通基主题：

Wolfram Language code: CompleteKaryTree[2, 3, PlotTheme -> "Business"]

使用单色主题：

Wolfram Language code: CompleteKaryTree[2, 3, PlotTheme -> "Monochrome"]

特色主题 (2)

使用大图主题：

Wolfram Language code: CompleteKaryTree[2, 3, PlotTheme -> "LargeGraph"]

使用经典图表主题：

Wolfram Language code: CompleteKaryTree[2, 3, PlotTheme -> "ClassicDiagram"]

VertexCoordinates (3)

默认情况下，自动计算任意顶点坐标：

Wolfram Language code: CompleteKaryTree[2, 3]

使用 AbsoluteOptions 提取所得的顶点坐标：

Wolfram Language code: AbsoluteOptions[%, VertexCoordinates]

指定沿着一个椭圆的布局函数：

Wolfram Language code: ellipseLayout[n_, {a_, b_}] := Table[{a Cos[2Pi / n u], b Sin[2Pi / n u]}, {u, 1, n}]

Wolfram Language code: Graphics[Point[ellipseLayout[20, {2, 1}]]]

使用它来生成图的顶点坐标：

Wolfram Language code: CompleteKaryTree[3, 3, VertexCoordinates -> ellipseLayout[13, {2, 1}]]

VertexCoordinates 具有比 GraphLayout 更高的优先级：

Wolfram Language code: CompleteKaryTree[2, 3, VertexCoordinates -> Table[{i, i}, {i, 4}], GraphLayout -> "CircularEmbedding"]

VertexLabels (13)

将顶点名称作为标签使用：

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> "Name"]

对单个顶点添加标签：

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> {2 -> "one"}]

对所有顶点添加标签：

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> Table[i -> Subscript[v, i], {i, 4}]]

将任意表达式作为标签使用：

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> {1 -> [image], 2 -> [image], 3 -> [image]}]

使用具有符号位置信息的 Placed 来控制标签位置，包括外部位置：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexSize -> 0.1, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], PlotLabel -> p, ImagePadding -> 20], {p, {Before, After, Below, Above}}]

拐角位置外的符号表示：

Wolfram Language code: pl = {{Before, Below}, {After, Below}, {Before, Above}, {After, Above}};

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexSize -> 0.1, VertexShapeFunction -> "Square", ImagePadding -> 20, VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], PlotLabel -> p], {p, pl}]

符号式内部位置：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexSize -> 0.45, VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], VertexShapeFunction -> "Square", PlotLabel -> p], {p, {Left, Top, Right, Bottom}}]

内拐角位置的符号表示：

Wolfram Language code: pl = {{Left, Bottom}, {Right, Bottom}, {Left, Top}, {Right, Top}};

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexSize -> 0.45, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], PlotLabel -> p], {p, pl}]

使用显式坐标来放置标签中心：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexSize -> 0.45, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed[[image], p], {i, 4}], PlotLabel -> p, BaselinePosition -> Bottom], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

把所有标签放在顶点的右上角，并且在标签内改变坐标：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexSize -> 0.45, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed[[image], {{1, 1}, p}], {i, 4}], PlotLabel -> p, BaselinePosition -> Bottom], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

放置多个标签：

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> {1 -> Placed[{"lbl1", "lbl2"}, {Above, Below}]}]

可以使用任意数目的标签：

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> {1 -> Placed[{"lbl1", "lbl2", "lbl3", "lbl4"}, {Above, After, Below, Before}]}]

使用 Placed 的参数来控制格式，包括t Tooltip：

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> Placed["Name", Tooltip]]

或者 StatusArea：

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> Placed["Name", StatusArea]]

使用更复杂的格式函数：

Wolfram Language code: rotateLabel[lab_] := Rotate[lab, 45Degree]

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> Table[i -> Placed["xxx", Below, rotateLabel], {i, 4}]]

Wolfram Language code: panelLabel[lab_] := Panel[lab, FrameMargins -> 0, Background -> Lighter[Yellow, 0.7]]

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> Table[i -> Placed["xxx", Center, panelLabel], {i, 4}]]

Wolfram Language code: hyperlinkLabel[lab_] := Hyperlink[lab, "http://www.wolfram.com"]

Wolfram Language code: CompleteKaryTree[2, 3, VertexLabels -> Table[i -> Placed["xxx", Center, hyperlinkLabel], {i, 4}]]

VertexShape (5)

将任意 Graphics、Image 或者 Graphics3D 作为顶点形状使用：

Wolfram Language code: Table[CompleteKaryTree[2, 3, VertexShape -> s, VertexSize -> Medium], {s, {[image], [image], [image]}}]

对单个顶点，指定顶点形状：

Wolfram Language code: CompleteKaryTree[2, 3, VertexShape -> {2 -> [image]}, VertexSize -> Large]

VertexShape 可以与 VertexSize 组合使用：

Wolfram Language code: Table[CompleteKaryTree[2, 3, VertexSize -> s, VertexShape -> [image], PlotLabel -> s], {s, {Small, Large}}]

VertexShape 不受 VertexStyle 影响：

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> 0.2, VertexShape -> [image], VertexStyle -> Blue]

VertexShapeFunction 具有比 VertexShape 更高的优先级：

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> 0.2, VertexShapeFunction -> "Square", VertexShape -> [image]]

VertexShapeFunction (10)

获取 VertexShapeFunction 的内置设置列表：

Wolfram Language code: ResourceData["VertexShapeFunction"]

利用 VertexShapeFunction 在 "Basic" 集合中的内置设置：

Wolfram Language code: ResourceData["VertexShapeFunction", "Basic"]

简单基本形状：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, {"Triangle", "Square", "Rectangle", "Pentagon", "Hexagon", "Octagon"}}]

普通基本形状：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, {"DownTrapezoid", "UpTrapezoid", "Parallelogram", "FiveDown", "Circle", "Diamond", "Star", "Capsule"}}]

使用 VertexShapeFunction 在 "Rounded" 集合中的内置设置：

Wolfram Language code: ResourceData["VertexShapeFunction", "Rounded"]

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, ResourceData["VertexShapeFunction", "Rounded"]}]

使用 VertexShapeFunction 在 "Concave" 集合中的内置设置：

Wolfram Language code: ResourceData["VertexShapeFunction", "Concave"]

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, ResourceData["VertexShapeFunction", "Concave"]}]

绘制单个顶点：

Wolfram Language code: CompleteKaryTree[2, 3, VertexShapeFunction -> { 1 -> "Square"}, VertexSize -> 0.2]

与默认的顶点函数组合：

Wolfram Language code: CompleteKaryTree[2, 3, VertexShapeFunction -> { 1 -> "Square", "Triangle"}, VertexSize -> 0.2]

使用预定义的图形绘制顶点：

Wolfram Language code: CompleteKaryTree[2, 3, VertexShapeFunction -> (Inset[[image], #]&)]

通过运行程序，绘制顶点：

Wolfram Language code:

vf[{xc_, yc_}, name_, {w_, h_}] := 
	Block[{xmin = xc - w, xmax = xc + w, ymin = yc - h, ymax = yc + h}, 
	Polygon[{{xmin, ymin}, {xmax, ymax}, {xmin, ymax}, {xmax, ymin}}]
	];

Wolfram Language code: CompleteKaryTree[2, 3, VertexShapeFunction -> vf, VertexSize -> 0.2]

VertexShapeFunction 可以与 VertexStyle 组合使用：

Wolfram Language code: vf1[{xc_, yc_}, name_, {w_, h_}] := Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf1]

VertexShapeFunction 具有比 VertexStyle 更高的优先级：

Wolfram Language code: vf2[{xc_, yc_}, name_, {w_, h_}] := {Red, Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]}

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf2]

VertexShapeFunction 可以与 VertexSize 组合使用：

Wolfram Language code: CompleteKaryTree[2, 3, VertexShapeFunction -> "Star", VertexSize -> {1 -> Small, Medium}]

VertexShapeFunction 具有比 VertexShape 更高的优先级：

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> 0.3, VertexShapeFunction -> "Star", VertexShape -> [image]]

VertexSize (8)

默认情况下，自动计算顶点大小：

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> Automatic]

使用符号顶点尺寸，指定所有顶点的大小：

Wolfram Language code: Table[CompleteKaryTree[2, 3, VertexSize -> s, PlotLabel -> s], {s, {Tiny, Small, Medium, Large}}]

使用顶点坐标之间的最小距离的百分比：

Wolfram Language code: Table[CompleteKaryTree[2, 3, VertexSize -> s, PlotLabel -> s], {s, 0.1, 1, 0.3}]

对所有顶点坐标，使用整体对角线比率：

Wolfram Language code: Table[CompleteKaryTree[2, 3, VertexSize -> {"Scaled", s}, PlotLabel -> {"Scaled", s}], {s, 0.1, 1, 0.3}]

指定在和方向上的尺寸：

Wolfram Language code: Table[CompleteKaryTree[2, 3, VertexSize -> s, PlotLabel -> s], {s, {{0.1, 0.2}, {0.2, 0.1}}}]

对单个顶点，指定大小：

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> {1 -> 0.2, 2 -> 0.3}]

VertexSize 可以与 VertexShapeFunction 组合使用：

Wolfram Language code: Table[CompleteKaryTree[2, 3, VertexSize -> s, VertexShapeFunction -> "Square", PlotLabel -> s], {s, {0.05, 0.1, 0.2}}]

VertexSize 可以与 VertexShape 组合使用：

Wolfram Language code: Table[CompleteKaryTree[2, 3, VertexSize -> s, VertexShape -> [image], PlotLabel -> s], {s, {0.1, 0.2, 0.4}}]

VertexStyle (5)

对所有顶点进行样式化处理：

Wolfram Language code:

Table[CompleteKaryTree[2, 3, VertexStyle -> style, VertexSize -> 0.3, PlotLabel -> style], {style, {Yellow, EdgeForm[Dashed]}}]

对单个顶点进行样式化处理：

Wolfram Language code: CompleteKaryTree[2, 3, VertexStyle -> {1 -> Blue, 2 -> Red}, VertexSize -> 0.2]

VertexShapeFunction 可以与 VertexStyle 组合使用：

Wolfram Language code: vf1[{xc_, yc_}, name_, {w_, h_}] := Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf1]

VertexShapeFunction 具有比 VertexStyle 更高的优先级：

Wolfram Language code: vf2[{xc_, yc_}, name_, {w_, h_}] := {Red, Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]}

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf2]

VertexStyle 可以与 BaseStyle 组合使用：

Wolfram Language code: CompleteKaryTree[2, 3, VertexStyle -> LightBlue, BaseStyle -> EdgeForm[Dotted], VertexSize -> 0.2]

VertexStyle 具有比 BaseStyle 更高的优先级：

Wolfram Language code: CompleteKaryTree[2, 3, VertexStyle -> LightBlue, BaseStyle -> Gray, VertexSize -> 0.2]

VertexShape 不受 VertexStyle 的影响：

Wolfram Language code: CompleteKaryTree[2, 3, VertexSize -> 0.2, VertexShape -> [image], VertexStyle -> Blue]

VertexWeight (2)

设置所有顶点的权值：

Wolfram Language code: CompleteKaryTree[2, 3, VertexWeight -> {2, 3, 4, 5}]

Wolfram Language code: AnnotationValue[{%, 1}, VertexWeight]

将任意数值表达式作为权值使用：

Wolfram Language code: CompleteKaryTree[2, 3, VertexWeight -> {a, b, c, d}]

Wolfram Language code: AnnotationValue[{%, 1}, VertexWeight]

应用 (7)

一个完全 k 叉树的 GraphCenter：

Wolfram Language code: Table[HighlightGraph[#, GraphCenter[#]]&[CompleteKaryTree[i, 2, VertexSize -> Medium]], {i, 2, 4}]

GraphPeriphery：

Wolfram Language code: Table[HighlightGraph[#, GraphPeriphery[#]]&[CompleteKaryTree[i, 2, VertexSize -> Medium]], {i, 2, 4}]

VertexEccentricity：

Wolfram Language code: VertexEccentricity[CompleteKaryTree[3, 2], #]& /@ VertexList[CompleteKaryTree[3, 2]]

突出显示顶点离心率路径：

Wolfram Language code:

FindVertexEccentricityPath[g_ ? UndirectedGraphQ, u_] /; MemberQ[VertexList[g], u] := Module[{d = GraphDistanceMatrix[g], posu, posv, vl = VertexList[g]}, posu = VertexIndex[g, u];
	posv = First@First@Position[d[[posu]], Max[d[[posu]]]];
	PathGraph[FindShortestPath[g, u, vl[[posv]]]]]

Wolfram Language code: Table[HighlightGraph[g = CompleteKaryTree[3, 2], FindVertexEccentricityPath[g, u]], {u, Range[3]}]

GraphRadius：

Wolfram Language code: Table[GraphRadius[CompleteKaryTree[i, 2]], {i, 2, 4}]

突出显示半径路径：

Wolfram Language code:

FindRadiusPath[g_ ? UndirectedGraphQ] := Module[{c = First@GraphCenter[g], d, v, pos}, d = Table[GraphDistance[g, c, u], {u, VertexList[g]}];
	pos = First@Position[d, Max[d]];
	v = First@Part[VertexList[g], pos];
	PathGraph[FindShortestPath[g, c, v]]]

Wolfram Language code: Table[HighlightGraph[#, FindRadiusPath[#]]&[CompleteKaryTree[i, 2, VertexSize -> Tiny]], {i, 2, 4}]

GraphDiameter：

Wolfram Language code: Table[GraphDiameter[CompleteKaryTree[i, 2]], {i, 2, 4}]

突出显示直径路径：

Wolfram Language code:

FindDiameterPath[g_ ? UndirectedGraphQ] := Module[{d = GraphDistanceMatrix[g], u, v, pos}, pos = First@Position[d, Max[d]];
	{u, v} = Part[VertexList[g], pos];
	PathGraph[FindShortestPath[g, u, v]]]

Wolfram Language code: Table[HighlightGraph[#, FindDiameterPath[#]]&[CompleteKaryTree[i, 2, VertexSize -> Tiny]], {i, 2, 4}]

突出显示 CompleteKaryTree 的顶点度：

Wolfram Language code:

HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];

Wolfram Language code: g = CompleteKaryTree[3, 2, VertexSize -> Large];

Wolfram Language code: HighlightCentrality[g, VertexDegree[g]]

突出显示紧密中心度：

Wolfram Language code: HighlightCentrality[g, ClosenessCentrality[g]]

突出显示特征向量中心度：

Wolfram Language code: HighlightCentrality[g, EigenvectorCentrality[g]]

从到的顶点连通度是从到的与顶点无关的路径数目：

Wolfram Language code: g = CompleteKaryTree[3, 2, VertexLabels -> "Name"]

对于一颗树的所有顶点对，顶点连通度是 1：

Wolfram Language code: Table[HighlightGraph[g, PathGraph[FindShortestPath[g, 2, k]]], {k, Complement[Range[7], {2}]}]

属性和关系 (8)

CompleteKaryTree[n,k] 具有个顶点：

Wolfram Language code: VertexCount[CompleteKaryTree[n, k]]

CompleteKaryTree[n,k] 具有条边：

Wolfram Language code: EdgeCount[CompleteKaryTree[n, k]]

具有个顶点的一个完全 k 叉树含有条边：

Wolfram Language code: CompleteKaryTree[3, 3]

Wolfram Language code: VertexCount[%] - EdgeCount[%]

一棵完全 k 叉树是一个树图：

Wolfram Language code: CompleteKaryTree[3, 4]

Wolfram Language code: TreeGraphQ[%]

一个完全 k 叉树是一个二部图：

Wolfram Language code: BipartiteGraphQ[CompleteKaryTree[3, 3]]

一个完全 k 叉树是无环的：

Wolfram Language code: AcyclicGraphQ[CompleteKaryTree[3, 3]]

一个完全 k 叉树是无回路的：

Wolfram Language code: LoopFreeGraphQ[CompleteKaryTree[3, 3]]

一个完全 k 叉树是 k 叉树的一个特例：

Wolfram Language code: Table[CompleteKaryTree[3, i], {i, {2, 3, 4}}]

Wolfram Language code: Table[KaryTree[(i^3 - 1) / (i - 1), i], {i, {2, 3, 4}}]

Top

AlignmentPoint	Center	在图形内对齐的缺省点
AnnotationRules	{}	图、边和顶点的注释
AspectRatio	Automatic	高与宽的比
Axes	False	是否绘制轴
AxesLabel	None	坐标轴标签
AxesOrigin	Automatic	坐标轴原点
AxesStyle	{}	坐标轴样式指定
Background	None	绘图的背景色
BaselinePosition	Automatic	如何与环绕文本基线对齐
BaseStyle	{}	图形的基本样式指定
ContentSelectable	Automatic	是否允许进行内容选择
CoordinatesToolOptions	Automatic	坐标工具的详细行为
DirectedEdges	Automatic	是否将 Rule 解释为 DirectedEdge
EdgeLabels	None	边的标签和标签放置
EdgeLabelStyle	Automatic	边的标签所使用的样式
EdgeShapeFunction	Automatic	如何生成边的图形表示
EdgeStyle	Automatic	边的样式
EdgeWeight	Automatic	边的权值
Epilog	{}	主图形之后执行的图形指令
FormatType	TraditionalForm	文本的缺省样式类型
Frame	False	是否在图形周围放置边框
FrameLabel	None	边框标签
FrameStyle	{}	边框的样式指定
FrameTicks	Automatic	边框刻度
FrameTicksStyle	{}	边框刻度的样式指定
GraphHighlight	{}	要突出显示的图的元素
GraphHighlightStyle	Automatic	突出显示时使用的样式
GraphLayout	Automatic	如何设计顶点和边的布局
GridLines	None	绘制的网格线
GridLinesStyle	{}	网格线的样式指定
ImageMargins	0.	图形周围的边幅
ImagePadding	All	为标签等额外填充内容
ImageSize	Automatic	图形的绝对尺寸
LabelStyle	{}	标签的样式指定
Method	Automatic	使用图形方式的细节
PerformanceGoal	Automatic	优化的目标
PlotLabel	None	图形的一个整体标签
PlotRange	All	图形值的范围
PlotRangeClipping	False	是否在图形范围剪切
PlotRangePadding	Automatic	填充图形值范围的程度
PlotRegion	Automatic	填充的最后显示区域
PlotTheme	$PlotTheme	图的整体主题样式
PreserveImageOptions	Automatic	当显示相同图形的新版本时，是否保存图形选项
Prolog	{}	主图形之前执行的图形指令
RotateLabel	True	是否在边框上旋转 y 标签
Ticks	Automatic	坐标轴标记
TicksStyle	{}	坐标轴标记的样式指定
VertexCoordinates	Automatic	顶点的坐标
VertexLabels	None	顶点的标签和位置
VertexLabelStyle	Automatic	顶点的标签所使用的样式
VertexShape	Automatic	顶点的形状
VertexShapeFunction	Automatic	生成顶点的形状的函数
VertexSize	Medium	顶点的大小
VertexStyle	Automatic	顶点的样式
VertexWeight	Automatic	顶点的权值

CompleteKaryTree

更多信息和选项

所有选项的列表

范例

基本范例 (3)

选项 (79)

AnnotationRules (2)

DirectedEdges (1)

EdgeLabels (6)

EdgeShapeFunction (6)

EdgeStyle (2)

EdgeWeight (2)

GraphLayout (5)

GraphHighlight (3)

GraphHighlightStyle (2)

PlotTheme (4)

基本主题 (2)

特色主题 (2)

VertexCoordinates (3)

VertexLabels (13)

VertexShape (5)

VertexShapeFunction (10)

VertexSize (8)

VertexStyle (5)

VertexWeight (2)

应用 (7)

属性和关系 (8)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX