Wolfram 语言与系统参考资料中心

DensityPlot3D

DensityPlot3D[f,{x,x_min,x_max},{y,y_min,y_max},{z,z_min,z_max}]

将 f 作为 x、y 和 z 的函数绘制其密度图线.

DensityPlot3D[f,{x,y,z}∈reg]

在几何区域 reg 内取变量值.

范例

打开所有单元关闭所有单元

基本范例 (3)

绘制三维函数：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

绘制球上的函数：

Wolfram Language code: DensityPlot3D[Sin[x]Cos[y]Sin[z], {x, y, z}∈Ball[{0, 0, 0}, 5], PlotTheme -> "Marketing"]

使用不同的颜色方案和图例：

Wolfram Language code: f = PDF[DirichletDistribution[{1, 2, 3, 4}], {x, y, z}]

Wolfram Language code: DensityPlot3D[f, {x, 0, 0.5}, {y, 0, 1}, {z, 0, 1}, ColorFunction -> "SunsetColors", PlotLegends -> Automatic]

范围 (13)

采样 (6)

函数变成非实数的区域被排除在外：

Wolfram Language code: DensityPlot3D[Sqrt[x y z], {x, y, z}∈Ball[], OpacityFunction -> None]

用 PlotPoints 控制采样：

Wolfram Language code: Table[DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotPoints -> pp], {pp, {5, 20, 50}}]

定义域可以用包括 Cone 在内的区域指定：

Wolfram Language code: DensityPlot3D[x y z, {x, y, z}∈Cone[]]

包括 ImplicitRegion 的公式区域：

Wolfram Language code:

ℛ = ImplicitRegion[(x ^ 2 + (9 / 4)y ^ 2 + z ^ 2 - 1) ^ 3 - x ^ 2z ^ 3 - (9 / 80)y ^ 2z ^ 3 <= 0, {{x, -1.2, 1.2}, {y, -0.7, 0.7}, {z, -1, 1.3}}];

Wolfram Language code: DensityPlot3D[x y z, {x, y, z}∈ℛ]

包括 BoundaryMeshRegion 的基于网格的区域：

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {25, 3}]]

Wolfram Language code: DensityPlot3D[x y z, {x, y, z}∈ℛ]

使用 PlotRange 限制范围以展示更多详情：

Wolfram Language code:

DensityPlot3D[Exp[-(x ^ 2 + y ^ 2 + z ^ 2)], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotRange -> {{-1, 0}, All, All}, BoxRatios -> Automatic]

使用 ClipPlanes 指定一个或者多个剪切平面. 在下面的例子里，剪切：

Wolfram Language code:

DensityPlot3D[Sin[x + y + z] / 10, {x, 0, 10}, {y, 0, 10}, {z, 0, 10}, OpacityFunction -> None, ClipPlanes -> {1, 1, -1, 0}]

使用 RegionFunction 更普遍地约束点的包含性：

Wolfram Language code:

DensityPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, RegionFunction -> Function[{x, y, z, f}, x < y ^ 3]]

外观 (7)

使用 PlotTheme 立即获取整体样式：

Wolfram Language code:

Table[DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotLabel -> t, PlotTheme -> t], {t, {"Minimal", "Scientific", "Marketing"}}]

用 PlotLegends 获取不同值的颜色条：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotLegends -> Automatic]

用 Axes 控制轴的显示：

Wolfram Language code:

Table[DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotLabel -> a, Axes -> a], {a, {True, False, {True, False, True}}}]

用 AxesLabel 给轴添加标签，并且使用 PlotLabel 给整个图线添加标签：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Ticks -> None, AxesLabel -> {x, y, z}, PlotLabel -> x y z]

用 ColorFunction 根据函数值对图线着色：

Wolfram Language code:

Table[DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotLabel -> c, ColorFunction -> c], {c, {Hue, "BlueGreenYellow"}}]

TargetUnits 指定可视化中使用的单位：

Wolfram Language code:

DensityPlot3D[Quantity[x y z, "kg/m^3"], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesLabel -> Automatic, PlotLegends -> Automatic, TargetUnits -> {"Feet", "Feet", "Feet", "g/ft^3"}]

对轴使用对数标尺：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y] + z, {x, 0, 1}, {y, 0, 1}, {z, 0, 1}, ScalingFunctions -> {"Log", None, None}]

反转轴，使值随着轴向下的方向增加：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y] + z, {x, 0, 1}, {y, 0, 1}, {z, 0, 1}, ScalingFunctions -> {None, None, "Reverse"}]

选项 (69)

Axes (4)

默认情况下，DensityPlot3D 会在图中绘制坐标轴：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

用 AxesFalse 不绘制坐标轴：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Axes -> False]

用 AxesOrigin 指定坐标轴在何处相交：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesOrigin -> {0, 0, 0}]

依次显示各个坐标轴：

Wolfram Language code:

{DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Axes -> {False, False, True}], DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Axes -> {True, False, False}], DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Axes -> {False, True, False}]}

AxesLabel (4)

默认情况下不绘制坐标轴的标签：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

在轴放置标签：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesLabel -> z]

指定坐标轴的标签：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesLabel -> {"X", "Y", "Z"}]

用 DensityPlot3D 中指定的变量作为标签：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesLabel -> Automatic]

AxesOrigin (2)

自动确定坐标轴的位置：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

明确指定坐标轴的原点：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesOrigin -> {0, 0, 0}]

AxesStyle (4)

改变坐标轴的样式：

Wolfram Language code: DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesStyle -> Red]

指定每个坐标轴的样式：

Wolfram Language code:

DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesStyle -> {{Thick, Brown}, {Thick, Blue}, {Thick, Green}}]

为刻度和坐标轴设置不同的样式：

Wolfram Language code:

DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesStyle -> Green, TicksStyle -> StandardBlue]

为标签和坐标轴设置不同的样式：

Wolfram Language code:

DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesStyle -> Green, LabelStyle -> StandardBlue]

BoxRatios (2)

默认情况下，边界框的边具有相同长度：

Wolfram Language code: DensityPlot3D[Sin[x ]Cos[y] Sin[z], {x, -Pi / 2, 3Pi / 2}, {y, -Pi / 2, 3Pi / 2}, {z, -3Pi, 3Pi}]

使用 BoxRatios->Automatic 显示三维坐标值的自然刻度：

Wolfram Language code:

DensityPlot3D[Sin[x ]Cos[y] Sin[z], {x, -Pi / 2, 3Pi / 2}, {y, -Pi / 2, 3Pi / 2}, {z, -3Pi, 3Pi}, BoxRatios -> Automatic]

ClipPlanes (3)

使用 ClipPlanes 指定一个或者多个剪切面. 在这个例子里，剪切：

Wolfram Language code:

DensityPlot3D[Sin[x + y + z] / 10, {x, 0, 10}, {y, 0, 10}, {z, 0, 10}, OpacityFunction -> None, ClipPlanes -> {{1, 1, -1, 0}}]

指定若干剪切平面. 在这个例子里，剪切和：

Wolfram Language code:

DensityPlot3D[Sin[x + y + z] / 10, {x, 0, 10}, {y, 0, 10}, {z, 0, 10}, OpacityFunction -> None, ClipPlanes -> {{1, 1, -1, 0}, {0, 1, 0, -4}}]

与普通 RegionFunction 比较：

Wolfram Language code:

DensityPlot3D[Sin[x + y + z] / 10, {x, 0, 10}, {y, 0, 10}, {z, 0, 10}, OpacityFunction -> None, RegionFunction -> Function[{x, y, z}, x + y - z ≥ 0]]

ColorFunction (1)

根据 x、y、z 或者 f 的值对函数着色：

Wolfram Language code: f = PDF[DirichletDistribution[{1, 2, 3, 4}], {x, y, z}]

Wolfram Language code:

Table[DensityPlot3D[f, {x, -0.1, 0.5}, {y, 0, 1}, {z, 0, 1}, ColorFunction -> cf], {cf, Take[ColorData["Gradients"], 4]}]

ColorFunctionScaling (2)

ColorFunction 的参数通常被缩放为0和1之间的数值：

Wolfram Language code: DensityPlot3D[x + y + z, {x, 0, 3}, {y, 0, 3}, {z, 0, 3}, ColorFunction -> Hue]

通过把 ColorFunctionScaling 设置为 False 以使用未缩放密度值：

Wolfram Language code:

DensityPlot3D[Sin[2x y z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ColorFunction -> (If[# < 0, Red, Green]&), ColorFunctionScaling -> False, PlotPoints -> 100]

ImageSize (7)

使用已命名尺寸，如 Tiny、Small、Medium 和 Large：

Wolfram Language code:

{DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ImageSize -> Tiny], DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ImageSize -> Small]}

指定绘图的宽度：

Wolfram Language code:

{DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ImageSize -> 150], DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AspectRatio -> 1.5, ImageSize -> 150]}

指定绘图的高度：

Wolfram Language code:

{DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ImageSize -> {Automatic, 150}], DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

允许宽度和高度达到一定的大小：

Wolfram Language code:

{DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ImageSize -> UpTo[200]], DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AspectRatio -> 2, ImageSize -> UpTo[200]]}

指定图形的宽度和高度，必要时用空白填充：

Wolfram Language code:

DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ImageSize -> {200, 300}, Background -> StandardGray]

设置 AspectRatioFull 将填充可用空间：

Wolfram Language code:

DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AspectRatio -> Full, ImageSize -> {200, 300}, Background -> StandardGray]

使用允许的最大宽度和高度：

Wolfram Language code:

{DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ImageSize -> {UpTo[150], UpTo[100]}], DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

用 ImageSizeFull 填充对象中的可用空间：

Wolfram Language code:

Framed[Pane[DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ImageSize -> Full, Background -> StandardGray], {200, 100}]]

以可用空间的比例指定图像的大小：

Wolfram Language code:

Framed[Pane[DensityPlot3D[Sin[2π x]Sin[2π y]Sin[2π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> StandardGray], {200, 200}]]

OpacityFunction (6)

默认情况下 OpacityFunction 是 Automatic：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

设置 OpacityFunctionNone 下关闭透明度：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, OpacityFunction -> None]

使区间和中的数值更加不透明：

Wolfram Language code:

DensityPlot3D[Sin[π x]Sin[π y] Sin[π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, OpacityFunction -> Interval[{-1, -0.6}, {0.6, 1}], OpacityFunctionScaling -> False, PlotLegends -> Automatic]

使用常量透明度 Opacity[0.05]：

Wolfram Language code:

DensityPlot3D[Sin[π x]Sin[π y] Sin[π z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, OpacityFunction -> 0.05, PlotLegends -> Automatic]

使用与 Image3D 中相同的不透明度函数：

Wolfram Language code: f = PDF[DirichletDistribution[{1, 2, 3, 4}], {x, y, z}];

Wolfram Language code: DensityPlot3D[f, {x, 0, 1}, {y, 0, 1}, {z, 0, 1}, OpacityFunction -> "Image3D", PlotLegends -> Automatic]

使用自定义的透明函数来指定每个密度值的透明度：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, OpacityFunction -> Function[f, (1 - f) ^ 2]]

OpacityFunctionScaling (3)

默认情况下，使用缩放的数值：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, OpacityFunction -> Function[f, (1 - f) ^ 2]]

通过把 OpacityFunctionScaling 设置为 False，使用未缩放的密度值：

Wolfram Language code:

DensityPlot3D[x + y + z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, OpacityFunction -> Function[f, If[f > 0, 1, 0]], OpacityFunctionScaling -> False]

指定未缩放的不透明区间：

Wolfram Language code:

DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, OpacityFunction -> Interval[{-1, 0}], OpacityFunctionScaling -> False, PlotLegends -> Automatic, ColorFunction -> "BrightBands"]

PerformanceGoal (2)

生成更高质量的图线：

Wolfram Language code: Timing[DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PerformanceGoal -> "Quality"]]

强调性能，可能以质量为代价：

Wolfram Language code: Timing[DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PerformanceGoal -> "Speed"]]

PlotLegends (2)

默认情况下不使用图例：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

使用 PlotLegends->Automatic 显示图例图线：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotLegends -> Automatic]

PlotPoints (2)

使用更多点获取更平滑的密度：

Wolfram Language code: Table[DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotPoints -> pp], {pp, {5, 20, 50}}]

在方向上使用2个点，在方向使用4个点，而在方向使用8个点：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotPoints -> {2, 4, 8}]

PlotRange (3)

以完全的、、范围显示密度图线：

Wolfram Language code: DensityPlot3D[Exp[-(x ^ 2 + y ^ 2 + z ^ 2)], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

使用特定范围显示更多细节：

Wolfram Language code:

DensityPlot3D[Exp[-(x ^ 2 + y ^ 2 + z ^ 2)], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotRange -> {{-1, 0}, All, All}, BoxRatios -> Automatic]

只显示0和1之间的函数数值：

Wolfram Language code: DensityPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotRange -> {0, 1}]

等价地，完整的规范：

Wolfram Language code: DensityPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotRange -> {All, All, All, {0, 1}}]

PlotTheme (3)

使用图线主题：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotTheme -> "Marketing"]

选项设置覆盖主题设置，在这个例子里删除面网格：

Wolfram Language code: DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotTheme -> "Marketing", FaceGrids -> None]

比较不同的图线主题：

Wolfram Language code:

Table[DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotLabel -> t, PlotTheme -> t, ImageSize -> 130], {t, {"Scientific", "Monochrome", "Minimal", "Web", "Working", "Classic", "Business", "Marketing", "Detailed"}}]

RegionFunction (3)

在、和中的球面上绘制图线：

Wolfram Language code:

DensityPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, RegionFunction -> Function[{x, y, z, f}, x ^ 2 + y ^ 2 + z ^ 2 ≤ 4]]

只显示的区域：

Wolfram Language code:

DensityPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, RegionFunction -> Function[{x, y, z, f}, f < 2]]

区域不必是连通的：

Wolfram Language code:

DensityPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, RegionFunction -> Function[{x, y, z, f}, x < -1 || x > 1]]

ScalingFunctions (4)

默认情况下，DensityPlot3D 在所有方向都有线性标尺：

Wolfram Language code: DensityPlot3D[x + y + z, {x, 0, 10}, {y, 0, 10}, {z, 0, 10}]

创建一个轴为对数标尺的图：

Wolfram Language code: DensityPlot3D[x + y + z, {x, 0, 10}, {y, 0, 10}, {z, 0, 10}, ScalingFunctions -> {"Log", None, None}]

使用 ScalingFunctions 在方向反转坐标方向：

Wolfram Language code: DensityPlot3D[x + y + z, {x, 0, 10}, {y, 0, 10}, {z, 0, 10}, ScalingFunctions -> {None, None, "Reverse"}]

使用由函数定义的标尺，指定函数及其逆函数：

Wolfram Language code: DensityPlot3D[x + y + z, {x, 0, 10}, {y, 0, 10}, {z, 0, 10}, ScalingFunctions -> {{-Log[#]&, Exp[-#]&}, None, None}]

TargetUnits (2)

轴和图例按照由 TargetUnits 指定的单位添加标签：

Wolfram Language code:

DensityPlot3D[x y z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, AxesLabel -> Automatic, PlotLegends -> Automatic, TargetUnits -> {"Meters", "Meters", "Meters", "kg/m^3"}]

由 Quantity 指定的单位转化为由 TargetUnits 指定的单位：

Wolfram Language code:

DensityPlot3D[Quantity[x y z, "kg/m^3"], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotLegends -> Automatic, TargetUnits -> "g/ft^3"]

Ticks (6)

自动为每幅图标出刻度：

Wolfram Language code: DensityPlot3D[ Cos[ y] Sin[z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

用 TicksNone 绘制，但不显示刻度：

Wolfram Language code: DensityPlot3D[ Cos[ y] Sin[z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> None]

在特定位置放置刻度线：

Wolfram Language code:

DensityPlot3D[ Cos[ y] Sin[z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> {{-1.5, 0, 1.5}, {-1.5, 0, 1.5}, {-1.5, 0, 1.5}}]

在指定位置绘制刻度线，并显示指定的标签：

Wolfram Language code:

DensityPlot3D[ Cos[ y] Sin[z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> {{{-1.5, -a}, {0, 0}, {1.5, a}}, {{-1.5, -a}, {0, 0}, {1.5, a}}, {{-1.5, -a}, {0, 0}, {1.5, a}}}]

用缩放形式的长度指定刻度线：

Wolfram Language code:

DensityPlot3D[ Cos[ y] Sin[z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> {{{-1.5, -a, .1}, {0, 0, .1}, {1.5, a, .1}}, {{-1.5, -a, .05}, {0, 0, .05}, {1.5, a, .05}}, {{-1.5, -a, .15}, {0, 0, .15}, {1.5, a, .15}}}]

通过指定位置、长度、标签和样式自定义每个刻度：

Wolfram Language code:

DensityPlot3D[ Cos[ y] Sin[z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> {{{-1.5, -a, .1, Directive[Red, Dashed, Thick]}, {0, 0, .1, Directive[Red, Dashed]}, {1.5, a, .1, Directive[Red]}}, {{-1.5, -a, .05, Directive[Blue, Dashed, Thick]}, {0, 0, .05, Directive[Blue, Dashed]}, {1.5, a, .05, Directive[Blue]}}, {{-1.5, -a, .15, Directive[Darker@Green, Dashed, Thick]}, {0, 0, .15, Directive[Darker@Green, Dashed]}, {1.5, a, .15, Directive[Darker@Green]}}}]

TicksStyle (3)

默认情况下，刻度和刻度标签使用与坐标轴相同的样式：

Wolfram Language code: DensityPlot3D[ Cos[ y] Sin[z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AxesStyle -> Directive[Thick, Red]]

指定刻度的整体样式，包括标签：

Wolfram Language code: DensityPlot3D[ Cos[ y] Sin[z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, TicksStyle -> Directive[Bold, Red]]

指定每个轴的刻度的样式：

Wolfram Language code:

DensityPlot3D[ Cos[ y] Sin[z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, TicksStyle -> {Directive[Green, Bold], Directive[Bold, Red], Directive[Bold, Blue]}]

WorkingPrecision (1)

使用机器精度算术计算函数：

Wolfram Language code: DensityPlot3D[Sin[x y z + 10 ^ 16], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

应用 (17)

Elementary Functions (4)

绘制函数的图线：

Wolfram Language code: DensityPlot3D[x, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

绘制函数和的图线：

Wolfram Language code:

{DensityPlot3D[y, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}], 
	DensityPlot3D[z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

绘制函数和的图线：

Wolfram Language code:

{DensityPlot3D[x + y, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}], 
	DensityPlot3D[y + z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

绘制函数和的图线：

Wolfram Language code:

{DensityPlot3D[x + y + z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}], 
	DensityPlot3D[x - y + z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

绘制函数和的图线：

Wolfram Language code:

{DensityPlot3D[x ^ 2 + y ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}], DensityPlot3D[y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

绘制函数和的图线：

Wolfram Language code:

{DensityPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}], DensityPlot3D[x ^ 2 + y ^ 2 + 2z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

绘制的图线，这是单变量函数的乘积：

Wolfram Language code: DensityPlot3D[Sin[π x]Sin[π y]Sin[π z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

绘制和，单变量和双变量函数的图线：

Wolfram Language code:

{DensityPlot3D[Sin[π x]Sin[π (y + z)], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}], DensityPlot3D[Sin[π (x + y)]Sin[π z], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

绘制三变量函数的图线：

Wolfram Language code: DensityPlot3D[Sin[π (x + y + z)], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

绘制指数的和 $sum_ialpha_i exp(-TemplateBox[{{p, -, {p, _, i}}}, Norm]^2)$ ：

Wolfram Language code: f = Exp[-Norm[{x, y, z} - {-1, -1, -1}]^2] + Exp[-Norm[{x, y, z} - {1, 1, 1}]^2];

Wolfram Language code: DensityPlot3D[f, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

在框中随机挑选点：

Wolfram Language code: f = Sum[Exp[-2Norm[{x, y, z} - pi]^2], {pi, RandomPoint[Cuboid[{-1, -1, -1}, {1, 1, 1}], 10]}];

Wolfram Language code: DensityPlot3D[f, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

Distribution Functions (6)

绘制分布的 PDF 图线：

Wolfram Language code:

𝒟 = MultinormalDistribution[{0, 0, 0}, {{1, 0.5, 0}, {0.5, 1, 0}, {0, 0, 1}}];
f = PDF[𝒟, {x, y, z}];

Wolfram Language code: d = DensityPlot3D[f, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

模拟分布，并且显示点分布：

Wolfram Language code: pts = RandomVariate[𝒟, 10 ^ 4];

Wolfram Language code: Show[d, Graphics3D[{Green, AbsolutePointSize[1], Point[pts]}]]

绘制分布的 CDF 图线：

Wolfram Language code:

𝒟 = MultinormalDistribution[{0, 0, 0}, {{1, 0.5, 0}, {0.5, 1, 0}, {0, 0, 1}}];
cdf = CDF[𝒟, {x, y, z}];

Wolfram Language code: DensityPlot3D[cdf, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotLegends -> Automatic]

SurvivalFunction：

Wolfram Language code: sf = SurvivalFunction[𝒟, {x, y, z}];

Wolfram Language code: DensityPlot3D[sf, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotLegends -> Automatic]

HazardFunction：

Wolfram Language code: hf = HazardFunction[𝒟, {x, y, z}];

Wolfram Language code: DensityPlot3D[hf, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotLegends -> Automatic]

探索 MultinormalDistribution 的 Correlation 参数，其中 ρ_ab 是 a 和 b 之间的相关性：

Wolfram Language code:

cov[{σx_, σy_, σz_}, {ρxy_, ρyz_, ρxz_}] := {{σx^2, σx σy ρxy, σx σz ρxz}, {σx σy ρxy, σy^2, σy σz ρyz}, {σx σz ρxz, σy σz ρyz, σz^2}};

只有 x 和 y 之间的相关性：

Wolfram Language code:

Σ = cov[{1, 1, 1}, {0.5, 0, 0}];
f = PDF[MultinormalDistribution[{0, 0, 0}, Σ], {x, y, z}];

Wolfram Language code: DensityPlot3D[f, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

只有 y 和 z 之间的相关性：

Wolfram Language code:

Σ = cov[{1, 1, 1}, {0, 0.5, 0}];
f = PDF[MultinormalDistribution[{0, 0, 0}, Σ], {x, y, z}];

Wolfram Language code: DensityPlot3D[f, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

只有 y 和 z 之间的相关性，但是 z 分量中较大的方差：

Wolfram Language code:

Σ = cov[{1, 1, 2}, {0, 0.5, 0}];
f = PDF[MultinormalDistribution[{0, 0, 0}, Σ], {x, y, z}];

Wolfram Language code: DensityPlot3D[f, {x, -2, 2}, {y, -2, 2}, {z, -4, 4}, BoxRatios -> Automatic]

可视化 ProductDistribution 的 PDF：

Wolfram Language code:

𝒟 = ProductDistribution[{NormalDistribution[0, 1], 3}];
f = PDF[𝒟, {x, y, z}]

Wolfram Language code: DensityPlot3D[f, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

三个不同的分布的乘积：

Wolfram Language code:

𝒟 = ProductDistribution[NormalDistribution[], LaplaceDistribution[], WeibullDistribution[1, 1]];
f = PDF[𝒟, {x, y, z}]

Wolfram Language code: DensityPlot3D[f, {x, -2, 2}, {y, -2, 2}, {z, 0, 5}]

双变量和单变量分布的乘积：

Wolfram Language code:

𝒟 = ProductDistribution[BinormalDistribution[1 / 2], ExponentialDistribution[3]];
f = PDF[𝒟, {x, y, z}]

Wolfram Language code: DensityPlot3D[f, {x, -2, 2}, {y, -2, 2}, {z, 0, 3}]

绘制 CopulaDistribution 的 PDF：

Wolfram Language code:

𝒟 = CopulaDistribution[{"Frank", 1}, {GammaDistribution[3, 2 / 3], ExponentialDistribution[2], NormalDistribution[]}];
f = PDF[𝒟, {x, y, z}]

Wolfram Language code: DensityPlot3D[f, {x, 0, 6}, {y, 0, 3}, {z, -3, 3}]

可视化一些三变量数据的内核密度估计的 PDF：

Wolfram Language code:

data = RandomVariate[NormalDistribution[], {1000, 3}];
f = PDF[SmoothKernelDistribution[data], {x, y, z}];

Wolfram Language code: DensityPlot3D[f, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}]

使用 ClipPlanes 查看内部：

Wolfram Language code: DensityPlot3D[f, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}, ClipPlanes -> {1, 1, -1, 0}]

Partial Differential Equations (3)

在周期性边界条件下可视化非线性正弦-Gordon 方程，其中时间用轴表示：

Wolfram Language code:

L = 4;
usol = NDSolveValue[{D[u[t, x, y], t, t] == D[u[t, x, y], x, x] + D[u[t, x, y], y, y] + Sin[u[t, x, y]], u[t, -L, y] == u[t, L, y], u[t, x, -L] == u[t, x, L], u[0, x, y] == Exp[-(x ^ 2 + y ^ 2)], Derivative[1, 0, 0][u][0, x, y] == 0}, u, {t, 0, L / 2}, {x, -L, L}, {y, -L, L}]

在轴上按照时间演化的解：

Wolfram Language code: DensityPlot3D[usol[t, x, y], {x, -L, L}, {y, -L, L}, {t, 0, L / 2}, AxesLabel -> Automatic, PlotLegends -> Automatic]

横断面视图：

Wolfram Language code: DensityPlot3D[usol[t, x, y], {x, -L, L}, {y, -L, L}, {t, 0, L / 2}, AxesLabel -> Automatic, ClipPlanes -> {0, 1, 0, 0}]

在两个空间维度内可视化 Wolfram 非线性波动方程，其中时间在轴上表示：

Wolfram Language code:

usol = NDSolveValue[{D[u[t, x, y], t, t] == D[u[t, x, y], x, x] + D[u[t, x, y], y, y] / 2 + (1 - u[t, x, y] ^ 2)(1 + 2u[t, x, y]), u[0, x, y] == E^-(x^2 + y^2), u[t, -5, y] == u[t, 5, y], u[t, x, -5] == u[t, x, 5], u^(1, 0, 0)[0, x, y] == 0}, u, {t, 0, 4}, {x, -5, 5}, {y, -5, 5}]

横断面视图：

Wolfram Language code:

DensityPlot3D[usol[t, x, y], {x, -5, 5}, {y, -5, 5}, {t, 1, 4}, AxesLabel -> Automatic, ClipPlanes -> {0, 1, 0, 0}, ColorFunction -> "BrightBands", PlotLegends -> Automatic]

可视化三维偏微分方程的解. 在这个例子里，是 Ball 上的具有狄利克雷边界条件的泊松方程：

Wolfram Language code:

usol = NDSolveValue[{Subsuperscript[∇, {x, y, z}, 2]u[x, y, z] == 1, DirichletCondition[u[x, y, z] == x y z, True]}, u, {x, y, z}∈Ball[]]

绘制图线：

Wolfram Language code: DensityPlot3D[usol[x, y, z], {x, y, z}∈Ball[], PlotLegends -> Automatic]

Potential and Wave Functions (4)

可视化随机放置的电荷的场：

Wolfram Language code: v = Total[Table[1 / Norm[{x, y, z} - p], {p, RandomReal[{-0.5, 0.5}, {5, 3}]}]];

Wolfram Language code: DensityPlot3D[v, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

在空间中绘制来自三个源的球面波 $cos(omega TemplateBox[{{p, -, {p, _, i}}}, Norm])$ 的图线：

Wolfram Language code: f = Sum[Cos[10 Norm[{x, y, z} - {Sin[θ], 0, Cos[θ]}]], {θ, 0, (4 π/3), (2 π/3)}]

Wolfram Language code: DensityPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotTheme -> "Minimal"]

绘制声四极图线：

Wolfram Language code:

f = (((x y) Exp[I ((6π/5) - π Sqrt[x^2 + y^2 + z^2])]) (-1 + 2 I + (3 + I/Sqrt[x^2 + y^2 + z^2]))/(x^2 + y^2 + z^2) Sqrt[x^2 + y^2 + z^2]);

Wolfram Language code:

DensityPlot3D[Clip[Re[f], {-50, 50}], {x, -0.5, 0.5}, {y, -0.5, 0.5}, {z, -0.5, 0.5}, PlotLegends -> Automatic, OpacityFunctionScaling -> False, OpacityFunction -> Interval[{-50, -10}, {10, 50}], ColorFunction -> "RedGreenSplit"]

对于量子数、、，绘制氢元素轨道密度图线：

Wolfram Language code: a0 = Quantity["BohrRadius"] / Quantity["Meters"]

Wolfram Language code:

ψ[{n_, l_, m_}, {r_, θ_, ϕ_}] := With[{ρ = 2r / (n a0)}, Sqrt[((2/n a0))^3((n - l - 1)!/2n(n + l)!)]Exp[-ρ / 2]ρ^lLaguerreL[n - l - 1, 2l + 1, ρ]SphericalHarmonicY[l, m, θ, ϕ]]

绘制的图线：

Wolfram Language code:

DensityPlot3D[(Abs@ψ[{2, 1, 0}, {Sqrt[x^2 + y^2 + z^2], ArcTan[z, Sqrt[x^2 + y^2]], ArcTan[x, y]}])^2, {x, -5 a0, 5 a0}, {y, -5 a0, 5 a0}, {z, -5 a0, 5 a0}, PlotLegends -> Automatic]

属性和关系 (5)

对于数据，使用 ListDensityPlot3D：

Wolfram Language code: data = Table[x y z, {x, -1, 1, 0.05}, {y, -1, 1, 0.05}, {z, -1, 1, 0.05}];

Wolfram Language code: {ListDensityPlot3D[data], DensityPlot3D[x y z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

对于二维空间中的密度图线，使用 DensityPlot：

Wolfram Language code:

{DensityPlot[x ^ 2 + y ^ 2, {x, -1, 1}, {y, -1, 1}], DensityPlot3D[x ^ 2 + y ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, OpacityFunction -> None]}

对于切片曲面上的密度图线，使用 SliceDensityPlot3D：

Wolfram Language code:

{SliceDensityPlot3D[x y z, "BackPlanes", {x, -2, 2}, {y, -2, 2}, {z, -2, 2}], DensityPlot3D[x y z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

对于切片曲面上的等高线使用 SliceContourPlot3D：

Wolfram Language code:

{SliceContourPlot3D[x y z, "BackPlanes", {x, -2, 2}, {y, -2, 2}, {z, -2, 2}], DensityPlot3D[x y z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

对常量值曲面使用 ContourPlot3D：

Wolfram Language code:

{ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}], DensityPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

Top

	Automatic	自动确定
	None	无不透明函数，完全不透明
	α	常数透明度 Opacity[α]
	Interval[…]	使区间中的数值更加不透明
	"Image3D"	Image3D 中使用的默认透明函数
	func	普通透明函数

	s_f	缩放 f 等高值
	{s_x,s_y,s_z}	缩放 x、y 和 z 轴
	{s_x,s_y,s_z,s_f}	缩放 x、y 和 z 轴及 f 等高值

	"Log"		带有自动刻度标记的对数刻度
	"Log10"		以 10 为底的对数标尺，刻度为 10 的幂
	"SignedLog"		包含 0 和负数的类对数标尺
	"Reverse"		反转坐标方向
	"Infinite"		无限标尺

AlignmentPoint	Center	在图形内对齐的缺省点
AspectRatio	Automatic	高与宽的比
Axes	True	是否绘制轴
AxesEdge	Automatic	在哪条边上放置轴
AxesLabel	None	坐标轴标签
AxesOrigin	Automatic	坐标轴交叉的位置
AxesStyle	{}	指定坐标轴样式的图形指令
Background	None	图形背景色
BaselinePosition	Automatic	如何与环绕文本基线对齐
BaseStyle	{}	图形的基本样式指定
Boxed	True	是否绘制边框
BoxRatios	{1,1,1}	边界三维框比率
BoxStyle	{}	盒框的样式指定
ClipPlanes	None	剪切平面
ClipPlanesStyle	Automatic	剪切平面的样式指定
ColorFunction	Automatic	如何对图线着色
ColorFunctionScaling	True	是否缩放 ColorFunction 的参数
ContentSelectable	Automatic	是否允许内容选择
ControllerLinking	False	连接到外部旋转控制器的时间
ControllerPath	Automatic	尝试使用的外部控制器
Epilog	{}	在主图形显示后显示的二维图形基元
FaceGrids	None	在边框上绘制的网格线
FaceGridsStyle	{}	网格面的样式指定
FormatType	TraditionalForm	文本的缺省格式类型
ImageMargins	0.	图形周围预留的边幅
ImagePadding	All	允许为标签等设置的填充范围
ImageSize	Automatic	渲染图形的绝对尺寸
LabelStyle	{}	标签的样式指定
Lighting	Automatic	使用的模拟光照
Method	Automatic	使用的三维图形方法的详细信息
OpacityFunction	Automatic	如何计算每个点的不透明度
OpacityFunctionScaling	True	是否缩放 OpacityFunction 的参数
PerformanceGoal	$PerformanceGoal	优化的目标
PlotLabel	None	图形的标签
PlotLegends	None	颜色渐变的图例
PlotPoints	Automatic	函数在每个方向的样本的初始数目
PlotRange	{Full,Full,Full,Automatic}	f 的定义域或包含的其他数值
PlotRangePadding	Automatic	值域范围填充的程度
PlotRegion	Automatic	要填充的最终显示区域
PlotTheme	$PlotTheme	绘图的整体主题
PreserveImageOptions	Automatic	当显示相同图形的一个新版本时，是否保留图像选项
Prolog	{}	在主图形之前渲染的二维图形基元
RegionFunction	(True&)	如何决定是否应该包括一个点
RotationAction	"Fit"	互动旋转后渲染的方式
ScalingFunctions	None	如何缩放单个坐标
SphericalRegion	Automatic	是否将外切球体调整适合最后显示区域
TargetUnits	Automatic	使用的预期单位
Ticks	Automatic	指定刻度
TicksStyle	{}	刻度的样式指定
TouchscreenAutoZoom	False	当在一个触摸屏上激活时，是否放大为全屏
ViewAngle	Automatic	视图的角度
ViewCenter	Automatic	在中心显示的点
ViewMatrix	Automatic	显式转换矩阵
ViewPoint	{1.3,-2.4,2.}	观察位置
ViewProjection	Automatic	用于渲染远离观察者的对象的投影方法
ViewRange	All	要包含的观察距离范围
ViewVector	Automatic	模拟相机的位置和方向
ViewVertical	{0,0,1}	垂直的方向
WorkingPrecision	MachinePrecision	用于内部计算的精度

DensityPlot3D

更多信息和选项

所有选项的列表

范例

基本范例 (3)

范围 (13)

采样 (6)

外观 (7)

选项 (69)

Axes (4)

AxesLabel (4)

AxesOrigin (2)

AxesStyle (4)

BoxRatios (2)

ClipPlanes (3)

ColorFunction (1)

ColorFunctionScaling (2)

ImageSize (7)

OpacityFunction (6)

OpacityFunctionScaling (3)

PerformanceGoal (2)

PlotLegends (2)

PlotPoints (2)

PlotRange (3)

PlotTheme (3)

RegionFunction (3)

ScalingFunctions (4)

TargetUnits (2)

Ticks (6)

TicksStyle (3)

WorkingPrecision (1)

应用 (17)

Elementary Functions (4)

Distribution Functions (6)

Partial Differential Equations (3)

Potential and Wave Functions (4)

属性和关系 (5)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX