Wolfram 语言与系统参考资料中心

Dot

a.b.c 或 Dot[a,b,c]

给出向量、矩阵和张量的乘积.

范例

打开所有单元关闭所有单元

基本范例 (4)

三维向量的标量积：

Wolfram Language code: {a, b, c} . {x, y, z}

二维向量的标量积：

Wolfram Language code:

u = {1, 1};
v = {-1, 1};
u.v

如果向量的内积为零，则向量是互相垂直的：

Wolfram Language code: θ = VectorAngle[u, v]

可视化向量：

Wolfram Language code: GeometricScene[{"u" -> u, "v" -> v}, {PlanarAngle[{u, {0, 0}, v}] == θ}]["Graphics"]

矩阵和向量的积：

Wolfram Language code: {{a, b}, {c, d}} . {x, y}

向量和矩阵的积：

Wolfram Language code: {x, y} . {{a, b}, {c, d}}

矩阵和两个向量的积：

Wolfram Language code: {x, y} . {{a, b}, {c, d}} . {r, s}

两个矩阵的积：

Wolfram Language code: {{a, b}, {c, d}} . {{1, 2}, {3, 4}} //MatrixForm

以其他顺序相乘：

Wolfram Language code: {{1, 2}, {3, 4}} .{{a, b}, {c, d}} //MatrixForm

使用长方形矩阵：

Wolfram Language code: {{1, 2, 3}, {4, 5, 6}} .{{a, b}, {c, d}, {e, f}} //MatrixForm

范围 (28)

向量的点积 (7)

机器精度向量的标量积：

Wolfram Language code: Dot[{3.2, 4.2, 5.2}, {0.75, 1.1, 0.0625}]

精确向量的点积：

Wolfram Language code: {1, 2, 3, 4, 5}.{1, 8, 9, 0, -1}

符号向量的内积：

Wolfram Language code: {a, b, c} . {0, b, d + e}

任意精度向量的点积：

Wolfram Language code: {u, v} = RandomReal[4, {2, 3}, WorkingPrecision -> 20]

Wolfram Language code: u.v

Dot 允许复数输入，但不会取任意一个输入的共轭：

Wolfram Language code:

u = {1, 2 - I};
v = {z, 3};
u.v

如果想对复数或 Hermitian 内积进行计算，对其中一个输入应用 Conjugate：

Wolfram Language code: cDot[a_, b_] := Conjugate[a].b

Wolfram Language code: cDot[u, v]

一些资料，特别是在数学文献中，取第二个参数的共轭：

Wolfram Language code: cDot2[a_, b_] := a.Conjugate[b]

Wolfram Language code: cDot2[u, v]

用两个内积计算 u 的范数：

Wolfram Language code: {Sqrt[cDot[u, u]], Sqrt[cDot2[u, u]]}

用 Norm 验证结果：

Wolfram Language code: Norm[u]

稀疏向量的点积：

Wolfram Language code: v = SparseArray[{1 -> 1, 50 -> 3}, {100}]

Wolfram Language code: w = SparseArray[{50 -> 7, 100 -> 5}, {100}]

Wolfram Language code: v.w

计算两个 QuantityArray 向量的标量积：

Wolfram Language code: x = QuantityArray[{1, 2, 3}, "Meters"]

Wolfram Language code: f = QuantityArray[{0, 0, -9.8}, "Newtons"]

Wolfram Language code: x.f

矩阵-向量相乘 (5)

定义一个的矩阵：

Wolfram Language code:

r = {{0.187902, 0.498054, 0.767621}, {0.226789, 0.852257, 0.819982}};
r//MatrixForm

定义一个 2-向量和一个 3-向量：

Wolfram Language code:

v2 = {0.618678, 0.213605};
v3 = {0.804978, 0.587651, 0.2951};
{v2//MatrixForm, v3//MatrixForm}

矩阵只能从左侧被 2-向量相乘：

Wolfram Language code: v2.r

以相反的顺序相乘会因维数不兼容引发出错消息：

Wolfram Language code: r.v2

同样，矩阵只能从右侧被 3-向量相乘：

Wolfram Language code: r.v3

同时对矩阵两边相乘：

Wolfram Language code: v2.r.v3

定义一个方阵和一个兼容的向量：

Wolfram Language code:

m = {{1, 2}, {3, 4}};
v = {5, 6};

乘积 m.v 和 v.m 返回不同的向量：

Wolfram Language code: m . v

Wolfram Language code: v.m

乘积 v.m.v 是一个标量：

Wolfram Language code: v.m.v

定义一个列矩阵和一个行矩阵 c 和 r，其中的元素与 v 一样：

Wolfram Language code:

c = {{5}, {6}};
r = {{5, 6}};

涉及 m、c 和 r 的乘积与涉及 m 和 v 的乘积的元素一样，但都是矩阵：

Wolfram Language code: r.m

Wolfram Language code: m.c

Wolfram Language code: r.m.c

此外，产品必须按照符合矩阵维数的顺序完成：

Wolfram Language code: c.m.r

定义一个矩阵和两个向量：

Wolfram Language code:

m = {{.5, .32}, {.19, .73}};
u = {1.5, .27};
v = {-3.2, 5.5};

因为是一个向量，允许这样的乘积：

Wolfram Language code: m.u.v

注意，它实际上是在矩阵的左侧而不是右侧乘以：

Wolfram Language code: {v.m.u, u.m.v}

稀疏矩阵和稀疏向量的乘积是稀疏向量：

Wolfram Language code: SparseArray[{{1, 1} -> 5, {10, 10} -> 10}].SparseArray[{{10} -> 7}]

将结果格式化为行矩阵：

Wolfram Language code: MatrixForm[{%}]

一个稀疏矩阵和一个普通向量的乘积是一个正规向量：

Wolfram Language code: SparseArray[{{1, 1} -> 5, {10, 10} -> 10}].{1, 2, 3, 4, 5, 6, 7, 8, 9, 10}

如果可能，结构化矩阵与向量的乘积将保留结构：

Wolfram Language code: mat = SymmetrizedArray[{{1, 1} -> 2, {1, 2} -> 3, {2, 2} -> 5}, {2, 2}, Symmetric[{1, 2}]]

Wolfram Language code: mat.{7, 11}

Wolfram Language code: mat.SparseArray[{1, 2}]

正规矩阵与结构化向量的乘积可能具有向量的结构：

Wolfram Language code: {{2, 3}, {3, 5}}.QuantityArray[{a, b}, "Meters"]

矩阵-矩阵相乘 (11)

实机器数矩阵相乘：

Wolfram Language code:

m = {{1.2, 3.2, 5.2}, {2.2, 4.2, -6.4}, {3.1, 5.1, 7.3}};
n = {{4.2, 6.3, 8.2}, {2.5, -7.3, 9.3}, {6.3, 8.3, -1.10}};
m.n // MatrixForm

复矩阵的积：

Wolfram Language code:

m = {{1 + I, 2, 3 - 2 I}, {0, 4, 5I}, {0, 0, 6}};
n = {{6 + I, 4, 5 - 7 I}, {5, 3, 2I}, {5, 2, 7}};
m.n // MatrixForm

精确矩阵的积：

Wolfram Language code:

m = {{1, 2}, {3, 4}, {5, 6}};
n = {{6, 5, 4}, {3, 2, 1}};
m.n // MatrixForm

以另一种顺序相乘：

Wolfram Language code: n.m // MatrixForm

可视化输入和输出矩阵：

Wolfram Language code: {MatrixPlot[m], MatrixPlot[n], MatrixPlot[m.n], MatrixPlot[n.m]}

任意精度的矩阵相乘：

Wolfram Language code:

m = RandomReal[1, {4, 3}, WorkingPrecision -> 20];
n = RandomReal[1, {3, 2}, WorkingPrecision -> 20];
m.n//MatrixForm

因为，这些矩阵不能以相反的顺序相乘：

Wolfram Language code: n.m

符号矩阵的积：

Wolfram Language code: {{a, b}, {c, d}} . {{r, s}, {t, u}}

有限域元素矩阵的乘积：

Wolfram Language code:

ℱ = FiniteField[29, 4];
m = {{ℱ[12], ℱ[23], ℱ[34]}, {ℱ[45], ℱ[56], ℱ[67]}, {ℱ[78], ℱ[89], ℱ[90]}};
n = {{ℱ[123], ℱ[234]}, {ℱ[345], ℱ[456]}, {ℱ[567], ℱ[678]}};
m.n // MatrixForm

CenteredInterval 矩阵的乘积：

Wolfram Language code:

m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}];
n = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 2}, WorkingPrecision -> 10], {2}];
(mn = m.n)//MatrixForm

求 m 和 n 的随机表示 mrep 和 nrep：

Wolfram Language code:

ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"]
(mrep = Map[ranrep, m, {2}])//MatrixForm

Wolfram Language code: (nrep = Map[ranrep, n, {2}])//MatrixForm

验证 mn 包含 mrep 和 nrep 的乘积：

Wolfram Language code: MapThread[IntervalMemberQ, {mn, mrep.nrep}, 2]//MatrixForm

稀疏矩阵的乘积是另一个稀疏矩阵：

Wolfram Language code:

Dot[SparseArray[Automatic, {2, 3}, 0, {1, {{0, 1, 2}, {{3}, {2}}}, {3, 11}}], SparseArray[Automatic, {3, 3}, 0, {1, {{0, 0, 1, 2}, {{3}, {1}}}, {2, 9}}]]

格式化结果：

Wolfram Language code: %//MatrixForm

如果可能，结构化矩阵的乘积会保留结构：

Wolfram Language code:

Dot[SymmetrizedArray[StructuredArray`StructuredData[{3, 3}, {{{1, 1} -> 2, {2, 3} -> 35/2}, 
   Symmetric[{1, 2}]}]], SymmetrizedArray[StructuredArray`StructuredData[{3, 3}, {{{1, 1} -> 8, {2, 3} -> 10}, 
   Symmetric[{1, 2}]}]]]

格式化结果：

Wolfram Language code: %//MatrixForm

矩阵的三次方：

Wolfram Language code: m = {{a, 1}, {0, b}};

Wolfram Language code: m.m.m//MatrixForm

与 MatrixPower 的结果相比较：

Wolfram Language code: MatrixPower[m, 3]//MatrixForm

用 Dot 与 Apply (@@) 和 ConstantArray 计算矩阵的 10 次方：

Wolfram Language code: Dot @@ ConstantArray[m, {10}]//Expand

验证结果：

Wolfram Language code: MatrixPower[m, 10]//Expand

高效计算大型矩阵相乘：

Wolfram Language code:

mat = RandomReal[{0, 9}, {1000, 1000}];
mat2 = RandomComplex[1 + I, {1000, 300}];
Dot[mat, mat2];//AbsoluteTiming

高阶数组 (5)

Dot 适用于任意阶数的数组：

Wolfram Language code:

a = RandomInteger[9, {2, 3, 4}];
b  = RandomInteger[9, {4, 5, 2}];
c = RandomInteger[9, {2}];

Wolfram Language code: a.b

结果的维数是将输入的相同的维数折叠后的维数：

Wolfram Language code: Dimensions[%]

只要有相同的维数，任何组合都是允许的：

Wolfram Language code: c.a.b.c

创建一个三个维数都相同的三阶数组：

Wolfram Language code: (a = {{{8, 0}, {4, 2}}, {{0, 7}, {5, 6}}})//MatrixForm

创建维数与该数组一致的三个向量：

Wolfram Language code:

x = {1, 2};
y = {(1/2), (1/3)};
z = {-1, 1};

是完全缩并，将与的最后一层相配，将与的第一层相配：

Wolfram Language code: a.x.y.z

是不同的缩并，将与的第一层相配，将与的最后一层相配：

Wolfram Language code: a.z.y.x

将 m 的两个层分别与 a 的第二层和第三层进行缩并：

Wolfram Language code:

a = RandomReal[1, {2, 3, 4}];
m = RandomReal[1, {3, 4}];
Flatten[m].Flatten[a, {2, 3}]

两个稀疏数组的 Dot 通常是另一个稀疏数组：

Wolfram Language code: a = SparseArray[Automatic, {2, 2, 3, 4}, 0, {1, {{0, 2, 2}, {{2, 3, 4}, {1, 1, 1}}}, {x, y}}];

Wolfram Language code: m = SparseArray[Automatic, {4, 10}, 0, {1, {{0, 1, 1, 1, 2}, {{1}, {5}}}, {3, 2}}];

Wolfram Language code: a.m

一个稀疏数组与一个普通列表的 Dot 可能是另一个稀疏数组或普通列表：

Wolfram Language code: a.{1, 2, 3, 4}

Wolfram Language code: a.{{1}, {2}, {3}, {4}}

格式化三阶数组：

Wolfram Language code: %//MatrixForm

两个 SymmetrizedArray 对象的乘积通常是另一个对称数组：

Wolfram Language code:

s = SymmetrizedArray[StructuredArray`StructuredData[{4, 4, 4, 4}, 
  {{{1, 2, 3, 4} -> 1}, Symmetric[{1, 2, 3, 4}]}]];
m = SymmetrizedArray[StructuredArray`StructuredData[{4, 4}, {{{1, 2} -> 3}, Antisymmetric[{1, 2}]}]];
s.m

新数组的对称性可能比任一输入的对称性复杂得多：

Wolfram Language code:

a = SymmetrizedArray[StructuredArray`StructuredData[{4, 4, 4}, 
  {{{1, 2, 3} -> 2}, Antisymmetric[{1, 2, 3}]}]];
s.a

Wolfram Language code: TensorSymmetry[%]

应用 (16)

投影和基 (6)

将向量投影到由向量决定的直线上：

Wolfram Language code:

v = {-1, 3};l = {1, 1};
p = (v.l/l.l)l

可视化以及在由决定的直线上的投影：

Wolfram Language code:

Graphics[{InfiniteLine[{0, 0}, l], Arrow[{{0, 0}, v}], {Directive[StandardRed, Thick], Arrow[{{0, 0}, p}]}, {Dotted, Arrow[{p, v}]}}, PlotRangePadding -> .5, Axes -> True]

将向量投影到由向量和决定的平面上：

Wolfram Language code:

v = {1, 2, 1 / 2};
b1 = {2, 4, -2};
b2 = {-3, 3, 0};

首先，将替换为垂直于的平面中的一个向量：

Wolfram Language code: b3 = b2 - (b2.b1/b1.b1)b1

在平面上的投影是在和上的投影之和：

Wolfram Language code: p = (v.b1/b1.b1)b1 + (v.b3/b3.b3)b3

求垂直于平面的分量：

Wolfram Language code: v - p

将投影到平面的法线上以确认结果：

Wolfram Language code: % == (v.(b1⨯b2)/(b1⨯b2).(b1⨯b2))(b1⨯b2)

可视化平面、向量及其平行和垂直分量：

Wolfram Language code:

Graphics3D[{FaceForm[Opacity[.25]], InfinitePlane[{0, 0, 0}, {b1, b2}], Arrow[{{0, 0, 0}, v}], {Directive[StandardMagenta, Thick], Arrow[{{0, 0, 0}, p}]}, Directive[Thick, Dotted], Arrow[{p, v}]}, PlotRangePadding -> 1, Axes -> True]

应用 Gram–Schmidt 过程根据以下向量构建正交基：

Wolfram Language code:

{Subscript[v, 1], Subscript[v, 2], Subscript[v, 3], Subscript[v, 4]}  = {{-0.449, -0.028, -0.209, 0.376}, {0.547, -0.943, 0.141, -0.522}, {0.405, -0.078, -0.511, 0.532}, {-0.358, -0.452, 0.651, -0.13}};

正交基中的第一个向量是归一化的：

Wolfram Language code: Subscript[e, 1] = Normalize[Subscript[v, 1]]

对于后续向量，在归一化之前减去与前一个基向量平行的分量：

Wolfram Language code: Subscript[e, 2] = Normalize[Subscript[v, 2] - Subscript[v, 2].Subscript[e, 1]Subscript[e, 1]]

Wolfram Language code:

Subscript[e, 3] = Normalize[Subscript[v, 3] - Subscript[v, 3].Subscript[e, 1]Subscript[e, 1] - Subscript[v, 3].Subscript[e, 2]Subscript[e, 2]]

Wolfram Language code:

Subscript[e, 4] = Normalize[Subscript[v, 4] - Subscript[v, 4].Subscript[e, 1]Subscript[e, 1] - Subscript[v, 4].Subscript[e, 2]Subscript[e, 2] - Subscript[v, 4].Subscript[e, 3]Subscript[e, 3]]

用 Orthogonalize 确认答案：

Wolfram Language code:

{Subscript[e, 1], Subscript[e, 2], Subscript[e, 3], Subscript[e, 4]} == Orthogonalize[{Subscript[v, 1], Subscript[v, 2], Subscript[v, 3], Subscript[v, 4]}]

定义的基向量：

Wolfram Language code:

Subscript[e, 1] = {1, 1, 0, 0} / Sqrt[2];
Subscript[e, 2] = {1, -1, 0, 0} / Sqrt[2];
Subscript[e, 3] = {0, 0, 1, -1} / Sqrt[2];
Subscript[e, 4] = {0, 0, 1, 1} / Sqrt[2];

验证基向量是正交的：

Wolfram Language code: Table[Subscript[e, i].Subscript[e, j], {i, 4}, {j, 4}]//MatrixForm

求一般向量相对于这些新基向量的分量：

Wolfram Language code: v = {w, x, y, z};

Wolfram Language code: {Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]} = Table[v.Subscript[e, j], {j, 4}]

验证这些相对于的分量：

Wolfram Language code: v == Sum[Subscript[c, j] Subscript[e, j], {j, 4}]//Simplify

定义的基向量：

Wolfram Language code:

{Subscript[b, 1], Subscript[b, 2], Subscript[b, 3], Subscript[b, 4], Subscript[b, 5]} = {{0, 1, 4, -2, -5}, {-4, -1, 0, 3, -5}, {-3, -3, 0, 4, -4}, {0, -4, -2, -3, 3}, {1, -2, -1, 3, 1}};

通过显示由向量形成的矩阵具有非零行列式来验证它是一个基：

Wolfram Language code: Det[{Subscript[b, 1], Subscript[b, 2], Subscript[b, 3], Subscript[b, 4], Subscript[b, 5]}]

基矩阵的变化是列为的矩阵的逆：

Wolfram Language code: c = Inverse[Transpose[{Subscript[b, 1], Subscript[b, 2], Subscript[b, 3], Subscript[b, 4], Subscript[b, 5]}]]

标准基中坐标为的向量相对于的坐标为：

Wolfram Language code:

{Subscript[y, 1], Subscript[y, 2], Subscript[y, 3], Subscript[y, 4], Subscript[y, 5]} = c.{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}

验证这些坐标可以给出向量：

Wolfram Language code: Sum[Subscript[y, i]Subscript[b, i], {i, 5}]//Simplify

Frenet–Serret 系统将每条空间曲线的属性编码到向量基和标量函数中. 考虑以下曲线：

Wolfram Language code: c[t_] := {Cos[t], Sin[t], (t/2π)}

通过减去平行投影，根据前三个导数构建一个正交基：

Wolfram Language code:

{Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]} = Table[Normalize[Derivative[j][c][t] - Underoverscript[∑, k = 1, j - 1](Derivative[j][c][t].Derivative[k][c][t]/Derivative[k][c][t].Derivative[k][c][t])Derivative[k][c][t]], {j, 3}]~Simplify~(t∈Reals)

确保基为右手系的：

Wolfram Language code: Subscript[e, 3] = Simplify[Det[{Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]}]]Subscript[e, 3];

计算曲率和扭矩，它们量化了曲线弯曲的程度：

Wolfram Language code:

{κ, τ} = {(D[Subscript[e, 1], t].Subscript[e, 2]/Sqrt[c'[t].c'[t]]), -(D[Subscript[e, 3], t].Subscript[e, 2]/Sqrt[c'[t].c'[t]])}//Simplify

用 FrenetSerretSystem 验证答案：

Wolfram Language code: Simplify[{{κ, τ}, {Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]}} == FrenetSerretSystem[c[t], t], t∈Reals]

可视化曲线和相关的移动基，也称为框架：

Wolfram Language code:

DynamicModule[{s}, Labeled[Show[ParametricPlot3D[c[t], {t, 0, 6π}, PlotRangePadding -> {.5, .5, .9}], Graphics3D[{StandardBlue, Arrow[{c[t], c[t] + Subscript[e, 1]}], StandardRed, Arrow[{c[t], c[t] + Subscript[e, 2]}], StandardPurple, Arrow[{c[t], c[t] + Subscript[e, 3]}]}] /. t -> Dynamic[s]], Animator[Dynamic[s], {0, 6π}], Top]]

矩阵和线性算子 (6)

如果，则矩阵是正交矩阵. 证明旋转矩阵是正交的：

Wolfram Language code: r = RotationMatrix[θ, {1, 1, 1}]

Wolfram Language code: r.Transpose[r]//Simplify

用 OrthogonalMatrixQ 确认：

Wolfram Language code: OrthogonalMatrixQ[r]

如果，则矩阵是酉矩阵. 证明 Pauli 矩阵是酉矩阵：

Wolfram Language code: p = PauliMatrix[2]

Wolfram Language code: p.ConjugateTranspose[p]

用 UnitaryMatrixQ 确认：

Wolfram Language code: UnitaryMatrixQ[p]

如果，则矩阵是正规矩阵. 证明以下矩阵是正规矩阵：

Wolfram Language code:

m = {{1, 2, -1}, {-1, 1, 2}, {2, -1, 1}};
MatrixForm /@ {m.Transpose[m], Transpose[m].m}

用 NormalMatrixQ 确认：

Wolfram Language code: NormalMatrixQ[m]

正规矩阵包括许多其他类型的矩阵，为正规矩阵的特例. 酉矩阵是正规矩阵：

Wolfram Language code:

p = {{0, -I}, {I, 0}};
p . ConjugateTranspose[p] == ConjugateTranspose[p].p == {{1, 0}, {0, 1}}

厄米特矩阵或自伴随矩阵 () 也是正规矩阵，如矩阵所示：

Wolfram Language code: p == ConjugateTranspose[p]

但是，矩阵不是已命名的正规矩阵，如酉矩阵或厄米特矩阵：

Wolfram Language code: {UnitaryMatrixQ[m], HermitianMatrixQ[m]}

在量子力学中，具有有限多个状态的系统由单位向量表示，物理量由作用于它们的矩阵表示. 考虑一个自旋 1/2 的粒子，如电子. 它可能处于如下状态：

Wolfram Language code: s = {(1/Sqrt[5]), (2I/Sqrt[5])};

方向上的角动量由以下矩阵给出：

Wolfram Language code: jz = (ℏ/2)PauliMatrix[3]

该状态的角动量是：

Wolfram Language code: Conjugate[s].jz.s

该状态的角动量的不确定性是：

Wolfram Language code: σz = Simplify[Sqrt[Conjugate[s].jz.jz.s - (Conjugate[s].jz.s)^2], ℏ > 0]

可用类似方式计算方向上的不确定性：

Wolfram Language code: jy = (ℏ/2)PauliMatrix[2]

Wolfram Language code: σy = Simplify[Sqrt[Conjugate[s].jy.jy.s - (Conjugate[s].jy.s)^2], ℏ > 0]

不确定性原理给出了不确定性乘积的下限，：

Wolfram Language code: Simplify[σy σz > (ℏ/2)Abs[ Conjugate[s].(jy.jz - jz.jy).s] , ℏ > 0]

来看一个线性映射：

Wolfram Language code:

n = 10;
u = Array[Subscript[x, #]&, n];
l = ListConvolve[{1, -2, 1} n ^ 2, u, {2, 2}]

获取的矩阵表示：

Wolfram Language code: {c, m} = N[CoefficientArrays[%, u]]

创建一个要处理的向量：

Wolfram Language code: v = Sin[2. Pi Range[n] / n];

使用不同的方法将线性映射应用于向量：

Wolfram Language code: ListConvolve[{1, -2, 1} n ^ 2, v, {2, 2}]

Wolfram Language code: l /. Thread[u -> v]

Wolfram Language code: m.v

将与 Dot 一起使用是最快的方法：

Wolfram Language code:

trials = 10000;
Map[First, {AbsoluteTiming[Do[ListConvolve[{1, -2, 1} n ^ 2, v, {2, 2}], {trials}]], 
	AbsoluteTiming[Do[l /. Thread[u -> v], {trials}]], AbsoluteTiming[Do[m.v, {trials}]]}]

将单个矩阵应用于多个向量，可用 ${v_i}.TemplateBox[{m}, Transpose]$ 来计算：

Wolfram Language code: m = RandomReal[1, {3, 3}];

Wolfram Language code: vs = RandomReal[1, {10^6, 3}];

Wolfram Language code: Map[m.#&, vs] == vs.Transpose[m]

矩阵法比重复应用要快得多：

Wolfram Language code: vs.Transpose[m];//AbsoluteTiming

Wolfram Language code: Map[m.#&, vs];//AbsoluteTiming

具有对称性的矩阵和数组 (4)

实对称矩阵通过公式给出二次形式 $q:TemplateBox[{}, Reals]^n->TemplateBox[{}, Reals]$ ：

Wolfram Language code:

s = {{12, 7, 13}, {7, 10, -8}, {13, -8, 4}};
s//MatrixForm

Wolfram Language code: q[v_] := v.s.v

二次形式具有属性：

Wolfram Language code: q[α{x, y, z}] == α ^2q[{x, y, z}]//Simplify

相当于定义了以 $TemplateBox[{}, Reals]^n$ 的变量表示的齐次二次多项式：

Wolfram Language code: q[{x, y, z}]//Expand

多项式的值域可以是、、或 . 这里为：

Wolfram Language code: FunctionRange[%, {x, y, z}, q]

可视化多项式：

Wolfram Language code: DensityPlot3D[q[{x, y, z}], {x, y, z}∈Cuboid[5{-1, -1, -1}, 5{1, 1, 1}]]

正定实对称矩阵或度量矩阵通过来定义内积：

Wolfram Language code: (g = {{7, 2, 0}, {2, 6, -2}, {0, -2, 5}})//MatrixForm

Wolfram Language code: 〈u_, v_〉 := u.g.v

正定意味着对于，关联的二次型为正：

Wolfram Language code: FunctionSign[{〈{x, y, z}, {x, y, z}〉, {x, y, z} != {0, 0, 0}}, {x, y, z}, StrictInequalities -> True]

注意 Dot 本身是与单位矩阵相关的内积：

Wolfram Language code: {u, v, w}.{x, y, z} == {u, v, w}.IdentityMatrix[3].{x, y, z}

对标准基应用 Gram–Schmidt 过程以获取正交基：

Wolfram Language code:

{Subscript[b, 1], Subscript[b, 2], Subscript[b, 3]} = IdentityMatrix[3];
Do[ Subscript[e, j] = Subscript[b, j] - Underoverscript[∑, k = 1, j - 1]〈Subscript[b, j], Subscript[e, k]〉Subscript[e, k]; Subscript[e, j] = (Subscript[e, j]/Sqrt[〈Subscript[e, j], Subscript[e, j]〉]), {j, 3}];
{Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]}

确认确认这个基对于内积是正交的：

Wolfram Language code: Table[〈Subscript[e, i], Subscript[e, j]〉, {i, 3}, {j, 3}]//Simplify

对于反对称矩阵，定义了一个 Hamiltonian 2-form ：

Wolfram Language code: (Ω = {{0, 0, -1, 0}, {0, 0, 0, -1}, {1, 0, 0, 0}, {0, 1, 0, 0}})//MatrixForm

Wolfram Language code: ω[u_, v_] := u.Ω.v

在上验证条件：

Wolfram Language code: {AntisymmetricMatrixQ[Ω], Ω.Ω == -IdentityMatrix[4]}

全部为零：

Wolfram Language code: ω[{q1, q2, p1, p2}, {q1, q2, p1, p2}]

但是，这种形式是非简并的，则意味着：

Wolfram Language code: Solve[Subscript[∀, {q3, q4, p3, p4}]ω[{q1, q2, p1, p2}, {q3, q4, p3, p4}] == 0, {q1, q2, p1, p2}]

构建六个六维向量：

Wolfram Language code: {a, b, c, d, e, f} = RandomReal[1, {6, 6}]

用 LeviCivitaTensor 构建六维全反对称数组：

Wolfram Language code: ϵ = LeviCivitaTensor[6, SymmetrizedArray]

计算全缩并 $sum_( i_1... i_6) epsilon_(i_1,i_2,...,i_6)TemplateBox[{a, {i, _, 1}}, Superscript] TemplateBox[{b, {i, _, 2}}, Superscript]... TemplateBox[{f, {i, _, 6}}, Superscript]$ ：

Wolfram Language code: ϵ.f.e.d.c.b.a

这与由向量形成的矩阵的行列式相等：

Wolfram Language code: Det[{a, b, c, d, e, f}]

根据的反对称，反向缩并 (reversed contraction) 的区别是维度上相差：

Wolfram Language code: Block[{n = 6}, (-1)^(n(n + 1)/2)ϵ.a.b.c.d.e.f]

属性和关系 (16)

对于每个参数，Dot 都是线性的：

Wolfram Language code:

Subscript[u, 1] = {Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]};
Subscript[u, 2] = {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]};
Subscript[u, 3] = {Subscript[x, 3], Subscript[y, 3], Subscript[z, 3]};

Wolfram Language code:

Expand[Dot[a Subscript[u, 1] + Subscript[u, 3], Subscript[u, 2]] == a Dot[Subscript[u, 1], Subscript[u, 2]] + Dot[Subscript[u, 3], Subscript[u, 2]]]

Wolfram Language code:

Expand[Dot[Subscript[u, 1], b Subscript[u, 2] + Subscript[u, 3]] == b Dot[Subscript[u, 1], Subscript[u, 2]] + Dot[Subscript[u, 1], Subscript[u, 3]]]

对于实向量，Norm[v] 等于：

Wolfram Language code: vr = RandomReal[1, {3}]

Wolfram Language code: Norm[vr] == Sqrt[vr.vr]

对于复向量，模由给出：

Wolfram Language code: vc = RandomComplex[1 + I, {3}]

Wolfram Language code: Norm[vc] == Sqrt[vc.Conjugate[vc]] == Sqrt[Conjugate[vc].vc]

对于两个实向量， $u_1.u_2=TemplateBox[{{u, _, 1}}, Norm] TemplateBox[{{u, _, 2}}, Norm]cos(theta)$ ，其中为和之间的夹角：

Wolfram Language code: {u1, u2} = RandomReal[1, {2, 5}]

Wolfram Language code: u1.u2 == Norm[u1]Norm[u2]Cos[VectorAngle[u1, u2]]

向量的标量积是旋转不变的：

Wolfram Language code:

{u, v} = RandomReal[1, {2, 3}];
rt = RotationTransform[RandomReal[{0, 2Pi}], RandomReal[{-1, 1}, 3]];
u.v  == rt[u].rt[v]

对于两个矩阵，的第和第项是的第行与的第列的点积：

Wolfram Language code:

m = Array[x, {3, 4}];
n = Array[y, {4, 5}];
m.n == Table[m[[i, All]].n[[All, j]], {i, 3}, {j, 5}]

矩阵乘法是不可交换的，：

Wolfram Language code:

m = RandomInteger[{-10, 10}, {3, 3}];
n = RandomInteger[{-10, 10}, {3, 3}];
m.n  == n.m

用 MatrixPower 计算重复的矩阵相乘：

Wolfram Language code: a = {{1, 1, 0}, {0, 1, 1}, {0, 0, 1}};

Wolfram Language code: b = MatrixPower[a, 4]

与直接计算的结果相比较：

Wolfram Language code: b == Dot[a, a, a, a]

b 对向量的作用与用 a 对向量作用四次的结果一样：

Wolfram Language code: b.{v1, v2, v3} == Nest[x  a.x, {v1, v2, v3}, 4]

对于两个张量和，是张量：

Wolfram Language code:

t = RandomInteger[9, {2, 3, 4}];
u  = RandomInteger[9, {4, 5}];
t.u == Table[Sum[t[[i1, i2, k]] u[[k, j2]], {k, 4}], {i1, 2}, {i2, 3}, {j2, 5}]

对秩为的张量和秩为的张量应用 Dot 给出秩为的张量：

Wolfram Language code:

a = RandomInteger[9, {2, 3, 4}];
b  = RandomInteger[9, {4, 5}];

Wolfram Language code: TensorRank[a.b] == TensorRank[a] + TensorRank[b] - 2

对两个数组应用 Dot 是 Inner 的特例：

Wolfram Language code: Inner[Times, {a, b, c}, {x, y, z}, Plus]

Wolfram Language code: Dot[{a, b, c}, {x, y, z}]

Dot 实现了数组的标准内积：

Wolfram Language code: {{a, b}, {c, d}}.{{w, x}, {y, z}}

使用 Times 做元素乘法：

Wolfram Language code: {{a, b}, {c, d}} * {{w, x}, {y, z}}

可通过 TensorProduct 和 TensorContract 组合使用实现 Dot：

Wolfram Language code:

v = Array[x, {3}];
a = Array[y, {3, 4, 5}];
m = Array[z, {5, 6}];

Wolfram Language code: v.a.m == TensorContract[vam, {{1, 2}, {4, 5}}]//Simplify

将 Dot 与 Flatten 一起使用以缩并一个数组的多个层级与另一个数组的多个层级：

Wolfram Language code:

a = Array[x, {3, 4, 5}];
b = Array[y, {3, 4, 5}];

Wolfram Language code: TensorContract[ab, {{2, 5}, {3, 6}}] == Flatten[a, {{1}, {2, 3}}].Flatten[b, {{2, 3}, {1}}]

TensorReduce 可简化含有 Dot 的表达式：

Wolfram Language code: TensorReduce[v.m.v, Assumptions -> {m∈Matrices[{n, n}, Antisymmetric[{1, 2}]], v∈Vectors[n]}]

可用 Dot 计算两个向量的 Outer：

Wolfram Language code:

u = {1, 2, 3};
v = {x, y, z};
Outer[Times, u, v]

构建 u 和 v 对应的列矩阵和行矩阵：

Wolfram Language code: c = List /@ u

Wolfram Language code: r = {v}

外积等于 c.r：

Wolfram Language code: c.r

一个行矩阵和列矩阵的 Dot 等于对应向量的 KroneckerProduct：

Wolfram Language code:

u = {{1}, {2}, {3}};
v = {{4, 5, 6}};
u.v == KroneckerProduct[Flatten[u], Flatten[v]]

可能存在的问题 (2)

Dot 实际上从右边处理多维向量，可以视为列向量：

Wolfram Language code: a = {{1, 2}, {3, 4}, {5, 6}};

Wolfram Language code: a.{1, 1}

Wolfram Language code: a.{{1}, {1}}

Dot 实际上从左边边处理多维向量，可以视为行向量：

Wolfram Language code: {1, 1, 1}.a

Wolfram Language code: {{1, 1, 1}}.a

Dot 不给出的标准内积：

Wolfram Language code: a = {1 + I, 2 - I, -1 - 2I};

Wolfram Language code: a.a

对一个参数应用 Conjugate 以获取厄米特内积：

Wolfram Language code: Conjugate[a].a

检查结果是否与 a 的模的平方一致：

Wolfram Language code: Norm[a] ^ 2

Top

	{a₁,a₂}.{b₁,b₂}	向量的标积
	{a₁,a₂}.{{m₁₁,m₁₂},{m₂₁,m₂₂}}
		向量和矩阵的乘积
	{{m₁₁,m₁₂},{m₂₁,m₂₂}}.{a₁,a₂}
		矩阵和向量的乘积
	{{m₁₁,m₁₂},{m₂₁,m₂₂}}.{{n₁₁,n₁₂},{n₂₁,n₂₂}}
		两个矩阵的乘积

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Dot

更多信息

范例

基本范例 (4)

范围 (28)

向量的点积 (7)

矩阵-向量相乘 (5)

矩阵-矩阵相乘 (11)

高阶数组 (5)

应用 (16)

投影和基 (6)

矩阵和线性算子 (6)

具有对称性的矩阵和数组 (4)

属性和关系 (16)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

Dot

更多信息

范例

基本范例 (4)

范围 (28)

向量的点积 (7)

矩阵-向量相乘 (5)

矩阵-矩阵相乘 (11)

高阶数组 (5)

应用 (16)

投影和基 (6)

矩阵和线性算子 (6)

具有对称性的矩阵和数组 (4)

属性和关系 (16)

可能存在的问题 (2)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX