ExponentialDistribution
ExponentialDistribution
尺度が母数 λ に反比例する指数分布を表す．
詳細
- 指数分布における値
の確率密度は，
のときは 
に比例し，
のときは0である． » - ExponentialDistributionでは，λ は任意の正の実数でよい．
- ExponentialDistributionでは，λ は任意の単位次元の数量でよい． »
- ExponentialDistributionは，Mean，CDF，RandomVariate等の関数で使うことができる． »
予備知識
- ExponentialDistribution[λ]は，区間
上で定義され，正の実数 λ でパラメータ化された連続統計分布を表す．指数分布の確率密度関数(PDF)は，単調減少である．これに加え，PDFの裾部は，PDFが 
の大きい値について指数的に減少するという意味で「薄い」（この現象は，分布のSurvivalFunctionを分析することで数量的に正確にできる）．指数分布は時に負の指数分布，1母数指数分布，あるいは反対数分布と呼ばれることがある． - 歴史的に，指数分布は「時間的にランダム」におこる現象，つまり，個の未来の寿命が現在の状態に関係なく同じ分布に従う現象の説明のために幅広く使われてきた．指数分布の使用は，過去75年間に大幅に増大した．これは，一つには，1950年代の初頭から中頃にかけて始まった順序統計の分野で研究が盛んに行われたためである．それ以来指数分布は，ほぼ一定割合の区間内でのさまざまな現象，例えば一日の特定の時間帯にかかってくる電話の数のモデル化に使われてきた，確率過程では，指数分布は，同次ポアソン過程における到着間隔の長さ（つまり，増分が独立かつ定常でポアソン分布に従う，PoissonProcessとして実装されている連続時間計数過程）の説明に使われた．指数分布は，クレジットリスクのモデル化，待ち行列理論，信頼性理論，物理学，水文学にも使われている．
- RandomVariateを使って指数分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,ExponentialDistribution[λ]]（より簡略すると xExponentialDistribution[λ]）を使って，確率変数 x が，指数分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
- 確率密度関数および累積分布関数は，PDF[ExponentialDistribution[λ],x]およびCDF[ExponentialDistribution[λ],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
- DistributionFitTestを使って，与えられたデータ集合が指数分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリック指数分布を推定することが，FindDistributionParametersを使ってデータを指数分布にフィットすることができる．ProbabilityPlotを使って記号指数分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号指数分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
- TransformedDistributionを使って変換された指数分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使って指数分布を含む高次元分布を構築することが，ProductDistributionを使って指数分布を含む独立成分分布の結合分布を計算することができる．
- 指数分布は他の多くの分布と関係している．この分布のPoissonProcessと相対的な発現は，PoissonDistributionおよびCompoundPoissonDistributionとの関係を考えさせる．ExponentialDistributionは，ExponentialDistribution[1]がExtremeValueDistribution，GumbelDistribution，FrechetDistribution，WeibullDistributionのそれぞれに変換でき，ExponentialDistributionがGammaDistribution，LaplaceDistribution，BenktanderWeibullDistribution，LogisticDistribution，ParetoDistribution，PearsonDistribution，PowerDistribution，RayleighDistributionのそれぞれからTransformedDistributionおよび／またはTruncatedDistributionによって得られることから，極値分布族の基礎であると考えることができる．ExponentialDistributionと他の分布を組み合せていくつかの分布を派生させることができる（例えばExponentialDistributionとPoissonDistributionを組み合せてGeometricDistribution，GammaDistributionと組合せてKDistribution，ArcSinDistributionと組み合せてHoytDistribution，ErlangDistributionまたはGammaDistributionと組み合せてParetoDistribution等）．
例題
すべて開く すべて閉じる例 (4)
Plot[Table[PDF[ExponentialDistribution[λ], x], {λ, {1 / 2, 1, 2}}]//Evaluate, {x, 0, 3}, Filling -> Axis, PlotRange -> All]PDF[ExponentialDistribution[λ], x]Plot[Table[CDF[ExponentialDistribution[λ], x], {λ, {1 / 2, 1, 2}}]//Evaluate, {x, 0, 4}, Filling -> Axis]CDF[ExponentialDistribution[λ], x]Mean[ExponentialDistribution[λ]]Variance[ExponentialDistribution[λ]]Median[ExponentialDistribution[λ]]スコープ (7)
data = RandomVariate[ExponentialDistribution[3.5], 10 ^ 4];Show[
Histogram[data, {0, 2, 0.1}, "PDF"],
Plot[PDF[ExponentialDistribution[3.5], x], {x, 0, 2}, PlotStyle -> Thick, PlotRange -> {0, 3}]]sample = RandomVariate[ExponentialDistribution[5], 10 ^ 3];edist = EstimatedDistribution[sample, ExponentialDistribution[λ]]サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：
Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 1.2}, PlotStyle -> Thick]]Skewness[ExponentialDistribution[λ]]Kurtosis[ExponentialDistribution[λ]]FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[ExponentialDistribution[λ], r], {r, 5}], M]Moment[ExponentialDistribution[λ], r]FormulaGrid[Table[CentralMoment[ExponentialDistribution[λ], r], {r, 5}], CM]CentralMoment[ExponentialDistribution[λ], r]FormulaGrid[Table[FactorialMoment[ExponentialDistribution[λ], r], {r, 5}], FM]FormulaGrid[Table[Cumulant[ExponentialDistribution[λ], r], {r, 5}], C]Cumulant[ExponentialDistribution[λ], r]HazardFunction[ExponentialDistribution[λ], x]Plot[Table[Quantile[ExponentialDistribution[λ], q], {λ, {0.5, 1, 3}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[ExponentialDistribution[λ], q]母数でQuantityを一貫して使うとQuantityDistributionが与えられる：
serviceTime𝒟 = ExponentialDistribution[Quantity[25, 1/"Months"]]UnitConvert[serviceTime𝒟, "Days"]//NMedian[%]アプリケーション (9)
寿命が1時間あたり比率母数
の指数分布に従う電池がある．無作為抽出した電池の寿命が2500時間より短い確率を求める：
Probability[t < Quantity[2500., "Hours"], t ExponentialDistribution[1 / Quantity[3000, "Hours"]]]CDF[ExponentialDistribution[1 / Quantity[3000, "Hours"]], Quantity[2500., "Hours"]]寿命が故障率 
／年の指数分布に従う継電器がある．製品保証の経費を見積るために，使用開始から6ヶ月の間に故障する継電器の数が10000の中でいくつあるかを推定する．故障率はハザード率としても知られている：
HazardFunction[ExponentialDistribution[λ], 1] -> Quantity[0.002, 1/"Years"]relayLifeDistribution = ExponentialDistribution[λ] /. %p = NProbability[t < Quantity[6, "Months"], trelayLifeDistribution]10000個の継電器のうちで最初の6ヶ月間に予想される故障数：
Mean[BinomialDistribution[10000, p]]故障までの時間が母数 
の指数分布に従う製品がある．製品の信頼性を1年間，2年間，3年間について求める．信頼性とはSurvivalFunctionの別名である：
dist = ExponentialDistribution[Quantity[1/2, 1/"Years"]]SurvivalFunction[dist][{Quantity[1., "Years"], Quantity[2., "Years"], Quantity[3., "Years"]}]HazardFunction[dist, Quantity[t, "Years"]]ある電化製品の寿命が平均10年の指数分布に従うと仮定し，製品の寿命分布を求める：
{sol} = Solve[Mean[ExponentialDistribution[λ]] == Quantity[10, "Years"], λ]applianceLifetime = ExponentialDistribution[λ] /. sol使用年数が 
年の中古の電化製品が次の5年間に故障しない確率を求める：
Probability[t > Quantity[t0, "Years"] + Quantity[5., "Years"]t > Quantity[t0, "Years"], tapplianceLifetime, Assumptions -> t0 > 0]ExponentialDistributionの無記憶性を使用する：
Probability[t > Quantity[5., "Years"], tapplianceLifetime]レストランの顧客の待ち時間が平均5分の指数分布に従うと仮定し，顧客が10分以上待たなければならない確率を求める：
waitTime𝒟 = ExponentialDistribution[1 / Quantity[5, "Minutes"]]NProbability[t > Quantity[10., "Minutes"], twaitTime𝒟]すでに少なくとも10分待っている顧客がさらに10分待たなければならない確率を求める（過去は関係ない）：
NProbability[t > Quantity[10., "Minutes"] + Quantity[10., "Minutes"]t > Quantity[10, "Minutes"], twaitTime𝒟]1902年12月16日から1977年3月4日までに世界で起った大地震（マグニチュードが最低7.5，あるいは死者が1000人以上）の発生間隔を日を単位として記録したデータがある：
earthquakesWaitingTimes = Quantity[ExampleData[{"Statistics", "EarthquakeWaitingTimes"}], "Days"];ExponentialDistributionをデータにフィットする：
edist = EstimatedDistribution[earthquakesWaitingTimes, ExponentialDistribution[λ]]Show[Histogram[earthquakesWaitingTimes, 15, "PDF", AxesLabel -> Automatic], Plot[Evaluate@PDF[edist, Quantity[x, "Days"]], {x, 0, 2000}, PlotStyle -> Thick]]Mean[edist]Probability[x ≤ Quantity[100, "Days"], xedist]今後世界中で起る30の大地震について，地震と地震の間の日数のシミュレーションを行う：
ListPlot[{RandomVariate[edist, 30], {{0, Mean[edist]}, {30, Mean[edist]}}}, Filling -> Axis, Joined -> {False, True}, AxesOrigin -> {0, 0}, AxesLabel -> Automatic]4つの独立した送信機からの信号を待つ受信機側の待ち時間は母数をそれぞれ 
，
，
，
として指数分布に従っている．3番目の送信機からの信号が最初に受信機に届く確率を求める：
Probability[Min[u, v, w, z] == w, {uExponentialDistribution[λ1], vExponentialDistribution[λ2], wExponentialDistribution[λ3], zExponentialDistribution[λ4]}]𝒟 = TransformedDistribution[Min[u, v, w, z], {uExponentialDistribution[λ1], vExponentialDistribution[λ2], wExponentialDistribution[λ3], zExponentialDistribution[λ4]}]Mean[𝒟]1つの信号から次の信号までの受信機の待ち時間を 
，
，
，
についてそれぞれシミュレーションする：
Block[{λ1 = 1, λ2 = 0.5, λ3 = 0.7, λ4 = 0.3}, ListPlot[{RandomVariate[𝒟, 100], {{0, Mean[𝒟]}, {100, Mean[𝒟]}}}, Joined -> {False, True}, Filling -> Axis, AxesOrigin -> {0, 0}]]寿命が母数
／時の指数分布に従う4つの独立した部品からなるシステムがある．500時間経過するまでどの部品も故障しない確率を求める：
Probability[t1 > Quantity[500, "Hours"] && t2 > Quantity[500, "Hours"] && t3 > Quantity[500, "Hours"] && t4 > Quantity[500, "Hours"], {t1, t2, t3, t4}ProductDistribution[{ExponentialDistribution[1 / Quantity[1000, "Hours"]], 4}]]N[%]SurvivalFunctionを直接使う：
SurvivalFunction[ExponentialDistribution[1 / Quantity[1000, "Hours"]], Quantity[500, "Hours"]] ^ 4最初の1200時間で厳密に1つの部品が故障する確率を求める：
tmax = Quantity[1200, "Hours"];
Probability[Min[t1, t2, t3, t4] < tmax∧RankedMin[{t1, t2, t3, t4}, 2] > tmax, {t1, t2, t3, t4}ProductDistribution[{ExponentialDistribution[1 / Quantity[1000, "Hours"]], 4}]]CDFとSurvivalFunctionを直接使う：
Binomial[4, 1] CDF[ExponentialDistribution[1 / Quantity[1000, "Hours"]], Quantity[1200, "Hours"]] SurvivalFunction[ExponentialDistribution[1 / Quantity[1000, "Hours"]], Quantity[1200, "Hours"]] ^ 3N[%]BooleanCountingFunctionを使うと論理条件も定義できる：
ExactlyK[k_, v_] := BooleanCountingFunction[{k}, Length[v]]@@vExactlyK[1, {a, b, c, d}]//BooleanConvertProbability[ExactlyK[1, {t1 ≤ Quantity[1200, "Hours"], t2 ≤ Quantity[1200, "Hours"], t3 ≤ Quantity[1200, "Hours"], t4 ≤ Quantity[1200, "Hours"]}], {t1, t2, t3, t4}ProductDistribution[{ExponentialDistribution[1 / Quantity[1000, "Hours"]], 4}]]N[%]光通信システムでは，透過光は受信機で電流を生成する．電子の数は光のタイプによりポアソン分布と他の分布のパラメトリック混合分布に従う．光源に強度 λ のコヒーレントレーザー光線を使う場合，電子の数はポアソン分布に従う：
Bdist = TransformedDistribution[λ x, xBernoulliDistribution[1]];PDF[Bdist, x]𝒟1 = ParameterMixtureDistribution[PoissonDistribution[μ], μBdist];PDF[𝒟1, x]PDF[PoissonDistribution[λ], x]光源に熱照明を使う場合，ポアソン母数は母数
のExponentialDistributionに従い，電子数の分布は以下のようになる：
𝒟2 = ParameterMixtureDistribution[PoissonDistribution[μ], μExponentialDistribution[1 / λ]]//SimplifyBlock[{λ = 3}, Histogram[{RandomVariate[𝒟1, 10 ^ 3], RandomVariate[𝒟2, 10 ^ 3]}, Automatic, "PDF"]]特性と関係 (31)
TransformedDistribution[k * u, uExponentialDistribution[λ]]Mean[ExponentialDistribution[λ]] ^ 2% - Variance[ExponentialDistribution[λ]]TransformedDistribution[Min[u, v], {uExponentialDistribution[Subscript[λ, 1]], vExponentialDistribution[Subscript[λ, 2]]}]
OrderDistribution[{ExponentialDistribution[λ], n}, 1]Probability[x > ξ + px > p, xExponentialDistribution[λ], Assumptions -> ξ > 0 && p > 0]Probability[x > ξ, xExponentialDistribution[λ], Assumptions -> ξ > 0]% - %%
BenktanderWeibullDistributionを簡約すると切断ExponentialDistributionになる：
PDF[BenktanderWeibullDistribution[a, 1], x]PDF[TruncatedDistribution[{1, Infinity}, ExponentialDistribution[a]], x]FullSimplify[% - %%, x > 1]シフトされたExponentialDistributionはBenktanderWeibullDistributionである：
TransformedDistribution[u + 1, uExponentialDistribution[λ]]指数分布はスケールされたBetaDistributionの極限である：
𝒟 = TransformedDistribution[u n, uBetaDistribution[1, n]];PDF[𝒟, x]Limit[%, n -> ∞]PDF[ExponentialDistribution[1], x]FullSimplify[% - %%, x ≠ 0]PowerDistributionは指数分布の変換である：
TransformedDistribution[Exp[-u] / k, uExponentialDistribution[λ]]指数分布はPowerDistributionから得ることができる：
TransformedDistribution[-Log[X], XPowerDistribution[1, a]]指数分布はBetaDistributionから得ることができる：
TransformedDistribution[-Log[X], XBetaDistribution[a, 1]]独立指数分布に従う確率変数の総和はErlangDistributionに従う：
TransformedDistribution[u + v + w, {u, v, w}ProductDistribution[{ExponentialDistribution[λ], 3}]]CharacteristicFunction[ExponentialDistribution[λ], t] ^ kCharacteristicFunction[ErlangDistribution[k, λ], t]% - %%//FullSimplify[#, Element[k, Integers]]&ExponentialDistribution[1]は極値分布族に変換することができる：
TransformedDistribution[α - β Log[u], uExponentialDistribution[1], Assumptions -> α > 0 && β > 0]TransformedDistribution[α + β Log[u], uExponentialDistribution[1], Assumptions -> α > 0 && β > 0]TransformedDistribution[β * 1 / u ^ (1 / α), uExponentialDistribution[1], Assumptions -> α > 0 && β > 0]TransformedDistribution[β * u ^ (1 / α), uExponentialDistribution[1], Assumptions -> α > 0 && β > 0]ExponentialDistributionはWeibullDistributionの特殊ケースである：
PDF[WeibullDistribution[1, 1 / λ], x]PDF[ExponentialDistribution[λ], x]% - %%//Simplify[#, x > 0]&ExponentialDistributionはGammaDistributionの特殊ケースである：
PDF[GammaDistribution[1, 1 / λ], x]PDF[ExponentialDistribution[λ], x]% - %%//Simplify[#, x > 0]&同じ指数分布に従う2変量の差はLaplaceDistributionに従う：
TransformedDistribution[u - v, {u, v}ProductDistribution[{ExponentialDistribution[1 / λ], 2}]]2つの異なる指数分布の差はVarianceGammaDistributionに従う：
TransformedDistribution[u - v, {uExponentialDistribution[ Subscript[λ, 1]], vExponentialDistribution[Subscript[λ, 2]]}]指数分布はLaplaceDistributionを変換したものである：
TransformedDistribution[Abs[z - μ], zLaplaceDistribution[μ, β]]LogisticDistributionは指数分布から変換したものである：
𝒟 = TransformedDistribution[μ - β Log[Exp[-u] / (1 - Exp[-u])], uExponentialDistribution[1]];PDF[𝒟, x]//Simplify[#, β > 0]&PDF[LogisticDistribution[μ, β], x]FullSimplify[% - %%, β > 0]LogisticDistributionは指数分布を変換したものである：
𝒟 = TransformedDistribution[μ - β Log[u / v], {u, v}ProductDistribution[{ExponentialDistribution[1], 2}]];PDF[𝒟, x]//Simplify[#, β > 0]&PDF[LogisticDistribution[μ, β], x]FullSimplify[% - %%, β > 0]ParetoDistributionは指数分布を変換したものである：
TransformedDistribution[k * Exp[u], uExponentialDistribution[α]]ParetoDistributionの変換は指数分布を与える：
TransformedDistribution[Log[u / k], uParetoDistribution[k, λ]]指数分布はタイプ3のPearsonDistributionの特殊ケースである：
PDF[PearsonDistribution[3, 1, 0, 0, (1/λ), 0], x]//Simplify[#, λ > 0]&PDF[ExponentialDistribution[λ], x]% - %%//FullSimplify[#, λ > 0 && x ≠ 0]&PowerDistributionは指数分布を変換したものである：
𝒟 = TransformedDistribution[1 / k Exp[-u], uExponentialDistribution[a]];PDF[𝒟, x]//FullSimplify[#, k > 0]&PDF[PowerDistribution[k, a], x]FullSimplify[% - %%, 0 < x < 1 / k]指数分布はRayleighDistributionから得ることができる：
𝒟 = TransformedDistribution[1 / 2 u ^ 2, uRayleighDistribution[Sqrt[1 / λ]]];PDF[𝒟, x]PDF[ExponentialDistribution[λ], x]% - %%指数分布は 
の極限分布である．ただし，
はUniformDistributionに従うものとする：
mindist = TransformedDistribution[n u, uOrderDistribution[{UniformDistribution[{0, 1}], n}, 1]];CDF[mindist, x]Limit[CDF[mindist, x], n -> ∞]CDF[ExponentialDistribution[1], x]% - %%//FullSimplifyPoissonDistributionと指数分布のパラメトリック混合分布はGeometricDistributionに従う：
ParameterMixtureDistribution[PoissonDistribution[μ], μExponentialDistribution[1 / λ]]//SimplifyKDistributionはExponentialDistributionとGammaDistributionから得ることができる：
TransformedDistribution[Sqrt[u v], {uExponentialDistribution[λ], vGammaDistribution[α, β]}]HoytDistributionはExponentialDistributionとArcSinDistributionから得ることができる：
𝒟 = TransformedDistribution[(2 q) / (1 + q ^ 2)Sqrt[ω u v], {uArcSinDistribution[{1 / 2 (1 + q ^ 2), 1 / 2 (1 + 1 / q ^ 2)}], vExponentialDistribution[1]}];Block[{q = .2, ω = 3}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[HoytDistribution[q, ω], x], {x, 0, 6}, PlotStyle -> Thick]]]ParetoDistributionはExponentialDistributionとErlangDistributionの商として求められる：
𝒟 = TransformedDistribution[u / v, {uExponentialDistribution[λ], vErlangDistribution[n, λ]}];PDF[𝒟, x]PDF[ParetoDistribution[1, n, 0], x]FullSimplify[% - %%, x ≠ 0]ParetoDistributionはExponentialDistributionとGammaDistributionの商として求められる：
𝒟 = TransformedDistribution[u / v, {uExponentialDistribution[λ], vGammaDistribution[n, 1 / λ]}];PDF[𝒟, x]PDF[ParetoDistribution[1, n, 0], x]FullSimplify[% - %%, x ≠ 0]考えられる問題 (2)
ExponentialDistributionは，λ が正の実数でなければ定義されない：
Mean[ExponentialDistribution[-1]]
Mean[ExponentialDistribution[λ]] /. {λ -> 3 + I}おもしろい例題 (1)
累積分布関数の等高線を持つ λ のさまざまな値についての確率密度関数：
cdf = Function[{x, λ}, Evaluate[CDF[ExponentialDistribution[λ], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];Legended[Plot3D[PDF[ExponentialDistribution[λ], x], {x, 0, 3}, {λ, 0.2, 4}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 100, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> {0, 4}], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2007), ExponentialDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExponentialDistribution.html （2016年に更新）.
テキスト
Wolfram Research (2007), ExponentialDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExponentialDistribution.html （2016年に更新）.
CMS
Wolfram Language. 2007. "ExponentialDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/ExponentialDistribution.html.
APA
Wolfram Language. (2007). ExponentialDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ExponentialDistribution.html