KagiChart
詳細とオプション
- カギ足は水平線と連結した一連の垂直線として描かれる.値は閾値 rt を超えて反転するまで1つの列に描かれる.閾値を超えると前列と連結した水平線で形で新たな列が始まる.
- 線のスタイルは値が前の列の最高値あるいは最低値を超えると変化する.
- KagiChart[…]は平均株価の2%の反転閾値についてはKagiChart[…,{"Relative",0.02}]に等しい.
- 反転閾値 rt の指定には次の引数が使える.
-
{"Percent",p} 前の値との百分率 {"Relative",p} 値幅との割合(デフォルト) {"Absolute",p} 絶対値動き - 日付 dateiは順序だった一連の事象とみなされ,絶対時間尺では表示されない.
- dateiの日付形式はDateListPlotで使われているものと同じである.
- "name"と daterange はFinancialDataで使われているものと同じである.
- KagiChartのデータ要素は次の形式で与えることができる,
-
{datei,pi} 純粋な日付と値のペア {datei,Quantity[pi,ui]} 単位の付いた日付と値のペア wi[{datei,pi},…] 日付と値のペアおよびラッパー wi formi->mi メタデータ miを含む日付と値のペア - 1本の線分でいくつかの日付と値のペアを表すことがある.対応するラッパーはその線分全体に適用される.
- 上記の形式以外で与えられたデータは欠測値とみなされ図表の生成時に除外されることが多い.
- KagiChartのデータは次の形式で与えられる.
-
{e1,e2,…} ラッパーがある/ない要素のリスト TimeSeries[…],EventSeries[…],TemporalData[…] 時系列,事象系列,一時データ w[{e1,e2,…}] データ全体に適用されたラッパー - KagiChart[Tabular[…]cspec]は,列指定 cspec を使って表オブジェクトから値を抽出し,これをプロットする.
- 表データのプロットには,次の列指定の形式 cspec を使うことができる.
-
{coldate,colp} colpからの値と coldateからの日付をプロットする - 次のラッパーをデータ要素に使うことができる.
-
Annotation[e,label] 注釈を付ける Button[e,action] 要素がクリックされたときに実行するアクションを定義する EventHandler[e,…] 要素の一般的なイベントハンドラを定義する Hyperlink[e,uri] 要素がハイパーリンクとして動作するようにする Labeled[e,…] 要素をラベル付きで表示する PopupWindow[e,cont] 要素にポップアップウィンドウを付ける StatusArea[e,label] 要素上にマウスが置かれたときにステータスエリアに表示する Style[e,opts] 要素を指定されたスタイルで表示する Tooltip[e,label] 要素に任意のツールチップを付ける - KagiChartでは,LabeledとPlacedに次の位置が使える.
-
Above, Below, Before, After 点またはフィギュアの外の位置 {lx,ly} ラベル内のスケールされた位置{lx,ly} - KagiChartにはGraphicsと同じオプションに以下の追加・変更を加えたものが使える. [全オプションのリスト]
-
AspectRatio 1/GoldenRatio 全体的な縦横比 Axes True 軸を描くかどうか ChartBaseStyle Automatic 棒の全体的なスタイル DateFunction Automatic どのように日付を標準形に変換するか EventLabels None ラベルを付ける事象 GridLines Automatic 描画する格子線 GridLinesStyle Automatic 格子線のスタイル PerformanceGoal $PerformanceGoal パフォーマンスのどの面について最適化するか PlotTheme $PlotTheme グラフの全体的なテーマ ScalingFunctions None y 軸をどのようにスケールするか TargetUnits Automatic グラフ内に表示する単位 TrendStyle Automatic 上昇傾向と下降傾向をどのようにスタイリングするか - ScalingFunctions->syのとき,関数 sy は値に適用される.ScalingFunctionsは表示のみに影響し,コントロールには影響しない.
- KagiChartのオプションその他の構造からのスタイルその他の指定は事実上TrendStyle,Styleその他のラッパーの順に適用され,後で適用されたものが先に適用されたものに優先する.
全オプションのリスト
例題
すべて開く すべて閉じる例 (2)
data = FinancialData["AAPL", "Close", {{2009, 5, 1}, {2010, 4, 30}, "Day"}];KagiChart[data]FinancialDataの項目から3ヶ月間の価格を使う:
KagiChart["^GSPC"]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}]スコープ (26)
データとラッパー (16)
KagiChart["AAPL"]KagiChart[{"IBM", {{2009, 10, 1}, {2010, 3, 31}}}]FinancialDataからデータを得る:
data = FinancialData["MSFT", {{2009, 6, 1}, {2009, 12, 1}}];KagiChart[data]Table[KagiChart[{"IBM", {{2009, 10}, {2010, 2}}}, i, PlotLabel -> i], {i, {Automatic, {"Relative", 0.02}}}]Table[KagiChart[{"IBM", {{2009, 8}, {2010, 2}}}, {"Relative", i}, PlotLabel -> i], {i, {0.02, 0.05}}]Table[KagiChart[{"IBM", {{2009, 8}, {2010, 2}}}, {"Percent", i}, PlotLabel -> i], {i, {1, 2}}]Table[KagiChart[{"IBM", {{2009, 10}, {2010, 2}}}, bs, PlotLabel -> bs], {bs, {{"Absolute", 1}, {"Absolute", 2}}}]data = FinancialData["AAPL", {{2010, 1, 1}, {2010, 2, 28}}];KagiChart[data, AxesLabel -> Automatic]data = FinancialData["AAPL", {{2010, 1, 1}, {2010, 2, 28}}];KagiChart[data, AxesLabel -> Automatic, TargetUnits -> "Euros"]データは,TimeSeries,EventSeries,あるいはTemporalDataでよい:
data = EventSeries[FinancialData["BAC", {{2014, 1}, {2014, 4}}]]KagiChart[data]KagiChart[{{{2010, 1, 4}, 130.54}, {{2010, 1, 5}, 128.96}, {{2010, 1, 6}, 128.13}, Style[{{2010, 1, 7}, 127.68}, Blue], {{2010, 1, 8}, 128.96}, {{2010, 1, 11}, 127.61}, {{2010, 1, 12}, 128.63}, {{2010, 1, 13}, 128.35}, {{2010, 1, 14}, 130.4}, {{2010, 1, 15}, 129.88}, {{2010, 1, 19}, 132.21}, {{2010, 1, 20}, 128.37}}, 0.01]KagiChart[Style[{{{2010, 1, 4}, 130.54}, {{2010, 1, 5}, 128.96}, {{2010, 1, 6}, 128.13}, {{2010, 1, 7}, 127.68}, {{2010, 1, 8}, 128.96}, {{2010, 1, 11}, 127.61}, {{2010, 1, 12}, 128.63}, {{2010, 1, 13}, 128.35}, {{2010, 1, 14}, 130.4}, {{2010, 1, 15}, 129.88}, {{2010, 1, 19}, 132.21}, {{2010, 1, 20}, 128.37}}, Dashed], 0.01]KagiChart[Style[{{{2010, 1, 4}, 130.54}, {{2010, 1, 5}, 128.96}, {{2010, 1, 6}, 128.13}, Style[{{2010, 1, 7}, 127.68}, Blue], {{2010, 1, 8}, 128.96}, {{2010, 1, 11}, 127.61}, {{2010, 1, 12}, 128.63}, {{2010, 1, 13}, 128.35}, {{2010, 1, 14}, 130.4}, {{2010, 1, 15}, 129.88}, {{2010, 1, 19}, 132.21}, {{2010, 1, 20}, 128.37}}, Dashed], 0.01]KagiChart[{{{2010, 1, 4}, 130.54}, {{2010, 1, 5}, 128.96}, {{2010, 1, 6}, 128.13}, Tooltip[{{2010, 1, 7}, 127.68}, "label"], {{2010, 1, 8}, 128.96}, {{2010, 1, 11}, 127.61}, {{2010, 1, 12}, 128.63}, {{2010, 1, 13}, 128.35}, {{2010, 1, 14}, 130.4}, {{2010, 1, 15}, 129.88}, {{2010, 1, 19}, 132.21}, {{2010, 1, 20}, 128.37}}, 0.01]PopupWindowを使って追加的なドリルダウン情報を加える:
KagiChart[PopupWindow[{{{2010, 1, 4}, 130.54}, {{2010, 1, 5}, 128.96}, {{2010, 1, 6}, 128.13}, {{2010, 1, 7}, 127.68}, {{2010, 1, 8}, 128.96}, {{2010, 1, 11}, 127.61}, {{2010, 1, 12}, 128.63}, {{2010, 1, 13}, 128.35}, {{2010, 1, 14}, 130.4}, {{2010, 1, 15}, 129.88}, {{2010, 1, 19}, 132.21}, {{2010, 1, 20}, 128.37}}, TradingChart["GOOG"]], 0.01]Buttonを使って任意のアクションを起すことができる:
KagiChart[{{{2010, 1, 4}, 130.54}, {{2010, 1, 5}, 128.96}, {{2010, 1, 6}, 128.13}, Button[{{2010, 1, 7}, 127.68}, Speak["Close at 127.68"]], {{2010, 1, 8}, 128.96}, {{2010, 1, 11}, 127.61}, {{2010, 1, 12}, 128.63}, {{2010, 1, 13}, 128.35}, {{2010, 1, 14}, 130.4}, {{2010, 1, 15}, 129.88}, {{2010, 1, 19}, 132.21}, {{2010, 1, 20}, 128.37}}, 0.01]表形式データ (1)
stock = ToTabular[IconizedObject[«stock data»], "Columns", <|"ColumnKeys" -> {"date", "open", "high", "low", "close", "volume"}|>]KagiChart[stock -> {"date", "high"}]KagiChart[stock -> {"date", "high"}, {"Relative", 0.01}]スタイルと外観 (6)
KagiChart[{"IBM", {{2010, 1, 1}, {2010, 5, 1}}}, TrendStyle -> {Green, Red}]KagiChart[{"IBM", {{2010, 1, 1}, {2010, 5, 1}}}, TrendStyle -> "RedGreen"]KagiChart[{"IBM", {{2010, 1, 1}, {2010, 5, 1}}}, TrendStyle -> "BlueYellow"]ChartBaseStyleを使ってすべてのチャート要素を設定することができる:
KagiChart[{"IBM", {{2010, 1, 1}, {2010, 5, 1}}}, TrendStyle -> {Green, Red}, ChartBaseStyle -> AbsoluteThickness[5]]Styleを使ってスタイルを無効にすることができる:
KagiChart[Style[{{{2010, 1, 4}, 130.54}, {{2010, 1, 5}, 128.96}, {{2010, 1, 6}, 128.13}, {{2010, 1, 7}, 127.68}, {{2010, 1, 8}, 128.96}, {{2010, 1, 11}, 127.61}, {{2010, 1, 12}, 128.63}, {{2010, 1, 13}, 128.35}, {{2010, 1, 14}, 130.4}, {{2010, 1, 15}, 129.88}, {{2010, 1, 19}, 132.21}, {{2010, 1, 20}, 128.37}}, Dotted], 0.01, ChartBaseStyle -> Dashed]KagiChart[{"JPM", {{2010, 4, 1}, {2010, 5, 13}}}, PlotTheme -> "Business"]暗い背景でコントラストがはっきりしたカラースキームのテーマを使う:
KagiChart[{"JPM", {{2010, 4, 1}, {2010, 5, 13}}}, PlotTheme -> "Marketing"]ラベル (3)
Labeledを使ってロウソクにラベルを付ける:
KagiChart[{{{2010, 1, 4}, 130.54}, {{2010, 1, 5}, 128.96}, {{2010, 1, 6}, 128.13}, {{2010, 1, 7}, 127.68}, {{2010, 1, 8}, 128.96}, {{2010, 1, 11}, 127.61}, {{2010, 1, 12}, 128.63}, {{2010, 1, 13}, 128.35}, {{2010, 1, 14}, 130.4}, {{2010, 1, 15}, 129.88}, Labeled[{{2010, 1, 19}, 132.21}, "label"], {{2010, 1, 20}, 128.37}}, 0.01]Table[KagiChart[{{{2010, 1, 4}, 130.54}, {{2010, 1, 5}, 128.96}, {{2010, 1, 6}, 128.13}, {{2010, 1, 7}, 127.68}, {{2010, 1, 8}, 128.96}, {{2010, 1, 11}, 127.61}, {{2010, 1, 12}, 128.63}, {{2010, 1, 13}, 128.35}, {{2010, 1, 14}, 130.4}, {{2010, 1, 15}, 129.88}, Labeled[{{2010, 1, 19}, 132.21}, "label", p], {{2010, 1, 20}, 128.37}}, 0.01], {p, {Above, Below, Before, After}}]KagiChart[{"IBM", {{2010, 1, 1}, {2010, 1, 15}}}, 0.01, EventLabels -> {{2010, 1, 5} -> "●", {2010, 1, 8} -> "▲", {2010, 1, 14} -> "■"}]Placedを使ってLabeledと同じ位置になるようにラベル配置を制御する:
KagiChart[{"IBM", {{2010, 1, 1}, {2010, 1, 15}}}, 0.01, EventLabels -> {{2010, 1, 5} -> Placed["●", After], {2010, 1, 11} -> Placed["■", Above]}]オプション (64)
AspectRatio (3)
デフォルトで,KagiChartはプロットに固定された縦横比を使う:
KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}]AspectRatio1を使って幅と高さを等しくする:
KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AspectRatio -> 1]AspectRatioFullとすると,他の構築物内にぴったり納まるように高さと幅が調整される:
chart = KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AspectRatio -> Full];{Framed[Pane[chart, {75, 150}]], Framed[Pane[chart, {100, 100}]], Framed[Pane[chart, {150, 75}]]}Axes (3)
デフォルトでAxesが描かれる:
KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}]KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, Axes -> False]{KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, Axes -> {True, False}], KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, Axes -> {False, True}]}AxesLabel (3)
KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}]KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AxesLabel -> "$"]FinancialDataを使う際に単位をラベルとして使う:
KagiChart[FinancialData["TSLA", {{2019, 10}, {2021, 1}}], AxesLabel -> Automatic]AxesOrigin (3)
KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}]KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AxesOrigin -> {{2020, 6, 28}, Automatic}]Table[KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AxesOrigin -> {i, Automatic}, PlotLabel -> i], {i, {Left, Right}}]AxesStyle (4)
KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AxesStyle -> Red]KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AxesStyle -> {{Thick, Red}, {Thick, Blue}}]KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AxesStyle -> Green, TicksStyle -> Red]KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AxesStyle -> Green, LabelStyle -> StandardBlue]ChartBaseStyle (1)
ChartBaseStyleを使って棒にスタイルを付ける:
Table[KagiChart[{"AAPL", {{2010, 1}, {2010, 5}}}, ChartBaseStyle -> s], {s, {Thickness[0.02], Dotted, Opacity[0.5], Directive[Thickness[0.03], JoinForm["Round"]]}}]EventLabels (3)
KagiChart[{"IBM", {{2009, 10}, {2010, 3, 1}}}, EventLabels -> {{2010, 1, 12} -> "label"}]FinancialData["IBM", "RawClose", {{2010, 1, 12}}]Placedを使ってラベル配置を制御する:
Table[KagiChart[{"IBM", {{2009, 10}, {2010, 3, 1}}}, EventLabels -> {{2010, 1, 10} -> Placed["label", i]}, PlotLabel -> i], {i, {Above, Below, Before, After}}]Placedを使ってラベルの外観を制御する:
Table[KagiChart[{"IBM", {{2009, 10}, {2010, 3, 1}}}, EventLabels -> {{2010, 1, 10} -> Placed["label", Automatic, s]}], {s, {Style[#, 24]&, Framed, Panel, "GlassBubble"}}]Frame (3)
KagiChartは,デフォルトで,枠は使わない:
KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Frame -> True]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Frame -> {{True, False}, {True, False}}]FrameStyle (2)
KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Frame -> True, FrameStyle -> Directive[StandardBlue, Thick]]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Frame -> True, FrameStyle -> {{Directive[Orange, Thick], Directive[Red]}, {Directive[Gray, Thick], Directive[Blue]}}]GridLines (4)
KagiChart[{"AAPL", {{2009, 10}, {2010, 5}}}]KagiChart[{"C", {{2009, 10}, {2010, 5}}}, GridLines -> {None, Automatic}]KagiChart[{"JPM", {{2009, 10}, {2010, 5}}}, GridLines -> {Automatic, None}]Table[KagiChart[{"SP500", {{2009, 10}, {2010, 5}}}, GridLines -> {d, Automatic}, PlotLabel -> d], {d, {"Month", "Year"}}]KagiChart[{"SP500", {{2009, 10}, {2010, 5}}}, GridLines -> {{{"Year", Directive[Dashed, Thick, Red]}, "Month"}, Automatic}]GridLinesStyle (4)
デフォルトで,GridLinesStyleは点線の格子線う:
KagiChart[{"AAPL", {{2010, 1}, {2010, 5}}}]KagiChart[{"AAPL", {{2009, 10}, {2010, 5}}}]KagiChart[{"AAPL", {{2009, 10}, {2010, 5}}}, GridLinesStyle -> {Directive[Red, Dotted], Dotted}]GridLinesはGridLinesStyleを無効にする:
KagiChart[{"AAPL", {{2009, 10}, {2010, 5}}}, GridLines -> {{{"Month", StandardBlue}}, None}, GridLinesStyle -> Red]ImageSize (7)
Tiny,Small,Medium,Largeのような名前付きのサイズを使う:
{KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, ImageSize -> Tiny], KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, ImageSize -> Small]}{KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, ImageSize -> 150], KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AspectRatio -> 1.5, ImageSize -> 150]}{KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, ImageSize -> {Automatic, 150}], KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AspectRatio -> 1, ImageSize -> {Automatic, 150}]}{KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, ImageSize -> UpTo[200]], KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AspectRatio -> 1, ImageSize -> UpTo[200]]}グラフィックスの幅と高さを指定して,必要な場合はスペースで充填する:
KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, ImageSize -> {200, 200}, Background -> StandardGray]AspectRatioFullと設定すると使用可能なスペースが塗り潰される:
KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AspectRatio -> Full, ImageSize -> {200, 200}, Background -> StandardGray]{KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, ImageSize -> {UpTo[150], UpTo[100]}], KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, AspectRatio -> 1, ImageSize -> {UpTo[150], UpTo[100]}]}ImageSizeFullを使ってオブジェクト内の使用可能なスペースを塗り潰す:
Framed[Pane[KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, ImageSize -> Full, Background -> StandardGray], {200, 100}]]Framed[Pane[KagiChart[{"TSLA", {{2019, 10}, {2021, 1}}}, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> StandardGray], {200, 100}]]PerformanceGoal (3)
インタラクティブなハイライト機能のあるKagiChartを作る:
KagiChart[{"IBM", {{2009, 10}, {2010, 5}}}, PerformanceGoal -> "Quality"]インタラクティブ機能を無効にしてパフォーマンスを向上させる:
KagiChart[{"IBM", {{2009, 10}, {2010, 5}}}, PerformanceGoal -> "Speed"]一般に,インタラクティブ機能がないグラフの方がメモリ量は少なくて済む:
Table[ByteCount@KagiChart[{"IBM", {{2009, 10}, {2010, 5}}}, PerformanceGoal -> p], {p, {"Quality", "Speed"}}]PlotRange (3)
KagiChartは自動的にすべての価格の日付を表示する:
KagiChart[{"SP500", {{2010, 2}, {2010, 5}}}, 0.005]KagiChart[{"SP500", {{2010, 2}, {2010, 5}}}, 0.005, PlotRange -> {{{2010, 3, 1}, {2010, 4, 15}}, Automatic}]PlotRangeはデータのある日付のみを入れる:
KagiChart[{"SP500", {{2010, 2, 1}, {2010, 3, 31}}}, 0.005, PlotRange -> {{{2010, 2, 1}, {2010, 4, 30}}, Automatic}]PlotTheme (2)
ScalingFunction (1)
Ticks (7)
KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Ticks -> None]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Ticks -> {Automatic, None}]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Ticks -> {{{1, a}, {5, b}, {10, c}}, {{700, d}, {1000, e}}}]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Ticks -> {Automatic, {{700, d}, {1000, e}}}]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Ticks -> {Automatic, {{700, d, .2}, {1000, e, .6}}}]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Ticks -> {Automatic, {{700, d, {.2, .2}}, {1000, e, {.6, .3}}}}]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, Ticks -> {Automatic, {{700, d, {.2, .2}, Directive[Thick, Dashed, Red]}, {1000, e, {.6, .3}, Directive[Blue, Thick]}}}]TicksStyle (4)
デフォルトで,目盛と目盛ラベルには軸と同じスタイルが使われる:
KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, AxesStyle -> Red]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, TicksStyle -> Red]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, TicksStyle -> {Directive[Blue, Thick], Directive[Red, Bold]}]KagiChart[{"^GSPC", {{2009, 1, 1}, {2009, 12, 31}}}, TicksStyle -> Directive[StandardBlue, Thick], LabelStyle -> Red]TrendStyle (4)
KagiChart[{"AAPL", {{2009, 10}, {2010, 5}}}, TrendStyle -> {Green, Red}]Table[KagiChart[{"DOW", {{2009, 10}, {2010, 5}}}, TrendStyle -> ts, PlotLabel -> ts], {ts, {"BlueYellow", "PurpleGold", "BrownYellow", "Blue", "Gold", "BlackSilver"}}]TrendStyleをChartBaseStyleと組み合せる:
KagiChart[{"JPM", {{2009, 10}, {2010, 5}}}, TrendStyle -> {Purple, Orange}, ChartBaseStyle -> Thickness[0.02]]TrendStyleをNoneにすると,ChartBaseStyleが使われる:
KagiChart[{"BAC", {{2009, 10}, {2010, 5}}}, TrendStyle -> None, ChartBaseStyle -> Orange]アプリケーション (1)
KagiChartにWeatherDataを使ってシカゴの平均気温を見る:
KagiChart[WeatherData["Chicago", "MeanTemperature", {{2023, 10, 1}, {2024, 9, 1}, "Day"}]]特性と関係 (7)
Table[KagiChart[{"IBM", {{2009, 8}, {2010, 2}}}, i, PlotLabel -> i], {i, {0.02, 0.05}}]KagiChartは株価が大幅に変化した時間区分のみを示す:
FinancialData["IBM", "Close", {"Jan 1, 2010", "Jan 31, 2010", "Day"}]KagiChart[{"IBM", {"Jan 1, 2010", "Jan 31, 2010"}}]CandlestickChartを使って金融データを可視化する:
CandlestickChart[{"AAPL", {{2010, 1, 1}, {2010, 5, 31}}}]TradingChartを使って金融データを可視化し分析する:
TradingChart[{"AAPL", {{2010, 1, 1}, {2010, 6, 1}}}, {"SMA", "V"}]InteractiveTradingChartを使って金融データを可視化しインタラクティブに分析する:
InteractiveTradingChart[{"IBM", {{2009, 6, 1}, {2010, 6, 1}}}]PointFigureChart,LineBreakChart,RenkoChartを使って金融価格と時間の関係を分析する:
{PointFigureChart["IBM"], LineBreakChart["GOOG"], RenkoChart["GOOG"]}DateListPlotを使って金融データを可視化する:
DateListPlot[FinancialData["MSFT", {{2010, 1, 1}, {2010, 6, 1}}]]テキスト
Wolfram Research (2010), KagiChart, Wolfram言語関数, https://reference.wolfram.com/language/ref/KagiChart.html (2025年に更新).
CMS
Wolfram Language. 2010. "KagiChart." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/KagiChart.html.
APA
Wolfram Language. (2010). KagiChart. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/KagiChart.html
BibTeX
@misc{reference.wolfram_2026_kagichart, author="Wolfram Research", title="{KagiChart}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/KagiChart.html}", note=[Accessed: 12-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_kagichart, organization={Wolfram Research}, title={KagiChart}, year={2025}, url={https://reference.wolfram.com/language/ref/KagiChart.html}, note=[Accessed: 12-November-2026]}