Wolfram 语言与系统参考资料中心

Eigenvalues

Eigenvalues[m]

给出方阵 m 的特征值构成的列表.

Eigenvalues[{m,a}]

给出矩阵 m 的关于 a 的广义特征值.

Eigenvalues[m,k]

给出矩阵 m 的前 k 个特征值.

Eigenvalues[{m,a},k]

给出前 k 个广义特征值.

范例

打开所有单元关闭所有单元

基本范例 (5)

精确二维矩阵的特征值：

Wolfram Language code: Eigenvalues[{{-3, 2}, {-15, 8}}]

将特征值赋给各变量：

Wolfram Language code:

m = {{1, 2}, {3, 4}};
{λ, μ} = Eigenvalues[{{1, 2}, {3, 4}}]

特征值是特征多项式的根：

Wolfram Language code: (x - λ)(x - μ) == CharacteristicPolynomial[m, x]//Simplify

三维矩阵的特征值：

Wolfram Language code: Eigenvalues[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}]

以机器精度计算的特征值：

Wolfram Language code: Eigenvalues[{{1.1, 2.2, 3.25}, {0.76, 4.6, 5}, {0.1, 0.1, 6.1}}]

符号特征值：

Wolfram Language code: Eigenvalues[{{a, b}, {c, d}}]

范围 (20)

基本用法 (6)

求机器精度矩阵的特征值：

Wolfram Language code: Eigenvalues[Table[N[1 / (i + j + 1)], {i, 3}, {j, 3}]]

近似的 20 位精度的特征值：

Wolfram Language code: Eigenvalues[Table[N[1 / (i + j + 1), 20], {i, 3}, {j, 3}]]

复矩阵的特征值：

Wolfram Language code: Eigenvalues[{{1.1 - .2I, 2.2, 3.25}, {0.76, 4.6, 5 - 2I}, {0.1, 0.1 + I, 6.1}}]

精确实矩阵的特征值：

Wolfram Language code: Eigenvalues[{{(1/3), (1/2), (3/5)}, {(1/2), (4/5), 1}, {(3/5), 1, (9/7)}}]

精确复矩阵的特征值：

Wolfram Language code: Eigenvalues[{{π, (1/3)}, {I, 5}}]

符号特征值：

Wolfram Language code:

Eigenvalues[(|   |   |   |
| - | - | - |
| a | 2 | 0 |
| 2 | 3 | 1 |
| 0 | 1 | 7 |)]

高效计算大型数值矩阵的特征值：

Wolfram Language code: m = RandomReal[{1, 9}, {100, 100}];

Wolfram Language code: Eigenvalues[m];//Timing

特征值的子集 (5)

五个最大的特征值：

Wolfram Language code: Eigenvalues[Table[If[Abs[i - j] < 3, 1.0, 0], {i, 100}, {j, 100}], 5]

三个最小的特征值：

Wolfram Language code: Eigenvalues[Table[N[1 / (i + j + 1), 20], {i, 10}, {j, 10}], -3]

求四个最大的特征值，如果没有那么多，则有多少给出多少：

Wolfram Language code:

Eigenvalues[(⁠|       |       |       |
| ----- | ----- | ----- |
| (1/3) | (1/4) | (1/5) |
| (1/4) | (1/5) | (1/6) |
| (1/5) | (1/6) | (1/7) |⁠), UpTo[4]]

列出重复的特征值：

Wolfram Language code: Eigenvalues[{{1, 0, 1}, {0, 1, 0}, {0, 0, 1}}]

提取特征值的子集时考虑重复的特征值：

Wolfram Language code: mat = {{(7/2), 0, (1/2), 0}, {0, 3, 0, 1}, {(1/2), 0, (7/2), 0}, {0, 1, 0, 3}};

Wolfram Language code: Eigenvalues[mat]

Wolfram Language code: Eigenvalues[mat, 3]

Wolfram Language code: Eigenvalues[mat, -3]

广义的特征值 (4)

机器精度的广义特征值：

Wolfram Language code: a = {{1., 1.5, 2.}, {3.1, 2., 2.9}, {3., 2., 1.}};

Wolfram Language code: b = {{1.3, .5, 1.1}, {0., 1.5, 2.3}, {1., 0., 1.}};

Wolfram Language code: Eigenvalues[{a, b}]

广义的精确特征值：

Wolfram Language code: a = {{1, 1, 1}, {1, 0, 1}, {0, 0, 1}};

Wolfram Language code: b = {{0, 1, 1}, {0, 1, 1}, {1, 0, 0}};

Wolfram Language code: Eigenvalues[{a, b}]

以有限的精度计算结果：

Wolfram Language code: Eigenvalues[N[{a, b}, 20]]

计算符号矩阵的广义特征值：

Wolfram Language code:

a = {{x, 1 + x}, {1 - x, x}};b = {{1, 1}, {1, 2x}};
Eigenvalues[{a, b}]

求两个最小的广义特征值：

Wolfram Language code:

a = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};
b = {{11, 12, 13}, {1, 15, 16}, {17, 18, 19}};
Eigenvalues[{a, b}, -2]

特殊矩阵 (5)

稀疏矩阵的特征值：

Wolfram Language code: SparseArray[{{1, 3} -> 2, {2, 2} -> 3, {3, 1} -> 1, {4, 2} -> 5}, {4, 4}]

Wolfram Language code: Eigenvalues[%]

Wolfram Language code: SparseArray[Band[{1, 1}, {-1, -1}] -> {{{1, 2}, {2, 1}}}, {4, 4}]

Wolfram Language code: Eigenvalues[%]

结构化矩阵的特征值：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 2, {1, 2} -> 1}, {2, 2}, Symmetric[All]]

Wolfram Language code: Eigenvalues[%]

Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}}, "Meters"]

QuantityArray 对象的单位在特征值中，而特征向量是无量纲的：

Wolfram Language code: Eigenvalues[%]

IdentityMatrix[n] 的特征值全部是 1：

Wolfram Language code: Eigenvalues[IdentityMatrix[12]]

HilbertMatrix 的特征值：

Wolfram Language code: Eigenvalues[HilbertMatrix[3]]

CenteredInterval 矩阵的特征值：

Wolfram Language code: SeedRandom[777];(m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm

Wolfram Language code: vals = Eigenvalues[m]

求 m 的随机代表 mrep 的特征值：

Wolfram Language code:

ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"]
(mrep = Map[ranrep, m, {2}])//MatrixForm

Wolfram Language code: rvals = Eigenvalues[mrep]

验证重新排序后，vals 包含 rvals：

Wolfram Language code: MapThread[IntervalMemberQ, {vals, rvals[[{3, 1, 2}]]}]

选项 (11)

Cubics (1)

Eigenvalues 使用 Root 计算精确特征值：

Wolfram Language code: Eigenvalues[{{1, 2, 0}, {5, 1, 2}, {6, 7, 1}}]

显式使用立方公式以根式形式的结果：

Wolfram Language code: Eigenvalues[{{1, 2, 0}, {5, 1, 2}, {6, 7, 1}}, Cubics -> True]

Method (9)

"Arnoldi" (6)

Arnoldi 方法可用于机器和任意精度矩阵. Arnoldi 方法的实现基于 "ARPACK" 程序库. 它对于大型稀疏矩阵很有用.

方法 "Arnoldi"可以指定下列子选项：

	"BasisSize"	Arnoldi 基的大小
	"Criteria"	要使用的准则
	"MaxIterations"	最大迭代次数
	"Shift"	Arnoldi 位移量
	"StartingVector"	初始迭代向量
	"Tolerance"	用于终止迭代的容差

"Criteria" 的可能设置包括：

	"Magnitude"	基于 Abs
	"RealPart"	基于 Re
	"ImaginaryPart"	基于 Im
	"BothEnds"	实对称矩阵谱两端的少量特征值

使用不同的 "Criteria" 设置，计算最大特征向量. 矩阵 m 具有特征值 :

Wolfram Language code:

d = DiagonalMatrix[{1, 0.8 + 0.8I, I}];
t = {{1, 2, 0}, {0, 3, 2}, {1, 0, 4}};
m = t.d.Inverse[t];

默认情况下，"Criteria"->"Magnitude" 选择对应于最大幅度特征对：

Wolfram Language code: Eigenvalues[m, 1, Method -> "Arnoldi"]

求最大实部特征值：

Wolfram Language code: Eigenvalues[m, 1, Method -> {"Arnoldi", "Criteria" -> "RealPart"}]//Chop

求最大虚部特征值：

Wolfram Language code: Eigenvalues[m, 1, Method -> {"Arnoldi", "Criteria" -> "ImaginaryPart"}]//Chop

求来自对称矩阵谱两端的两个特征值：

Wolfram Language code:

d = DiagonalMatrix[{1, 0.8, -1, 2}];
t = Orthogonalize[{{1, 2, 0, 1}, {0, 3, 2, -2}, {1, 0, 4, -1}, {0, 1, 0, 1}}];
m = t.d.Transpose[t];

Wolfram Language code: Eigenvalues[m, 2, Method -> {"Arnoldi", "Criteria" -> "BothEnds"}]

使用 "StartingVector" 避免随机性：

Wolfram Language code:

d = DiagonalMatrix[{1, -1, 0.}];
t = {{1, 2, 0}, {0, 3, 2}, {1, 0, 4}};
m = t.d.Inverse[t];

不同的初始向量可能收敛到不同的特征值：

Wolfram Language code: Eigenvalues[m, 1, Method -> {"Arnoldi", "StartingVector" -> {1, 0, 0}}]

Wolfram Language code: Eigenvalues[m, 1, Method -> {"Arnoldi", "StartingVector" -> {0, 0, 1}}]

使用 "Shift"->μ 通过将矩阵变换为平移特征值. 这保持了特征向量，但是将特征值改变了 -μ. 方法对变化了的特征值进行补偿. "Shift" 通常用于求没有选择最大或者最小幅度的标准的特征对：

Wolfram Language code:

d = DiagonalMatrix[{1, 2, 3}];
t = {{1, 2, 0}, {0, 3, 2}, {1, 0, 4}};
m = N@t.d.Inverse[t];

Wolfram Language code: μ = 2.1;

手动平移矩阵，以调整所得的特征值：

Wolfram Language code: λl1 = Eigenvalues[m - μ IdentityMatrix[3], -1, Method -> "Arnoldi"]

Wolfram Language code: λl1 = λl1 + μ

自动平移，并且调整特征值：

Wolfram Language code: λl2 = Eigenvalues[m, -1, Method -> {"Arnoldi", "Shift" -> μ}]

用 Arnoldi 方法计算两个最小的广义特征值：

Wolfram Language code:

n = 10;
s = SparseArray[{{i_, i_} -> -2., {i_, j_} /; Abs[i - j] == 1 -> 1.}, {n, n}];
m = SparseArray[{{i_, i_} -> 1}, {n, n}];
Eigenvalues[{s, m}, -2, Method -> "Arnoldi"]

"Banded" (1)

带状方法可用于实对称或复厄米特机器精度矩阵. 该方法对于求出所有特征值最有用.

计算带状矩阵的两个最大的特征值：

Wolfram Language code: m = SparseArray[{{i_, i_} -> -2., {i_, j_} /; Abs[i - j] == 1 -> 1.}, {2000, 2000}];

Wolfram Language code: MatrixPlot[m]

Wolfram Language code: Eigenvalues[m, 2, Method -> "Banded"]

"FEAST" (2)

FEAST 方法可用于实对称或者复 Hermitian 机器精度矩阵. 方法对于在给定区间内求特征值很有用.

方法 "FEAST" 可以指定下列子选项：

	"ContourPoints"	选择轮廓点数
	"Interval"	特征值搜索区间
	"MaxIterations"	最大细化循环次数
	"NumberOfRestarts"	最大重启次数
	"SubspaceSize"	子空间的初始大小
	"Tolerance"	终止细化的容差
	"UseBandedSolver"	是否使用带状求解器

计算对应于来自区间的特征值的特征向量：

Wolfram Language code: s = SparseArray[{{i_, i_} -> -2., {i_, j_} /; Abs[i - j] == 1 -> 1.}, {1000, 1000}];

用 "Interval" 指定区间：

Wolfram Language code: Eigenvalues[s, Method -> {"FEAST", "Interval" -> {-1.0, -0.9}}]

FEAST 求特征值的区间不包括区间的端点.

Quartics (1)

4×4矩阵：

Wolfram Language code: m = Table[{1, 2, -1, -2} ^ j, {j, 4}]

一般来说，对于4×4矩阵，结果以 Root 对象的形式给出：

Wolfram Language code: Eigenvalues[m]

您可以使用 Cubics 和 Quartics 选项获取以根式表示的结果：

Wolfram Language code: Eigenvalues[m, Cubics -> True, Quartics -> True]

应用 (15)

特征值的几何学 (3)

当被矩阵作用时，具有正特征值的特征向量指向相同的方向：

Wolfram Language code:

m = {{1, 2}, {2, 1}};
{λ1, λ2} = Eigenvalues[m]

Wolfram Language code: {v1, v2} = Eigenvectors[m]

Wolfram Language code: Graphics[{{Thick, Arrow[{{0, 0}, v1}]}, {Red, Arrow[{{0, 0}, m.v1}]}}, Axes -> True]

当被矩阵作用时，具有负特征值的特征向量指向相反的方向：

Wolfram Language code: Graphics[{{Thick, Arrow[{{0, 0}, v2}]}, {Red, Arrow[{{0, 0}, m.v2}]}}, Axes -> True]

思考以下矩阵及其相关的二次形式：

Wolfram Language code: a = {{-2, 2}, {2, 1}};

Wolfram Language code: q = {x, y}.a.{x, y}//Expand

特征向量是由定义的双曲线的轴：

Wolfram Language code: v = Eigenvectors[a]

特征值的符号对应双曲线方程右侧的符号：

Wolfram Language code: λ = Eigenvalues[a]

Wolfram Language code:

ContourPlot[Table[q == n, {n, {-9, -4, -1, 1, 4, 9}}]//Evaluate, {x, -3, 3}, {y, -3, 3}, Epilog -> (Arrow[{{0, 0}, #}]& /@ v), PlotLegends -> "Expressions"]

这是三个维度中的正定二次形式：

Wolfram Language code: q = 20 x ^ 2 - 16 x y + 23 y ^ 2 - 12 x z - 2 y z + 17 z ^ 2;

绘制曲面：

Wolfram Language code: cp = ContourPlot3D[q, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Contours -> {10}, Mesh -> False, ContourStyle -> Opacity[.5]]

使用 CoefficientArrays 获得二次式的对称矩阵：

Wolfram Language code: m = Normal[CoefficientArrays[q, {x, y, z}, Symmetric -> True][[3]]]

数值计算其特征值和特征向量：

Wolfram Language code: {vals, vecs} = {Eigenvalues[N[m]], Eigenvectors[N[m]]}

显示椭圆体的主轴：

Wolfram Language code: Show[cp, Graphics3D[{Thickness[0.015], Green, Table[Line[{{0, 0, 0}, vecs[[i]] * Sqrt[10 / vals[[i]]]}], {i, 1, 3}]}]]

对角化 (4)

将以下矩阵对角化为 . 首先，计算的特征值：

Wolfram Language code: m = {{9, -7, 3}, {12, -10, 3}, {16, -16, 1}};

Wolfram Language code: Eigenvalues[m]

根据特征值构建对角矩阵：

Wolfram Language code: d = DiagonalMatrix[%]

接下来，计算的特征向量并将其放置于矩阵的列中：

Wolfram Language code: p = Transpose[Eigenvectors[m]]

验证恒等式：

Wolfram Language code: m == p.d.Inverse[p]

矩阵的任何函数可以形式计算. 例如，MatrixPower：

Wolfram Language code: MatrixPower[m, k] == p . MatrixPower[d, k].Inverse[p]

同样，只需要对的对角线元素求幂即可使 MatrixExp 变为平凡：

Wolfram Language code: MatrixExp[m] == p . MatrixExp[d].Inverse[p]

Wolfram Language code: MatrixExp[d]

令为其标准矩阵由矩阵给出的线性变换. 求 $TemplateBox[{}, Reals]^4$ 的基，其性质为在该基中的表示为对角线矩阵：

Wolfram Language code:

a = (|    |    |   |   |
| -- | -- | - | - |
| -6 | 4  | 0 | 9 |
| -3 | 0  | 1 | 6 |
| -1 | -2 | 1 | 0 |
| -4 | 4  | 0 | 7 |);

求的特征值：

Wolfram Language code: λ = Eigenvalues[a]

设由特征向量组成，设为矩阵，其列是的元素：

Wolfram Language code: b = Transpose[Eigenvectors[a]]

从坐标转换为标准坐标. 其逆矩阵变换为反方向：

Wolfram Language code: bInv = Inverse[b]

因此由给出，为对角线矩阵：

Wolfram Language code: bInv . a .b//MatrixForm

请注意这只是对角矩阵，其项为特征值：

Wolfram Language code: % == DiagonalMatrix[λ]

实值对称矩阵可正交对角化为，其中为实对角矩阵且为正交矩阵. 验证以下矩阵是否对称，并进行对角化：

Wolfram Language code: (s = {{1, 4, -2}, {4, 5, -3}, {-2, -3, 2}})//MatrixForm

Wolfram Language code: Transpose[s] == s

计算特征值，结果如预期所想是实数：

Wolfram Language code: λ = Eigenvalues[s]

矩阵在对角线上具有特征值：

Wolfram Language code: d = DiagonalMatrix[λ]

接下来，计算的特征向量：

Wolfram Language code: v = Eigenvectors[s]

对于正交矩阵，需要在将特征向量放入列之前正规化：

Wolfram Language code: o = Transpose[FullSimplify[Normalize /@ v]]

验证：

Wolfram Language code: s == o.d.Transpose[o]//FullSimplify

如果，则矩阵称为正规矩阵. 正规矩阵是可以通过酉变换进行对角化的最通用的矩阵类型. 所有实对称矩阵都是正规矩阵，因为等式的两边都仅为：

Wolfram Language code:

TensorExpand[ConjugateTranspose[s].s == s.ConjugateTranspose[s] == s.s, Assumptions -> s∈Matrices[{n, n}, Reals, Symmetric[{1, 2}]]]

证明下面的矩阵是正规矩阵，并对其对角化：

Wolfram Language code: (n = {{3, -1}, {1, 3}})//MatrixForm

Wolfram Language code: n.ConjugateTranspose[n] == ConjugateTranspose[n].n

使用 NormalMatrixQ 进行验证：

Wolfram Language code: NormalMatrixQ[n]

非对称实正规矩阵的特征值是复值：

Wolfram Language code: λ = Eigenvalues[n]

根据特征值构造对角矩阵：

Wolfram Language code: (d = DiagonalMatrix[λ])//MatrixForm

计算特征向量：

Wolfram Language code: v = Eigenvectors[n]

对特征向量进行正规化并将其放置于列中会得到酉矩阵：

Wolfram Language code:

u = Transpose[Normalize /@ v];
UnitaryMatrixQ[u]

验证对角化：

Wolfram Language code: n == u.d.ConjugateTranspose[u]

微分方程和动力系统 (4)

求解常微分方程 (ODE) 方程组 , , . 首先，构造右侧的系数矩阵：

Wolfram Language code: a = {{0, 1, 0}, {0, 0, 1}, {-2, 1, 2}};

求特征值和特征向量：

Wolfram Language code: {λ, v} = {Eigenvalues[a], Eigenvectors[a]}

构造一个对角矩阵，其项是的指数：

Wolfram Language code: d = DiagonalMatrix[Exp[t λ]]

构造其列是对应特征向量的矩阵：

Wolfram Language code: p = Transpose[v]

三个任意起始值的通解为：

Wolfram Language code: p.d.Inverse[p] . {C[1], C[2], C[3]}

使用 DSolveValue 验证解：

Wolfram Language code: Simplify[% == DSolveValue[{x'[t] == y[t], y'[t] == z[t], z'[t] == -2x[t] + y[t] + 2z[t]}, {x[t], y[t], z[t]}, t]]

假设一个粒子在平面力场中运动，其位置向量满足且，其中和为如下. 当时求解初始问题：

Wolfram Language code:

a = (|    |    |
| -- | -- |
| 4  | -5 |
| -2 | 1  |);

Wolfram Language code:

Subscript[x, 0] = (⁠|     |
| --- |
| 1.9 |
| 3.6 |⁠);

首先，计算的特征值和对应的特征向量：

Wolfram Language code: λ = Eigenvalues[a]

Wolfram Language code: v = Eigenvectors[a]

方程组的通解为 . 使用 LinearSolve 确定系数：

Wolfram Language code: c = LinearSolve[Transpose[v], Subscript[x, 0]]

为特征向量构建线性组合：

Wolfram Language code: x[t_] = (c Exp[λ t]).v

使用 DSolveValue 验证该解：

Wolfram Language code:

x[t] == DSolveValue[{{u1'[t], u2'[t]} == a.{u1[t], u2[t]}, {u1[0], u2[0]} == Subscript[x, 0]}, {u1[t], u2[t]}, t] //Simplify//Chop

当是以下随机矩阵时，计算动力系统的通解：

Wolfram Language code:

a = (|     |     |     |
| --- | --- | --- |
| .90 | .01 | .09 |
| .01 | .90 | .01 |
| .09 | .09 | .90 |);

求特征值和特征向量，使用 Chop 丢弃小数值误差：

Wolfram Language code:

{{Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}, {Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]}} = Chop[{Eigenvalues[a], Eigenvectors[a]}]

通解是形式为的项的任意线性组合：

Wolfram Language code: x[k_] = Sum[C[i] Subsuperscript[λ, i, k]Subscript[v, i], {i, 3}]

验证在数值舍入完成之前满足动力学方程：

Wolfram Language code: x[k] == a.x[k - 1]//Simplify//Chop

Lorenz 方程：

Wolfram Language code:

leqn = {Derivative[1][x][t] == -3(x[t] - y[t]), Derivative[1][y][t] == -x[t] z[t] + 26 x[t] - y[t], Derivative[1][z][t] == x[t] y[t] - z[t]};

求方程右边的雅可比行列式：

Wolfram Language code: lj = D[leqn[[All, 2]], {{x[t], y[t], z[t]}}]

求出平衡点：

Wolfram Language code: eqp = Solve[leqn /. {x'[t] -> 0, y'[t] -> 0, z'[t] -> 0}, {x[t], y[t], z[t]}]

在第一个八分圆处求雅可比行列式的特征值和特征向量：

Wolfram Language code: vals = Eigenvalues[N[lj /. eqp[[3]]]]

Wolfram Language code: vecs = Eigenvectors[N[lj /. eqp[[3]]]]

沿 dir 方向上、 pt 中的向后小干扰积分函数：

Wolfram Language code:

st[pt_, dir_] := First[{x[t], y[t], z[t]} /. NDSolve[{leqn, Thread[{x[0], y[0], z[0]} == pt + 10^-6dir]}, {x, y, z}, {t, 0, -4}]];

显示右侧平衡点的稳定曲线：

Wolfram Language code:

pt = {x[t], y[t], z[t]} /. eqp[[3]];dir = vecs[[3]];sr = ParametricPlot3D[Evaluate[{st[pt, dir], st[pt, -dir]}], {t, 0, -4}, PlotStyle -> Table[{Thickness[0.015], Red}, {2}]]

求出左侧平衡点的稳定曲线：

Wolfram Language code:

pt = {x[t], y[t], z[t]} /. eqp[[2]];{vals, vecs} = Eigensystem[N[lj /. eqp[[2]]]];
dir = vecs[[3]];sl = ParametricPlot3D[Evaluate[{st[pt, dir], st[pt, -dir]}], {t, 0, -4}, PlotStyle -> Table[{Thickness[0.015], Green}, {2}]];

显示带有 Lorenz 方程解的稳定曲线：

Wolfram Language code:

Show[{ParametricPlot3D[Evaluate[{x[t], y[t], z[t]} /. NDSolve[{leqn, x[0] == 5, y[0] == 0, z[0] == 25}, {x, y, z}, {t, 0, 100}]], {t, 0, 100}], sr, sl}, PlotRange -> {{-25, 25}, {-25, 25}, {0, 50}}]

物理 (4)

在量子力学中，状态由复单位向量表示，物理量由厄米特线性算子表示. 特征值表示可能的观测值，关于特征向量的分量的模的平方表示这些观测值的概率. 对于给定的自旋算子和状态，找出可能的观测值及其概率：

Wolfram Language code:

σ = (ℏ/2)(|   |    |
| - | -- |
| 0 | -I |
| I | 0  |);ψ = (1/Sqrt[5])(⁠|     |
| --- |
| 1   |
| 2 I |⁠);

计算特征值，可能的观测值为 :

Wolfram Language code: Eigenvalues[σ]

找到特征向量并正规化以计算正确投影：

Wolfram Language code: {e1, e2} = Normalize /@ Eigenvectors[σ]

的相对概率为，的为：

Wolfram Language code: {Abs[e1.ψ]^2, Abs[e2.ψ]^2}//Simplify

在量子力学中，能量算子称为哈密顿量，根据薛定谔方程具有能量的状态. 给定方向上恒定磁场中自旋 1 粒子的哈密顿量，求处于初始状态表示表示的粒子在时间的状态：

Wolfram Language code:

ℋ = (Subscript[ω, 0]ℏ/Sqrt[2]) (|   |    |    |
| - | -- | -- |
| 0 | -I | 0  |
| I | 0  | -I |
| 0 | I  | 0  |);Subscript[ψ, 0] = {1, 0, 0};

计算特征值，能级为和：

Wolfram Language code: {Subscript[ℰ, 1], Subscript[ℰ, 2], Subscript[ℰ, 3]} = Eigenvalues[ℋ]

求得并正规化特征向量：

Wolfram Language code: {Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]} = Normalize /@ Eigenvectors[ℋ]

时间的状态是根据薛定谔方程演化的每个特征态的总和：

Wolfram Language code:

ψ[t_] = Underoverscript[∑, i = 1, 3]Exp[-(I Subscript[ℰ, i]t/ℏ)]Subscript[e, i].Subscript[ψ, 0] Subscript[e, i] //FullSimplify

惯性矩是一个实对称矩阵，描述了刚体对不同方向旋转的阻力. 该矩阵的特征值称为主惯性矩，相应的特征向量（必须正交）称为主轴. 求下列四面体的主惯性矩和主轴：

Wolfram Language code: tet = Tetrahedron[{{-1.25, -1, -0.75}, {3.75, -1, -0.75}, {-1.25, 3., -0.75}, {-1.25, -1, 2.25}}]

首先计算惯性矩：

Wolfram Language code: (ℐ = MomentOfInertia[tet])//MatrixForm

主矩是的特征值：

Wolfram Language code: Eigenvalues[ℐ]

主轴为的特征向量：

Wolfram Language code: a = Eigenvectors[ℐ]

验证轴为正交：

Wolfram Language code: a.a//Chop

四面体的质心在原点：

Wolfram Language code: RegionCentroid[tet]

可视化四面体及其主轴：

Wolfram Language code: Graphics3D[{{Opacity[.5], tet}, Arrow[{{0, 0, 0}, 3#}]& /@ a}]

广义特征系统可用于找到解耦项的耦合振荡的正规模. 思考图中所示的系统：

根据胡克定律，该系统服从 , . 代入通解得到矩阵方程，其中刚度矩阵和质量矩阵为如下：

Wolfram Language code:

k = {{k1 + k2, -k2}, {-k2, k2}};
m = {{m1, 0}, {0, m2}};

如果 , , 且，求特征频率和正规模：

Wolfram Language code:

k = k /. {k1 -> 9.5, k2 -> 4.5};
m = m /. {m1 -> 2, m2 -> 3};

计算关于的广义特征值：

Wolfram Language code: λ = Eigenvalues[{k, m}]

特征频率是特征值的平方根：

Wolfram Language code: {ω1, ω2} = Sqrt[λ]

可从广义特征向量推导出模的形状：

Wolfram Language code: v = Eigenvectors[{k, m}]

将正规模解构造为广义特征向量乘以相应指数：

Wolfram Language code: sol1[t_] = First[v]Exp[I ω1 t];

Wolfram Language code: sol2[t_] = Last[v]Exp[I ω2 t];

验证两者是否满足系统的微分方程：

Wolfram Language code: -k.sol1[t] == m.sol1''[t] && -k.sol2[t] == m.sol2''[t]//FullSimplify

属性和关系 (15)

Eigenvalues[m] 实际上是 Eigensystem 返回配对的第一个元素：

Wolfram Language code:

m = RandomReal[1, {3, 3}];
Eigenvalues[m] == First[Eigensystem[m]]

如果同时需要特征向量和特征值，仅调用 Eigensystem 通常会更有效：

Wolfram Language code: m = RandomReal[1, {1000, 1000}];

Wolfram Language code: AbsoluteTiming[Eigensystem[m];]

Wolfram Language code: AbsoluteTiming[{Eigenvalues[m], Eigenvectors[m]};]

特征值是特征多项式的根：

Wolfram Language code: Eigenvalues[{{a, b}, {c, d}}]

使用 CharacteristicPolynomial 计算多项式：

Wolfram Language code: CharacteristicPolynomial[{{a, b}, {c, d}}, x]

验证是否相等：

Wolfram Language code: SolveValues[% == 0, x]

广义特征多项式由给出:

Wolfram Language code:

a = {{1, 2}, {3, 2}};
b = {{1, 1}, {1, 1}};

Wolfram Language code: {CharacteristicPolynomial[{a, b}, λ], Det[a - λ b]}

广义特征多项式只定义了有限特征值：

Wolfram Language code: Eigenvalues[{a, b}]

Wolfram Language code: SolveValues[CharacteristicPolynomial[{a, b}, λ] == 0, λ]

无限广义特征值对应于的特征向量，其中：

Wolfram Language code: Eigenvectors[a]

Wolfram Language code: b.{-1, 1}

m 的特征值的乘积等于 Det[m]：

Wolfram Language code:

m = RandomInteger[{-10, 10}, {4, 4}];
Times @@ Eigenvalues[m] == Det[m]//Simplify

m 的特征值之和等于 Tr[m]：

Wolfram Language code:

m = RandomReal[1, {4, 4}];
Total[Eigenvalues[m]] == Tr[m]

如果所有特征值不同，则 DiagonalizableMatrixQ[m] 给出 True：

Wolfram Language code:

m1 = {{0, -1, -1}, {1, 1, -1}, {-1, 0, -1}};
{Eigenvalues[m1], DiagonalizableMatrixQ[m1]}

反之为假：

Wolfram Language code:

m2 = IdentityMatrix[3];
{Eigenvalues[m2], DiagonalizableMatrixQ[m2]}

对于可逆矩阵，的特征值是的特征值的倒数：

Wolfram Language code:

m = {{0, 3, 7}, {0, -3, 1}, {-4, 2, -8}};
Eigenvalues[Inverse[m]]

因为 Eigenvalues 按绝对值排序，所以会给出相同的值但相反的顺序：

Wolfram Language code: (1/Eigenvalues[m])//FullSimplify

对于解析函数，将应用于的特征值即会得到的特征值：

Wolfram Language code:

m = {{1, 1, 0}, {-1, 1, 0}, {0, 0, 5}};
λ = Eigenvalues[m]

例如，的特征值为：

Wolfram Language code: Eigenvalues[m.m] == λ^2

同样，的特征值为：

Wolfram Language code: Eigenvalues[MatrixExp[m]] == Exp[λ]//FullSimplify

实对称矩阵的特征值是实数：

Wolfram Language code: (s = {{1, 4, -2}, {4, 0, -3}, {-2, -3, 2}})//MatrixForm

Wolfram Language code: SymmetricMatrixQ[s]

Wolfram Language code: Eigenvalues[s]

任何埃尔米特矩阵的特征值也是如此：

Wolfram Language code: (h = {{0, -I}, {I, 0}})//MatrixForm

Wolfram Language code: HermitianMatrixQ[h]

Wolfram Language code: Eigenvalues[h]

实反对称矩阵的特征值是虚数：

Wolfram Language code: (a = {{0, 4, -2}, {-4, 0, -3}, {2, 3, 0}})//MatrixForm

Wolfram Language code: AntisymmetricMatrixQ[a]

Wolfram Language code: Eigenvalues[a]

任何反埃尔米特矩阵的特征值也是如此：

Wolfram Language code: (ah = {{0, I}, {I, 0}})//MatrixForm

Wolfram Language code: AntihermitianMatrixQ[ah]

Wolfram Language code: Eigenvalues[ah]

正交矩阵的特征值位于单位圆上：

Wolfram Language code:

o = {{(1/3) (1 + Sqrt[3]), (1/3) (1 - Sqrt[3]), (1/3)}, {(1/3), (1/3) (1 + Sqrt[3]), (1/3) (1 - Sqrt[3])}, {(1/3) (1 - Sqrt[3]), (1/3), (1/3) (1 + Sqrt[3])}};

Wolfram Language code: OrthogonalMatrixQ[o]

Wolfram Language code: Eigenvalues[o]

Wolfram Language code: Abs[%]

任何酉矩阵的特征值也是如此：

Wolfram Language code: u = {{(1/Sqrt[2]), (I/Sqrt[2])}, {(I/Sqrt[2]), (1/Sqrt[2])}};

Wolfram Language code: UnitaryMatrixQ[u]

Wolfram Language code: Eigenvalues[u]

Wolfram Language code: Abs[%]

SingularValueList[m] 等于非零特征值的平方根：

Wolfram Language code: m = {{-52, 0, -50, -61}, {17, 54, -43, 73}, {-86, -108, 36, -207}};

Wolfram Language code: s = SingularValueList[m]

Wolfram Language code: λ = Eigenvalues[m . ConjugateTranspose[m]]

Wolfram Language code: s == Sqrt[Most[λ]]

思考一个具有一组完整特征向量的矩阵：

Wolfram Language code:

m = {{-(1/Sqrt[2]), -(1/Sqrt[2])}, {(1/Sqrt[2]), -(1/Sqrt[2])}};
DiagonalizableMatrixQ[m]

JordanDecomposition[m] 返回由特征值和特征向量构建的矩阵：

Wolfram Language code: {s, j} = JordanDecomposition[m]

矩阵是具有特征值项的对角矩阵，但可能与 Eigensystem 的顺序不同：

Wolfram Language code: j == DiagonalMatrix[Reverse[Eigenvalues[m]]]

对于数值正规矩阵，SchurDecomposition[n,RealBlockDiagonalFormFalse]：

Wolfram Language code:

n = {{1., 3., -1.}, {-1., 1., 3.}, {3., -1., 1.}};
NormalMatrixQ[n]

Wolfram Language code: {q, t} = SchurDecomposition[n, RealBlockDiagonalForm -> False]//Chop

t 矩阵是有特征值项的对角矩阵，可能与 Eigensystem 的顺序不同：

Wolfram Language code: t == DiagonalMatrix[Eigenvalues[n]]

如果矩阵共用维度为的零空间，则其广义特征值的为 Indeterminate：

Wolfram Language code:

a = {{1, 1, 1}, {1, 1, 1}, {1, 1, 1}};b = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};
NullSpace[a]

关于自身的两个广义特征值为 Indeterminate：

Wolfram Language code: Eigenvalues[{a, a}]

矩阵有一维零空间：

Wolfram Language code: NullSpace[b]

其位于的零空间中：

Wolfram Language code: MatrixRank[Join[NullSpace[a], NullSpace[b]]]

因此，关于的广义特征值为 Indeterminate：

Wolfram Language code: Eigenvalues[{a, b}]

可能存在的问题 (5)

Eigenvalues 和 Eigenvectors 不能保证绝对按相应顺序给出结果：

Wolfram Language code:

mat = N@AdjacencyMatrix@GraphData["DodecahedralGraph"];
vec7 = Eigenvectors[mat][[7]];
{val6, val7} = Eigenvalues[mat][[{6, 7}]];

第六个和第七个特征值基本上相等但正负相反：

Wolfram Language code: val6 + val7//Chop

在此特定情况下，第七个特征向量不对应于第七个特征值：

Wolfram Language code: Norm[mat.vec7 - val7 vec7]

它对应的是第六个特征值：

Wolfram Language code: Norm[mat.vec7 - val6 vec7]//Chop

用 Eigensystem[mat] 确保相应的结果始终匹配：

Wolfram Language code:

{val, vec} = Eigensystem[mat][[All, 7]];
Norm[mat.vec - val vec]//Chop

符号的例子，迅速得到很复杂的解：

Wolfram Language code: Array[a, {2, 2}]

Wolfram Language code: Eigenvalues[Array[a, {2, 2}]]

表达式个数呈指数级增长：

Wolfram Language code: Table[ByteCount[Eigenvalues[Array[a, {n, n}]]], {n, 4}]

20×20 的 Hilbert 矩阵：

Wolfram Language code: m = Table[1 / (i + j + 1), {i, 20}, {j, 20}];

计算最小特征值的数值解：

Wolfram Language code: N[Eigenvalues[m, -1]]

以机器精度计算最小特征值：

Wolfram Language code: Eigenvalues[N[m], -1]

最小和最大特征值间无关联：

Wolfram Language code: (Eigenvalues[N[m], 1] + Eigenvalues[N[m], -1]) - Eigenvalues[N[m], 1]

足够的数值计算精度：

Wolfram Language code: Eigenvalues[N[m, 30], -1]

当特征值紧密分组时，稀疏矩阵的迭代方法不收敛：

Wolfram Language code: s = SparseArray[{{x_, y_} /; Abs[x - y] ≤ 1 -> 3. Abs[x - y] - 2.}, {1000, 1000}];

迭代在1000次后没有收敛：

Wolfram Language code: vals = Eigenvalues[s, 3];

您可以对算法平移到期望值，以加速收敛：

Wolfram Language code: vals = Eigenvalues[s, 3, Method -> {"Arnoldi", Shift -> -4}]

不包括为 FEAST 方法指定的区间的端点. 设置一个特征值为 3 和 9 的矩阵：

Wolfram Language code: ck = With[{n = 24}, N[SparseArray[{{i_, j_} /; Abs[i - j] == 1 :> With[{k = Min[i, j]}, Sqrt[k (n - k)]]}, {n, n}]]];

在区间内求特征值不能返回端点处的值：

Wolfram Language code: Eigenvalues[ck, Method -> {"FEAST", "Interval" -> {3., 9.}}]

将区间扩大至，FEAST 即可找到特征值 3 和 9：

Wolfram Language code: Eigenvalues[ck, Method -> {"FEAST", "Interval" -> {2.9, 9.1}}]

Top

	"Arnoldi"	Arnoldi 迭代方法，以求解一些特征值
	"Banded"	厄米特矩阵的带状矩阵直接求解器 (direct banded matrix solver)
	"Direct"	求解所有特征值的直接方法
	"FEAST"	FEAST 迭代方法，以求解某区间内的特征值（只应用于 Hermitian 矩阵）

Cubics	False	是否使用根式求解三次曲线
Method	Automatic	选择使用的方法
Quartics	False	是否使用根式求解四次曲线

Eigenvalues

更多信息和选项

范例

基本范例 (5)

范围 (20)

基本用法 (6)

特征值的子集 (5)

广义的特征值 (4)

特殊矩阵 (5)

选项 (11)

Cubics (1)

Method (9)

"Arnoldi" (6)

"Banded" (1)

"FEAST" (2)

Quartics (1)

应用 (15)

特征值的几何学 (3)

对角化 (4)

微分方程和动力系统 (4)

物理 (4)

属性和关系 (15)

可能存在的问题 (5)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX