WOLFRAM

Wolfram 语言与系统参考资料中心

Callout[data,expr]

将绘图中的 expr 显示为指向 data 的标注.

Callout[data,expr,pos]

在由 pos 指定的位置处显示标注 expr.

Callout[data,expr,pos,apos]

显示锚定于 apos 指定的位置处的标注.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
标签放置  
锚定点的位置  
演示  
选项  
Appearance  
Background  
CalloutMarker  
Show More Show More
CalloutStyle  
Frame  
FrameMargins  
LabelVisibility  
LeaderSize  
LabelStyle  
RoundingRadius  
应用  
参见
相关指南
历史
按以下格式引用：

Callout

Callout[data,expr]

将绘图中的 expr 显示为指向 data 的标注.

Callout[data,expr,pos]

在由 pos 指定的位置处显示标注 expr.

Callout[data,expr,pos,apos]

显示锚定于 apos 指定的位置处的标注.

更多信息和选项

  • Callout[data,expr,…] 可作为封装被用在可视化函数中，如 Plot、ListPlot 等.
  • Callout[expr,…] 可用在 PlotLabels 中，用来指定标注，类似于 Placed.
  • expr 可以是任意表达式，包括字符串、图形和公式.
  • 在没有指定位置时，自动计算标注的位置 pos 和锚定位置 apos.
  • 可能的标注的位置 pos 随函数而变，一般情况下包括：
  • x靠近数据曲线，在位置 x 处
    {x,y}在位置 {x,y} 处
    Scaled[s]沿数据曲线的比例位置 s
    Above,Below,Before,After相对位置
    {s,Above},{s,Below},…沿数据曲线的相对位置 s
    {pos,epos}位置 pos 处 expr 内的位置 epos
    Automatic自动确定 pos
  • 可能的锚定位置 apos 包括：
  • x靠近数据曲线，在位置 x 处
    {x,y}在位置 {x,y} 处
    Scaled[s]沿数据曲线的比例位置 s
    Automatic自动确定 apos
  • Callout 接受下列选项：
  • Appearance Automatic标注的整体样式
    Background Automatic标签背景的样式
    CalloutMarker None锚定位置 apos 的标记
    CalloutStyle Automaticstroke 和 knockout 的样式
    Frame Automatic标签的边框
    FrameMargins Automatic边框内的留白
    LabelStyle {}标签的样式
    LabelVisibility Automatic相对于其他标签的优先级
    LeaderSize Automatic引导线的长度和角度
    RoundingRadius 0圆角的半径
  • Appearance 的可能的值为：
  • "Leader"用引导线从标签指向数据
    "CurvedLeader"弧形引导线
    "SlantedLabel"按一定角度摆放的标签和颈线
    "Frame"在 expr 周围加上完整的边框
    "Line"为 expr 加上部分边框
    "Corners"在 expr 周围的边角处加上边框
    "Balloon"在 expr 周围加上气球状边框
    "LineBalloon"在 expr 周围加上部分气球状边框
    None不包括引导线
  • CalloutMarker 的可能设置为：
  • None不使用标记
    "name"使用已命名的标记
    Arrowheads[…]箭头规范
    g表达式 g
  • 已命名的标记 "name" 有：
  • "CirclePoint","Circle"圆形标记
    "BoxPoint", "Box"方形标记
    "Star", "OpenStar"星形标记
    "Arrow", "OpenArrow"箭头标记
  • CalloutStyle 指定标记、引导线、颈线和边框的样式. 一般情况下，标记、引导线和颈线周围都留有空间，并辅之以背景色以增加可见性.
  • CalloutStyle 的可能的值有：
  • Automatic采用缺省样式
    sty使用样式 sty，同时使用缺省的 knockout 样式
    {sty,kosty}采用 kosty knockout 样式
  • LeaderSize 的可能的值有：
  • Automatic自动确定引导线的尺寸
    lr引导线的长度
    {lr,lθ,s}引导线的长度为 lr，角度为 lθ，到锚定点的间距为 s
    {{lr,lθ,s},{nr,nθ}}包括颈线的长度 nr 和角度 nθ 的引导线规范

范例

打开所有单元 关闭所有单元

基本范例  (4)

用 callout 来标注点：

Wolfram Language code: ListPlot[Table[Callout[i, i], {i, 1, 5}]]

已命名位置：

Wolfram Language code: ListPlot[{16, 35, 39, Callout[44, "label", Below], 61, 74, 84, 86, 97, 100}]

用 callout 标注曲线：

Wolfram Language code: Plot[{Sin[x], Callout[Cos[x], "label"]}, {x, 0, 2π}]

用相对于曲线的已命名位置放置标注：

Wolfram Language code: Plot[{Callout[Log[x]Sin[x], "max", Above], Log[x]Cos[x]}, {x, 0, 2π}]

样式化 callout：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "min", Bottom, LabelStyle -> Directive[Bold, Italic], Background -> StandardBlue, FrameMargins -> 7], {x, 0, 2π}]

范围  (15)

标签放置  (8)

靠近各个点的地方放置标注：

Wolfram Language code: ListPlot[Table[Callout[Fibonacci[n], Fibonacci[n]], {n, 10}]]

自动在各个曲线末端放置标注：

Wolfram Language code: Plot[{Callout[Sin[x], "sine"], Callout[Cos[x], "cosine"]}, {x, 0, 10}]

按点的相对位置放置标注：

Wolfram Language code: Table[ListPlot[Table[Callout[Fibonacci[n], Fibonacci[n], p], {n, 10}], Frame -> True], {p, {Above, Below, Before, After}}]
Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", p], {x, -10, 10}, Frame -> True, BaselinePosition -> Bottom], {p, {Above, Below}}]

在曲线的绝对位置附近放置标签：

Wolfram Language code: Plot[Callout[Sinc[x], "label", 7], {x, 0, 10}]

在曲线的比例位置处放置标签：

Wolfram Language code: Plot[Callout[Sinc[x], "label", Scaled[0.75]], {x, 0, 10}]

在指定位置附近把标签放在曲线上面：

Wolfram Language code: Plot[Callout[Sinc[x], "label", {3, Above}], {x, 0, 10}]
Wolfram Language code: Plot[Callout[Sinc[x], "label", {Scaled[0.3], Above}], {x, 0, 10}]

在指定点放置标签：

Wolfram Language code: Plot[Callout[Sinc[x], "label", {6, 0.5}], {x, 0, 10}]

指定标签与引导线相连的位置：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", {5Pi / 2, {s, 0.5}}], {x, 0, 10}], {s, {0, 1}}]

锚定点的位置  (3)

用绝对位置指定引导线指向曲线的点：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", {5, 0.8}, a], {x, -10, 10}], {a, {2, 8}}]

用比例对位置指定引导线指向曲线的点：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", {5, 0.8}, Scaled[a]], {x, -10, 10}], {a, {0.6, 0.9}}]

明确给出引导线应指向的点：

Wolfram Language code: ListLinePlot[Callout[Table[{t Cos[t], t Sin[t]}, {t, 0, 10, 0.1}], "label", {-3, 3}, {2.5Cos[2.5], 2.5Sin[2.5]}]]

演示  (4)

把标注 (callout) 放在方框中：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "max", Above, Appearance -> "Frame"], {x, 0, 2π}, PlotTheme -> "Minimal"]

使用气球状边框：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "max", Above, Appearance -> "Balloon"], {x, 0, 2π}, PlotTheme -> "Minimal"]

用圆圈标出曲线上标注的锚定点：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "min", Below, CalloutMarker -> "Circle"], {x, 0, 2π}, PlotTheme -> "Business"]

用箭头指向它：

Wolfram Language code: Plot[Callout[Log[x]Sin[x], "min", Below, CalloutMarker -> "Arrow"], {x, 0, 2π}, PlotTheme -> "Business"]

为所有标注指定样式一致的引导线：

Wolfram Language code: ListPlot[Table[Callout[Prime[n], Prime[n], LeaderSize -> {{12, 135°, 6}, {5, 180°}}], {n, 10}], PlotMarkers -> Automatic, PlotTheme -> "Web"]

把标注设计成和他们所指的曲线相匹配的样式：

Wolfram Language code: Plot[{Callout[Sin[x], Sin[x], Above, Background -> RGBColor[0.790588, 0.201176, 0.], LabelStyle -> GrayLevel[1]], Callout[Cos[x], Cos[x], Below, Background -> RGBColor[0.192157, 0.388235, 0.807843], LabelStyle -> GrayLevel[1], Appearance -> "Balloon"]}, {x, 0, 2Pi}, PlotTheme -> "Web"]

选项  (17)

Appearance  (2)

使用不同的已命名外观：

Wolfram Language code: Table[Plot[Callout[Log[x]Sin[x], "label", Scaled[0.2], Appearance -> a], {x, 0, 10}, PlotLabel -> a], {a, {"Leader", "CurvedLeader", "SlantedLabel", "Frame", "Line", "Corners", "Balloon", "LineBalloon"}}]

将外观与其他样式相结合：

Wolfram Language code: Plot[{Callout[Log[x]Sin[x], "label", Automatic, 4, Appearance -> "Corners", Background -> StandardGreen, LeaderSize -> {20, 60 °, 5}, CalloutStyle -> {StandardBlue, StandardGreen}], Cos[x]}, {x, 0, 2π}]

Background  (1)

样式化标注 (callout) 标签的背景：

Wolfram Language code: Plot[{Callout[Log[x] Sin[x], "label", {Scaled[0.65], Above}, Background -> StandardGray], Tan[x]Sin[x]}, {x, 0, 10}]

CalloutMarker  (2)

使用已命名标记：

Wolfram Language code: Table[ListLinePlot[Callout[Fibonacci[Range[6]], "label", {3, 5}, 4, CalloutMarker -> i], PlotLabel -> i], {i, {"CirclePoint", "Circle", "BoxPoint", "Box", "Star", "OpenStar", "Arrow", "OpenArrow"}}]

使用 Arrowheads 作为标记：

Wolfram Language code: ListLinePlot[{Callout[Fibonacci[Range[6]], "Fibonacci", {4, 10}, 5, CalloutMarker -> Arrowheads[0.04]], Table[LucasL[n], {n, 6}]}]

CalloutStyle  (2)

改变引导线的颜色：

Wolfram Language code: ListLinePlot[{Range[20], Callout[Prime[Range[20]], "label", Scaled[0.6], CalloutStyle -> Red]}]

指定 knockout 的样式：

Wolfram Language code: ListLinePlot[{Callout[Prime[Range[20]], "label", 14, CalloutStyle -> {White, Red}], Range[20]}, GridLines -> Automatic, PlotTheme -> "Marketing"]

Frame  (1)

使用边框：

Wolfram Language code: Plot[{Callout[Sin[x], "label", Top, Frame -> True], Cos[x]}, {x, 0, 10}]

只画出上面和下面的边框：

Wolfram Language code: Plot[{Callout[Sin[x], "label", Top, Frame -> {{False, False}, {True, True}}], Cos[x]}, {x, 0, 10}]

FrameMargins  (1)

控制标注 (callout) 标签周围的留白：

Wolfram Language code: Table[ListLinePlot[Callout[Prime[Range[20]], "label", Scaled[0.6], Frame -> True, FrameMargins -> i]], {i, {3, 6}}]

使用气球状边框：

Wolfram Language code: Table[ListLinePlot[Callout[Prime[Range[20]], "label", Scaled[0.6], Appearance -> "Balloon", FrameMargins -> i]], {i, {3, 6}}]

LabelVisibility  (3)

标注被调整以避免重叠：

Wolfram Language code: ListPlot[Table[Callout[{i, i}, i, LabelVisibility -> Automatic], {i, 50}], ImageSize -> 200]

标记图中的所有偶数点，即使其中一些会发生重叠：

Wolfram Language code: ListPlot[Table[Callout[{i, i}, i, LabelVisibility -> If[EvenQ[i], All, None]], {i, 50}], ImageSize -> 200]

标记偶数点，同时避免重叠：

Wolfram Language code: ListPlot[Table[Callout[{i, i}, i, LabelVisibility -> If[EvenQ[i], Infinity, -Infinity]], {i, 50}], ImageSize -> 200]

LeaderSize  (3)

指定引导线的长度：

Wolfram Language code: Table[Plot[{Callout[Log[x] Sin[x], "label", Automatic, 2, LeaderSize -> s], Sin[x]}, {x, 0, 10}], {s, {15, 30}}]

控制引导线的斜度：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", Automatic, 0, LeaderSize -> {20, θ, 5}], {x, -10, 10}, PlotRange -> {-1, 2}], {θ, {0°, 45°, 135°, 180°}}]

指定引导线和曲线之间的距离：

Wolfram Language code: Table[Plot[Callout[Sinc[x], "label", Automatic, 1, LeaderSize -> {25, 45°, g}], {x, -10, 10}, PlotRange -> {-1, 2}], {g, {0, 10}}]

指定引导线和颈线的长度和角度：

Wolfram Language code: Plot[{Callout[Log[x] Sin[x], "label", Automatic, 6.5, LeaderSize -> {{35, 110°, 5}, {10, 150°}}], Sin[x]}, {x, 0, 10}]

LabelStyle  (1)

为标注 (callout) 标签添加样式：

Wolfram Language code: Plot[{Callout[Sin[x] + x / 2, "label", {Scaled[0.75], Below}, LabelStyle -> {14, Bold, StandardBlue}], Sin[x] + x}, {x, 0, 10}]

RoundingRadius  (1)

在标注 (callout) 标签周围加上圆角矩形：

Wolfram Language code: Plot[Callout[x ^ 4 - 25 x ^ 2 + 20 x + 15, "label", Scaled[0.6], RoundingRadius -> 5, Appearance -> "Frame"], {x, -5, 5}]

使用气球状外观：

Wolfram Language code: Plot[Callout[x ^ 4 - 25 x ^ 2 + 20 x + 15, "label", Scaled[0.6], RoundingRadius -> 5, Appearance -> "Balloon"], {x, -5, 5}]

应用  (1)

获取世界上每个国家的面积和人口信息：

Wolfram Language code: data = EntityValue[["all countries"], {"Name", "Area", "Population"}];

为某些面积或人口较极端的国家加上标注：

Wolfram Language code: annotated = data /.  {{n : "Macau" | "Monaco" | "India", a_, b_} :> Callout[{a, b}, n, Above], {n : "Pitcairn Islands" | "Svalbard" | "Greenland", a_, b_} :> Callout[{a, b}, n, Below], {r : "Russia" | "China", a_, b_} :> Callout[{a, b}, r, After], {"Vatican City", a_, b_} :> Callout[{a, b}, "Vatican City", Before], {n_, a_, b_} :> Tooltip[{a, b}, n]};

在对数图上绘制数据：

Wolfram Language code: ListLogLogPlot[annotated, PlotTheme -> "Detailed", FrameLabel -> Automatic]
Wolfram Research (2016)，Callout，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Callout.html （更新于 2019 年）.

文本

Wolfram Research (2016)，Callout，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Callout.html （更新于 2019 年）.

CMS

Wolfram 语言. 2016. "Callout." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/Callout.html.

APA

Wolfram 语言. (2016). Callout. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Callout.html 年

BibTeX

@misc{reference.wolfram_2026_callout, author="Wolfram Research", title="{Callout}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Callout.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_callout, organization={Wolfram Research}, title={Callout}, year={2019}, url={https://reference.wolfram.com/language/ref/Callout.html}, note=[Accessed: 15-August-2026]}