Wolfram 语言与系统参考资料中心

DiscreteWaveletTransform

DiscreteWaveletPacketTransform[data]

给出一个 data 阵列的离散小波包变换(DWPT).

DiscreteWaveletPacketTransform[data,wave]

给出使用小波 wave 的离散小波包变换.

DiscreteWaveletPacketTransform[data,wave,r]

给出使用 r 精细度的离散小波包变换.

范例

打开所有单元关闭所有单元

基本范例 (3)

使用 HaarWavelet 计算离散小波变换：

Wolfram Language code: DiscreteWaveletTransform[{56, 40, 8, 24, 48, 48, 40, 16}]

使用 Normal 查看所有系数：

Wolfram Language code: Normal[%]

对音频信号进行变换：

Wolfram Language code: a = Audio["ExampleData/rule30.wav"]

Wolfram Language code: dwd = DiscreteWaveletTransform[a, Automatic, 3]

用 dwd[…,"Audio"] 提取系数信号：

Wolfram Language code: dwd[All, "Audio"]

计算逆变换：

Wolfram Language code: InverseWaveletTransform[dwd]

变换一个 Image 对象：

Wolfram Language code: dwd = DiscreteWaveletTransform[[image], Automatic, 2]

使用 dwd[…,"Image"] 提取系数图像：

Wolfram Language code: dwd[All, "Image"]

计算逆变换：

Wolfram Language code: InverseWaveletTransform[dwd]

范围 (36)

基本用途 (6)

计算一个小波变换：

Wolfram Language code: dwd = DiscreteWaveletTransform[{0, 0, 1, 0, 0}]

由此得出的 DiscreteWaveletData 表示变换系数的树：

Wolfram Language code: dwd["TreeView"]

逆变换重构输入：

Wolfram Language code: InverseWaveletTransform[dwd]

有用的属性可以从 DiscreteWaveletData 对象中提取：

Wolfram Language code: dwd = DiscreteWaveletTransform[RandomReal[1, {16}], DaubechiesWavelet[4], 2]

获取属性的全部列表：

Wolfram Language code: dwd["Properties"]

获取数据和系数维数：

Wolfram Language code: dwd["DataDimensions"]

Wolfram Language code: dwd["Dimensions"]

使用 Normal 明确获取所有小波系数：

Wolfram Language code: dwd = DiscreteWaveletTransform[Range[8]];

Wolfram Language code: Normal[dwd]

使用 All 作为一个参数获得所有系数：

Wolfram Language code: dwd[All]

使用 Automatic 只获得用于逆变换的系数：

Wolfram Language code: dwd[Automatic]

使用 "TreeView" 或 "WaveletIndex" 找到哪个小波系数可用：

Wolfram Language code: dwd = DiscreteWaveletTransform[Range[8], HaarWavelet[], 2];

Wolfram Language code: dwd["TreeView"]

Wolfram Language code: dwd["WaveletIndex"]

提取指定的系数阵列：

Wolfram Language code: dwd[{0}]

Wolfram Language code: dwd[{0, 0}]

提取多个对应于小波索引指标列表的小波系数：

Wolfram Language code: dwd[{{0}, {0, 1}}]

提取小波索引与模式匹配的所有系数：

Wolfram Language code: dwd[{_}]

Wolfram Language code: dwd[{{_, 0}, {_, 1}}]

Automatic 系数在函数诸如 WaveletListPlot 中被默认使用：

Wolfram Language code: dwd = DiscreteWaveletTransform[Table[Sin[x ^ 2], {x, 0, 10, 0.2}], Automatic, 4];

Wolfram Language code: First /@ dwd[Automatic]

Wolfram Language code: WaveletListPlot[dwd, Ticks -> Full]

使用更高的精细度增加频率分辨率：

Wolfram Language code: data = Table[Sin[x ^ 2] + RandomReal[{-0.2, 0.2}], {x, 0, 10, 0.02}];

Wolfram Language code: ListLinePlot[data]

更小的精细度，更多的信号能量存在于 {0,0,0}：

Wolfram Language code: dwt1 = DiscreteWaveletTransform[data, DaubechiesWavelet[4], 3];

Wolfram Language code: WaveletListPlot[dwt1, PlotLayout -> "CommonYAxis"]

更高的精细度，{0,0,0} 分解进更多的组件中：

Wolfram Language code: dwt2 = DiscreteWaveletTransform[data, DaubechiesWavelet[4], 4];

Wolfram Language code: WaveletListPlot[dwt2, PlotLayout -> "CommonYAxis"]

小波族 (10)

使用不同的小波族计算离散小波变换：

Wolfram Language code: data = Table[Sin[x ^ 2], {x, 0, 10, 0.02}];

Wolfram Language code:

dwd1 = DiscreteWaveletTransform[data, DaubechiesWavelet[4], 3];
dwd2 = DiscreteWaveletTransform[data, SymletWavelet[4], 3];

比较系数：

Wolfram Language code: {WaveletListPlot[dwd1], WaveletListPlot[dwd2]}

使用不同的小波族，捕捉不同的特征：

Wolfram Language code: data = Table[Sin[t^2], {t, -3π, 3π, 0.01}];

Wolfram Language code: ListLinePlot[data]

HaarWavelet（默认的）：

Wolfram Language code: dwd = DiscreteWaveletTransform[data, HaarWavelet[], 3];

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", Filling -> Axis]

DaubechiesWavelet:

Wolfram Language code: data = Table[Sin[t^2], {t, -3π, 3π, 0.01}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data, DaubechiesWavelet[2], 3];

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", Filling -> Axis]

BattleLemarieWavelet:

Wolfram Language code: data = Table[Sin[t^2], {t, -3π, 3π, 0.01}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data, BattleLemarieWavelet[3], 3];

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", Filling -> Axis]

BiorthogonalSplineWavelet:

Wolfram Language code: data = Table[Sin[t^2], {t, -3π, 3π, 0.01}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data, BiorthogonalSplineWavelet[4, 2], 3];

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", Filling -> Axis]

CoifletWavelet:

Wolfram Language code: data = Table[Sin[t^2], {t, -3π, 3π, 0.01}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data, CoifletWavelet[2], 3];

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", Filling -> Axis]

MeyerWavelet:

Wolfram Language code: data = Table[Sin[t^2], {t, -3π, 3π, 0.01}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data, MeyerWavelet[3], 3];

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", Filling -> Axis]

ReverseBiorthogonalSplineWavelet:

Wolfram Language code: data = Table[Sin[t^2], {t, -3π, 3π, 0.01}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data, ReverseBiorthogonalSplineWavelet[4, 2], 3];

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", Filling -> Axis]

ShannonWavelet:

Wolfram Language code: data = Table[Sin[t^2], {t, -3π, 3π, 0.01}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data, ShannonWavelet[8], 3];

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", Filling -> Axis]

SymletWavelet:

Wolfram Language code: data = Table[Sin[t^2], {t, 0, 3π, 0.01}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data, SymletWavelet[3], 3];

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis", Filling -> Axis]

矢量数据 (6)

使用 WaveletListPlot 在共同横轴上绘制系数：

Wolfram Language code: dwd = DiscreteWaveletTransform[Table[Sin[x ^ 2], {x, 0, 10, 0.02}], Automatic, 3];

Wolfram Language code: WaveletListPlot[dwd]

在共同纵轴上绘制：

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis"]

使用 WaveletScalogram 可视化作为时间函数的系数和精细度：

Wolfram Language code: dwd = DiscreteWaveletTransform[Table[Sin[20x] + Sin[10x], {x, 1, 10, 0.01}], Automatic, 4];

当鼠标移至系数时，系数索引在提示文本中出现：

Wolfram Language code: WaveletScalogram[dwd, All]

常数数据：

Wolfram Language code: data = Table[1, {x, 0, 10, 0.02}];

Wolfram Language code: ListLinePlot[data]

所有系数都小，除了粗系数 {0,0,…}：

Wolfram Language code: dwd = DiscreteWaveletTransform[data, DaubechiesWavelet[4], 3];

Wolfram Language code: WaveletListPlot[dwd, All, PlotLayout -> "CommonYAxis"]

在最高可解析的频率（奈奎斯特频率）的数据振荡：

Wolfram Language code: data = Table[(-1)^n, {n, 80}];

Wolfram Language code: ListLinePlot[data]

只有第一个细节系数 {1} 不小：

Wolfram Language code: dwd = DiscreteWaveletTransform[data, Automatic, 3];

Wolfram Language code: WaveletListPlot[dwd, All, PlotLayout -> "CommonYAxis", Ticks -> Full]

具有很大不连续的数据：

Wolfram Language code: data = Table[Piecewise[{{1, 1 < x < 3.1}}, 0], {x, 0, 4, 0.02}];

Wolfram Language code: ListLinePlot[data]

粗系数 {0,…} 具有与数据一样大的结构规模：

Wolfram Language code: dwd = DiscreteWaveletTransform[data, Automatic, 3];

Wolfram Language code: WaveletListPlot[dwd, {0..}, FrameTicks -> Full]

细节系数对不连续很明感：

Wolfram Language code: WaveletListPlot[dwd, Except[{0..}], FrameTicks -> Full]

具有空间和频率的结构的数据：

Wolfram Language code: data = Table[Piecewise[{{5, n <= 30}, {2 + (-1)^n, Inequality[30, Less, n, LessEqual, 60]}, {5, 60 < n}}], {n, 90}];

Wolfram Language code: ListLinePlot[data, PlotRange -> {0, 5}]

粗系数 {0,…} 跟踪数据的局部均值：

Wolfram Language code: dwd = DiscreteWaveletTransform[data, Automatic, 3];

Wolfram Language code: WaveletListPlot[dwd, {0..}, Ticks -> Full]

第一个细节系数识别振荡区域：

Wolfram Language code: WaveletListPlot[dwd, {1, 0...}, Ticks -> Full]

在共同垂直轴上的所有系数：

Wolfram Language code: WaveletListPlot[dwd, All, PlotLayout -> "CommonYAxis", AxesOrigin -> {0, -5}]

矩阵数据 (5)

计算一个二维的离散小波变换：

Wolfram Language code:

dwd = DiscreteWaveletTransform[(⁠|   |   |   |   |   |
| - | - | - | - | - |
| 0 | 0 | 1 | 0 | 0 |
| 0 | 1 | 1 | 1 | 0 |
| 1 | 1 | 1 | 1 | 1 |
| 0 | 1 | 1 | 1 | 0 |
| 0 | 0 | 1 | 0 | 0 |⁠)]

小波系数树的视图：

Wolfram Language code: dwd[{"TreeView", Left}]

进行逆变换找回原始的信号：

Wolfram Language code: InverseWaveletTransform[dwd]//Chop//MatrixForm

使用 WaveletMatrixPlot 可视化不同的小波系数：

Wolfram Language code: dwd = DiscreteWaveletTransform[DiamondMatrix[32], Automatic, 2]

Wolfram Language code: WaveletMatrixPlot[dwd, ImageSize -> Small]

更高精细层的小波变换的 WaveletMatrixPlot：

Wolfram Language code: WaveletMatrixPlot[DiscreteWaveletTransform[DiamondMatrix[32], Automatic, 3], ImageSize -> Small]

二维中，每个方向的滤波操作矢量是可以计算的：

Wolfram Language code: Tuples[{0, 1}, 2] /. {0 -> "lowpass", 1 -> "highpass"}

作为二进制数字扩展来诠释这些向量，我们可以获得小波索引数：

Wolfram Language code: FromDigits[#, 2]& /@ Tuples[{0, 1}, 2]

获得哈尔小波的低通和高通滤波器：

Wolfram Language code: {lp, hp} = Map[Last, WaveletFilterCoefficients[HaarWavelet[], {"PrimalLowpass", "PrimalHighpass"}], {2}]

由此得到的2D滤波器是两个方向滤波器的外积：

Wolfram Language code: Apply[KroneckerProduct, Tuples[{lp, hp}, 2], {1}]

Wolfram Language code: Map[MatrixPlot, %]

阶梯数据的小波变换：

Wolfram Language code:

step[{a_, b_, c_, d_}] := 
	ArrayFlatten[{{ConstantArray[a, {3, 3}], ConstantArray[b, {3, 5}]}, {ConstantArray[c, {5, 3}], ConstantArray[d, {5, 5}]}}];

具有垂直不连续的数据：

Wolfram Language code: MatrixPlot[step[{0, 1, 0, 1}], FrameTicks -> False]

只有垂直细节系数，小波索引 {…,1} 不为零：

Wolfram Language code: WaveletMatrixPlot[DiscreteWaveletTransform[step[{0, 1, 0, 1}]], ImageSize -> Small]

具有水平不连续的数据：

Wolfram Language code: MatrixPlot[step[{0, 0, 1, 1}], FrameTicks -> False]

只有水平细节系数，小波索引 {…,2} 不为零：

Wolfram Language code: WaveletMatrixPlot[DiscreteWaveletTransform[step[{0, 0, 1, 1}]], ImageSize -> Small]

具有对角不连续的数据：

Wolfram Language code: MatrixPlot[Reverse@IdentityMatrix[8], FrameTicks -> False]

只有对角细节系数，小波索引 {…,3} 不为零：

Wolfram Language code: WaveletMatrixPlot[DiscreteWaveletTransform[Reverse@IdentityMatrix[8]], ImageSize -> Small]

阵列数据 (2)

计算一个三维离散小波变换：

Wolfram Language code: data = RandomReal[1, {16, 16, 16}];

Wolfram Language code: dwd = DiscreteWaveletTransform[data, Automatic, 2]

所有系数的树视图：

Wolfram Language code: dwd["TreeView"]

逆变换找回原始信号：

Wolfram Language code: Norm[Flatten[data - InverseWaveletTransform[dwd]]]

三维交叉阵列的小波变换：

Wolfram Language code: data = CrossMatrix[All, {8, 8, 8}];

Wolfram Language code: Graphics3D[{Red, Cuboid /@ Position[data, 1]}]

Wolfram Language code: dwd = DiscreteWaveletTransform[data, Automatic, 1]

可视化小波系数：

Wolfram Language code:

Table[i -> Graphics3D[{If[Positive[Extract[dwd[i][[1, 2]], #]], Red, Green], Cuboid[#]}& /@ Position[dwd[i][[1, 2]], u_ /; Abs[u] > 0], PlotRange -> Automatic], {i, dwd["IndexMap"]}]

变换系数时，原始数据的能量是守恒的：

Wolfram Language code: Total[Flatten[data]^2] == Total[Flatten[dwd[Automatic][[All, 2]]]^2]

图像数据 (4)

变换一个 Image 对象：

Wolfram Language code: img = Image[DiamondMatrix[All, {64, 64}]]

Wolfram Language code: dwd = DiscreteWaveletTransform[img, HaarWavelet[], 3]

逆变换产生一个重建的 Image 对象：

Wolfram Language code: InverseWaveletTransform[dwd]

小波系数通常以每个图像通道的数据列表形式给出：

Wolfram Language code: dwd = DiscreteWaveletTransform[[image], HaarWavelet[], 2];

Wolfram Language code: Dimensions[{0, 0} /. Normal[dwd]]

获取以 Image 对象表示的所有系数：

Wolfram Language code: dwd[All, {"Image", ImageSize -> 80}]

获取原 Image 对象，没有调整色彩级别：

Wolfram Language code: dwd[All, {"Image", "ImageFunction" -> Identity, ImageSize -> 80}]

以 Image 对象的形式获得 {0,1} 系数的逆变换：

Wolfram Language code: dwd[{0, 1}, {"Image", "Inverse"}]

使用 WaveletImagePlot 在分层网格中绘制逆变换中的系数：

Wolfram Language code: dwd = DiscreteWaveletTransform[[image], HaarWavelet[], 3];

Wolfram Language code: WaveletImagePlot[dwd, BaseStyle -> Red]

Image 小波系数位于 ImageType 有效范围之外：

Wolfram Language code: img = [image];

Wolfram Language code: dwd = DiscreteWaveletTransform[img, CDFWavelet["9/7"], 1];

"ImageFunction"->Identity 给出没有归一化的图像小波系数：

Wolfram Language code: i1 = First[dwd[{0}, {"Values", {"Image", "ImageFunction" -> Identity}}]];

Wolfram Language code: {r1, g1, b1} = Flatten /@ ImageData /@ ColorSeparate[i1];

色彩通道位于其有效的0到1的范围之外：

Wolfram Language code: {i1, BoxWhiskerChart[{r1, g1, b1}, ChartStyle -> {Red, Green, Blue}]}

默认情况下，"ImageFunction"-> ImageAdjust 被用于归一化系数：

Wolfram Language code: i2 = First[dwd[{0}, {"Values", {"Image", "ImageFunction" -> ImageAdjust}}]];

Wolfram Language code: {r2, g2, b2} = Flatten /@ ImageData /@ ColorSeparate[i2];

现在色彩通道在有效的0到1范围之内：

Wolfram Language code: {i2, BoxWhiskerChart[{r2, g2, b2}, ChartStyle -> {Red, Green, Blue}]}

声数据 (3)

变换一个 Sound 对象：

Wolfram Language code: snd = ExampleData[{"Sound", "Apollo11ReturnSafely"}]

Wolfram Language code: dwd = DiscreteWaveletTransform[snd]

逆变换产生一个重建的 Sound 对象：

Wolfram Language code: InverseWaveletTransform[dwd]

默认情况下，系数是以每个声通道的数据列表的形式给出：

Wolfram Language code: dwd = DiscreteWaveletTransform[ExampleData[{"Sound", "PianoScale"}]];

Wolfram Language code: Dimensions[{0, 0, 1} /. Normal[dwd]]

以 Sound 对象的形式给出系数 {0,1}：

Wolfram Language code: dwd[{0, 0, 1}, "Sound"]

以 Sound 对象的形式给出系数 {0,0,1} 的逆变换：

Wolfram Language code: dwd[{0, 0, 1}, {"Sound", "Inverse"}]

使用 MenuView 浏览所有系数：

Wolfram Language code: dwd = DiscreteWaveletTransform[ExampleData[{"Sound", "Clarinet"}]];

Wolfram Language code: MenuView[dwd[All, "Sound"]]

推广和延伸 (3)

DiscreteWaveletTransform 可用于符号量的阵列：

Wolfram Language code: dwd = DiscreteWaveletTransform[{a, b, c, d}, WorkingPrecision -> ∞];

Wolfram Language code: Normal[dwd]//Simplify

逆变换确切地恢复输入：

Wolfram Language code: InverseWaveletTransform[dwd]//Simplify

指定内部工作精度：

Wolfram Language code: dwd = DiscreteWaveletTransform[{1, 2, 5, 2}, WorkingPrecision -> 20];

Wolfram Language code: Normal[dwd]

使用复数值数据：

Wolfram Language code: data = Exp[I RandomReal[1, 4]];

Wolfram Language code: dwd = DiscreteWaveletTransform[data]

小波系数是复数：

Wolfram Language code: dwd[Automatic]

逆变换恢复输入：

Wolfram Language code: Norm[InverseWaveletTransform[dwd] - data]

选项 (5)

Padding (2)

Padding 的设置与 ArrayPad 的方法一样，包括 "Periodic"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Periodic"]

"Reversed":

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reversed"]

"ReversedNegation":

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedNegation"]

"Reflected":

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reflected"]

"ReflectedDifferences":

Wolfram Language code: ArrayPad[{a, b, c}, 3, "ReflectedDifferences"]

"ReversedDifferences":

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedDifferences"]

"Extrapolated":

Wolfram Language code: ArrayPad[{a, b, c}, 3, "Extrapolated"]

填充可以去除边界效应：

Wolfram Language code: data = Table[UnitStep[x], {x, -2, 2, 4 / 255}];

Wolfram Language code: ListLinePlot[data]

默认情况下使用 "Periodic" 填充：

Wolfram Language code: dwt1 = DiscreteWaveletTransform[data, DaubechiesWavelet[2], 5];

Wolfram Language code: WaveletListPlot[dwt1]

"Extrapolated" 填充对非周期数据具有较少的边界效应：

Wolfram Language code: dwt2 = DiscreteWaveletTransform[data, DaubechiesWavelet[2], 5, Padding -> "Extrapolated"];

Wolfram Language code: WaveletListPlot[dwt2]

WorkingPrecision (3)

默认情况下，使用 WorkingPrecision->MachinePrecision：

Wolfram Language code: data = RandomInteger[1, {10}];

Wolfram Language code: dwd1 = DiscreteWaveletTransform[data]

Wolfram Language code: dwd2 = DiscreteWaveletTransform[data, WorkingPrecision -> MachinePrecision]

Wolfram Language code: dwd1 == dwd2

使用更高精度的计算：

Wolfram Language code: data = {0, 0, 1, 1};

Wolfram Language code: dwd = Normal@DiscreteWaveletTransform[data, WorkingPrecision -> 30]

随着数字接近于零，Accuracy 可以更好地表明正确的数字：

Wolfram Language code: {Precision[dwd], Accuracy[dwd]}

使用 WorkingPrecision->∞ 进行确切计算：

Wolfram Language code: data = RandomInteger[10, {4}];

Wolfram Language code: Normal@DiscreteWaveletTransform[data, WorkingPrecision -> ∞]//Simplify

应用 (11)

小波压缩 (1)

通过找到与几个非零系数的表示压缩数据：

Wolfram Language code: data = Table[t^3, {t, -1, 1, 2 / 2047}];

Wolfram Language code: ListLinePlot[data]

SymletWavelet[n] 有 n 个消失矩，表示 n 次多项式：

Wolfram Language code: dwd = Table[DiscreteWaveletTransform[data, SymletWavelet[n], Padding -> "Extrapolated"], {n, 5}];

Count 小波系数接近于0的数目：

Wolfram Language code: Table[n -> Count[Flatten[dwd[[n]][Automatic][[All, 2]]], u_ /; Chop[Abs[u], 10^-3] == 0], {n, 5}]

检测不连续性和边缘 (2)

在小波域中可视化不连续性：

Wolfram Language code: data = Table[HeavisideLambda[x], {x, -2, 2, 4 / 1023}];

Wolfram Language code: ListLinePlot[data]

不连续域的细节系数有更大的值：

Wolfram Language code: dwd = DiscreteWaveletTransform[data, DaubechiesWavelet[3], 5, Padding -> "Reflected"];

Wolfram Language code: WaveletScalogram[dwd, {___, 1}, Method -> "Inverse" -> True, ColorFunction -> "BlueGreenYellow"]

检测图像的边缘：

Wolfram Language code: dwd = DiscreteWaveletTransform[[image], SymletWavelet[2], 4];

Wolfram Language code: WaveletImagePlot[dwd, Automatic, ImageAdjust[ImageAdjust[#], {1, 0.2, 1.9}]&]

设置粗系数为0，只用细节系数进行重建：

Wolfram Language code:

imgEdge[img_, {0, 0, 0, 0}] := ImageApply[# 0.0&, img]
imgEdge[img_, ___] := ImageApply[# 2&, img]

Wolfram Language code: Sharpen[InverseWaveletTransform[WaveletMapIndexed[imgEdge, dwd]]]

能量比较 (1)

比较信号的累积能量、小波系数和傅立叶系数：

Wolfram Language code: data = Table[N[2 - 5t + 5 Exp[-500(t - 0.5)^2]], {t, 0, 1, 1 / 63}];

Wolfram Language code: ListLinePlot[data]

计算信号中排序的累积能量：

Wolfram Language code: cumulativeEnergy[data_] := Module[{c = Sort[Flatten[data]^2, Greater]}, Accumulate[c] / Total[c]]

Wolfram Language code: ListLinePlot[cumulativeEnergy[data]]

计算小波系数和傅立叶系数：

Wolfram Language code: dwd = DiscreteWaveletTransform[data];

Wolfram Language code: dft = Fourier[data];

DWT 比 DFT 捕获更多的能量，用更少的系数：

Wolfram Language code:

ListLinePlot[{cumulativeEnergy[data], cumulativeEnergy[Last /@ dwd[Automatic]], cumulativeEnergy[Abs[dft]]}, BaseStyle -> Thick, PlotStyle -> {Red, Blue, Orange}, PlotRange -> All]

降噪 (3)

执行依赖能量的阈值：

Wolfram Language code: data = Table[Sin[x] + RandomReal[{-0.1, 0.1}], {x, 0, 2π, 0.01}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: dwd = DiscreteWaveletTransform[data, SymletWavelet[4], 6];

计算每个精细度包含的能量比例：

Wolfram Language code: efrac = dwd["EnergyFraction"]

设置所含能量少于1%的小波系数为0：

Wolfram Language code:

eth[x_, ind_] := If[(ind /. efrac) < 0.01, x * 0., x] /; MemberQ[efrac[[All, 1]], ind]
eth[x_, ___] := x

Wolfram Language code: WaveletMapIndexed[eth, dwd];

Wolfram Language code: ListLinePlot[InverseWaveletTransform[%]]

执行依赖于幅度的阈值：

Wolfram Language code:

data = Table[N[5Exp[-100(t - 0.5)^2] + 5Exp[-10t]], {t, 0, 1, 1 / 511}];
noise = RandomVariate[NormalDistribution[0, 0.2], Length[data]];

Wolfram Language code: ListLinePlot[data + noise]

Wolfram Language code: dwd = DiscreteWaveletTransform[data + noise, DaubechiesWavelet[4]];

使用 WaveletThreshold 执行 "Universal" 阈值：

Wolfram Language code: WaveletThreshold[dwd];

Wolfram Language code: ListLinePlot[{InverseWaveletTransform[%], data}]

使用 Stein 的无偏风险估计平滑：

Wolfram Language code: WaveletThreshold[dwd, "SURE"];

Wolfram Language code: ListLinePlot[{InverseWaveletTransform[%], data}]

对一个 Image 进行降噪：

Wolfram Language code: nimg = ImageEffect[[image], {"GaussianNoise", 0.2}];

Wolfram Language code: dwd = DiscreteWaveletTransform[nimg, BiorthogonalSplineWavelet[5, 5]];

执行 "Soft" 阈值，每一级自适应计算阈值 "SURE"：

Wolfram Language code: wtdwd = WaveletThreshold[dwd, {"Soft", "SURELevel"}, {1 | 2 | 3}];

逆变换阈值系数：

Wolfram Language code: {Image[InverseWaveletTransform[wtdwd], ImageSize -> All], Image[nimg, ImageSize -> All]}

频率滤波 (1)

小波变换可用于滤波频率：

Wolfram Language code: d1 = Table[Sin[x] + Cos[2x], {x, -2π, 2π, (4π/2047)}];

Wolfram Language code: d2 = Table[(ArcSin[Sin[20x]]/5), {x, -2π, 2π, (4π/2047)}];

Wolfram Language code: ListLinePlot[d1 + d2]

滤波两个信号，首先执行小波变换：

Wolfram Language code: dwd = DiscreteWaveletTransform[d1 + d2, SymletWavelet[4], 6];

使用 WaveletListPlot 可视化频率分布：

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonXAxis", DataRange -> {-2π, 2π}]

滤波低频，只保留粗系数：

Wolfram Language code: rdwd1 = WaveletMapIndexed[(# * 0.0)&, dwd, {___, 1}];

Wolfram Language code:

{ListLinePlot[d1, PlotLabel -> "data"], ListLinePlot[InverseWaveletTransform[rdwd1], PlotLabel -> "filtered coarse data"]}

滤波高频，只保留细节系数：

Wolfram Language code: rdwd2 = WaveletMapIndexed[(# * 0.0)&, dwd, {___, 0}];

Wolfram Language code: {ListLinePlot[d2, PlotLabel -> "data"], ListLinePlot[InverseWaveletTransform[rdwd2], PlotLabel -> "filtered fine data"]}

金融 (3)

提取自从2000年1月1日的 IBM 股票价格趋势：

Wolfram Language code: price = FinancialData["IBM", "Jan. 1, 2000"];

Wolfram Language code: DateListPlot[price, Joined -> True, Frame -> False]

Wolfram Language code: dwd = DiscreteWaveletTransform[QuantityMagnitude[price["Values"]], BiorthogonalSplineWavelet[3, 3], 4];

在低通滤波器系数中捕获该序列趋势：

Wolfram Language code: WaveletListPlot[dwd, PlotLayout -> "CommonYAxis"]

阈值所有细节系数，逆变换该序列给出趋势：

Wolfram Language code: tr = InverseWaveletTransform[WaveletThreshold[dwd, {"Hard", 100}]];

Wolfram Language code: DateListPlot[Transpose[{price["Times"], tr}], Joined -> True, Frame -> False]

去趋势金融序列：

Wolfram Language code: price = FinancialData["AAPL", "Jan. 1, 2009"];

Wolfram Language code: DateListPlot[price, Joined -> True, Frame -> False]

Wolfram Language code: dwd = DiscreteWaveletTransform[QuantityMagnitude[price["Values"]], SymletWavelet[2], 4, Padding -> "Extrapolated"]

细节系数捕获去趋势序列：

Wolfram Language code: WaveletListPlot[dwd]

通过去除粗系数和逆变换去除趋势：

Wolfram Language code: dtr = InverseWaveletTransform[WaveletMapIndexed[# 0.0&, dwd, {___, 0}]];

Wolfram Language code: DateListPlot[Transpose[{price["Times"], dtr}], Joined -> True]

在金融时间序列中研究利润的变动：

Wolfram Language code: ret = FinancialData["GE", "Return", {{1962, 1, 1}, {1963, 1, 1}, "Day"}];

Wolfram Language code: DateListPlot[ret, PlotRange -> All]

使用 HaarWavelet 和 SymletWavelet 执行小波变换：

Wolfram Language code:

dwd1 = DiscreteWaveletTransform[QuantityMagnitude[ret["Values"]], HaarWavelet[], 4];
dwd2 = DiscreteWaveletTransform[QuantityMagnitude[ret["Values"]], SymletWavelet[8], 4];

因为 GE 的利润系列没有出现低频振荡，更高尺度的细节系数没有表明相对于零点的大的波动：

Wolfram Language code: WaveletListPlot[{dwd1, dwd2}, PlotLayout -> "CommonYAxis"]

虽然两个滤波器会捕获序列的变动，它们是不同地分布因为它们近似带通的属性：

Wolfram Language code: hvar = Variance[#[[2]]]& /@ dwd1[Automatic];

Wolfram Language code: symvar = Variance[#[[2]]]& /@ dwd2[Automatic];

SymletWavelet 在某个频率间隔的隔离特征好于 HaarWavelet：

Wolfram Language code:

BarChart[Transpose@{hvar, symvar}, ChartLabels -> {Placed[dwd1[Automatic, "IndexMap"], Axis, Rotate[#, -Pi / 4]&], None}, ChartLegends -> {"Haar Wavelet", "Symlet Wavelet"}, ChartStyle -> {Orange, Green}]

属性和关系 (15)

DiscreteWaveletPacketTransform 计算小波系数的全树：

Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[{1, 1, 3, 1, 1}];

Wolfram Language code: dwpt[{"TreeView", Left}]

DiscreteWaveletTransform 计算系数全树的子集：

Wolfram Language code: dwt = DiscreteWaveletTransform[{1, 1, 3, 1, 1}];

Wolfram Language code: dwt[{"TreeView", Left}]

DiscreteWaveletTransform 系数在每个精细度层上长度减半：

Wolfram Language code: Normal[DiscreteWaveletTransform[{1, 2, 3, 4}]]

旋转数据给出不同的系数：

Wolfram Language code: Normal[DiscreteWaveletTransform[{2, 3, 4, 1}]]

StationaryWaveletTransform 系数具有与原始数据一样的长度：

Wolfram Language code: Normal[StationaryWaveletTransform[{1, 2, 3, 4}]]

旋转数据给出旋转系数：

Wolfram Language code: Normal[StationaryWaveletTransform[{2, 3, 4, 1}]]

多维离散小波变换与一维包变换相关：

Wolfram Language code:

dwt = DiscreteWaveletTransform[(⁠|   |   |
| - | - |
| a | b |
| c | d |⁠), WorkingPrecision -> ∞];

Wolfram Language code: Simplify[dwt[Automatic]]

Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[{a, b, c, d}, WorkingPrecision -> ∞];

Wolfram Language code: Simplify[dwpt[Automatic]]

对于哈尔小波（默认）和数据长度，计算得出的系数是一样的：

Wolfram Language code: Sort[Expand@Simplify@Flatten[dwt[Automatic, "Values"]]] == Sort[Flatten[Expand[dwpt[Automatic, "Values"]]]]

默认的精细度由 $TemplateBox[{{{InterpretationBox[{log, _, DocumentationBuild`Utils`Private`Parenth[2]}, Log2, AutoDelete -> True], (, n, )}, +, {1, /, 2}}}, Floor]$ 给出：

Wolfram Language code: data = RandomReal[1, {100}];

Wolfram Language code: r = Floor[Log2[Length[data]] + (1/2)]

Wolfram Language code: DiscreteWaveletTransform[data] == DiscreteWaveletTransform[data, Automatic, r]

更高维的：

Wolfram Language code: data = RandomReal[1, {100, 10, 10}];

Wolfram Language code: r = Floor[Log2[Min[Dimensions[data]]] + (1/2)]

Wolfram Language code: DiscreteWaveletTransform[data] == DiscreteWaveletTransform[data, Automatic, r]

对于正交小波族，能量范数是守恒的：

Wolfram Language code: data = RandomReal[1, {100}];

Wolfram Language code: dwt = DiscreteWaveletTransform[data, Padding -> 0.];

Wolfram Language code: Norm[data] == Norm[Flatten[Last /@ dwt[Automatic]]]

对于双正交小波族，能量范数是近似守恒的：

Wolfram Language code: data = RandomReal[1, {100}];

Wolfram Language code: dwt = DiscreteWaveletTransform[data, BiorthogonalSplineWavelet[2, 4], Padding -> 0.];

Wolfram Language code: Norm[data]

Wolfram Language code: Norm[Flatten[Last /@ dwt[Automatic]]]

数据均值在变换的最大精细度层获得：

Wolfram Language code: data = RandomReal[1, {64}];

Wolfram Language code: dwt = DiscreteWaveletTransform[data, HaarWavelet[]];

提取最大精细度的系数：

Wolfram Language code: r = dwt["Refinement"]

Wolfram Language code: dwt[ConstantArray[0, {r}]]

在每个精细度上弥补的归一化：

Wolfram Language code: %[[1, 2, 1]] / (Sqrt[2])^r

Wolfram Language code: Mean[data]

来自于单个系数阵列的逆变换的和给出原始数据：

Wolfram Language code: data = Table[DiscreteDelta[n], {n, -2, 2}]

Wolfram Language code: dwt = DiscreteWaveletTransform[data];

Wolfram Language code: dwt["TreeView"]

单独逆变换每个小波系数阵列：

Wolfram Language code: data1 = InverseWaveletTransform[dwt, Automatic, {0, 0}]

Wolfram Language code: data2 = InverseWaveletTransform[dwt, Automatic, {0, 1}]

Wolfram Language code: data3 = InverseWaveletTransform[dwt, Automatic, {1}]

它们的和为原始数据：

Wolfram Language code: data1 + data2 + data3

计算周期数据的离散小波系数：

Wolfram Language code: x = Range[8];

Wolfram Language code: dwd = DiscreteWaveletTransform[x, HaarWavelet[]];

Wolfram Language code: J = dwd["Refinement"];

定义具有紧支集（compact support）的滤波系数：

Wolfram Language code:

lp = WaveletFilterCoefficients[HaarWavelet[], "PrimalLowpass"];
hp = WaveletFilterCoefficients[HaarWavelet[], "PrimalHighpass"];

Wolfram Language code:

a[n_] := If[1 ≤ n ≤ Length[lp], lp[[n, 2]], 0]
b[n_] := If[1 ≤ n ≤ Length[hp], hp[[n, 2]], 0]

在第层的粗系数由给出，其中：

Wolfram Language code: SetAttributes[c, Listable]

Wolfram Language code:

c[0, n_] := x[[n]];
c[j_, n_] := Sqrt[2] Underoverscript[∑, m = -20, 20]a[m - 2 n + 2] c[j - 1, Mod[m, Length[x], 1]]

Wolfram Language code: dwd[{___, 0}, "Values"] == Table[c[j, Range[2^J - j]], {j, 1, J}]

在第层的细节系数由给出：

Wolfram Language code: SetAttributes[d, Listable];

Wolfram Language code: d[j_, n_] := Sqrt[2]Underoverscript[∑, m = -20, 20]b[m - 2 n + 2] c[j - 1, Mod[m, Length[x], 1]]

Wolfram Language code: dwd[{___, 1}, "Values"] == Table[d[j, Range[2^J - j]], {j, 1, J}]

计算部分离散小波逆变换：

Wolfram Language code: x = Range[8];

Wolfram Language code: dwd = DiscreteWaveletTransform[x, HaarWavelet[]];

Wolfram Language code: J = dwd["Refinement"];

定义具有紧支集（compact support）的滤波系数：

Wolfram Language code:

lp = WaveletFilterCoefficients[HaarWavelet[], "PrimalLowpass"];
hp = WaveletFilterCoefficients[HaarWavelet[], "PrimalHighpass"];

Wolfram Language code:

a[n_] := If[1 ≤ n ≤ Length[lp], lp[[n, 2]], 0]
b[n_] := If[1 ≤ n ≤ Length[hp], hp[[n, 2]], 0]

在第层的粗系数为：

Wolfram Language code: SetAttributes[c, Listable]

Wolfram Language code:

c[0, n_] := x[[n]];
c[j_, n_] := c[j, n] = Sqrt[2] Underoverscript[∑, m = -20, 20]a[m - 2 n + 2] c[j - 1, Mod[m, Length[x], 1]]

在第层的细节系数为：

Wolfram Language code: SetAttributes[d, Listable];

Wolfram Language code: d[j_, n_] := d[j, n] = Sqrt[2]Underoverscript[∑, m = -20, 20]b[m - 2 n + 2] c[j - 1, Mod[m, Length[x], 1]]

在第层的小波逆变换由给出：

Wolfram Language code: SetAttributes[iwt, Listable];

Wolfram Language code:

iwt[j_Integer, n_Integer] := Sqrt[2]Underoverscript[∑, m = -20, 20]a[n - 2 m + 2]c[j + 1, Mod[m, 2^J - (j + 1), 1]]   + Sqrt[2]Underoverscript[∑, m = -20, 20]b[n - 2 m + 2]d[j + 1, Mod[m, 2^J - (j + 1), 1]]

在精细度时，重建粗系数 {0,0}：

Wolfram Language code: iwt[2, Range[2]] == First[dwd[{0, 0}, "Values"]]

在精细度时，重建粗系数 {0}：

Wolfram Language code: iwt[1, Range[4]] == First[dwd[{0}, "Values"]]

计算小波系数的维数：

Wolfram Language code: dwd = DiscreteWaveletTransform[RandomReal[1, {99}], SymletWavelet[4], 3];

Wolfram Language code: fl = Length[WaveletFilterCoefficients[dwd["Wavelet"]]];

在精细度为时，小波系数的维数由 $wd_(j+1)=TemplateBox[{{{1, /, 2}, , {(, {{wd, _, j}, +, fl, -, 2}, )}}}, Ceiling]$ 给出，其中表示输入 data 的维数：

Wolfram Language code: wd[0] := dwd["DataDimensions"];

Wolfram Language code: wd[j_] := Ceiling[(1/2) (wd[j - 1] + fl - 2)]

比较维数与 dwd 中的系数维数：

Wolfram Language code: Table[j -> wd[j], {j, dwd["Refinement"]}]

Wolfram Language code: Length[#[[1]]] -> #[[2]]& /@ (dwd["Dimensions"])

计算一维的哈尔离散小波变换：

Wolfram Language code:

low[v_] := Partition[v, 2].{(1/Sqrt[2]), (1/Sqrt[2])}
high[v_] := Partition[v, 2].{(1/Sqrt[2]), -(1/Sqrt[2])}

Wolfram Language code: HaarDWT[v_] := {{0} -> low[v], {1} -> high[v]};

计算 {0} 和 {1} 小波系数：

Wolfram Language code: HaarDWT[{a, b, c, d}]

与 DiscreteWaveletTransform 相比较：

Wolfram Language code: DiscreteWaveletTransform[{a, b, c, d}, HaarWavelet[], 1, WorkingPrecision -> ∞][All]

在二维中，每个方向应用分别的滤波器：

Wolfram Language code: f2d[fx_, fy_] := Composition[Map[fy, #]&, Map[fx, #]&]

哈尔小波的低通和高通滤波器：

Wolfram Language code:

low[v_] := Partition[v, 2].{(1/Sqrt[2]), (1/Sqrt[2])}
high[v_] := Partition[v, 2].{(1/Sqrt[2]), -(1/Sqrt[2])}

矩阵数据的哈尔小波变换：

Wolfram Language code: data = Table[Sin[x y], {x, -2, 2, 4 / 63}, {y, -2, 2, 4 / 63}];

Wolfram Language code:

Table[MatrixPlot[f2d[fx, fy][data], PlotLabel -> {fx, fy}, FrameTicks -> None], {fx, {low, high}}, {fy, {low, high}}]//Flatten

使用 HaarWavelet 与 DiscreteWaveletTransform 相比较：

Wolfram Language code: dwd = DiscreteWaveletTransform[data, HaarWavelet[], 1];

Wolfram Language code: Table[MatrixPlot[Last[p], PlotLabel -> First[p], FrameTicks -> None], {p, Normal[dwd]}]

图像通道是分别变换的：

Wolfram Language code: dwds = Map[DiscreteWaveletTransform, ColorSeparate[[image]]]

组合分别变换的图像通道的 {0} 系数：

Wolfram Language code: w = Image[Table[First[{0} /. Normal[t]], {t, dwds}], Interleaving -> False]

比较原始图像的 DiscreteWaveletTransform 的 {0} 系数：

Wolfram Language code: dwd = DiscreteWaveletTransform[[image]];

Wolfram Language code: {0} /. dwd[All, {"Image", "ImageFunction" -> Identity}]

图像是相同的：

Wolfram Language code: ImageSubtract[w, %]

DWT 类似于 LiftingWaveletTransform，需要额外的系数进行填充：

Wolfram Language code: data = Table[2Sin[x] + x / 2, {x, 0, 15, 15 / 63}];

Wolfram Language code:

dwt = DiscreteWaveletTransform[data, Automatic, 1];
lwt = LiftingWaveletTransform[data, Automatic, 1];

Wolfram Language code: WaveletListPlot[dwt, PlotLayout -> "CommonYAxis"]

Wolfram Language code: WaveletListPlot[lwt, PlotLayout -> "CommonYAxis"]

可能存在的问题 (1)

填充可能会影响小波系数的总能量：

Wolfram Language code: data = RandomReal[1, {10}];

Wolfram Language code: dwd1 = DiscreteWaveletTransform[data, DaubechiesWavelet[4], Padding -> "Fixed"];

能量不守恒：

Wolfram Language code: {Norm[data]^2, Norm[Flatten[Last /@ dwd1[Automatic]]]^2}

以0填充以确保系数的能量守恒：

Wolfram Language code: dwd2 = DiscreteWaveletTransform[data, DaubechiesWavelet[4], Padding -> 0];

Wolfram Language code: {Norm[data]^2, Norm[Flatten[Last /@ dwd2[Automatic]]]^2}

巧妙范例 (1)

创建一个填充的数据矩阵：

Wolfram Language code: data = ArrayPad[IdentityMatrix[4], 8, "Reflected"];

Wolfram Language code: ListPlot3D[data, InterpolationOrder -> 0, Mesh -> None, Filling -> Axis]

创建哈尔 DWT 系数的三维图：

Wolfram Language code:

WaveletPlot3D[wr_] := Map[First[#] -> ListPlot3D[Last[#], InterpolationOrder -> 0, Mesh -> None, Filling -> Axis]&, wr[All]]

Wolfram Language code: WaveletPlot3D[DiscreteWaveletTransform[data, HaarWavelet[], 2]]

Top

	list	任意阶数的数值数组
	image	任意 Image 对象
	audio	Audio 或抽样 Sound 对象

	BattleLemarieWavelet[…]	基于 B 样条的 Battle–Lemarié 小波
	BiorthogonalSplineWavelet[…]	B 样条为基础的小波
	CoifletWavelet[…]	Daubechies 小波的对称变量
	DaubechiesWavelet[…]	Daubechies 小波
	HaarWavelet[…]	典型的哈尔（Haar）小波
	MeyerWavelet[…]	在频域定义的小波
	ReverseBiorthogonalSplineWavelet[…]	B 样条为基础的小波（反向对偶和基本的）
	ShannonWavelet[…]	Sinc 函数为基础的小波
	SymletWavelet[…]	最不对称的正交小波

DiscreteWaveletTransform

更多信息和选项

范例

基本范例 (3)

范围 (36)

基本用途 (6)

小波族 (10)

矢量数据 (6)

矩阵数据 (5)

阵列数据 (2)

图像数据 (4)

声数据 (3)

推广和延伸 (3)

选项 (5)

Padding (2)

WorkingPrecision (3)

应用 (11)

小波压缩 (1)

检测不连续性和边缘 (2)

能量比较 (1)

降噪 (3)

频率滤波 (1)

金融 (3)

属性和关系 (15)

可能存在的问题 (1)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX