WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Callout[data,expr]

プロット中の expr を data を指すコールアウトとして表示する．

Callout[data,expr,pos]

pos で指定された位置の expr をコールアウトとして表示する．

Callout[data,expr,pos,apos]

apos で指定された位置にアンカーで繋いだコールアウトを表示する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
ラベルの置き方  
アンカーの配置  
プレゼンテーション  
オプション  
Appearance  
Background  
CalloutMarker  
Show More Show More
CalloutStyle  
Frame  
FrameMargins  
LabelVisibility  
LeaderSize  
LabelStyle  
RoundingRadius  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

Callout

Callout[data,expr]

プロット中の expr を data を指すコールアウトとして表示する．

Callout[data,expr,pos]

pos で指定された位置の expr をコールアウトとして表示する．

Callout[data,expr,pos,apos]

apos で指定された位置にアンカーで繋いだコールアウトを表示する．

詳細とオプション

  • Callout[data,expr,…]は，PlotやListPlot等の可視化関数のラッパーとして使うことができる．
  • Callout[expr,…]をPlotLabelsで使って，Placedと同じようにコールアウトを指定することができる．
  • expr は，文字列，グラフ，公式を含む任意の式でよい．
  • 特定の位置が指定されていない場合は，コールアウトの位置 pos とアンカーの位置 apos が自動的に計算される．
  • コールアウトの可能な位置 pos は関数によって変わるが，通常は以下を含んでいる．
  • x位置 x のデータの近く
    {x,y}位置{x,y}
    Scaled[s]データに沿ったスケールされた位置 s
    Above,Below,Before,After相対的な位置
    {s,Above},{s,Below},…データに沿った位置 s と相対的な位置
    {pos,epos}位置 pos に置かれた expr 内の epos
    Automaticpos は自動的に決定される
  • 使用可能なアンカー位置 apos
  • x位置 x のデータの近く
    {x,y}位置{x,y}
    Scaled[s]データに沿ったスケールされた位置 s
    Automaticapos は自動的に決定される
  • Calloutは次のオプションを取る．
  • Appearance Automaticコールアウトの全体的なスタイル
    Background Automaticラベルの背景のスタイル
    CalloutMarker Noneアンカー位置 apos に使うマーカー
    CalloutStyle Automaticストロークやノックアウトに使用するスタイル
    Frame Automaticラベルボックスの枠
    FrameMargins Automatic枠内に残す余白
    LabelStyle {}ラベルに使用するスタイル
    LabelVisibility Automatic他のラベルと相対的な優先度
    LeaderSize Automaticリーダーに使用する凡例と角度
    RoundingRadius 0丸みを帯びたコーナーの半径
  • Appearanceの可能な値
  • "Leader"ラベルからデータまでのリーダーを使用
    "CurvedLeader"曲線のリーダー
    "SlantedLabel"角度付きのラベルとネック
    "Frame"expr の周りに完全に枠を付ける
    "Line"exprの周りに部分的に枠を付ける
    "Corners"expr の周りの枠のコーナー
    "Balloon"expr の周りの吹出し
    "LineBalloon"expr の周りの部分的な吹出し
    Noneリーダーは描かない
  • CalloutMarkerの可能な設定
  • Noneマーカーは使わない
    "name"名前付きのマーカーを使う
    Arrowheads[…]鏃の指定
    g式 g
  • 名前付きのマーカー"name"
  • "CirclePoint","Circle"円形のマーカー
    "BoxPoint", "Box"正方形のマーカー
    "Star", "OpenStar"星型のマーカー
    "Arrow", "OpenArrow"矢印のマーカー
  • CalloutStyleは，マーカー，リーダー，ネック，枠に使用するスタイルを指定する．マーカー，リーダー，ネックの周りには，可視性を上げるためにアンビアントな背景色の余白が置かれることが多い．
  • CalloutStyleの可能な値
  • Automaticデフォルトスタイルが使われる
    styスタイル sty をデフォルトのノックアウトスタイルとともに使う
    {sty,kosty}ノックアウトスタイルに kosty を使う
  • LeaderSizeの可能な値
  • Automaticリーダーの自動サイズ
    lrリーダーの長さ
    {lr,lθ,s}アンカーまでの角度 lθ，ギャップ s のリーダー lrの長さ
    {{lr,lθ,s},{nr,nθ}}ネックの長さ nr，角度 nθでリーダーを指定

例題

すべて開く すべて閉じる

例  (4)

コールアウトで点にラベルを付ける：

Wolfram Language code: ListPlot[Table[Callout[i, i], {i, 1, 5}]]

コールアウトに名前付きの位置を使う：

Wolfram Language code: ListPlot[{16, 35, 39, Callout[44, "label", Below], 61, 74, 84, 86, 97, 100}]

コールアウトで曲線にラベルを付ける：

Wolfram Language code: Plot[{Sin[x], Callout[Cos[x], "label"]}, {x, 0, 2π}]

曲線と相対的な名前付きの位置を使ってコールアウトを置く：

Wolfram Language code: Plot[{Callout[Log[x]Sin[x], "max", Above], Log[x]Cos[x]}, {x, 0, 2π}]

コールアウトにスタイルを付ける：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "min", Bottom, LabelStyle -> Directive[Bold, Italic], Background -> StandardBlue, FrameMargins -> 7], {x, 0, 2π}]

スコープ  (15)

ラベルの置き方  (8)

コールアウトは個々の点の近くに置かれる：

Wolfram Language code: ListPlot[Table[Callout[Fibonacci[n], Fibonacci[n]], {n, 10}]]

コールアウトは曲線の終りに自動的に置かれる：

Wolfram Language code: Plot[{Callout[Sin[x], "sine"], Callout[Cos[x], "cosine"]}, {x, 0, 10}]

コールアウトを点と相対的に置く：

Wolfram Language code: Table[ListPlot[Table[Callout[Fibonacci[n], Fibonacci[n], p], {n, 10}], Frame -> True], {p, {Above, Below, Before, After}}]
Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", p], {x, -10, 10}, Frame -> True, BaselinePosition -> Bottom], {p, {Above, Below}}]

ラベルを曲線の絶対位置近くに置く：

Wolfram Language code: Plot[Callout[Sinc[x], "label", 7], {x, 0, 10}]

ラベルを曲線のスケールされた位置近くに置く：

Wolfram Language code: Plot[Callout[Sinc[x], "label", Scaled[0.75]], {x, 0, 10}]

ラベルを指定された点の近くで曲線の上に置く：

Wolfram Language code: Plot[Callout[Sinc[x], "label", {3, Above}], {x, 0, 10}]
Wolfram Language code: Plot[Callout[Sinc[x], "label", {Scaled[0.3], Above}], {x, 0, 10}]

ラベルを特定の点に置く：

Wolfram Language code: Plot[Callout[Sinc[x], "label", {6, 0.5}], {x, 0, 10}]

ラベル内のリーダーに接続する位置を指定する：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", {5Pi / 2, {s, 0.5}}], {x, 0, 10}], {s, {0, 1}}]

アンカーの配置  (3)

リーダーが指す曲線上の点を絶対位置で指定する：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", {5, 0.8}, a], {x, -10, 10}], {a, {2, 8}}]

リーダーが指す曲線上の点をスケールされた位置で指定する：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", {5, 0.8}, Scaled[a]], {x, -10, 10}], {a, {0.6, 0.9}}]

リーダーが指す余分な点を指定する：

Wolfram Language code: ListLinePlot[Callout[Table[{t Cos[t], t Sin[t]}, {t, 0, 10, 0.1}], "label", {-3, 3}, {2.5Cos[2.5], 2.5Sin[2.5]}]]

プレゼンテーション  (4)

コールアウトに枠を付ける：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "max", Above, Appearance -> "Frame"], {x, 0, 2π}, PlotTheme -> "Minimal"]

吹出しを使う：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "max", Above, Appearance -> "Balloon"], {x, 0, 2π}, PlotTheme -> "Minimal"]

曲線上のコールアウトのアンカー点に丸を付ける：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "min", Below, CalloutMarker -> "Circle"], {x, 0, 2π}, PlotTheme -> "Business"]

アンカー点を矢印で指する：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "min", Below, CalloutMarker -> "Arrow"], {x, 0, 2π}, PlotTheme -> "Business"]

コールアウトに均一のリーダー線を使う：

Wolfram Language code: ListPlot[Table[Callout[Prime[n], Prime[n], LeaderSize -> {{12, 135°, 6}, {5, 180°}}], {n, 10}], PlotMarkers -> Automatic, PlotTheme -> "Web"]

曲線にマッチするようにコールアウトにスタイルを付ける：

Wolfram Language code: Plot[{Callout[Sin[x], Sin[x], Above, Background -> RGBColor[0.790588, 0.201176, 0.], LabelStyle -> GrayLevel[1]], Callout[Cos[x], Cos[x], Below, Background -> RGBColor[0.192157, 0.388235, 0.807843], LabelStyle -> GrayLevel[1], Appearance -> "Balloon"]}, {x, 0, 2Pi}, PlotTheme -> "Web"]

オプション  (17)

Appearance  (2)

別の名前付き外観を使う：

Wolfram Language code: Table[Plot[Callout[Log[x]Sin[x], "label", Scaled[0.2], Appearance -> a], {x, 0, 10}, PlotLabel -> a], {a, {"Leader", "CurvedLeader", "SlantedLabel", "Frame", "Line", "Corners", "Balloon", "LineBalloon"}}]

外観を他のスタイリングと組み合せる：

Wolfram Language code: Plot[{Callout[Log[x]Sin[x], "label", Automatic, 4, Appearance -> "Corners", Background -> StandardGreen, LeaderSize -> {20, 60 °, 5}, CalloutStyle -> {StandardBlue, StandardGreen}], Cos[x]}, {x, 0, 2π}]

Background  (1)

コールアウトラベルの背景にスタイルを付ける：

Wolfram Language code: Plot[{Callout[Log[x] Sin[x], "label", {Scaled[0.65], Above}, Background -> StandardGray], Tan[x]Sin[x]}, {x, 0, 10}]

CalloutMarker  (2)

名前付きのマーカーを使う：

Wolfram Language code: Table[ListLinePlot[Callout[Fibonacci[Range[6]], "label", {3, 5}, 4, CalloutMarker -> i], PlotLabel -> i], {i, {"CirclePoint", "Circle", "BoxPoint", "Box", "Star", "OpenStar", "Arrow", "OpenArrow"}}]

Arrowheadsをマーカーとして使う：

Wolfram Language code: ListLinePlot[{Callout[Fibonacci[Range[6]], "Fibonacci", {4, 10}, 5, CalloutMarker -> Arrowheads[0.04]], Table[LucasL[n], {n, 6}]}]

CalloutStyle  (2)

リーダーの色を変える：

Wolfram Language code: ListLinePlot[{Range[20], Callout[Prime[Range[20]], "label", Scaled[0.6], CalloutStyle -> Red]}]

ノックアウトスタイルを指定する：

Wolfram Language code: ListLinePlot[{Callout[Prime[Range[20]], "label", 14, CalloutStyle -> {White, Red}], Range[20]}, GridLines -> Automatic, PlotTheme -> "Marketing"]

Frame  (1)

枠を使う：

Wolfram Language code: Plot[{Callout[Sin[x], "label", Top, Frame -> True], Cos[x]}, {x, 0, 10}]

上下の枠だけを描画する：

Wolfram Language code: Plot[{Callout[Sin[x], "label", Top, Frame -> {{False, False}, {True, True}}], Cos[x]}, {x, 0, 10}]

FrameMargins  (1)

コールアウトラベル周囲の余白を制御する：

Wolfram Language code: Table[ListLinePlot[Callout[Prime[Range[20]], "label", Scaled[0.6], Frame -> True, FrameMargins -> i]], {i, {3, 6}}]

吹出しの外観にする：

Wolfram Language code: Table[ListLinePlot[Callout[Prime[Range[20]], "label", Scaled[0.6], Appearance -> "Balloon", FrameMargins -> i]], {i, {3, 6}}]

LabelVisibility  (3)

コールアウトは衝突を避けるために削られる：

Wolfram Language code: ListPlot[Table[Callout[{i, i}, i, LabelVisibility -> Automatic], {i, 50}], ImageSize -> 200]

プロット中の偶数のすべての点に，たとえ衝突するものがあっても，ラベルを付ける：

Wolfram Language code: ListPlot[Table[Callout[{i, i}, i, LabelVisibility -> If[EvenQ[i], All, None]], {i, 50}], ImageSize -> 200]

衝突を避けて偶数の点にラベルを付ける：

Wolfram Language code: ListPlot[Table[Callout[{i, i}, i, LabelVisibility -> If[EvenQ[i], Infinity, -Infinity]], {i, 50}], ImageSize -> 200]

LeaderSize  (3)

リーダーの長さを指定する：

Wolfram Language code: Table[Plot[{Callout[Log[x] Sin[x], "label", Automatic, 2, LeaderSize -> s], Sin[x]}, {x, 0, 10}], {s, {15, 30}}]

リーダーの傾斜を制御する：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", Automatic, 0, LeaderSize -> {20, θ, 5}], {x, -10, 10}, PlotRange -> {-1, 2}], {θ, {0°, 45°, 135°, 180°}}]

リーダーと曲線の間の距離を指定する：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", Automatic, 1, LeaderSize -> {25, 45°, g}], {x, -10, 10}, PlotRange -> {-1, 2}], {g, {0, 10}}]

リーダーとネックの長さと角度を指定する：

Wolfram Language code: Plot[{Callout[Log[x] Sin[x], "label", Automatic, 6.5, LeaderSize -> {{35, 110°, 5}, {10, 150°}}], Sin[x]}, {x, 0, 10}]

LabelStyle  (1)

コールアウトラベルを指定する：

Wolfram Language code: Plot[{Callout[Sin[x] + x / 2, "label", {Scaled[0.75], Below}, LabelStyle -> {14, Bold, StandardBlue}], Sin[x] + x}, {x, 0, 10}]

RoundingRadius  (1)

角が丸みを帯びた長方形をコールアウトラベルの周りに使う：

Wolfram Language code: Plot[Callout[x ^ 4 - 25 x ^ 2 + 20 x + 15, "label", Scaled[0.6], RoundingRadius -> 5, Appearance -> "Frame"], {x, -5, 5}]

吹出しの外観にする：

Wolfram Language code: Plot[Callout[x ^ 4 - 25 x ^ 2 + 20 x + 15, "label", Scaled[0.6], RoundingRadius -> 5, Appearance -> "Balloon"], {x, -5, 5}]

アプリケーション  (1)

世界のすべての国について，その面積と人口を取得する：

Wolfram Language code: data = EntityValue[["all countries"], {"Name", "Area", "Population"}];

面積または人口が極端ないくつかの国にコールアウトを付ける：

Wolfram Language code: annotated = data /.  {{n : "Macau" | "Monaco" | "India", a_, b_} :> Callout[{a, b}, n, Above], {n : "Pitcairn Islands" | "Svalbard" | "Greenland", a_, b_} :> Callout[{a, b}, n, Below], {r : "Russia" | "China", a_, b_} :> Callout[{a, b}, r, After], {"Vatican City", a_, b_} :> Callout[{a, b}, "Vatican City", Before], {n_, a_, b_} :> Tooltip[{a, b}, n]};

データを両対数スケールでプロットする：

Wolfram Language code: ListLogLogPlot[annotated, PlotTheme -> "Detailed", FrameLabel -> Automatic]
Wolfram Research (2016), Callout, Wolfram言語関数， https://reference.wolfram.com/language/ref/Callout.html （2019年に更新）.

テキスト

Wolfram Research (2016), Callout, Wolfram言語関数， https://reference.wolfram.com/language/ref/Callout.html （2019年に更新）.

CMS

Wolfram Language. 2016. "Callout." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Callout.html.

APA

Wolfram Language. (2016). Callout. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Callout.html

BibTeX

@misc{reference.wolfram_2026_callout, author="Wolfram Research", title="{Callout}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Callout.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_callout, organization={Wolfram Research}, title={Callout}, year={2019}, url={https://reference.wolfram.com/language/ref/Callout.html}, note=[Accessed: 12-September-2026]}