Wolfram 语言与系统参考资料中心

DiscreteWaveletData

DiscreteWaveletData[{wind₁coef₁,…},wave,wtrans]

产生离散小波数据对象，其中小波系数 coef_i 对应于小波索引 wind_i，小波 wave 和小波变换 wtrans.

DiscreteWaveletData[{wind₁coef₁,…},wave,wtrans,{d₁,…}]

产生离散小波数据对象，假设数据维数为 {d₁,…}.

范例

打开所有单元关闭所有单元

基本范例 (3)

从小波变换中获得 DiscreteWaveletData：

Wolfram Language code: dwd = DiscreteWaveletTransform[Range[10]]

DiscreteWaveletData 代表一个变换系数的树：

Wolfram Language code: dwd["TreeView"]

提取属性，包括每个系数的总能量部分：

Wolfram Language code: dwd["EnergyFraction"]

在其它小波函数中使用 DiscreteWaveletData 对象：

Wolfram Language code: dwd = DiscreteWaveletTransform[DiamondMatrix[32], Automatic, 3]

WaveletMatrixPlot[dwd] 在分层网格布局中绘制矩阵小波系数：

Wolfram Language code: WaveletMatrixPlot[dwd]

计算平稳小波变换系数的逆小波变换：

Wolfram Language code:

InverseWaveletTransform[DiscreteWaveletData[{{0, 1} -> {-1, 3, 0, 0}, {0} -> {0, 2, 2, 0}}, HaarWavelet[], StationaryWaveletTransform]]

范围 (25)

基本用途 (8)

从诸如 DiscreteWaveletTransform 的小波变换中获得 DiscreteWaveletData：

Wolfram Language code: dwd = DiscreteWaveletTransform[{1, 2, 3, 4}]

在树布局中，显示计算得到的小波系数：

Wolfram Language code: dwd["TreeView"]

获得规则列表形式的小波阵列：

Wolfram Language code: Normal[dwd]

InverseWaveletTransform 作用于 DiscreteWaveletData：

Wolfram Language code: dwd = StationaryWaveletTransform[{1, 2, 3, 4}, HaarWavelet[]]

对于诸如 HaarWavelet[] 的正交小波，逆变换是确切的：

Wolfram Language code: InverseWaveletTransform[dwd]

提取对应于小波索引指标的系数：

Wolfram Language code: dwd = StationaryWaveletTransform[{1, 1, 3, 1}]

以规则列表的形式给出系数：

Wolfram Language code: dwd[{{0}, {1}}]

提取对应于小波索引形式 {0,_} 的所有系数：

Wolfram Language code: dwd[{0, _}]

提取一个系数阵列列表而不是一个规则列表：

Wolfram Language code: dwd[{0, _}, "Values"]

提取简单的列表图：

Wolfram Language code: dwd[{0, _}, "ListPlot"]

提取小波变换数据的属性：

Wolfram Language code: dwd = DiscreteWaveletTransform[RandomReal[1, 12], DaubechiesWavelet[]]

所用的离散正变换、精细度的数和小波：

Wolfram Language code: {dwd["Transform"], dwd["Refinement"], dwd["Wavelet"]}

每个小波系数的维数：

Wolfram Language code: dwd["Dimensions"]

所有可用的属性：

Wolfram Language code: dwd["Properties"]

在其它小波函数中使用 DiscreteWaveletData：

Wolfram Language code: data = Table[Sin[x + x^2], {x, 0, 10, 0.1}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data]

逆变换：

Wolfram Language code: InverseWaveletTransform[dwd]//ListLinePlot

小波可视化函数：

Wolfram Language code: {WaveletListPlot[dwd], WaveletScalogram[dwd]}

使用小波函数变换 DiscreteWaveletData：

Wolfram Language code: data = Table[Sin[20Log[x]], {x, 1, 10, 0.1}];

Wolfram Language code: dwd1 = DiscreteWaveletTransform[data, Automatic, 3]

应用阈值操作于系数：

Wolfram Language code: dwd2 = WaveletThreshold[dwd1]

对每个系数应用一个任意的函数：

Wolfram Language code: dwd3 = WaveletMapIndexed[c  Rescale[c], dwd1]

在每个小波数据对象中绘制系数：

Wolfram Language code: Table[WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", PlotRange -> 2], {dwd, {dwd1, dwd2, dwd3}}]

从给出系数阵列的规则列表中构建一个 DiscreteWaveletData：

Wolfram Language code: dwd = DiscreteWaveletData[{{0, 0} -> {-1}, {1, 0} -> {6}}]

结果代表一个包括指定系数的小波系数的树：

Wolfram Language code: dwd["TreeView"]

其它系数假设为零：

Wolfram Language code: Normal[dwd]

使用指定的小波和正变换的 DiscreteWaveletData：

Wolfram Language code:

dwd = DiscreteWaveletData[{{1} -> {2, 0, 0, 0, -3}, {0, 0, 1} -> {4, -2, 5}}, SymletWavelet[2], DiscreteWaveletTransform]

在逆变换中使用指定的小波和正变换：

Wolfram Language code: InverseWaveletTransform[dwd]

获取系数 (7)

找到哪种系数可用：

Wolfram Language code: dwd = DiscreteWaveletPacketTransform[{1, 3, 0, 0}]

Wolfram Language code: dwd["WaveletIndex"]

在树布局中显示所有的系数：

Wolfram Language code: dwd["TreeView"]

不同的小波索引指标从 DiscreteWaveletData 中提取系数阵列：

Wolfram Language code: dwd = DiscreteWaveletPacketTransform[{1, 3, 0, 0}]

提取单个系数阵列：

Wolfram Language code: dwd[{1}]

对应于索引列表的系数：

Wolfram Language code: dwd[{{0}, {1}}]

小波索引匹配一个模式的所有系数：

Wolfram Language code: dwd[{_, 1}]

索引和模式列表：

Wolfram Language code: dwd[{{1}, {_, Except[1]}}]

在小波逆变换中缺省使用的系数：

Wolfram Language code: dwd[Automatic]

所有系数：

Wolfram Language code: dwd[All]

获得不同形式的系数阵列：

Wolfram Language code: dwd = DiscreteWaveletTransform[RandomReal[1, 6]]

获得规则列表：

Wolfram Language code: dwd[{{0}, {1}}, "Rules"]

只获得值：

Wolfram Language code: dwd[{{0}, {1}}, "Values"]

以小型列表图表示系数：

Wolfram Language code: dwd[{{0}, {1}}, "ListPlot"]

获得每个系数阵列的逆变换：

Wolfram Language code: dwd[{{0}, {1}}, "Inverse"]

组合形式：

Wolfram Language code: dwd[{{0}, {1}}, {"Rules", "Inverse", "ListPlot"}]

以小型矩阵图表示矩阵小波系数：

Wolfram Language code: dwd = DiscreteWaveletTransform[CrossMatrix[3]]

Wolfram Language code: dwd[{{0}, {1}, {2}}, "MatrixPlot"]

以小型矩阵图表示单个系数的逆变换：

Wolfram Language code: dwd[{{0}, {1}, {2}}, {"Inverse", "MatrixPlot"}]

获得图像小波系数，缺省情况下是应用了 ImageAdjust 的 Image 对象：

Wolfram Language code: dwd = DiscreteWaveletTransform[[image]]

Wolfram Language code: dwd[{_}, "Image"]

获得没有经过色彩级别调整的图像：

Wolfram Language code: dwd[{_}, {"Image", "ImageFunction" -> Identity}]

缺省情况下，图像小波系数是以每个色彩通道的像素值的阵列给出：

Wolfram Language code: ArrayQ[dwd[{0}, "Values"], _, NumberQ]

Wolfram Language code: Dimensions[dwd[{0}, "Values"]]

以 Audio 对象形式获取音频小波系数：

Wolfram Language code: dwd = DiscreteWaveletTransform[Audio["ExampleData/rule30.wav"]]

Wolfram Language code: dwd[{1}, "Audio"]

以 Audio 对象形式对单个系数进行逆变换：

Wolfram Language code: dwd[{0, 0, 0, 0, 0}, {"Audio", "Inverse"}]

获得作为 Sound 对象的声音小波系数:

Wolfram Language code: dwd = DiscreteWaveletTransform[ExampleData[{"Sound", "Tuba"}]]

Wolfram Language code: dwd[{1}, "Sound"]

作为 Sound 对象的单个系数的逆变换:

Wolfram Language code: dwd[{1}, {"Sound", "Inverse"}]

设置系数 (6)

构建 List 输入的 DiscreteWaveletData：

Wolfram Language code: dwd = LiftingWaveletTransform[Range[8], DaubechiesWavelet[3]]

Wolfram Language code: wrules = dwd[All]

对于 List 系数，输入类型为 {wind₁->coef₁,…} 的规则列表 wrules：

Wolfram Language code: newdwd = DiscreteWaveletData[wrules, DaubechiesWavelet[3]]

执行 InverseWaveletTransform：

Wolfram Language code: InverseWaveletTransform[newdwd]

Image 输入：

Wolfram Language code: dwd = LiftingWaveletTransform[[image], CDFWavelet[], 3]

Wolfram Language code: irules = dwd[All, {"Image", "ImageFunction" -> Identity}]

对于 Image 系数，输入类型为 {wind₁->icoef₁,…} 的规则列表 irules：

Wolfram Language code: newdwd = DiscreteWaveletData[irules, CDFWavelet[]]

执行 InverseWaveletTransform：

Wolfram Language code: InverseWaveletTransform[newdwd]

Sound 输入：

Wolfram Language code: snd = Sound[SampledSoundList[Table[Sin[1000 t], {t, 0, 1, 1. / 255}], 250]]

Wolfram Language code: dwd = LiftingWaveletTransform[snd, SymletWavelet[2], 2]

Wolfram Language code: srules = dwd[All, "Sound"];

对于 Sound 系数，输入类型为 {wind₁->scoef₁,…} 的规则列表 srules：

Wolfram Language code: newdwd = DiscreteWaveletData[srules, SymletWavelet[2], SampleRate -> 250]

执行 InverseWaveletTransform：

Wolfram Language code: InverseWaveletTransform[newdwd]

默认情况下，自动计算参数小波变换 wtrans：

Wolfram Language code: DiscreteWaveletData[{{0} -> Range[10], {1} -> Range[10]}]

Wolfram Language code: ListLinePlot[InverseWaveletTransform[%]]

指定参数小波变换 wtrans：

Wolfram Language code: DiscreteWaveletData[{{0} -> Range[10], {1} -> Range[10]}, Automatic, LiftingWaveletTransform]

Wolfram Language code: ListLinePlot[InverseWaveletTransform[%]]

默认情况下，自动计算数据维数 {d₁,…}：

Wolfram Language code: dwd = DiscreteWaveletTransform[Range[8]]

Wolfram Language code: DiscreteWaveletData[Normal[dwd], Automatic, DiscreteWaveletTransform]

指定数据维数：

Wolfram Language code: DiscreteWaveletData[Normal[dwd], Automatic, DiscreteWaveletTransform, {8}]

执行简单的边缘检测:

Wolfram Language code:

DiscreteWaveletData[{{1} -> [image], {3} -> [image], {2} -> [image], {0, 1} -> [image], {0, 3} -> [image], {0, 2} -> [image]}]

Wolfram Language code: ImageAdjust@InverseWaveletTransform[%]

属性 (4)

获得小波变换的属性：

Wolfram Language code: dwd = StationaryWaveletPacketTransform[RandomReal[1, 8], DaubechiesWavelet[], Full]

使用的正变换、小波和填充方法：

Wolfram Language code: {dwd["Transform"], dwd["Wavelet"], dwd["Padding"]}

精细度的数，对应于最长的小波索引：

Wolfram Language code: {dwd["Refinement"], Max[Length /@ dwd["WaveletIndex"]]}

小波系数的属性：

Wolfram Language code: dwd = DiscreteWaveletPacketTransform[{6, 1, 4, 0}]

所有可用系数的小波索引：

Wolfram Language code: dwd["WaveletIndex"]

不同布局的所有系数的树视图：

Wolfram Language code: Table[dwd[{"TreeView", pos}], {pos, {Top, Left, Center}}]

每个系数阵列的维数以规则列表的形式给出：

Wolfram Language code: dwd["Dimensions"]

与小波基相关的属性：

Wolfram Language code: dwd = WaveletBestBasis[DiscreteWaveletPacketTransform[{1, 2, 3, 3}]]

在基中的小波索引：

Wolfram Language code: dwd["BasisIndex"]

显示在所有系数的树视图或块网格中突出的小波基：

Wolfram Language code: {dwd["TreeView"], dwd["BestBasisBlockView"]}

在基系数中的信号能量分布：

Wolfram Language code: dwd["EnergyFraction"]

由 WaveletBestBasis 计算的基的每个系数阵列的损失值:

Wolfram Language code: dwd["BestBasisCostValues"]

与输入数据相关的属性:

Wolfram Language code: data = [image];

Wolfram Language code: dwd = DiscreteWaveletTransform[data]

数据维数与声音或颜色通道的数量:

Wolfram Language code: {dwd["DataDimensions"], dwd["DataChannels"]}

自动应用于一个逆变换结果的封装函数:

Wolfram Language code: dwd["DataWrapper"]

Wolfram Language code: {Head[data], Head[InverseWaveletTransform[dwd]]}

选项 (7)

Method (1)

Method 的设置与小波变换的方法相同：

Wolfram Language code: lwd = LiftingWaveletTransform[Range[8], Method -> "IntegerLifting"]

生成 DiscreteWaveletData 以执行 "IntegerLifting"：

Wolfram Language code: ilwd = DiscreteWaveletData[Normal[lwd], Method -> "IntegerLifting"]

Wolfram Language code: InverseWaveletTransform[ilwd]

Padding (2)

Padding 的设置与 ArrayPad 的方法相同，包括 "Periodic"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Periodic"]

"Reversed"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reversed"]

"ReversedNegation"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedNegation"]

"Reflected"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reflected"]

"ReflectedDifferences"：

Wolfram Language code: ArrayPad[{a, b, c}, 3, "ReflectedDifferences"]

"ReversedDifferences"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedDifferences"]

"Extrapolated"：

Wolfram Language code: ArrayPad[{a, b, c}, 3, "Extrapolated"]

默认情况下，使用 Padding->"Periodic" 选项：

Wolfram Language code: DiscreteWaveletData[{{0} -> Range[10]}, Padding -> "Periodic"] == DiscreteWaveletData[{{0} -> Range[10]}]

SampleRate (1)

对于 Sound 输入，自动计算 SampleRate：

Wolfram Language code: snd = Sound[SampledSoundList[Table[Cos[100 t^2], {t, 0, 1, 1. / 255}], 250]]

Wolfram Language code: dwd = LiftingWaveletTransform[snd, Automatic, 2];

默认情况下，从第一个系数规则提取 SampleRate：

Wolfram Language code: srules = dwd[All, "Sound"];

Wolfram Language code: First[srules]

Wolfram Language code: InverseWaveletTransform[DiscreteWaveletData[srules]]

明确指定 SampleRate：

Wolfram Language code: InverseWaveletTransform[DiscreteWaveletData[srules, SampleRate -> 250]]

WorkingPrecision (3)

默认情况下，使用 WorkingPrecision->MachinePrecision：

Wolfram Language code: dwd1 = DiscreteWaveletData[{{0} -> {1, 2, 3, 4}, {1} -> {1, 2, 3, 4}}]

Wolfram Language code: dwd2 = DiscreteWaveletData[{{0} -> {1, 2, 3, 4}, {1} -> {1, 2, 3, 4}}, WorkingPrecision -> MachinePrecision]

Wolfram Language code: dwd1 == dwd2

使用高精度计算：

Wolfram Language code: dwd = Normal@DiscreteWaveletData[{{0} -> {1, 2, 3, 4}}, WorkingPrecision -> 25]

当数字与0接近时，准确度对于正确数位的数目是一个较好的指标：

Wolfram Language code: {Precision[dwd], Accuracy[dwd]}

使用 WorkingPrecision->∞ 进行精确计算：

Wolfram Language code: data = RandomInteger[10, {4}];

Wolfram Language code: dwd = LiftingWaveletTransform[data, WorkingPrecision -> ∞];

Wolfram Language code: Normal[dwd]//Simplify

Wolfram Language code: ndwd = DiscreteWaveletData[Normal[dwd], WorkingPrecision -> ∞];

Wolfram Language code: Normal[ndwd]//Simplify

应用 (3)

执行简单的无损失数据压缩：

Wolfram Language code:

data = ConstantArray[N@Sin[5 Range[0, 2π, (2π/1023)]], {1024}];
data = data + Transpose[data];

Wolfram Language code: MatrixPlot[data]

执行小波变换：

Wolfram Language code: dwd = LiftingWaveletTransform[data, Automatic, 8]

提取小波系数用于重建：

Wolfram Language code: wcoeff = dwd[Automatic];

比较 data 的 ByteCount 与相应的小波系数 wcoeff：

Wolfram Language code:

cdata = Compress[data];
cwcoeff = Compress[wcoeff];

Wolfram Language code: BarChart[{(ByteCount[cdata]/1024^2), (ByteCount[cwcoeff]/1024^2)}, ChartLabels -> {"data", "wavelet coefficients"}]

从压缩小波系数重建原始数据：

Wolfram Language code: ndwd = DiscreteWaveletData[Uncompress[cwcoeff]]

Wolfram Language code: MatrixPlot[InverseWaveletTransform[ndwd]]

通过把 UnitVector 设置为在细化层的低通系数，计算尺度函数：

Wolfram Language code:

j = 10;
wind = ConstantArray[0, j];

Wolfram Language code:

dwd = DiscreteWaveletData[{wind -> Sqrt[2]^j UnitVector[4, 1]}, DaubechiesWavelet[2], LiftingWaveletTransform, Padding -> 0]

执行 InverseWaveletTransform：

Wolfram Language code: ϕ = InverseWaveletTransform[dwd];

与计算所得的尺度函数比较：

Wolfram Language code:

Show[ListLinePlot[ϕ, PlotRange -> All, DataRange -> {0, 4}], Plot[WaveletPhi[DaubechiesWavelet[2]][x], {x, 0, 4}, PlotRange -> All, PlotStyle -> {Red, Dashed}]]

通过把 UnitVector 设置为细化层上的高通系数，计算小波函数：

Wolfram Language code:

j = 10;
wind = ConstantArray[0, j];
wind[[-1]] = 1;

Wolfram Language code:

dwd = DiscreteWaveletData[{wind -> Sqrt[2]^j UnitVector[3, 2]}, DaubechiesWavelet[2], LiftingWaveletTransform, Padding -> 0]

执行 InverseWaveletTransform：

Wolfram Language code: ψ = InverseWaveletTransform[dwd];

与计算所得的尺度函数比较：

Wolfram Language code:

Show[ListLinePlot[-ψ, PlotRange -> All, DataRange -> {-1, 2}], Plot[WaveletPsi[DaubechiesWavelet[2]][x], {x, -1, 2}, PlotRange -> All, PlotStyle -> {Red, Dashed}]]

属性和关系 (4)

DiscreteWaveletData 代表一个离散变换系数的树：

Wolfram Language code: dwd = DiscreteWaveletTransform[{1, 1, 8, 1, 1, 2, 2, 1, 1}]

Wolfram Language code: {dwd["TreeView"], WaveletListPlot[dwd, Ticks -> Full, PlotLayout -> "CommonYAxis"]}

ContinuousWaveletData 代表在一套尺度中的连续变换系数：

Wolfram Language code: cwd = ContinuousWaveletTransform[{1, 1, 8, 1, 1, 2, 2, 1, 1}]

Wolfram Language code: {TableForm[cwd["Scales"]], WaveletScalogram[cwd, Ticks -> Full]}

根据系数和属性，重构一个 DiscreteWaveletData：

Wolfram Language code: dwd = LiftingWaveletTransform[{1, 2, 3, 4}, DaubechiesWavelet[2]]

指定使用的系数、小波和正变换以及数据维数：

Wolfram Language code: dwd2 = DiscreteWaveletData[Normal[dwd], dwd["Wavelet"], dwd["Transform"], dwd["DataDimensions"]]

正变换和数据维数经常可以自动决定：

Wolfram Language code: dwd3 = DiscreteWaveletData[Normal[dwd], dwd["Wavelet"]]

比较逆变换：

Wolfram Language code: Map[InverseWaveletTransform, {dwd, dwd2, dwd3}]

以规则列表形式获得所有系数的等效的方法：

Wolfram Language code: dwd = DiscreteWaveletTransform[{1, 2, 3, 4}]

使用 Normal：

Wolfram Language code: Normal[dwd]

明确地提取 All 所有系数：

Wolfram Language code: dwd[All]

指定匹配任意小波索引的模式 Blank[] (_)：

Wolfram Language code: dwd[_]

只获得对应于小波索引指标的系数阵列的等效方法：

Wolfram Language code: dwd = DiscreteWaveletTransform[{1, 2, 3, 4}]

应用 Last 于由 dwd[wind] 返回的每个规则：

Wolfram Language code: Last /@ dwd[{_}]

使用 Part：

Wolfram Language code: dwd[{_}][[All, 2]]

只明确获得系数值：

Wolfram Language code: dwd[{_}, "Values"]

可能存在的问题 (2)

最佳基损失值只适用于来自于 WaveletBestBasis 的 DiscreteWaveletData：

Wolfram Language code: dwd = DiscreteWaveletPacketTransform[RandomReal[1, 6]]

Wolfram Language code: dwd["BestBasisCostValues"]

首先计算最佳基代表：

Wolfram Language code: best = WaveletBestBasis[dwd, "LogEnergy"]

Wolfram Language code: best["BestBasisCostValues"]

多于１个的正变换可能与指定的系数相一致：

Wolfram Language code: dwd = DiscreteWaveletData[{{0} -> {1, 2, 3, 4}}]

DiscreteWaveletData 选择一个一致的正变换来假设：

Wolfram Language code: dwd["Transform"]

明确地指定正变换：

Wolfram Language code: dwd2 = DiscreteWaveletData[{{0} -> {1, 2, 3, 4}}, Automatic, DiscreteWaveletTransform]

Wolfram Language code: dwd2["Transform"]

Top

	dwd[wind]	提取对应于 wind 的系数
	dwd[{wind₁,wind₂,…}]	提取数个小波系数阵列
	dwd[wpatt]	提取所有系数，其 wind 与模式 wpatt 匹配
	dwd[All]	提取所有系数
	dwd[Automatic]	提取在逆变换中使用的系数

	"Rules"	规则 {wind₁->…}
	"Values"	只有系数
	"Inverse"	逆变换的个别系数
	"ListPlot"	一维系数的简单列表图
	"MatrixPlot"	二维系数的简单矩阵图
	"Image"	图像系数的图像
	"Sound"	声音系数的声音对象
	"SampledSoundList"	声音系数的样本声音对象

	"BasisIndex"	逆变换中使用的小波索引
	"Dimensions"	给出小波系数组的维数
	"EnergyFraction"	系数组中的能量部分
	"Padding"	用于变换数据的填充
	"Refinement"	执行的精细度的数
	"Transform"	小波变换的类型
	{"TreeView",pos}	分解的树视图，具有 TreePlot 中的 pos
	"Wavelet"	使用的小波族
	"WaveletIndex"	所有小波索引 wind_i 的列表

	"BestBasisBlockView"	最佳基的块网格视图
	"BestBasisCostValues"	每个小波系数的损失值
	"BestBasisCostTable"	格式化的损失值表格

	"ThresholdValues"	每个小波系数的阈值
	"ThresholdTable"	格式化的阈值

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

DiscreteWaveletData

更多信息和选项

范例

基本范例 (3)

范围 (25)

基本用途 (8)

获取系数 (7)

设置系数 (6)

属性 (4)

选项 (7)

Method (1)

Padding (2)

SampleRate (1)

WorkingPrecision (3)

应用 (3)

属性和关系 (4)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

	"DataDimensions"	原数据的维数
	"DataChannels"	数据通道数
	"DataWrapper"	重建后应用于数据的包装函数

Method	Automatic	所使用的方法
Padding	"Periodic"	如何把数据扩展到边界之外
SampleRate	Automatic	声音数据的采样率
WorkingPrecision	MachinePrecision	内部计算所用的精度

DiscreteWaveletData

更多信息和选项

范例

基本范例 (3)

范围 (25)

基本用途 (8)

获取系数 (7)

设置系数 (6)

属性 (4)

选项 (7)

Method (1)

Padding (2)

SampleRate (1)

WorkingPrecision (3)

应用 (3)

属性和关系 (4)

可能存在的问题 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX