ChiSquareDistribution
ChiSquareDistribution
自由度 ν のカイ二乗(
)分布を表す．
詳細
- カイ二乗分布における値
の確率密度は，
のときは
に比例し，
のときは0である． » - 整数 ν ついては，自由度が ν のカイ二乗分布は正規分布から独立にサンプルした ν の値の平方和の分布を与える．
- ChiSquareDistributionでは，ν は任意の正の実数でよい．
- ChiSquareDistributionでは，ν は無次元量でよい． »
- ChiSquareDistributionは，Mean，CDF，RandomVariate等の関数で使うことができる． »
予備知識
- ChiSquareDistribution[ν]は，分布の自由度を表す正の値 ν でパラメータ化された統計分布を表す．ν はカイ二乗分布の確率密度関数(PDF)の一般的な形を決定し，ν の値によって，確率密度関数は，単調減少になるか，潜在的特異値が領域の下方境界に近付く単一の「峰」（大域最大値）を持つようになるかする．
- ChiSquareDistributionは，カイ分布に従う確率変数の二乗が従う分布である．つまり，もし
が確率変数であり 
（
は「として分布する」の意）であるなら，
である．同一正規分布に従う独立確率変数の集合 
, 
, …, 
の総和 
もまたカイ二乗分布に従う．カイ二乗分布は，理論的あるいは経験的モデルとサンプル集合との間の自由度の数量化に使うことができる．具体的な適用分野として，磁気共鳴画像法，疾病に触れることと伝染との考えられる関連の分析等がある． - RandomVariateを使って，カイ二乗分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,ChiSquareDistribution[ν]]（より簡略すると xChiSquareDistribution[ν]）を使って，確率変数 x がカイ二乗分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
- カイ二乗分布の確率密度関数および累積分布関数は，PDF[ChiSquareDistribution[ν],x]およびCDF[ChiSquareDistribution[ν],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
- DistributionFitTestを使って，与えられたデータ集合がカイ二乗分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリックカイ二乗分布を推定することが，FindDistributionParametersを使ってデータをカイ二乗分布にフィットすることができる．ProbabilityPlotを使って記号カイ二乗分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号カイ二乗分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
- TransformedDistributionを使って変換されたカイ二乗分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってカイ二乗分布を含む高次元分布を構築することが，ProductDistributionを使ってカイ二乗分布を含む独立成分分布の結合分布を計算することができる．
- ChiSquareDistributionは他の数多くの分布と関連している．例えば，GammaDistribution，ExponentialDistribution，InverseChiSquareDistribution，UniformDistribution，LaplaceDistributionを含むいくつかの分布は，ChiSquareDistributionの変換として得ることができ，NormalDistributionおよびFRatioDistributionはChiSquareDistributionの変換バージョンの極限値である．さらに，ChiSquareDistributionは，RayleighDistribution，MaxwellDistribution，PearsonDistribution，ParetoDistributionを含む数多くの他のより一般的な関数の特殊形であると見ることができる．ChiSquareDistributionは，BetaDistribution，StudentTDistribution，UniformDistribution，NoncentralChiSquareDistributionとも密接な関係がある．
例題
すべて開く すべて閉じる例 (4)
Plot[Table[PDF[ChiSquareDistribution[ν], x], {ν, {0.5, 3, 5}}]//Evaluate, {x, 0, 6}, Filling -> Axis]PDF[ChiSquareDistribution[ν], x]Plot[Table[CDF[ChiSquareDistribution[ν], x], {ν, {0.5, 3, 5}}]//Evaluate, {x, 0, 6}, Filling -> Axis]CDF[ChiSquareDistribution[ν], x]Mean[ChiSquareDistribution[ν]]Variance[ChiSquareDistribution[ν]]Median[ChiSquareDistribution[ν]]スコープ (8)
data = RandomVariate[ChiSquareDistribution[3], 10 ^ 4];Show[
Histogram[data, {0, 15, 1}, "PDF"],
Plot[PDF[ChiSquareDistribution[3], x], {x, 0, 15}, PlotStyle -> Thick]]sample = RandomVariate[ChiSquareDistribution[13], 10 ^ 3];edist = EstimatedDistribution[sample, ChiSquareDistribution[ν]]サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：
Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 30}, PlotStyle -> Thick]]Plot[Skewness[ChiSquareDistribution[ν]], {ν, 0, 10}]Skewness[ChiSquareDistribution[ν]]Limit[Skewness[ChiSquareDistribution[ν]], ν -> ∞]Plot[Kurtosis[ChiSquareDistribution[ν]], {ν, 0, 10}]Kurtosis[ChiSquareDistribution[ν]]極限値はNormalDistributionの尖度である：
Limit[Kurtosis[ChiSquareDistribution[ν]], ν -> ∞]FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[ChiSquareDistribution[ν], k]//Together, {k, 5}], M]Moment[ChiSquareDistribution[ν], r]FormulaGrid[Table[CentralMoment[ChiSquareDistribution[ν], k]//Together, {k, 5}], CM]CentralMoment[ChiSquareDistribution[ν], r]FormulaGrid[Table[FactorialMoment[ChiSquareDistribution[ν], k]//Together, {k, 5}], FM]FormulaGrid[Table[Cumulant[ChiSquareDistribution[ν], k], {k, 5}], C]Cumulantには閉じた形がある：
Cumulant[ChiSquareDistribution[ν], r]Plot[Table[HazardFunction[ChiSquareDistribution[ν], x], {ν, {3, 5, 7}}]//Evaluate, {x, 0, 4}, Filling -> Axis]HazardFunction[ChiSquareDistribution[ν], x]Plot[Table[Quantile[ChiSquareDistribution[ν], q], {ν, {5, 10, 20}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[ChiSquareDistribution[ν], q]無次元Quantityを使って自由度母数 ν を指定する：
ChiSquareDistribution[Quantity[2, "dozens"]]アプリケーション (2)
ChiSquareDistributionは厳密な（小さい）サンプリング理論に使われる．
統計を定義する：
χSquare[data_, σ_] := Total[(data - Mean[data]) ^ 2] / σ ^ 2データがNormalDistributionに従っているのであれば，
統計はデータのサンプルサイズが小さいもの（30未満）であってもChiSquareDistributionに従う：
With[{n = 10}, Show[Histogram[Table[χSquare[RandomVariate[NormalDistribution[], n], 1], {i, 10 ^ 3}], 20, "PDF"], Plot[PDF[ChiSquareDistribution[n - 1], x], {x, 0, 40}, PlotStyle -> Thick]]]特定の箱入りのシリアルの重み（単位：グラム）は正規分布に従うことが知られている．品質管理部が15箱を無作為に抽出し重みを記録した．製品の重みの標準偏差が36未満であるという仮定を調べる：
weights = Quantity[{367.9, 384.7, 353.8, 334.7, 450.9, 390.6, 422.6, 352.2, 330.9, 342.0, 388.9, 386.7, 374.2, 388.5, 382.2}, "Grams"];{Mean[weights], StandardDeviation[weights]}
という帰無仮説の下では次の統計はChiSquareDistributionに従う：
σ0 = Quantity[36, "Grams"];
χ2stat = (15 - 1)Variance[weights] / σ0^2χ2stat < InverseCDF[ChiSquareDistribution[14], 0.05]製品の重みの標準偏差が32に等しいと仮定して，検定の検出力としても知られる帰無仮説をサンプルサイズの関数として5%レベルで棄却する確率を計算する：
powerFunc[σ1_, n_] := CDF[ChiSquareDistribution[n - 1], (σ0^2/σ1^2) InverseCDF[ChiSquareDistribution[n - 1], 0.05]]DiscretePlot[powerFunc[Quantity[32, "Grams"], n], {n, 15, 300}]検定の検出力が少なくても80%であるために必要なサンプルサイズを求める：
Ceiling[n] /. FindRoot[powerFunc[Quantity[32, "Grams"], n] == 0.8, {n, 200, 300}]特性と関係 (23)
ChiSquareDistribution[ν]は ν->∞で正規分布に収束する：
{μ, σ} = {Mean[ChiSquareDistribution[ν]], StandardDeviation[ChiSquareDistribution[ν]]}Table[Plot[{PDF[ChiSquareDistribution[ν], x], PDF[NormalDistribution[μ, σ], x]}, {x, μ - 2σ, μ + 2σ}, AxesOrigin -> {μ - 2σ - σ, 0}, Ticks -> {{{μ - 2σ, HoldForm[μ - 2σ]}, {μ, HoldForm[μ]}, {μ + 2σ, HoldForm[μ + 2σ]}}, Automatic}, PlotLabel -> ν], {ν, {5, 10, 25, 100}}]TransformedDistribution[u + v, {uChiSquareDistribution[ν1], vChiSquareDistribution[ν2]}]
NoncentralChiSquareDistributionを簡約するとカイ二乗分布になる：
PDF[NoncentralChiSquareDistribution[ν, 0], x]PDF[ChiSquareDistribution[ν], x]% - %%カイ二乗分布はFRatioDistributionの極限の場合である：
Limit[PDF[FRatioDistribution[1, m], x], m -> Infinity]PDF[ChiSquareDistribution[1], x]% - %%カイ二乗分布に従う2つの変数の割合はFRatioDistributionに従う：
TransformedDistribution[(u / ν1) / (v / ν2), {uChiSquareDistribution[ν1], vChiSquareDistribution[ν2]}]
個のNormalDistributionに従う変数の平方和はカイ二乗分布に従う：
𝒟 = TransformedDistribution[x ^ 2 + y ^ 2 + z ^ 2, {x, y, z}ProductDistribution[{NormalDistribution[], 3}]]カイ二乗分布はGammaDistributionの特殊ケースである：
PDF[ChiSquareDistribution[ν], x]PDF[GammaDistribution[ν / 2, 2], x]% - %%スケールされたカイ二乗分布はGammaDistributionに従う：
TransformedDistribution[c * X, XChiSquareDistribution[a], Assumptions -> c > 0]カイ二乗変数の二乗根はChiDistributionに従う：
TransformedDistribution[Sqrt[u], uChiSquareDistribution[ν]]
のRayleighDistributionの平方はカイ二乗分布の特殊なケースである：
𝒟 = TransformedDistribution[u ^ 2, uRayleighDistribution[1]]PDF[𝒟, x]PDF[ChiSquareDistribution[2], x]Simplify[% - %%, x > 0]
のMaxwellDistributionの平方はカイ二乗分布の特殊なケースである：
𝒟 = TransformedDistribution[u ^ 2, uMaxwellDistribution[1]];PDF[𝒟, x]PDF[ChiSquareDistribution[3], x]FullSimplify[% - %%, x > 0]カイ二乗分布とInverseChiSquareDistributionは互いに逆の関係にある：
TransformedDistribution[1 / u, uChiSquareDistribution[ν]]カイ二乗分布はタイプ3のピアソン分布(PearsonDistribution)の特殊なケースである：
PDF[PearsonDistribution[3, 1, -ν + 2, 0, 2, 0], x]//FullSimplifyPDF[ChiSquareDistribution[ν], x]% - %%カイ二乗分布を変換するとBetaDistributionになる：
TransformedDistribution[u / (u + v), {uChiSquareDistribution[ν1], vChiSquareDistribution[ν2]}]カイ二乗分布はUniformDistributionを変換したものである：
𝒟 = TransformedDistribution[-2 Log[u], uUniformDistribution[{0, 1}]];PDF[𝒟, x]//FullSimplify[#, x∈Reals]&PDF[ChiSquareDistribution[2], x]FullSimplify[% - %%, x > 0]カイ二乗分布はLaplaceDistributionを変換したものである：
𝒟 = TransformedDistribution[2 / β (Abs[u - μ] + Abs[v - μ] + Abs[w - μ]), {u, v, w}ProductDistribution[{LaplaceDistribution[μ, β], 3}]];CDF[𝒟, x]//Simplify[#, β > 0]&CDF[ChiSquareDistribution[6], x]//FunctionExpand//Simplify% - %%
𝒟1 = TransformedDistribution[2 / β Abs[z - μ], zLaplaceDistribution[μ, β]];CharacteristicFunction[𝒟1, t] ^ n//PowerExpandCharacteristicFunction[ChiSquareDistribution[2n], t]FullSimplify[% - %%, n∈Integers]カイ二乗分布はParetoDistributionを変換したものである：
𝒟 = TransformedDistribution[2 α Log[(u v w z) k ^ -4], {u, v, w, z}ProductDistribution[{ParetoDistribution[k, α], 4}]];Block[{α = 2, k = 3, n = 4}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 30, "PDF"], Plot[PDF[ChiSquareDistribution[2 n], x], {x, 0, 25}, PlotStyle -> Thick]]]カイ二乗分布はParetoDistributionを変換したものである：
𝒟 = TransformedDistribution[2 α Log[(u v w z) / (Min[{u, v, w, z}] ^ 4)], {u, v, w, z}ProductDistribution[{ParetoDistribution[k, α], 4}]];Block[{α = 2, k = 3, n = 4}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 30, "PDF"], Plot[PDF[ChiSquareDistribution[2 n - 2], x], {x, 0, 25}, PlotStyle -> Thick]]]StudentTDistributionはカイ二乗分布を変換したものである：
𝒟 = TransformedDistribution[1 / 2 Sqrt[ν](u - v) / Sqrt[u v ], {u, v}ProductDistribution[{ChiSquareDistribution[ν], 2}]];Block[{ν = 14}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], Automatic, "PDF"], Plot[PDF[StudentTDistribution[ν], x], {x, -4, 4}, PlotStyle -> Thick]]]StudentTDistributionはChiSquareDistributionとNormalDistributionから得られる：
𝒟 = TransformedDistribution[z Sqrt[ν / w], {zNormalDistribution[], wChiSquareDistribution[ν]}];PDF[𝒟, x]//FullSimplify[#, ν > 0]&PDF[StudentTDistribution[ν], x]//FunctionExpand//PowerExpandFullSimplify[% - %%, x ≠ 0]NoncentralBetaDistributionはChiSquareDistributionとNoncentralChiSquareDistributionの変換として得られる：
TransformedDistribution[(x/x + y), {xNoncentralChiSquareDistribution[n, δ], yChiSquareDistribution[m]}]NoncentralStudentTDistributionはNormalDistributionとChiSquareDistributionから得られる：
𝒟 = TransformedDistribution[(z + δ)Sqrt[ν / w], {zNormalDistribution[], wChiSquareDistribution[ν]}];Block[{δ = 3, ν = 15}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[NoncentralStudentTDistribution[ν, δ], x], {x, -10, 10}, PlotStyle -> Thick]]]考えられる問題 (2)
ChiSquareDistributionは，ν が正の実数でないときは定義されない：
Mean[ChiSquareDistribution[-1]]
Mean[ChiSquareDistribution[ν]] /. {ν -> I}おもしろい例題 (1)
累積分布関数の等高線を持つ ν のさまざまな値についての確率密度関数：
cdf = Function[{x, ν}, Evaluate[CDF[ChiSquareDistribution[ν], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];Legended[Plot3D[PDF[ChiSquareDistribution[ν], x], {x, 0, 10}, {ν, 2, 6}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 35, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> {0, 0.5}], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
An Elementary Introduction to the Wolfram Language
Wolfram Research (2007), ChiSquareDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChiSquareDistribution.html （2016年に更新）.
テキスト
Wolfram Research (2007), ChiSquareDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChiSquareDistribution.html （2016年に更新）.
CMS
Wolfram Language. 2007. "ChiSquareDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/ChiSquareDistribution.html.
APA
Wolfram Language. (2007). ChiSquareDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChiSquareDistribution.html