WOLFRAM

Wolfram 语言与系统参考资料中心

FeatureValueImpactPlot[model,data]

绘制 data 中给定特征的值对 model 结果的影响.

FeatureValueImpactPlot[model]

使用合成数据估计特征值的影响.

FeatureValueImpactPlot[modelfname,…]

只绘制指定特征 fname 的影响.

FeatureValueImpactPlot[modelfnameclass,…]

只绘制对分类 class 的影响.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
AspectRatio  
AxesLabel  
AxesStyle  
Show More Show More
Frame  
FrameLabel  
Filling  
MaxPlotPoints  
PlotLabel  
PlotLegends  
PlotStyle  
应用  
参见
相关指南
历史
按以下格式引用：

FeatureValueImpactPlot

FeatureValueImpactPlot[model,data]

绘制 data 中给定特征的值对 model 结果的影响.

FeatureValueImpactPlot[model]

使用合成数据估计特征值的影响.

FeatureValueImpactPlot[modelfname,…]

只绘制指定特征 fname 的影响.

FeatureValueImpactPlot[modelfnameclass,…]

只绘制对分类 class 的影响.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

在样本数据集上训练线性回归：

Wolfram Language code: trainingset = Table[x -> 2x - 1, {x, 10}]
Wolfram Language code: predictor = Predict[trainingset, Method -> "LinearRegression"]

可视化输入特征对平均模型结果的影响：

Wolfram Language code: FeatureValueImpactPlot[predictor, Range[10]]

将绘图与平均值和预测之间的数值偏差进行比较：

Wolfram Language code: predictor[Range[10]] - Information[predictor, "TrainingLabelMean"]

训练分类器从植物的某些特征中识别鸢尾属植物：

Wolfram Language code: data = ResourceData["Sample Data: Fisher's Irises"]; First[data]
Wolfram Language code: model = Classify[data -> "Species", Method -> "LogisticRegression"]

可视化特征值如何影响每个类别的几率

Wolfram Language code: FeatureValueImpactPlot[model -> "PetalLength", data]

范围  (4)

可视化对预测的累积影响：

Wolfram Language code: model = Predict[{{1.3, "P"} -> 1, {1.8, "Q"} -> 2.5, {1.9, "Q"} -> 3, {0.2, "P"} -> 1, {-3.2, "P"} -> -4.2, {0.3, "Q"} -> 2}]
Wolfram Language code: FeatureValueImpactPlot[model, {{1.3, "P"}, {1.8, "Q"}, {1.9, "Q"}, {0.2, "P"}, {-3.2, "P"}, {0.3, "Q"}}]

可视化对分类的累积影响：

Wolfram Language code: model = Classify[{{1.5, Blue} -> "A", {3.2, Blue} -> "A", {4.1, Red} -> "B", {5.3, Red} -> "B", {10., Green} -> "C", {12.4, Red} -> "C"}]
Wolfram Language code: FeatureValueImpactPlot[model, {{1.5, Blue}, {3.2, Blue}, {4.1, Red}, {5.3, Red}, {10., Green}, {12.4, Red}}]

用合成数据计算影响：

Wolfram Language code: model = Predict[{{1.3, "P"} -> 1, {1.8, "Q"} -> 2.5, {1.9, "Q"} -> 3, {0.2, "P"} -> 1, {-3.2, "P"} -> -4.2, {0.3, "Q"} -> 2}]
Wolfram Language code: FeatureValueImpactPlot[model, {{1.3, "P"}, {1.8, "Q"}, {1.9, "Q"}, {0.2, "P"}, {-3.2, "P"}, {0.3, "Q"}}]

可视化对特定分类的影响：

Wolfram Language code: model = Classify[{{1.5, Blue} -> "A", {3.2, Blue} -> "A", {4.1, Red} -> "B", {5.3, Red} -> "B", {10., Green} -> "C", {12.4, Red} -> "C"}]
Wolfram Language code: FeatureValueImpactPlot[model -> All -> "A", {{1.5, Blue}, {3.2, Blue}, {4.1, Red}, {5.3, Red}, {10., Green}, {12.4, Red}}]

可视化对一组类别的影响：

Wolfram Language code: FeatureValueImpactPlot[model -> All -> {"A", "C"}, {{1.5, Blue}, {3.2, Blue}, {4.1, Red}, {5.3, Red}, {10., Green}, {12.4, Red}}]

选项  (12)

AspectRatio  (1)

根据实际绘图选择高宽比：

Wolfram Language code: {FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]]], FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], AspectRatio -> Automatic]}

AxesLabel  (1)

指定每个轴的标签：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], AxesLabel -> {x, impact}]

AxesStyle  (1)

改变坐标轴的样式：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], AxesStyle -> Red]

Frame  (2)

在绘图周围绘制边框：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True]

在左侧和右侧绘制边框：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> {{True, True}, {False, False}}]

FrameLabel  (2)

在绘图的底部边框上放置标签：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True, FrameLabel -> {"x"}]

在每个边上都放置标签：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True, FrameLabel -> {{"left", "right"}, {"bottom", "top"}}]

Filling  (1)

在 "stem" 填充时使用符号或明确的值：

Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True, Filling -> Axis]
Wolfram Language code: FeatureValueImpactPlot[Predict[Table[x -> 2 - x, {x, 10}]], Frame -> True, Filling -> Pi]

MaxPlotPoints  (1)

默认情况下使用所有的数据点：

Wolfram Language code: predictor = Predict[Table[x -> 2 - x, {x, 10}]];
Wolfram Language code: FeatureValueImpactPlot[predictor]

绘图时只使用 20 个点：

Wolfram Language code: FeatureValueImpactPlot[predictor, MaxPlotPoints -> 20]

PlotLabel  (1)

默认情况下，对绘图进行标注：

Wolfram Language code: predictor = Predict[Catenate@Table[{x, y} -> y ^ 2 - x, {x, 10}, {y, 10}]];
Wolfram Language code: FeatureValueImpactPlot[predictor]

不对绘图进行标注：

Wolfram Language code: FeatureValueImpactPlot[predictor, PlotLabel -> None]

PlotLegends  (1)

默认情况下，基于输出的类别给出图例：

Wolfram Language code: data = {{1.5, Blue} -> "A", {3.2, Blue} -> "A", {4.1, Red} -> "B", {5.3, Red} -> "B", {10., Green} -> "C", {12.4, Red} -> "C"};classifier = Classify[data]
Wolfram Language code: FeatureValueImpactPlot[classifier, Keys@data]

不使用图例：

Wolfram Language code: FeatureValueImpactPlot[classifier, Keys@data, PlotLegends -> None]

用占位符文字作为图例：

Wolfram Language code: FeatureValueImpactPlot[classifier, Keys@data, PlotLegends -> "Placeholder"]

用指定标签作为图例：

Wolfram Language code: FeatureValueImpactPlot[classifier, Keys@data, PlotLegends -> {"Class: A", "Class: B", "Class: C"}]

PlotStyle  (1)

默认情况下，为多个曲线选择不同的样式：

Wolfram Language code: classifier = Classify[Table[x -> If[x < 5, "A", "B"], {x, 0, 10, .1}]];
Wolfram Language code: FeatureValueImpactPlot[classifier]

明确指定不同曲线的样式：

Wolfram Language code: FeatureValueImpactPlot[classifier, PlotStyle -> {Red, Blue}]

应用  (1)

分析不同的模型如何受特征变化的影响：

Wolfram Language code: trainingset = Flatten@Table[{x, y} -> x * y - 5y, {x, 10}, {y, 10}]; Short[trainingset]

训练一个线性模型来预测由两个特征的非线性组合给出的值：

Wolfram Language code: predictor = Predict[trainingset, Method -> "LinearRegression"]

不出所料，每个特征的影响仅取决于该特征值：

Wolfram Language code: FeatureValueImpactPlot[predictor, trainingset[[All, 1]], PlotStyle -> PointSize@Medium]

在同样的数据上训练非线性模型：

Wolfram Language code: predictor2 = Predict[trainingset, Method -> "GradientBoostedTrees"]

现在，取决于样例中的其他特征，同样的特征值可能会产生不同的影响：

Wolfram Language code: FeatureValueImpactPlot[predictor2, trainingset[[All, 1]], PlotStyle -> PointSize@Medium]
Wolfram Research (2022)，FeatureValueImpactPlot，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html.

文本

Wolfram Research (2022)，FeatureValueImpactPlot，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html.

CMS

Wolfram 语言. 2022. "FeatureValueImpactPlot." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html.

APA

Wolfram 语言. (2022). FeatureValueImpactPlot. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html 年

BibTeX

@misc{reference.wolfram_2026_featurevalueimpactplot, author="Wolfram Research", title="{FeatureValueImpactPlot}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_featurevalueimpactplot, organization={Wolfram Research}, title={FeatureValueImpactPlot}, year={2022}, url={https://reference.wolfram.com/language/ref/FeatureValueImpactPlot.html}, note=[Accessed: 12-September-2026]}