WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ExtremeValueDistribution[α,β]

位置母数 α，尺度母数 β の極値分布を表す．

ExtremeValueDistribution[]

位置母数0，尺度母数1の極値分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

ExtremeValueDistribution

ExtremeValueDistribution[α,β]

位置母数 α，尺度母数 β の極値分布を表す．

ExtremeValueDistribution[]

位置母数0，尺度母数1の極値分布を表す．

詳細

  • 極値分布は，正規分布等の分布からサンプルしたものの最大値の漸近分布を与える．
  • 極値分布における値 の確率密度は， に比例する． »
  • 最小値の漸近分布は，極値分布とも呼ばれるものだが，Wolfram言語にはGumbelDistributionとして実装されている． »
  • ExtremeValueDistributionでは，α は任意の実数で，β は任意の正の実数でよい．
  • ExtremeValueDistributionでは，α と β は同じ単位次元の任意の数量でよい． »
  • ExtremeValueDistributionは，Mean，CDF，RandomVariate等の関数で使うことができる． »

予備知識

  • ExtremeValueDistribution[α,β]は，実数集合上で定義され，実数 α（「位置母数」と呼ばれる），正の実数 β（「尺度母数」と呼ばれる）でパラメータ化される連続統計分布を表す．極値分布の確率密度関数(PDF)の全体的な動作は平滑かつ単峰性であるが，母数 α と β がPDFの水平位置と全体的な高さおよび傾きをそれぞれ決定する．これに加え，PDFの裾部は，PDFが の大きい値について指数的に減少するという意味で「薄い」（この動作は，分布のSurvivalFunctionを分析することで数量的に正確にできる）．極値分布はタイプIの極値分布，二重指数分布（やはり二重指数と呼ばれることがあるLaplaceDistributionと混同しないように），対数ワイブル分布(WeibullDistribution)，ガンベル型分布（GumbelDistributionと混同しないように）とも呼ばれることがある．
  • ExtremeValueDistributionは極値分布と呼ばれる分布であるが，実際は「極値分布」として分類される4つの極値分布の1つ（他の3つはGumbelDistribution，FrechetDistribution，WeibullDistribution）である．極値分布は次第に大きくなるランダムなサンプルの最大値の極限分布として得ることができる．PDFが二重に指数的（つまりExp[-Exp[…]]の形をしている）ので，分布のグラフにはより誇張された特徴（例えば，より高い峰やより薄い裾部）つまり，これらの分布に一意的な特徴が見られる．この分布は，1920年代初頭に，天文学で異常値を拒絶あるいは利用する必要に対応するために導入された．極値理論として知られる分野の基盤である極値分布は，異常洪水，壊滅的な保険の損失，大規模な山火事等の「起る可能性が極めて低い」状況（つまり，データ集合が中央値から極端に逸脱している変量からなる状況）を説明するのに広く使われてきた．さらに，極値分布は，生物学における進化論的な遺伝子の突然変異をモデル化するツールとしても使うことができる．
  • RandomVariateを使って極値分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,ExtremeValueDistribution[α,β]]（より簡略すると xExtremeValueDistribution[α,β]）を使って，確率変数 x が，極値分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[ExtremeValueDistribution[α,β],x]およびCDF[ExtremeValueDistribution[α,β],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
  • DistributionFitTestを使って，与えられたデータ集合が極値分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリック極値分布を推定することが，FindDistributionParametersを使ってデータを極値分布にフィットすることができる．ProbabilityPlotを使って記号極値分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号極値分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換された極値分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使って極値分布を含む高次元分布を構築することが，ProductDistributionを使って極値分布を含む独立成分分布の結合分布を計算することができる．
  • 極値分布は他の数多くの分布と関連がある．先述したように，ExtremeValueDistributionは，起る可能性が極めて低い事象の説明に用いられる，GumbelDistribution，FrechetDistribution，WeibullDistribution等の数多くの分布の1つである．この定性的な関係は，ExtremeValueDistribution[α,β]のPDFがTransformedDistribution[-β α Log[u/β]+α,u WeibullDistribution[α,β]]やTransformedDistribution[-β α Log[u/β]+α,u WeibullDistribution[α,β]]のそれと厳密に等しいように，数量的な成分も併せ持つ．ExtremeValueDistributionはExponentialDistributionおよびMinStableDistributionの変換で，ExtremeValueDistribution[α,β]のPDFがMaxStableDistribution[α,β,0]のそれと等しいという意味で，MaxStableDistributionの特殊ケースである．ExtremeValueDistributionは，ExpGammaDistribution，ExponentialDistribution，LogisticDistributionとも関係がある．

例題

すべて開く すべて閉じる

例  (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[ExtremeValueDistribution[α, 2], x], {α, {-3, 0, 4}}]//Evaluate, {x, -8, 12}, Filling -> Axis]
Wolfram Language code: Plot[Table[PDF[ExtremeValueDistribution[1.5, β], x], {β, {1.5, 2, 3}}]//Evaluate, {x, -5, 10}, Filling -> Axis]
Wolfram Language code: PDF[ExtremeValueDistribution[α, β], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[ExtremeValueDistribution[α, 2], x], {α, {-3, 0, 4}}]//Evaluate, {x, -8, 12}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[ExtremeValueDistribution[1.5, β], x], {β, {1.5, 2, 3}}]//Evaluate, {x, -5, 10}, Filling -> Axis]
Wolfram Language code: CDF[ExtremeValueDistribution[α, β], x]

平均と分散：

Wolfram Language code: Mean[ExtremeValueDistribution[α, β]]
Wolfram Language code: Variance[ExtremeValueDistribution[α, β]]

中央値：

Wolfram Language code: Median[ExtremeValueDistribution[α, β]]

スコープ  (7)

極値分布からの擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[ExtremeValueDistribution[3, 2.5], 10 ^ 4];

ヒストグラムと確率密度関数を比較する：

Wolfram Language code: Show[Histogram[data, 20, "PDF"], Plot[PDF[ExtremeValueDistribution[3, 2.5], x], {x, Min[data], Max[data]}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[ExtremeValueDistribution[2, 3], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, ExtremeValueDistribution[α, β]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, Min[sample], Max[sample]}, PlotStyle -> Thick]]

歪度と尖度は一定である：

Wolfram Language code: Skewness[ExtremeValueDistribution[α, β]]
Wolfram Language code: N[%]
Wolfram Language code: Kurtosis[ExtremeValueDistribution[α, β]]
Wolfram Language code: N[%]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[ExtremeValueDistribution[α, β], k]//FullSimplify, {k, 4}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[ExtremeValueDistribution[α, β], k], {k, 4}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[ExtremeValueDistribution[α, β], k]//FullSimplify, {k, 4}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[ExtremeValueDistribution[α, β], k], {k, 4}], C]

記号次数の閉じた形：

Wolfram Language code: Cumulant[ExtremeValueDistribution[α, β], r]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[ExtremeValueDistribution[α, 2], x], {α, {1 / 2, 4, 7}}]//Evaluate, {x, -4, 15}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[ExtremeValueDistribution[1 / 2, β], x], {β, {1 / 2, 1, 2}}]//Evaluate, {x, -2, 4}, Filling -> Axis]
Wolfram Language code: HazardFunction[ExtremeValueDistribution[α, β], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[ExtremeValueDistribution[2, β], q], {β, {0.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Plot[Table[Quantile[ExtremeValueDistribution[α, 1.5], q], {α, {-0.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Quantile[ExtremeValueDistribution[α, β], q]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: oilPrice𝒟 = ExtremeValueDistribution[["100 USDollars/barrel"], ["18 USDollars/barrel"]]

原油価格の中央値と四分位偏差を求める：

Wolfram Language code: {Median[oilPrice𝒟], QuartileDeviation[oilPrice𝒟]}//N

アプリケーション  (3)

寿命が極値分布に従うデバイスがある．このデバイスの信頼性を求める：

Wolfram Language code: r = SurvivalFunction[ExtremeValueDistribution[α, β], t]

故障率は第2母数のみに依存する水平漸近線を持つ：

Wolfram Language code: HazardFunction[ExtremeValueDistribution[α, β], t]
Wolfram Language code: Limit[HazardFunction[ExtremeValueDistribution[α, β], t], t -> ∞, Assumptions -> α > 0 && β > 0]

直列のこのようなデバイス2つの信頼性を求める：

Wolfram Language code: rs = r r//PiecewiseExpand

並列のこのようなデバイス2つの信頼性を求める：

Wolfram Language code: rp = 1 - (1 - r)(1 - r)//PiecewiseExpand

と について2つの系の信頼性を比較する：

Wolfram Language code: Block[{α = 2, β = 1.5}, Plot[{rs, rp}, {t, 0, 10}, PlotLegends -> {"in series", "in parallel"}]]

ExtremeValueDistributionを使って月間最大風速をモデル化することができる．次は，1950年1月から2009年12月までに記録されたマサチューセッツ州ボストンの月間最大風速(km/h)である：

Wolfram Language code: maxWinds = TemporalData[TimeSeries, {{StructuredArray[QuantityArray, {720}, StructuredArray`StructuredData[QuantityArray, {66.6, 55.8, 55.8, 51.84, 50.04, 50.04, 42.48, 38.88, 66.6, 44.64, 96.48, 55.8, 48.24, 72.36, 55.8, 53.64, 53.64, 44.64, 4 ... 2.48, 46.44, 51.84, 48.24, 46.44, 37.08, 46.44, 46.44, 48.24, 59.4}, "Kilometers"/"Hours", {{1}}]]}, {{1, 720, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 314.1];
Wolfram Language code: maxWinds["FirstValue"]

分布をデータにフィットする：

Wolfram Language code: edist = EstimatedDistribution[maxWinds, ExtremeValueDistribution[a, b]]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[maxWinds, 20, "ProbabilityDensity"], Plot[PDF[edist, Quantity[x, "km per hour"]], {x, 30, 140}, PlotStyle -> Thick]]

月間最大風速が時速60マイルを上回る確率を求める：

Wolfram Language code: Probability[x > Quantity[60, "mph"], xedist]

月間最大風速の平均を求める：

Wolfram Language code: Mean[edist]

30ヶ月間の最大風速のシミュレーションを行う：

Wolfram Language code: ListPlot[{RandomVariate[edist, 30], {{0, Mean[edist]}, {30, Mean[edist]}}}, Joined -> {False, True}, Filling -> Axis, AxesOrigin -> {0, 0}, AxesLabel -> Automatic]

サイズ の正規サンプルにおける最大値の分布の近似を行う：

Wolfram Language code: max𝒟 = OrderDistribution[{NormalDistribution[], n}, n]; approx𝒟 = ExtremeValueDistribution[InverseCDF[NormalDistribution[], 1 - (1/n + 1)], InverseCDF[NormalDistribution[], 1 - (1/(n + 1) E)] - InverseCDF[NormalDistribution[], 1 - (1/n + 1)]];

密度関数のプロットを比較する：

Wolfram Language code: Table[Plot[{PDF[max𝒟, y], PDF[approx𝒟, y]}, {y, -2, 4.5}, PlotStyle -> {Dashed, Orange}, PlotRange -> All], {n, {2, 4, 8}}]

近似の平均：

Wolfram Language code: approxMean = Simplify[Mean[approx𝒟]]
Wolfram Language code: exactMean[n_Integer] := Mean[OrderDistribution[{NormalDistribution[0., 1.], n}, n]]

厳密分布の平均と比較する：

Wolfram Language code: Show[DiscretePlot[exactMean[n], {n, 2, 100}, PlotStyle -> Orange], Plot[approxMean, {n, 2, 100}, PlotRange -> All, PlotStyle -> Directive[Thick, Dashed]]]

特性と関係  (17)

極値分布は平行移動と正の因子によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[a * u + b, uExtremeValueDistribution[]]

任意のパラメータ値で：

Wolfram Language code: TransformedDistribution[a * u + b, uExtremeValueDistribution[α, β]]

歪度はGumbelDistributionの歪度に負号を付けたものである：

Wolfram Language code: ExtremeValue = ExtremeValueDistribution[α, β]; Gumbel = GumbelDistribution[α, β];
Wolfram Language code: {Skewness[ExtremeValue], Skewness[Gumbel]}

ExtremeValueDistributionは右に歪み，GumbelDistributionは左に歪んでいる：

Wolfram Language code: Block[{α = 4, β = 2}, Plot[{PDF[ExtremeValue, x], PDF[Gumbel, x]}, {x, -5, 15}, Filling -> Axis, PlotLegends -> {"ExtremeValue", "Gumbel"}]]

尖度はGumbelDistributionの尖度に等しい：

Wolfram Language code: {Kurtosis[ExtremeValueDistribution[α, β]], Kurtosis[GumbelDistribution[α, β]]}

ExtremeValueDistributionはMaxを取る際に閉じている：

Wolfram Language code: OrderDistribution[{ExtremeValueDistribution[α, β], n}, n]
Wolfram Language code: TransformedDistribution[Max[x1, x2, x3], {x1, x2, x3}ProductDistribution[{ExtremeValueDistribution[α, β], 3}]]

ExtremeValueDistributionのCDFは安定性の仮定の方程式を解く：

Wolfram Language code: CDF[OrderDistribution[{ExtremeValueDistribution[α, β], n}, n], x] == CDF[ExtremeValueDistribution[α, β], a x + b]

上記が恒等式になるような と の条件を求める：

Wolfram Language code: Reduce[ForAll[x, %] && DistributionParameterAssumptions[ExtremeValueDistribution[α, β]], {a, b}, Reals]

他の分布との関係：

ExtremeValueDistributionはGumbelDistributionの否定である：

Wolfram Language code: TransformedDistribution[-u, uGumbelDistribution[α, β]]
Wolfram Language code: TransformedDistribution[-u, uExtremeValueDistribution[α, β]]

ExtremeValueDistributionはWeibullDistributionを変換したものである：

Wolfram Language code: TransformedDistribution[m - k * Log[c * u], uWeibullDistribution[α, β], Assumptions -> c > 0 && k > 0]

WeibullDistributionは極値分布を変換したものである：

Wolfram Language code: 𝒟 = TransformedDistribution[β Exp[-(u - α) / (α β) ], uExtremeValueDistribution[α, β]];
Wolfram Language code: Block[{α = 2, β = .5}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[WeibullDistribution[α, β], x], {x, 0, 1.5}, PlotStyle -> Thick]]]

極値分布はMaxStableDistributionの特殊ケースである：

Wolfram Language code: PDF[MaxStableDistribution[α, β, 0], x]
Wolfram Language code: PDF[ExtremeValueDistribution[α, β], x]
Wolfram Language code: % - %%//FullSimplify

極値分布はMinStableDistributionを変換したものである：

Wolfram Language code: 𝒟 = TransformedDistribution[-u, uMinStableDistribution[-α, β, 0]];
Wolfram Language code: PDF[𝒟, x]
Wolfram Language code: PDF[ExtremeValueDistribution[α, β], x]
Wolfram Language code: % - %%//FullSimplify

極値分布はExponentialDistributionを変換したものである：

Wolfram Language code: 𝒟 = TransformedDistribution[α - β Log[u], uExponentialDistribution[1]];
Wolfram Language code: PDF[𝒟, x]//FullSimplify[#, β > 0]&
Wolfram Language code: PDF[ExtremeValueDistribution[α, β], x]
Wolfram Language code: % - %%

極値分布に従う2変量の差はGumbelDistributionに従う2変量の差が従う分布，すなわちLogisticDistributionに従う：

Wolfram Language code: TransformedDistribution[u - v, {uExtremeValueDistribution[α1, β], vExtremeValueDistribution[α2, β]}]
Wolfram Language code: TransformedDistribution[u - v, {uGumbelDistribution[α1, β], vGumbelDistribution[α2, β]}]

極値分布とGumbelDistributionの和はLogisticDistributionに従う：

Wolfram Language code: TransformedDistribution[u + v, {uExtremeValueDistribution[α1, β], vGumbelDistribution[α2, β]}]

LogisticDistributionは極値分布のParameterMixtureDistributionである：

Wolfram Language code: 𝒟 = ParameterMixtureDistribution[ExtremeValueDistribution[α, β], αGumbelDistribution[-β Log[γ], β]];
Wolfram Language code: PDF[𝒟, x]
Wolfram Language code: PDF[LogisticDistribution[-Log[γ]β, β], x]//Simplify
Wolfram Language code: % - %%

ExponentialDistributionおよびExtremeValueDistributionの最大値はShiftedGompertzDistributionに従う：

Wolfram Language code: dist = TransformedDistribution[Max[x, y], {xExponentialDistribution[λ], yExtremeValueDistribution[Log[ξ] / λ, 1 / λ]}];
Wolfram Language code: CDF[dist, x]
Wolfram Language code: CDF[ShiftedGompertzDistribution[λ, ξ], x]
Wolfram Language code: % - %%//Simplify

個の独立した指数分布のランダム変数の最大値（ はPoissonDistributionに従う）は，ExtremeValueDistributionに従う：

Wolfram Language code: res1 = Sum[CDF[OrderDistribution[{ExponentialDistribution[λ], n}, n], x]PDF[PoissonDistribution[μ], n], {n, 0, ∞}]//FullSimplify[#, x >= 0]&
Wolfram Language code: res2 = CDF[ExtremeValueDistribution[-(Log[(1/μ)]/λ), (1/λ)], x]//FullSimplify
Wolfram Language code: FullSimplify[res1 / res2]

考えられる問題  (3)

最大値の分布はExtremeValueDistributionで与えられる：

Wolfram Language code: PDF[ExtremeValueDistribution[α, β], x]

最小値の分布はGumbelDistributionで与えられる：

Wolfram Language code: PDF[GumbelDistribution[α, β], x]

ExtremeValueDistributionは，α が実数ではないときは定義されない：

Wolfram Language code: Mean[ExtremeValueDistribution[3 + I, 1]]

ExtremeValueDistributionは，β が正の実数ではないときは定義されない：

Wolfram Language code: Mean[ExtremeValueDistribution[3, -1]]

記号出力に無効な母数値を代入すると意味のない結果が返される：

Wolfram Language code: Mean[ExtremeValueDistribution[α, β]] /. {α -> I, β -> 3}

おもしろい例題  (1)

累積分布関数の等高線を持つ α のさまざまな値についての確率密度関数：

Wolfram Language code: dist = ExtremeValueDistribution[α, 2];cdf = Function[{x, α}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, -4, 7}, {α, -3, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotPoints -> 100, PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2007), ExtremeValueDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExtremeValueDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2007), ExtremeValueDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExtremeValueDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2007. "ExtremeValueDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/ExtremeValueDistribution.html.

APA

Wolfram Language. (2007). ExtremeValueDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ExtremeValueDistribution.html

BibTeX

@misc{reference.wolfram_2026_extremevaluedistribution, author="Wolfram Research", title="{ExtremeValueDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ExtremeValueDistribution.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_extremevaluedistribution, organization={Wolfram Research}, title={ExtremeValueDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/ExtremeValueDistribution.html}, note=[Accessed: 16-September-2026]}