Wolfram 语言与系统参考资料中心

DeBruijnGraph

DeBruijnGraph[m,n]

给出具有 m 个符号的 n 维 De Bruijn 图.

DeBruijnGraph[m,n,type]

给出连通度由 type 确定的 De Bruijn 图.

范例

打开所有单元关闭所有单元

基本范例 (3)

具有两个符号和不同维度的前几个 De Bruijn 图：

Wolfram Language code: {DeBruijnGraph[2, 2], DeBruijnGraph[2, 3]}

在第二维有不同数目的符号的 De Bruijn 图：

Wolfram Language code: {DeBruijnGraph[2, 2], DeBruijnGraph[3, 2]}

具有不同连通度类型的 De Bruijn 图：

Wolfram Language code:

Table[DeBruijnGraph[2, 3, type, PlotLabel -> type, BaselinePosition -> Top], {type, {"Noncyclic", "LeftShift", "RightShift" }}]

选项 (79)

AnnotationRules (2)

指定顶点的注释：

Wolfram Language code: DeBruijnGraph[2, 2, AnnotationRules -> {1 -> {VertexLabels -> "hello"}}]

边：

Wolfram Language code: DeBruijnGraph[2, 2, AnnotationRules -> {23 -> {EdgeLabels -> "hello"}}]

EdgeLabels (7)

对边 12 添加标签：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeLabels -> {12 -> "Hello"}]

对每个边分别添加标签：

Wolfram Language code: el = EdgeList[DeBruijnGraph[2, 2]]

Wolfram Language code: DeBruijnGraph[2, 2, EdgeLabels -> Table[el[[i]] -> Subscript["e", i], {i, Length[el]}]]

使用任意表达式作为标签：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeLabels -> {12 -> [image], 23 -> [image], 31 -> [image]}]

使用带有符号位置信息的 Placed 来控制沿着一条边的标签位置：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, EdgeLabels -> {23 -> Placed["■■■", p]}, PlotLabel -> p], {p, {"Start", "Middle", "End"}}]

使用显式坐标来放置标签：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, EdgeLabels -> {23 -> Placed["■■■", p]}, PlotLabel -> p, BaselinePosition -> Bottom], {p, {0, 1 / 4, 1 / 3}}]

改变标签内的位置：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, EdgeLabels -> {23 -> Placed["■■■", {1 / 2, p}]}, PlotLabel -> p, BaselinePosition -> Bottom], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

放置多个标签：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeLabels -> {31 -> Placed[{"lbl1", "lbl2"}, {"Start", "End"}]}]

Wolfram Language code: DeBruijnGraph[2, 2, EdgeLabels -> {31 -> Placed[{"lbl1", "lbl2", "lbl3"}, {"Start", "Middle", "End"}]}]

通过 Tooltip 和 StatusArea 的值，使用自动标签：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeLabels -> Placed["Name", Tooltip]]

Wolfram Language code: DeBruijnGraph[2, 2, EdgeLabels -> Placed["Name", StatusArea]]

EdgeShapeFunction (6)

获取 EdgeShapeFunction 的内置设置列表：

Wolfram Language code: ResourceData["EdgeShapeFunction"]

包含基本线条的无向边：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeShapeFunction -> "Line"]

具有各种符号的边线条：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, {"BoxLine", "DiamondLine", "DotLine"}}]

包含实心箭头的有向边：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, ResourceData["EdgeShapeFunction", "FilledArrow"]}]

线型箭头：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, ResourceData["EdgeShapeFunction", "UnfilledArrow"]}]

开放式箭头：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, EdgeShapeFunction -> {{ef, "ArrowSize" -> 0.1}}, PlotLabel -> ef], {ef, ResourceData["EdgeShapeFunction", "CarvedArrow"]}]

对每条边指定一个边函数：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeShapeFunction -> {12 -> "CarvedArrow"}]

与一个不同的默认边函数合用：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeShapeFunction -> {12 -> "FilledArcArrow", "CarvedArrow"}]

通过运行程序绘制边：

Wolfram Language code:

ef[pts_List, e_] := 
	Block[{s = 0.015, g = [image]}, {Arrowheads[{{s, 0.33, g}, {s, 0.67, g}}], Arrow[pts]}]

Wolfram Language code: DeBruijnGraph[2, 2, EdgeShapeFunction -> ef]

EdgeShapeFunction 可以与 EdgeStyle 合起来使用:

Wolfram Language code: DeBruijnGraph[2, 2, EdgeStyle -> Blue, EdgeShapeFunction -> (Line[#1]&)]

EdgeShapeFunction 具有比 EdgeStyle 更高的优先级:

Wolfram Language code: DeBruijnGraph[2, 2, EdgeStyle -> Blue, EdgeShapeFunction -> ({Red, Line[#1]}&)]

EdgeStyle (2)

对所有边进行样式化处理：

Wolfram Language code: Table[DeBruijnGraph[2, 2, EdgeStyle -> style, PlotLabel -> style], {style, {Gray, Dashed, Thick}}]

对单条边进行样式化处理：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeStyle -> {12 -> Blue, 23 -> Dashed}]

EdgeWeight (2)

指定所有边的权值：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeWeight -> RandomInteger[5, 8]]

Wolfram Language code: WeightedAdjacencyMatrix[%]//MatrixForm

将任意数值表达式作为权值使用：

Wolfram Language code: DeBruijnGraph[2, 2, EdgeWeight -> {a, b, c, d, e, f, g, h}]

Wolfram Language code: WeightedAdjacencyMatrix[%]//MatrixForm

GraphHighlight (3)

突出显示顶点 1：

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> Tiny, GraphHighlight -> {1}]

突出显示边 23：

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> Tiny, GraphHighlight -> {23}]

突出显示顶点和边：

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> Tiny, GraphHighlight -> {1, 2, 23, 24}]

GraphHighlightStyle (2)

获取 GraphHighlightStyle 的内置设置列表：

Wolfram Language code: ResourceData["GraphHighlightStyle"]

使用 GraphHighlightStyle 的内置设置：

Wolfram Language code:

DeBruijnGraph[2, 2, GraphHighlight -> {1, 23}, VertexSize -> Small, GraphHighlightStyle -> #, PlotLabel -> #]& /@ Select[ResourceData["GraphHighlightStyle"], # =!= Automatic&]

GraphLayout (5)

默认情况下自动选择布局：

Wolfram Language code: DeBruijnGraph[2, 2, GraphLayout -> Automatic]

指定在特殊曲线上的布局：

Wolfram Language code: Table[DeBruijnGraph[5, 2, GraphLayout -> l, PlotLabel -> l], {l, {"CircularEmbedding", "SpiralEmbedding"}}]

指定满足最优化标准的布局：

Wolfram Language code:

Table[DeBruijnGraph[5, 2, GraphLayout -> l, PlotLabel -> l], {l, {"SpringEmbedding", "SpringElectricalEmbedding", "HighDimensionalEmbedding"}}]

VertexCoordinates 覆盖了 GraphLayout 坐标：

Wolfram Language code:

{DeBruijnGraph[2, 2, GraphLayout -> "SpringElectricalEmbedding"], 
	DeBruijnGraph[2, 2, GraphLayout -> "SpringElectricalEmbedding", VertexCoordinates -> Table[{i, i}, {i, 0, 3}]]}

通过一个布局算法，利用 AbsoluteOptions 提取计算所得的 VertexCoordinates：

Wolfram Language code: DeBruijnGraph[2, 2]

Wolfram Language code: AbsoluteOptions[%, VertexCoordinates]

PlotTheme (4)

基本主题 (2)

使用普通基本主题：

Wolfram Language code: DeBruijnGraph[2, 2, PlotTheme -> "Business"]

使用单色主题：

Wolfram Language code: DeBruijnGraph[2, 2, PlotTheme -> "Monochrome"]

特色主题 (2)

使用大型图主题：

Wolfram Language code: DeBruijnGraph[2, 2, PlotTheme -> "LargeGraph"]

使用经典示意图主题：

Wolfram Language code:

DeBruijnGraph[2, 2, VertexStyle -> LightDarkSwitched[RGBColor[1, 1, 0.85], GrayLevel[0.5]], PlotTheme -> "ClassicDiagram"]

VertexCoordinates (3)

默认情况下，自动计算任意顶点坐标：

Wolfram Language code: DeBruijnGraph[2, 2]

使用 AbsoluteOptions 提取所得的顶点坐标：

Wolfram Language code: AbsoluteOptions[%, VertexCoordinates]

指定沿着一个椭圆的布局函数：

Wolfram Language code: ellipseLayout[n_, {a_, b_}] := Table[{a Cos[2Pi / n u], b Sin[2Pi / n u]}, {u, 1, n}]

Wolfram Language code: Graphics[Point[ellipseLayout[20, {2, 1}]]]

使用它来生成图的顶点坐标：

Wolfram Language code: DeBruijnGraph[4, 2, VertexCoordinates -> ellipseLayout[16, {2, 1}]]

VertexCoordinates 具有比 GraphLayout 更高的优先级：

Wolfram Language code: DeBruijnGraph[2, 2, VertexCoordinates -> Table[{i, i}, {i, 4}], GraphLayout -> "CircularEmbedding"]

VertexLabels (13)

将顶点名称作为标签使用：

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> "Name"]

对单个顶点添加标签：

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> {2 -> "one"}]

对所有顶点添加标签：

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> Table[i -> Subscript[v, i], {i, 4}]]

将任意表达式用作标签：

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> {1 -> [image], 2 -> [image], 3 -> [image]}, ImagePadding -> 20]

使用具有符号位置信息的 Placed 来控制标签位置，包括内部位置：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexSize -> 0.1, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], PlotLabel -> p, ImagePadding -> 20], {p, {Before, After, Below, Above}}]

外拐角位置的符号表示：

Wolfram Language code: pl = {{Before, Below}, {After, Below}, {Before, Above}, {After, Above}};

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexSize -> 0.1, VertexShapeFunction -> "Square", ImagePadding -> 20, VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], PlotLabel -> p], {p, pl}]

内部位置的符号表示：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexSize -> 0.35, VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], VertexShapeFunction -> "Square", PlotLabel -> p], {p, {Left, Top, Right, Bottom}}]

内拐角位置的符号表示：

Wolfram Language code: pl = {{Left, Bottom}, {Right, Bottom}, {Left, Top}, {Right, Top}};

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexSize -> 0.35, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed["■■■", p], {i, 4}], PlotLabel -> p], {p, pl}]

使用显式坐标来放置标签中心：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexSize -> 0.35, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed[[image], p], {i, 4}], PlotLabel -> p, BaselinePosition -> Bottom], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

把所有标签放在顶点的右上角，并且在标签内改变坐标：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexSize -> 0.35, VertexShapeFunction -> "Square", VertexLabels -> Table[i -> Placed[[image], {{1, 1}, p}], {i, 4}], PlotLabel -> p, BaselinePosition -> Bottom], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

放置多个标签：

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> {1 -> Placed[{"lbl1", "lbl2"}, {Above, Below}]}]

可以使用任意数目的标签：

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> {1 -> Placed[{"lbl1", "lbl2", "lbl3", "lbl4"}, {Above, After, Below, Before}]}]

使用 Placed 的变量来控制格式，包括 Tooltip：

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> Placed["Name", Tooltip]]

或者 StatusArea：

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> Placed["Name", StatusArea]]

使用更美观的格式函数：

Wolfram Language code: rotateLabel[lab_] := Rotate[lab, 45Degree]

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> Table[i -> Placed["xxx", Below, rotateLabel], {i, 4}]]

Wolfram Language code: panelLabel[lab_] := Panel[lab, FrameMargins -> 0, Background -> StandardBlue]

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> Table[i -> Placed["xxx", Center, panelLabel], {i, 4}]]

Wolfram Language code: hyperlinkLabel[lab_] := Hyperlink[lab, "http://www.wolfram.com"]

Wolfram Language code: DeBruijnGraph[2, 2, VertexLabels -> Table[i -> Placed["xxx", Center, hyperlinkLabel], {i, 4}]]

VertexShape (5)

将任意 Graphics、Image 或者 Graphics3D 作为顶点形状使用：

Wolfram Language code: Table[DeBruijnGraph[2, 2, VertexShape -> s, VertexSize -> Medium], {s, {[image], [image], [image]}}]

对单个顶点，指定顶点形状：

Wolfram Language code: DeBruijnGraph[2, 2, VertexShape -> {2 -> [image]}, VertexSize -> Tiny]

VertexShape 可以与 VertexSize 合起来使用:

Wolfram Language code: Table[DeBruijnGraph[2, 2, VertexSize -> s, VertexShape -> [image], PlotLabel -> s], {s, {Small, Large}}]

VertexShape 不受 VertexStyle 影响:

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> 0.3, VertexShape -> [image], VertexStyle -> Blue]

VertexShapeFunction 具有比 VertexShape 更高的优先级：

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> 0.2, VertexShapeFunction -> "Square", VertexShape -> [image]]

VertexShapeFunction (10)

获取 VertexShapeFunction 的内置设置列表:

Wolfram Language code: ResourceData["VertexShapeFunction"]

使用 VertexShapeFunction 在 "Basic" 集合中的内置设置：

Wolfram Language code: ResourceData["VertexShapeFunction", "Basic"]

简单基本形状：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, {"Triangle", "Square", "Rectangle", "Pentagon", "Hexagon", "Octagon"}}]

普通基本形状：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, {"DownTrapezoid", "UpTrapezoid", "Parallelogram", "FiveDown", "Circle", "Diamond", "Star", "Capsule"}}]

使用 VertexShapeFunction 在 "Rounded" 集合中的内置设置：

Wolfram Language code: ResourceData["VertexShapeFunction", "Rounded"]

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, ResourceData["VertexShapeFunction", "Rounded"]}]

使用 VertexShapeFunction 在 "Concave" 集合中的内置设置：

Wolfram Language code: ResourceData["VertexShapeFunction", "Concave"]

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexShapeFunction -> vf, VertexSize -> 0.2, PlotLabel -> vf], {vf, ResourceData["VertexShapeFunction", "Concave"]}]

绘制单个顶点：

Wolfram Language code: DeBruijnGraph[2, 2, VertexShapeFunction -> { 1 -> "Square"}, VertexSize -> 0.2]

与默认的顶点函数合起来使用：

Wolfram Language code: DeBruijnGraph[2, 2, VertexShapeFunction -> { 1 -> "Square", "Triangle"}, VertexSize -> 0.2]

使用预定义的图形绘制顶点：

Wolfram Language code: DeBruijnGraph[2, 2, VertexShapeFunction -> (Inset[[image], #]&)]

通过运行程序绘制顶点：

Wolfram Language code:

vf[{xc_, yc_}, name_, {w_, h_}] := 
	Block[{xmin = xc - w, xmax = xc + w, ymin = yc - h, ymax = yc + h}, 
	Polygon[{{xmin, ymin}, {xmax, ymax}, {xmin, ymax}, {xmax, ymin}}]
	];

Wolfram Language code: DeBruijnGraph[2, 2, VertexShapeFunction -> vf, VertexSize -> 0.2]

VertexShapeFunction 可以与 VertexStyle 合起来使用：

Wolfram Language code: vf1[{xc_, yc_}, name_, {w_, h_}] := Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf1]

VertexShapeFunction 具有比 VertexStyle 更高的优先级：

Wolfram Language code: vf2[{xc_, yc_}, name_, {w_, h_}] := {Red, Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]}

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf2]

VertexShapeFunction 可以与 VertexSize 合起来使用：

Wolfram Language code: DeBruijnGraph[2, 2, VertexShapeFunction -> "Star", VertexSize -> {1 -> Small, Medium}]

VertexShapeFunction 具有比 VertexShape 更高的优先级：

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> 0.3, VertexShapeFunction -> "Star", VertexShape -> [image]]

VertexSize (8)

默认情况下，自动计算顶点大小：

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> Automatic]

使用符号顶点尺寸，指定所有顶点的大小：

Wolfram Language code: Table[DeBruijnGraph[2, 2, VertexSize -> s, PlotLabel -> s], {s, {Tiny, Small, Medium, Large}}]

使用顶点坐标之间的最小距离的百分比：

Wolfram Language code: Table[DeBruijnGraph[2, 2, VertexSize -> s, PlotLabel -> s], {s, 0.1, 1, 0.3}]

对所有顶点坐标，使用整体对角线比率：

Wolfram Language code: Table[DeBruijnGraph[2, 2, VertexSize -> {"Scaled", s}, PlotLabel -> {"Scaled", s}], {s, 0.1, 1, 0.3}]

指定在和方向上的尺寸：

Wolfram Language code: Table[DeBruijnGraph[2, 2, VertexSize -> s, PlotLabel -> s], {s, {{0.1, 0.2}, {0.2, 0.1}}}]

指定单个顶点大小：

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> {1 -> 0.2, 2 -> 0.3}]

VertexSize 可以与 VertexShapeFunction 合起来使用：

Wolfram Language code: Table[DeBruijnGraph[2, 2, VertexSize -> s, VertexShapeFunction -> "Square", PlotLabel -> s], {s, {0.05, 0.1, 0.2}}]

VertexSize 可以与 VertexShape 合起来使用：

Wolfram Language code: Table[DeBruijnGraph[2, 2, VertexSize -> s, VertexShape -> [image], PlotLabel -> s], {s, {0.1, 0.2, 0.4}}]

VertexStyle (5)

对所有顶点进行样式化处理：

Wolfram Language code:

Table[DeBruijnGraph[2, 2, VertexStyle -> style, VertexSize -> 0.3, PlotLabel -> style], {style, {Yellow, EdgeForm[Dashed]}}]

对单个顶点进行样式化处理：

Wolfram Language code: DeBruijnGraph[2, 2, VertexStyle -> {1 -> Blue, 2 -> Red}, VertexSize -> 0.2]

VertexShapeFunction 可以与 VertexStyle 合起来使用：

Wolfram Language code: vf1[{xc_, yc_}, name_, {w_, h_}] := Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf1]

VertexShapeFunction 具有比 VertexStyle 更高的优先级：

Wolfram Language code: vf2[{xc_, yc_}, name_, {w_, h_}] := {Red, Rectangle[{xc - w, yc - h}, {xc + w, yc + h}]}

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> 0.2, VertexStyle -> Blue, VertexShapeFunction -> vf2]

VertexStyle 可以与 BaseStyle 合起来使用：

Wolfram Language code: DeBruijnGraph[2, 2, VertexStyle -> LightBlue, BaseStyle -> EdgeForm[Dotted], VertexSize -> 0.2]

VertexStyle 具有比 BaseStyle 更高的优先级：

Wolfram Language code: DeBruijnGraph[2, 2, VertexStyle -> LightBlue, BaseStyle -> Gray, VertexSize -> 0.2]

VertexShape 不受 VertexStyle 影响：

Wolfram Language code: DeBruijnGraph[2, 2, VertexSize -> 0.2, VertexShape -> [image], VertexStyle -> Blue]

VertexWeight (2)

设置所有顶点的权值：

Wolfram Language code: DeBruijnGraph[2, 2, VertexWeight -> {2, 3, 4, 5}]

Wolfram Language code: AnnotationValue[{%, 1}, VertexWeight]

将任意数值表达式作为权值使用：

Wolfram Language code: DeBruijnGraph[2, 2, VertexWeight -> {a, b, c, d}]

Wolfram Language code: AnnotationValue[{%, 1}, VertexWeight]

应用 (6)

De Bruijn 图的 GraphCenter：

Wolfram Language code: Table[HighlightGraph[#, GraphCenter[#]]&[DeBruijnGraph[2, i, VertexSize -> 0.2]], {i, 2, 4}]

GraphPeriphery：

Wolfram Language code: Table[HighlightGraph[#, GraphPeriphery[#]]&[DeBruijnGraph[2, i, VertexSize -> 0.2]], {i, 2, 4}]

VertexEccentricity：

Wolfram Language code: VertexEccentricity[DeBruijnGraph[2, 2], #]& /@ VertexList[DeBruijnGraph[2, 2]]

突出显示顶点离心率路径：

Wolfram Language code:

FindVertexEccentricityPath[g_ ? DirectedGraphQ, u_] /; MemberQ[VertexList[g], u] := Module[{d = GraphDistanceMatrix[g], posu, posv, vl = VertexList[g]}, posu = VertexIndex[g, u];
	posv = First@First@Position[d[[posu]], Max[d[[posu]]]];
	PathGraph[FindShortestPath[g, u, vl[[posv]]], DirectedEdges -> True]]

Wolfram Language code: Table[HighlightGraph[g = DeBruijnGraph[2, 2], FindVertexEccentricityPath[g, u]], {u, Range[4]}]

GraphRadius：

Wolfram Language code: Table[GraphRadius[DeBruijnGraph[2, i]], {i, 2, 4}]

突出显示半径路径：

Wolfram Language code:

FindRadiusPath[g_ ? DirectedGraphQ] := Module[{c = First@GraphCenter[g], d, v, pos}, d = Table[GraphDistance[g, c, u], {u, VertexList[g]}];
	pos = First@Position[d, Max[d]];
	v = First@Part[VertexList[g], pos];
	PathGraph[FindShortestPath[g, c, v], DirectedEdges -> True]]

Wolfram Language code: Table[HighlightGraph[#, FindRadiusPath[#]]&[DeBruijnGraph[2, i, VertexSize -> Tiny]], {i, 2, 4}]

GraphDiameter：

Wolfram Language code: Table[GraphDiameter[DeBruijnGraph[2, i]], {i, 2, 4}]

突出显示直径路径：

Wolfram Language code:

FindDiameterPath[g_ ? DirectedGraphQ] := Module[{d = GraphDistanceMatrix[g], u, v, pos}, pos = First@Position[d, Max[d]];
	{u, v} = Part[VertexList[g], pos];
	PathGraph[FindShortestPath[g, u, v], DirectedEdges -> True]]

Wolfram Language code: Table[HighlightGraph[#, FindDiameterPath[#]]&[DeBruijnGraph[2, i, VertexSize -> Tiny]], {i, 2, 4}]

突出显示 DeBruijnGraph 的顶点度：

Wolfram Language code:

HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]]

Wolfram Language code: g = DeBruijnGraph[3, 2, VertexSize -> Large];

Wolfram Language code: HighlightCentrality[g, VertexDegree[g]]

突出显示紧密中心度：

Wolfram Language code: HighlightCentrality[g, ClosenessCentrality[g]]

突出显示特征向量中心度：

Wolfram Language code: HighlightCentrality[g, EigenvectorCentrality[g]]

属性和关系 (4)

DeBruijnGraph[m,n] 具有个顶点：

Wolfram Language code: VertexCount[DeBruijnGraph[m, n]]

DeBruijnGraph[m,n] 具有条边：

Wolfram Language code: EdgeCount[DeBruijnGraph[m, n]]

每个顶点恰好具有条入边和条出边：

Wolfram Language code: mat = AdjacencyMatrix[DeBruijnGraph[m = 2, 3]];

每个顶点的出边的数目：

Wolfram Language code: (Plus@@mat)//Normal

每个顶点的入边的数目：

Wolfram Language code: (Plus@@Transpose[mat])//Normal

DeBruijnGraph[m,n] 是具有相同符号的 DeBruijnGraph[m,n-1] 的线图：

Wolfram Language code: {LineGraph[DeBruijnGraph[2, 1]], DeBruijnGraph[2, 2]}

可能存在的问题 (1)

设置 DirectedEdges->False 不应用于 DeBruijnGraph：

Wolfram Language code: DeBruijnGraph[2, 2, DirectedEdges -> False]

Top

AlignmentPoint	Center	在图形内对齐的缺省点
AnnotationRules	{}	图、边和顶点的注释
AspectRatio	Automatic	高与宽的比
Axes	False	是否绘制轴
AxesLabel	None	坐标轴标签
AxesOrigin	Automatic	坐标轴原点
AxesStyle	{}	坐标轴样式指定
Background	None	绘图的背景色
BaselinePosition	Automatic	如何与环绕文本基线对齐
BaseStyle	{}	图形的基本样式指定
ContentSelectable	Automatic	是否允许进行内容选择
CoordinatesToolOptions	Automatic	坐标工具的详细行为
DirectedEdges	Automatic	是否将 Rule 解释为 DirectedEdge
EdgeLabels	None	边的标签和标签放置
EdgeLabelStyle	Automatic	边的标签所使用的样式
EdgeShapeFunction	Automatic	如何生成边的图形表示
EdgeStyle	Automatic	边的样式
EdgeWeight	Automatic	边的权值
Epilog	{}	主图形之后执行的图形指令
FormatType	TraditionalForm	文本的缺省样式类型
Frame	False	是否在图形周围放置边框
FrameLabel	None	边框标签
FrameStyle	{}	边框的样式指定
FrameTicks	Automatic	边框刻度
FrameTicksStyle	{}	边框刻度的样式指定
GraphHighlight	{}	要突出显示的图的元素
GraphHighlightStyle	Automatic	突出显示时使用的样式
GraphLayout	Automatic	如何设计顶点和边的布局
GridLines	None	绘制的网格线
GridLinesStyle	{}	网格线的样式指定
ImageMargins	0.	图形周围的边幅
ImagePadding	All	为标签等额外填充内容
ImageSize	Automatic	图形的绝对尺寸
LabelStyle	{}	标签的样式指定
Method	Automatic	使用图形方式的细节
PerformanceGoal	Automatic	优化的目标
PlotLabel	None	图形的一个整体标签
PlotRange	All	图形值的范围
PlotRangeClipping	False	是否在图形范围剪切
PlotRangePadding	Automatic	填充图形值范围的程度
PlotRegion	Automatic	填充的最后显示区域
PlotTheme	$PlotTheme	图的整体主题样式
PreserveImageOptions	Automatic	当显示相同图形的新版本时，是否保存图形选项
Prolog	{}	主图形之前执行的图形指令
RotateLabel	True	是否在边框上旋转 y 标签
Ticks	Automatic	坐标轴标记
TicksStyle	{}	坐标轴标记的样式指定
VertexCoordinates	Automatic	顶点的坐标
VertexLabels	None	顶点的标签和位置
VertexLabelStyle	Automatic	顶点的标签所使用的样式
VertexShape	Automatic	顶点的形状
VertexShapeFunction	Automatic	生成顶点的形状的函数
VertexSize	Medium	顶点的大小
VertexStyle	Automatic	顶点的样式
VertexWeight	Automatic	顶点的权值

	"Noncyclic"	, …,
	"LeftShift"	, s₂t₁, …, s_n
	"RightShift"	, …, ,

DeBruijnGraph

更多信息和选项

所有选项的列表

范例

基本范例 (3)

选项 (79)

AnnotationRules (2)

EdgeLabels (7)

EdgeShapeFunction (6)

EdgeStyle (2)

EdgeWeight (2)

GraphHighlight (3)

GraphHighlightStyle (2)

GraphLayout (5)

PlotTheme (4)

基本主题 (2)

特色主题 (2)

VertexCoordinates (3)

VertexLabels (13)

VertexShape (5)

VertexShapeFunction (10)

VertexSize (8)

VertexStyle (5)

VertexWeight (2)

应用 (6)

属性和关系 (4)

可能存在的问题 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX