WOLFRAM

Wolfram 语言与系统参考资料中心

Dynamic[expr]

表示一个显示 expr 动态更新值的对象. 如果用交互方式改变或编辑 Dynamic[expr]，则赋值 expr=val，给出 expr 新值 val，且该值与显示形式一致.

Dynamic[expr,None]

不允许交互方式改变或编辑.

Dynamic[expr,f]

在 val 进行交互式改变或编辑时继续计算 f[val,expr].

Dynamic[expr,{f,fend}]

在交互式改变或编辑完成时计算 fend[val,expr].

Dynamic[expr,{fstart,f,fend}]

在交互式改变或者编辑开始时计算 fstart[val,expr].

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本动态  
放置动态  
交互式动态  
高级动态  
选项  
BaseStyle  
Deinitialization  
Evaluator  
Show More Show More
ExcludedContexts  
IncludedContexts  
Initialization  
ShrinkingDelay  
SynchronousUpdating  
TrackedSymbols  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关的工作流程
相关链接
历史
按以下格式引用：

Dynamic

Dynamic[expr]

表示一个显示 expr 动态更新值的对象. 如果用交互方式改变或编辑 Dynamic[expr]，则赋值 expr=val，给出 expr 新值 val，且该值与显示形式一致.

Dynamic[expr,None]

不允许交互方式改变或编辑.

Dynamic[expr,f]

在 val 进行交互式改变或编辑时继续计算 f[val,expr].

Dynamic[expr,{f,fend}]

在交互式改变或编辑完成时计算 fend[val,expr].

Dynamic[expr,{fstart,f,fend}]

在交互式改变或者编辑开始时计算 fstart[val,expr].

更多信息和选项

  • Dynamic[expr] 不仅可以直接显示为表达式，也可以显示为基本图形的坐标或者滑尺之类的对象，或作为选项的设置.
  • 当用于通过交互运算为 expr 赋值时， Dynamic[expr] 中的表达式通常是一个符号 x、一个对象 x[i]、一个部分 e[[i]] 或者一个列表 {x,y,…}.
  • 例如在图形中，Point[Dynamic[{x,y}]] 表示一个点，其坐标根据 x 和 y 的当前值动态更新.当该点交互移动时，执行 {x,y}={valx,valy} 形式的赋值. Point[Dynamic[{x,y}]] 可以交互移动； 而Dynamic[Point[{x,y}]] 不行.
  • 当 Dynamic[expr] 需要 expr 值时便会对其进行计算，它确定其中任何变量值的类型，虽然有些可能已经被改变.
  • 如果 Refresh 或 Clock 对象出现在 Dynamic[expr] 的表达式计算中，则 expr 将通常需要重新计算.
  • Dynamic 具有属性 HoldFirst， 所以在需要显示 expr 值之前不对其进行计算.
  • Dynamic[expr] 等价于 Dynamic[expr,(expr=#)&].
  • Dynamic[expr,f] 使交互式运算不改变 expr，除了因为 f[val,expr] 计算.
  • Dynamic[expr,None] 表示对象不能交互式改变，但是如果 expr 的值由于其它原因改变时它也会改变.
  • Dynamic[expr,Temporary] 允许一个对象的显示形式在交互式运算过程中改变，但是只会在运算完成后对 expr 赋值更新.
  • 对交互式鼠标操作而言，Dynamic[expr,{fstart,f,fend}] 通常在按下鼠标时计算 fstart[val,expr]，然后在鼠标移动时计算 f[val,expr]，然后在鼠标释放时计算 fend[val,expr].
  • 如果鼠标未移动，则 fstart、f 和 fend 分别只计算一次.
  • f[val,expr] 每次在 fstart[val,expr] 计算后立即进行计算，最后计算完成时，val 的值总是与 fend[val,expr] 中相同.
  • 可以影响 Dynamic 对象的交互式操作包括拖曳图形中的元素或者类似 Slider 对象中的元素，以及诸如 InputField 对象中的字段编辑.
  • 函数 fstart、f 和 fend 可以如下：
  • Automatic利用 Set　赋值
    None不执行动作
    Temporary允许交互式操作以临时改变
    func计算 func[val,expr]
  • Dynamic[expr,f] 等价于 Dynamic[expr,{None,f,None}].
  • Dynamic[expr,Temporary] 等价于 Dynamic[expr,{None,Temporary,Automatic}].
  • Dynamic[expr,f] 可用于对 expr 的赋值进行约束.
  • 当 expr 为类似 x+y 的表达式时，Dynamic[expr,f] 可用于为单独变量赋值.
  • 一个函数 func[val,expr] 如果要为 expr 赋值就应该具有属性 HoldRest.这可以利用 Function[{v,e},body,HoldRest] 实现.
  • 可以给出以下可选项：
  • BaseStyle {}所显示的对象的基本样式指定
    Deinitialization None当 Dynamic 不能再显示时，计算的表达式
    Evaluator Automatic用于计算的核
    Initialization NoneDynamic 首次被显示时进行计算的表达式
    ShrinkingDelay 0.如果被显示对象缩小，在缩小前延迟多长时间
    SynchronousUpdating True是否对内容进行同步计算
    TrackedSymbols All符号变化触发更新
    UpdateIntervalInfinity进行更新的时间间隔
  • Dynamic[e] 在 StandardForm 和 TraditionalForm 中显示为 e 的当前的动态更新值，同 Dynamic[e] 在 InputForm 和 OutputForm 中一样.
  • 出于显示的需要，Dynamic[expr] 在明确要求数值的地方提供一个模拟赋值的显示，而不是进行表达式计算.

范例

打开所有单元 关闭所有单元

基本范例  (1)

Dynamic 仅返回其赋值的当前值：

Wolfram Language code: Dynamic[x]

为 赋一个值以更新以上输出：

Wolfram Language code: x = 0.5

把符号 结合到一个 Slider：

Wolfram Language code: Slider[Dynamic[x]]

范围  (24)

基本动态  (6)

Dynamic 内可以设置任意表达式：

Wolfram Language code: Dynamic /@ {1 + x, "string", Graphics[{Red, Disk[]}, ImageSize -> Tiny]}

Dynamic 不显示在 StandardForm 中，但仍然存在：

Wolfram Language code: InputForm /@ %

用 Dynamic 链接依据 的当前显示值：

Wolfram Language code: Dynamic[n]
Wolfram Language code: Slider[Dynamic[n]]
Wolfram Language code: Dynamic[NIntegrate[Sin[t], {t, -Pi, n}]]
Wolfram Language code: SetterBar[Dynamic[n], Range[0, 1, 0.2]]
Wolfram Language code: Dynamic[Plot[Sin[(n + 1) x], {x, 0, 6}]]

在默认情况下，Dynamic 中的变量不是局部变量：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}

用 DynamicModule 设定局部变量：

Wolfram Language code: {DynamicModule[{x}, {Slider[Dynamic[x]], Dynamic[x]}], Dynamic[x]}

并且初始化变量：

Wolfram Language code: {DynamicModule[{x = 0.5}, {Slider[Dynamic[x]], Dynamic[x]}], Dynamic[x]}

Dynamic 表达式可以自触发：

Wolfram Language code: DynamicModule[{x = 1}, Dynamic[x = Max[0, x - 0.01]]]

与 Slider 共用：

Wolfram Language code: DynamicModule[{x = 1}, {Slider[Dynamic[x]], Dynamic[x = Max[0, x - 0.01]]}]

诸如 RandomReal 和 DateString 的表达式不会自动更新：

Wolfram Language code: Dynamic[RandomReal[]]
Wolfram Language code: Dynamic[DateString[]]

用 UpdateInterval 指定动态更新：

Wolfram Language code: Dynamic[RandomReal[], UpdateInterval -> 1 / 2]
Wolfram Language code: Dynamic[DateString[], UpdateInterval -> 1]

Dynamic 保持它的变量，并且除非作为输出显示，否则不计算它：

Wolfram Language code: Dynamic[a = 5];

由于上面的 Dynamic 从未显示，因此不执行赋值：

Wolfram Language code: a

放置动态  (3)

Plot 需要特定数值来生成输出：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {1, 5}], Plot[Sin[Dynamic[x]i], {i, 0, 2Pi}]}]
Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {1, 5}], Dynamic[Plot[Sin[x i], {i, 0, 2Pi}]]}]

不同的 Dynamic 表达式分别更新，这样可以提高效率：

Wolfram Language code: x = Plot3D[Sin[n m], {n, 0, 4}, {m, 0, 4}];
Wolfram Language code: Slider[Dynamic[y]]
Wolfram Language code: TabView[{{Dynamic[x], Dynamic[y]}, Dynamic[{x, y}]}]

把 Dynamic 置于图形坐标周围，用图形作为控件输入：

Wolfram Language code: {DynamicModule[{p = {0, 0}}, Framed@Graphics[{Locator[Dynamic[p]]}, PlotRange -> 1, PlotLabel -> Dynamic[p]]], DynamicModule[{p = {0, 0}}, Framed@Graphics[{Dynamic[Locator[p]]}, PlotRange -> 1, PlotLabel -> Dynamic[p]]]}

用图形坐标作为控件输入并且观察滑尺效果：

Wolfram Language code: DynamicModule[{p1 = {0, 0}, p2 = {1, 0}, p3 = {0, 1}}, {Framed@Graphics[Polygon[{Dynamic[p1], Dynamic[p2], Dynamic[p3]}], PlotRange -> 1], Column[Slider2D[#, {-1, 1}]& /@ {Dynamic[p1], Dynamic[p2], Dynamic[p3]}]}]

交互式动态  (8)

用 Dynamic 连接有交互式控制的变量，例如 Slider：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}

Slider2D：

Wolfram Language code: {Slider2D[Dynamic[x]], Dynamic[x]}

InputField：

Wolfram Language code: {InputField[Dynamic[x]], Dynamic[x]}

TemplateBox[{ColorSlider, paclet:ref/ColorSlider}, RefLink, BaseStyle -> {InlineFormula}]：

Wolfram Language code: {ColorSlider[Dynamic[x]], Dynamic[x]}

PopupMenu：

Wolfram Language code: {PopupMenu[Dynamic[x], Range[10]], Dynamic[x]}

Locator：

Wolfram Language code: DynamicModule[{x = {0, 0}}, {Graphics[Locator[Dynamic[x]], PlotRange -> 1], Dynamic[x]}]

用 Dynamic 控制视图元素，例如 TabView：

Wolfram Language code: d = Table[Graphics[Disk[], ImageSize -> t], {t, {10, 20, 30, 40}}]
Wolfram Language code: {TabView[d, Dynamic[x]], Dynamic[x]}

FlipView：

Wolfram Language code: {FlipView[d, Dynamic[x]], Dynamic[x]}

PopupView：

Wolfram Language code: {PopupView[d, Dynamic[x]], Dynamic[x]}

OpenerView：

Wolfram Language code: {OpenerView[{Disk, d}, Dynamic[t]], Dynamic[t]}

用 Dynamic 设置前端的选项，如 ImageSize：

Wolfram Language code: Column[{PopupMenu[Dynamic[size], {Tiny, Small, Medium, Large}], Graphics[Disk[], ImageSize -> Dynamic[size]]}]

高级动态  (7)

在默认情况下，Dynamic 用在交互元素中时执行赋值运算：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}
Wolfram Language code: {Slider[Dynamic[y, (y = #)&]], Dynamic[y]}
Wolfram Language code: {Slider[Dynamic[z, Automatic]], Dynamic[z]}

用第二自变量指定一个交互过程中进行计算的函数：

Wolfram Language code: col = None;{Slider[Dynamic[x, (col = Blue;x = #)&], Background -> Dynamic[col]], Dynamic[x]}

提供一个在交互过程中和交互后进行计算的双函数列表：

Wolfram Language code: col = None;{Slider[Dynamic[x, {(col = Blue;x = #)&, (col = Green)&}], Background -> Dynamic[col]], Dynamic[x]}

提供一个在交互过程中和交互后进行计算的三函数列表：

Wolfram Language code: x = 0.5;{Slider[Dynamic[x, {(y = x)&, (x = #)&, (x = y)&}]], Dynamic[x]}

用 Temporary 在交互作用结束时更新动态变量：

Wolfram Language code: {Slider[Dynamic[x, Temporary]], Dynamic[x]}

用 None 拒绝更新动态变量：

Wolfram Language code: {Slider[Dynamic[x, None]], Dynamic[x]}

Dynamic 还为可交互式设置的前端选项执行分配操作：

Wolfram Language code: DynamicModule[{pt = {2, 4, 2}}, Column[{Dynamic[pt], Graphics3D[Cuboid[], ViewPoint -> Dynamic[pt]]}]]

选项  (10)

BaseStyle  (1)

设置基本样式：

Wolfram Language code: DynamicModule[{x = "this is some text"}, Dynamic[x, BaseStyle -> {FontColor -> Orange}]]

Deinitialization  (1)

指定当输出不再被显示时进行计算的表达式：

Wolfram Language code: CreateDialog[Dynamic[f[Pink], Initialization :> (f[x_] := Graphics[{x, Disk[]}]), Deinitialization :> CreateDialog[f[Blue]]]];

Evaluator  (1)

指定只在名称为 "Local" 的核内运行的 Dynamic：

Wolfram Language code: Dynamic[$CommandLine, Evaluator -> "Local"]

ExcludedContexts  (1)

默认情况下，某些系统内部的上下文不会保存在初始化选项中：

Wolfram Language code: x := $TimeZone Dynamic[x, SaveDefinitions -> True]//ToBoxes

用 ExcludedContexts{} 保存所有非保护符号的定义：

Wolfram Language code: Dynamic[x, ExcludedContexts -> {}, SaveDefinitions -> True]//ToBoxes

IncludedContexts  (1)

将符号定义的递归包含限制在上下文 "c1`" 和 "c2`" 范围内：

Wolfram Language code: c1`x := {c1`Private`bar , c2`baz} c1`Private`bar := 1 c2`baz := 3
Wolfram Language code: Dynamic[c1`x, IncludedContexts -> {"c1`", "c2`"}, SaveDefinitions -> True]//ToBoxes

Initialization  (2)

在默认情况下，外部定义在核心进程之间丢失：

Wolfram Language code: f[x_] := Range[x]
Wolfram Language code: Dynamic[f[10]]

用 Initialization 计算在显示输出时需要的表达式：

Wolfram Language code: Dynamic[g[10], Initialization :> (g[x_] := Range[x])]

ShrinkingDelay  (1)

为 赋一个数值或图形：

Wolfram Language code: SetterBar[Dynamic[h], {Graphics[Disk[], ImageSize -> Tiny] -> "Graphics", 1 -> "Number"}]

用 ShrinkingDelay 允许收缩输出尺寸前减少时间：

Wolfram Language code: Framed /@ {Dynamic[h], Dynamic[h, ShrinkingDelay -> 2]}

SynchronousUpdating  (1)

防止长运算超时或暂停系统：

Wolfram Language code: Dynamic[Pause[5];"result", SynchronousUpdating -> False]

TrackedSymbols  (1)

仅当 x 变化时更新 y ：

Wolfram Language code: DynamicModule[{x, y}, Column@{Labeled[Slider[Dynamic[x]], "x", Left], Labeled[Slider[Dynamic[y]], "y", Left], Dynamic[{x, y}, TrackedSymbols :> {x}]}]

应用  (5)

把一个点的坐标限制在一个圆上：

Wolfram Language code: DynamicModule[{p = {0, 1}}, Graphics[{Dashed, Circle[], PointSize[0.1], Point[Dynamic[p, (p = Normalize[#])&]]}, ImageSize -> Tiny, PlotRange -> 1.2]]

构造一个动态计算界面：

Wolfram Language code: DynamicModule[{a = 0, b = 0, s = {{5, 30}, {1, Infinity}}}, Deploy[Style[Panel[Grid[Transpose[{{Style["input a number", Red], Style["input another number", Red], "here is their sum", "their difference", "their product"}, {InputField[Dynamic[a], Number], InputField[Dynamic[b], Number], InputField[Dynamic[a + b], Enabled -> False], InputField[Dynamic[a - b], Enabled -> False], InputField[Dynamic[a b], Enabled -> False]}}], Alignment -> Right], ImageMargins -> 10], DefaultOptions -> {InputField -> {ContinuousAction -> True, FieldSize -> s}}]]]

生成一个定时器跟踪间隔时间（分秒），用 Trigger 作为控件：

Wolfram Language code: {Trigger[Dynamic[x, (a = FractionalPart[#];x = Round[#])&], {0, Infinity}], Dynamic[{Quotient[x, 60], Mod[x, 60], SetPrecision[10a, 2]}]}

生成一个国家形状的简单界面：

Wolfram Language code: DynamicModule[{c}, {PopupMenu[Dynamic[c], CountryData[]], Dynamic[CountryData[c, "Shape"], SynchronousUpdating -> False]}]

构造自定义控件，例如一个范围为 的箭头滑尺：

Wolfram Language code: DynamicModule[{angle = 0, p = {1, 0}}, {LocatorPane[Dynamic[p, (angle = ArcTan@@#;p = {Cos[angle], Sin[angle]})&], Graphics[{Circle[], Arrowheads[0.15], Arrow[Dynamic[{{0, 0}, p}]]}, ImageSize -> Tiny], Appearance -> None], Dynamic[angle]}]

一个范围为 的箭头滑尺：

Wolfram Language code: DynamicModule[{angle = 0, p = {1, 0}, angleCalc}, {LocatorPane[Dynamic[p, (angleCalc@@Normalize /@ {#, p})&], Graphics[{Circle[], Arrowheads[0.15], Arrow[Dynamic[{{0, 0}, p}]]}, ImageSize -> Tiny], Appearance -> None], Dynamic[angle]}, Initialization :> (angleCalc[newp_, oldp_] := (angle = angle + ArcCos[newp.oldp]Sign[Cross[newp].(newp - oldp)];p = {Cos[angle], Sin[angle]}))]

属性和关系  (4)

Dynamic 可用于直接显示其内容：

Wolfram Language code: DynamicModule[{x = 0}, Dynamic[x]]

只显示的 Dynamic 并没有交互性，第二个参数对它没有影响：

Wolfram Language code: DynamicModule[{x = 0}, Dynamic[x, (x = 1)&]]

另外，可将 Dynamic 作为一个值赋给交互控件、对象或选项：

Wolfram Language code: DynamicModule[{x = 0}, Slider[Dynamic[x]]]

当交互式改变值时，作为值使用的 Dynamic 会调用第二个参数：

Wolfram Language code: DynamicModule[{x = 0}, Slider[Dynamic[x, (x = 1)&]]]

等到结果显示在屏幕上时，动态表达式才会计算其内容：

Wolfram Language code: x=.; result = Dynamic[x = 5]; Print["x = ", x]

显示结果也不能保证表达式会立即解决：

Wolfram Language code: result Print["x = ", x];

如果时机很重要，则需使用 FinishDynamic：

Wolfram Language code: Dynamic[y = 10] FinishDynamic[] Print["y = ", y];

同步发生的动态根据 DynamicEvaluationTimeout 的值受时间限制：

Wolfram Language code: Style[Dynamic[Pause[2];"result"], DynamicEvaluationTimeout -> 1]

若某运算动态使用 $DynamicEvaluation 计算，则其可以检测：

Wolfram Language code: {Dynamic[$DynamicEvaluation], $DynamicEvaluation}

可能存在的问题  (5)

以下范例不成立，因为赋值运算失败：

Wolfram Language code: {Slider[Dynamic[1 - x]], Dynamic[x]}

用 Dynamic 的第二自变量控制赋值运算：

Wolfram Language code: {Slider[Dynamic[1 - y, (y = 1 - #)&]], Dynamic[y]}

自触发 Dynamic 可以很容易造成无限循环（删除该输出使之停止）：

Wolfram Language code: DynamicModule[{x = 1}, Dynamic[x = x + 1]]

在默认情况下，观看元素在显示前生成完整内容：

Wolfram Language code: Timing[MenuView[(# -> PolyhedronData[#])& /@ PolyhedronData["Uniform"]]]

用 Dynamic 和 ImageSize->Automatic 只在显示时生成内容：

Wolfram Language code: Timing[MenuView[(# -> Dynamic[PolyhedronData[#]])& /@ PolyhedronData["Uniform"], ImageSize -> Automatic]]

没有初始化 Module 变量，返回 Module 变量泄漏了符号的名称：

Wolfram Language code: Module[{x = 5}, Dynamic[x]] FinishDynamic[]; Quit[]

通常，应使用 DynamicModule 把变量初始化和本地化：

Wolfram Language code: DynamicModule[{x = 5}, Dynamic[x]] FinishDynamic[]; Quit[]

也可以用 Dynamic 把 Module 整个封装起来：

Wolfram Language code: Dynamic[Module[{x = 5}, x]] FinishDynamic[]; Quit[]

默认情况下，附加到 "System`" 符号的定义不会被引入：

Wolfram Language code: x := Subscript[y, 1] Subscript[y, 1] := 17 Options[Dynamic[x, SaveDefinitions -> True]//ToBoxes, Initialization]

用 ExcludedContexts{} 将所有上下文中的定义都加进来：

Wolfram Language code: Options[Dynamic[x, SaveDefinitions -> True, ExcludedContexts -> {}]//ToBoxes, Initialization]

也可以将定义附加到你自己的符号上：

Wolfram Language code: Clear[Subscript] y/:Subscript[y, 1] = 17 Options[Dynamic[x, SaveDefinitions -> True]//ToBoxes, Initialization]

巧妙范例  (6)

成对的 Slider：

Wolfram Language code: {Slider[Dynamic[x]], Slider[Dynamic[1 - x, (x = 1 - #)&]]}

成对的 Slider2D：

Wolfram Language code: {Slider2D[Dynamic[r], {-1, 1}], Slider2D[Dynamic[Through[{Cos, Sin}[ArcTan@@r]], (r = Normalize[#])&], {-1, 1}], Slider2D[Dynamic[{r[[1]], Sin[r[[1]] Pi]}, (r = {#[[1]], Sin[#[[1]] Pi]})&], {-1, 1}], Slider2D[Dynamic[{r[[1]], Cos[r[[1]] Pi]}, (r = {#[[1]], Cos[#[[1]] Pi]})&], {-1, 1}]}

一个“下垂”的 Slider：

Wolfram Language code: DynamicModule[{x = 1}, {Slider[Dynamic[x]], Dynamic[x = Max[0, x - 0.01]]}]

使一个圆盘跟随鼠标移动，鼠标超过图形区域时则居中：

Wolfram Language code: Framed@Graphics[Disk[Dynamic[MousePosition[{"Graphics", Graphics}, {0, 0}]], 0.2], PlotRange -> 2]

当鼠标离开图形区域时记住其最后位置：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, Framed@Graphics[Disk[Dynamic[pt = MousePosition[{"Graphics", Graphics}, pt];pt], 0.2], PlotRange -> 2]]

在框架区内点击并观察弹球：

Wolfram Language code: Framed@DynamicModule[{contents = {}}, EventHandler[Graphics[{PointSize[0.1], Point[Dynamic[contents = Map[If[#[[1, 2]] ≥ 0, {#[[1]] - #[[2]], #[[2]] + {0, 0.001}}, {{#[[1, 1]], 0}, {1, -0.8}#[[2]]}]&, contents];Map[First, contents]]]}, PlotRange -> {{0, 1}, {0, 1}}], "MouseDown" :> (AppendTo[contents, {MousePosition["Graphics"], {0, 0}}])]]
Wolfram Research (2007)，Dynamic，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Dynamic.html.

文本

Wolfram Research (2007)，Dynamic，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Dynamic.html.

CMS

Wolfram 语言. 2007. "Dynamic." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Dynamic.html.

APA

Wolfram 语言. (2007). Dynamic. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Dynamic.html 年

BibTeX

@misc{reference.wolfram_2026_dynamic, author="Wolfram Research", title="{Dynamic}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Dynamic.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dynamic, organization={Wolfram Research}, title={Dynamic}, year={2007}, url={https://reference.wolfram.com/language/ref/Dynamic.html}, note=[Accessed: 07-September-2026]}