WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FeatureValueImpactPlot[model,data]

data 中の与えられた特徴の値の model の結果に対するインパクトをプロットする．

FeatureValueImpactPlot[model]

合成データを使って特徴値のインパクトを推定する．

FeatureValueImpactPlot[modelfname,…]

指定された特徴 fname のインパクトだけをプロットする．

FeatureValueImpactPlot[modelfnameclass,…]

分類 class に対するインパクトだけをプロットする．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
AspectRatio  
AxesLabel  
AxesStyle  
Show More Show More
Frame  
FrameLabel  
Filling  
MaxPlotPoints  
PlotLabel  
PlotLegends  
PlotStyle  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

FeatureValueImpactPlot

FeatureValueImpactPlot[model,data]

data 中の与えられた特徴の値の model の結果に対するインパクトをプロットする．

FeatureValueImpactPlot[model]

合成データを使って特徴値のインパクトを推定する．

FeatureValueImpactPlot[modelfname,…]

指定された特徴 fname のインパクトだけをプロットする．

FeatureValueImpactPlot[modelfnameclass,…]

分類 class に対するインパクトだけをプロットする．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

線形回帰をサンプルのデータ集合について訓練する：

Wolfram Language code: trainingset = Table[x -> 2x - 1, {x, 10}]
Wolfram Language code: predictor = Predict[trainingset, Method -> "LinearRegression"]

モデルの結果の平均に対する入力の特徴のインパクトを可視化する：

Wolfram Language code: FeatureValueImpactPlot[predictor, Range[10]]

平均と予測の間の数値偏差とプロットを比較する：

Wolfram Language code: predictor[Range[10]] - Information[predictor, "TrainingLabelMean"]

植物のいくつかの特徴から「アヤメ」の種を識別するように分類器を訓練する：

Wolfram Language code: data = ResourceData["Sample Data: Fisher's Irises"]; First[data]
Wolfram Language code: model = Classify[data -> "Species", Method -> "LogisticRegression"]

特徴の値が各クラスの確率にどのように影響するかを可視化する：

Wolfram Language code: FeatureValueImpactPlot[model -> "PetalLength", data]

スコープ  (4)

予測に対する累積的インパクトを可視化する：

Wolfram Language code: model = Predict[{{1.3, "P"} -> 1, {1.8, "Q"} -> 2.5, {1.9, "Q"} -> 3, {0.2, "P"} -> 1, {-3.2, "P"} -> -4.2, {0.3, "Q"} -> 2}]
Wolfram Language code: FeatureValueImpactPlot[model, {{1.3, "P"}, {1.8, "Q"}, {1.9, "Q"}, {0.2, "P"}, {-3.2, "P"}, {0.3, "Q"}}]

分類に対する累積的インパクトを可視化する：

Wolfram Language code: model = Classify[{{1.5, Blue} -> "A", {3.2, Blue} -> "A", {4.1, Red} -> "B", {5.3, Red} -> "B", {10., Green} -> "C", {12.4, Red} -> "C"}]
Wolfram Language code: FeatureValueImpactPlot[model, {{1.5, Blue}, {3.2, Blue}, {4.1, Red}, {5.3, Red}, {10., Green}, {12.4, Red}}]

合成データを使ってインパクトを計算する：

Wolfram Language code: model = Predict[{{1.3, "P"} -> 1, {1.8, "Q"} -> 2.5, {1.9, "Q"} -> 3, {0.2, "P"} -> 1, {-3.2, "P"} -> -4.2, {0.3, "Q"} -> 2}]
Wolfram Language code: FeatureValueImpactPlot[model, {{1.3, "P"}, {1.8, "Q"}, {1.9, "Q"}, {0.2, "P"}, {-3.2, "P"}, {0.3, "Q"}}]

特定の分類に対するインパクトを可視化する：

Wolfram Language code: model = Classify[{{1.5, Blue} -> "A", {3.2, Blue} -> "A", {4.1, Red} -> "B", {5.3, Red} -> "B", {10., Green} -> "C", {12.4, Red} -> "C"}]
Wolfram Language code: FeatureValueImpactPlot[model -> All -> "A", {{1.5, Blue}, {3.2, Blue}, {4.1, Red}, {5.3, Red}, {10., Green}, {12.4, Red}}]

クラスのリストに対するインパクトを可視化する：

Wolfram Language code: FeatureValueImpactPlot[model -> All -> {"A", "C"}, {{1.5, Blue}, {3.2, Blue}, {4.1, Red}, {5.3, Red}, {10., Green}, {12.4, Red}}]

オプション  (12)

AspectRatio  (1)

実際のプロット値から縦横比を選択する：

Wolfram Language code: {FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]]], FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], AspectRatio -> Automatic]}

AxesLabel  (1)

各軸のラベルを指定する：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], AxesLabel -> {x, impact}]

AxesStyle  (1)

軸のスタイルを変更する：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], AxesStyle -> Red]

Frame  (2)

プロットの周りに枠を描く：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True]

左と右の辺に枠を描く：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> {{True, True}, {False, False}}]

FrameLabel  (2)

プロットの下の辺に沿ってラベルを置く：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True, FrameLabel -> {"x"}]

枠の各辺にラベルを置く：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True, FrameLabel -> {{"left", "right"}, {"bottom", "top"}}]

Filling  (1)

「幹」の塗潰しに記号的または明示的な値を使う：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True, Filling -> Axis]
Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True, Filling -> Pi]

MaxPlotPoints  (1)

デフォルトで，すべてのデータ点が使われる：

Wolfram Language code: predictor = Predict[Table[x -> 2 - x, {x, 10}]];
Wolfram Language code: FeatureValueImpactPlot[predictor]

20個の点だけをプロットに使う：

Wolfram Language code: FeatureValueImpactPlot[predictor, MaxPlotPoints -> 20]

PlotLabel  (1)

デフォルトで，プロットにはラベルが付けられる：

Wolfram Language code: predictor = Predict[Catenate@Table[{x, y} -> y ^ 2 - x, {x, 10}, {y, 10}]];
Wolfram Language code: FeatureValueImpactPlot[predictor]

ラベルが付けられないようにする：

Wolfram Language code: FeatureValueImpactPlot[predictor, PlotLabel -> None]

PlotLegends  (1)

デフォルトで，出力クラスに基づいた凡例が使われる：

Wolfram Language code: data = {{1.5, Blue} -> "A", {3.2, Blue} -> "A", {4.1, Red} -> "B", {5.3, Red} -> "B", {10., Green} -> "C", {12.4, Red} -> "C"};classifier = Classify[data]
Wolfram Language code: FeatureValueImpactPlot[classifier, Keys@data]

凡例は使わない：

Wolfram Language code: FeatureValueImpactPlot[classifier, Keys@data, PlotLegends -> None]

プレースホルダテキストがある凡例を作成する：

Wolfram Language code: FeatureValueImpactPlot[classifier, Keys@data, PlotLegends -> "Placeholder"]

特定のラベルがある凡例を作成する：

Wolfram Language code: FeatureValueImpactPlot[classifier, Keys@data, PlotLegends -> {"Class: A", "Class: B", "Class: C"}]

PlotStyle  (1)

デフォルトで，複数の曲線がある場合はそれぞれに異なったスタイルが選択される：

Wolfram Language code: classifier = Classify[Table[x -> If[x < 5, "A", "B"], {x, 0, 10, .1}]];
Wolfram Language code: FeatureValueImpactPlot[classifier]

異なる曲線に明示的なスタイルを指定する：

Wolfram Language code: FeatureValueImpactPlot[classifier, PlotStyle -> {Red, Blue}]

アプリケーション  (1)

特徴のバリエーションがさまざまなモデルに与える影響を分析する：

Wolfram Language code: trainingset = Flatten@Table[{x, y} -> x * y - 5y, {x, 10}, {y, 10}]; Short[trainingset]

2つの特徴の非線形結合によって与えられる値を予測するように線形モデルを訓練する：

Wolfram Language code: predictor = Predict[trainingset, Method -> "LinearRegression"]

期待されるように，各特徴のインパクトはその特徴の値のみに依存する：

Wolfram Language code: FeatureValueImpactPlot[predictor, trainingset[[All, 1]], PlotStyle -> PointSize@Medium]

同じデータについて非線形モデルを訓練する：

Wolfram Language code: predictor2 = Predict[trainingset, Method -> "GradientBoostedTrees"]

これで，例の中の他の特徴によって同じ特徴値が異なるインパクトを持てるようになった：

Wolfram Language code: FeatureValueImpactPlot[predictor2, trainingset[[All, 1]], PlotStyle -> PointSize@Medium]
Wolfram Research (2022), FeatureValueImpactPlot, Wolfram言語関数， https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html.

テキスト

Wolfram Research (2022), FeatureValueImpactPlot, Wolfram言語関数， https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html.

CMS

Wolfram Language. 2022. "FeatureValueImpactPlot." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html.

APA

Wolfram Language. (2022). FeatureValueImpactPlot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html

BibTeX

@misc{reference.wolfram_2026_featurevalueimpactplot, author="Wolfram Research", title="{FeatureValueImpactPlot}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html}", note=[Accessed: 06-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_featurevalueimpactplot, organization={Wolfram Research}, title={FeatureValueImpactPlot}, year={2022}, url={https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html}, note=[Accessed: 06-July-2026]}