Median
Median
詳細
- Medianは，強力な位置推定器である．つまり，これは外れ値にはあまり敏感ではない．
- VectorQ data
の中央値は「真ん中の値」と考えることができる． - 形式的には，data が
とソートされるとき，
が奇数であれば中央値はその中央の要素 
で与えられ，
が偶数であれば中央の2つの要素の平均
で与えられる． - Median[data]はQuantile[data,1/2,{{1/2,0},{0,1}}]に等しい．
- MatrixQ data の中央値は各列ベクトルについて計算される．Median[{{x1,y1,…},{x2,y2,…},…}]は{Median[{x1,x2,…}],Median[{y1,y2,…}],…}に等しい． »
- ArrayQ data の中央値はArrayReduce[Median,data,1]に等しい． »
- data は次の追加的な形式と解釈を持つことがある．
-
Association 値（キーは無視される） » SparseArray 配列として，Normal[data]に等しい » QuantityArray 配列としての数量 » WeightedData もとになっているEmpiricalDistributionに基づく » EventData もとになっているSurvivalDistributionに基づく » TimeSeries, TemporalData, … ベクトルまたは値の配列（タイムスタンプは無視される） » Image,Image3D RGBチャンネル値またはグレースケールの強度値 » Audio すべてのチャンネルの振幅値 » DateObject, TimeObject 日付のリストまたは時間のリスト » - Median[dist]は，Probability[x≤m,xdist]≥1/2かつProbability[x≥m,xdist]≥1/2となるような数値 m の集合の最小値である． »
- 連続分布 dist の中央値は累積分布関数を使って
![CDF[dist,q_(1/2)]=1/2](Files/Median.ja/4.png "CDF[dist,q_(1/2)]=1/2")
と定義できる． - Median[dist]はQuantile[dist,1/2]に等しい．
- ランダム過程 proc については，中央値関数
は時点 t におけるスライス分布SliceDistribution[proc,t]についてMedian[SliceDistribution[proc,t]]として計算できる． »
例題
すべて開く すべて閉じる例 (4)
Median[{1, 2, 3, 4, 5, 6, 7}]Median[{1, 2, 3, 4, 5, 6, 7, 8}]dates = Table[DateObject[{2024, k}], {k, 1, 12}]Median[dates]Median[ExponentialDistribution[λ]]スコープ (24)
基本的な用法 (8)
Median[{1, 2, 3, 4}]Median[{π, E, 2}]Median[{1., 2., 3., 4.}]Median[N[{1, 2, 3, 4}, 30]]WeightedDataの中央値を求める：
Median[WeightedData[{1, 2, 3}, {3, 7, 4}]]data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};Median[WeightedData[data, weights]]EventDataの中央値を求める：
e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};Median[EventData[e, ci]]TemporalDataの中央値を求める：
s1 = {2, 1, 6, 5, 7, 4};
s2 = {4, 7, 5, 6, 1, 2};
t = {1, 2, 5, 10, 12, 15};td = TemporalData[{s1, s2}, {t}];Median[td[10]]TimeSeriesの中央値を求める：
v = {3, 8, 4, 11, 9, 2};
t = {1, 3, 5, 7, 8, 10};
ts = TimeSeries[v, {t}];Median[ts]Median[ts["Values"]]MovingMap[Median, {2.5, 1.2, 6.9, 5.8, 7.1, 4.8}, Quantity[3, "Events"]]data = Quantity[RandomReal[1, 6], "Meters"]Median[data]配列データ (5)
行列のMedianは列ごとの中央値を与える：
Median[{{1, 11, 3}, {4, 6, 7}}]テンソルのMedianは第1レベルの列ごとの中央値を与える：
Median[{{{3, 7}, {2, 1}}, {{5, 19}, {12, 4}}}]Median[RandomReal[1, 10 ^ 7]]Median[RandomReal[1, {10 ^ 6, 5}]]入力がAssociationのとき，Medianはその値に作用する：
mat = RandomReal[1, {3, 2}];assoc = AssociationThread[Range[3], mat]
Median[assoc]SparseArrayデータは密な配列と同じように使うことができる：
Median[SparseArray[{{1} -> 1, {100} -> 1}]]Median[SparseArray[{{1, 1} -> 1, {2, 2} -> 2, {3, 3} -> 3, {1, 3} -> 4}]]QuantityArrayの中央値を求める：
data = QuantityArray[RandomReal[1, 6], "Pounds"]Median[data]画像データと音声データ (2)
日付と時間 (5)
dates = WolframLanguageData[All, "DateIntroduced"];DateHistogram[dates]Median[dates]dates = RandomDate[4]weights = {1, 1, 1, 3};Median[WeightedData[dates, weights]]異なる暦で与えられたDateObjectオブジェクトの中央値を計算する：
dates = {DateObject[{6024, 1, 15}, CalendarType -> "Jewish"], DateObject[{2024, 2, 29}, CalendarType -> "Julian"], DateObject[{1524, 1, 1}, CalendarType -> "Islamic"]}Median[dates]TimelinePlot[dates, ImageSize -> Medium]データの支配的なデータ型はないので，並べ替えると結果の暦の型が変わる：
RotateLeft[dates]Median[%]% == Median[dates]TimeObjectオブジェクトの中央値を計算する：
times = RandomTime[3]Median[times]times = {TimeObject[{12}, TimeZone -> -3], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}Median[times]DateValue[%, "TimeZone"]データで支配的な時刻帯はないので，並べ替えると結果の時刻帯が変わる：
RotateRight[times]Median[%]% == Median[times]分布と過程 (4)
Median[NormalDistribution[μ, σ]]Median[TransformedDistribution[x^2, xNormalDistribution[]]]Median[ProbabilityDistribution[8.x ^ 7 / 255, {x, 1, 2}]]data = RandomVariate[NormalDistribution[], 10 ^ 3];Median[HistogramDistribution[data]]Median[GammaDistribution[1.7, Quantity[7, "Meters"]]]Median[EmpiricalDistribution[QuantityArray[RandomChoice[{0, 5}, 1000], "Volts"]]]Median[PoissonProcess[3][4]]Plot[Median[PoissonProcess[3][t]], {t, 0, 10}]アプリケーション (7)
dists = {NormalDistribution[3, 1], WeibullDistribution[2, 2]};Table[With[{m = Median[𝒟]}, Plot[PDF[𝒟, x], {x, 0, 6}, Filling -> Axis, Epilog -> {Directive[Red, Dotted, Thick], Line[{{m, 0}, {m, PDF[𝒟, m]}}]}]], {𝒟, dists}]dists = {ExponentialDistribution[1], MixtureDistribution[{2, 1}, {NormalDistribution[2, 0.5], NormalDistribution[5, 1 / 2]}]};Table[With[{m = Median[𝒟]}, Plot[PDF[𝒟, x], {x, 0, 6}, Filling -> Axis, Epilog -> {Directive[Red, Dotted, Thick], Line[{{m, 0}, {m, PDF[𝒟, m]}}]}]], {𝒟, dists}]北米の141の主な河川について，長さの中央値をマイル単位で求める：
data = ExampleData[{"Statistics", "RiverLengths"}];Length[data]m = Median[data]このデータのHistogramをプロットする：
highlightbar[{{x0_, x1_}, {y0_, y1_}}, data_, meta___] := {If[x0 ≤ First[meta] < x1, Red, {}], Rectangle[{x0, y0}, {x1, y1}]}Histogram[data -> m, ChartElementFunction -> highlightbar]NProbability[x > 0.9m, xdata]data = TemporalData[TimeSeries, {{{26.27, 24.26, 23.94, 23.08, 24.17, 23.99, 23.27, 24.09, 22.78, 21.51,
21.68, 21.74, 20.97, 18.74, 18.27, 17.52, 17.52, 17.73, 17.81, 18.24, 18.02, 17.74, 17.43,
16.44, 16.34, 16.91, 17.44, 16.82, 17.44, 17.18, ... 200, 3628281600,
3628368000, 3628540800, 3628800000, 3628886400, 3628972800, 3629145600}}}, 1,
{"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1,
ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 10.1];med = MovingMap[Median, data, {Quantity[90, "Day"]}];Show[DateListPlot[data, PlotStyle -> GrayLevel[.7]], DateListPlot[med, Joined -> True, PlotStyle -> Thick]]Median[{1, 5, 2, 6, 10, 10 ^ 5, 5, 4}]極端な値はMeanに大きく影響する：
Mean[{1, 5, 2, 6, 10, 10 ^ 5, 5, 4}]//Ndata = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];times = Range[0, 1, .1];med = Map[{#, Median[data[#]]}&, times];Show[ListPlot[data], ListLinePlot[med, PlotStyle -> Green]]heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147,
150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic]m = Median[heights]ListPlot[{heights, {{0, m}, {25, m}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]特性と関係 (7)
data = RandomReal[20, 50];Quantile[data, 1 / 2, {{1 / 2, 0}, {0, 1}}]Median[data]ほぼ対称のサンプルの場合，MedianとMeanはほとんど同じである：
Mean[{1, 2, 3, 4, 4, 3, 1, 1}]//NMedian[{1, 2, 3, 4, 4, 3, 1, 1}]//N一変量のデータについては，MedianはSpatialMedianと一致する：
Median[{1, 2, 3, 4, 4, 3, 1, 1}]SpatialMedian[{1, 2, 3, 4, 4, 3, 1, 1}]Medianからの絶対偏差のMedianはMedianDeviationである：
data = RandomReal[10, 10];MedianDeviation[data]Median[Abs[data - Median[data]]]MovingMedianは連続する中央値である：
MovingMedian[{1, 5, 2, 3, 10, 6}, 3]Table[Median[Take[{1, 5, 2, 3, 10, 6}, {i, i + 2}]], {i, 4}]任意の分布について，InverseCDF[dist,1/2]=Median[dist]が存在する：
Subscript[𝒟, 1] = NormalDistribution[];
Subscript[𝒟, 2] = GeometricDistribution[1 / 12];InverseCDF[Subscript[𝒟, 1], 1 / 2] == Median[Subscript[𝒟, 1]]InverseCDF[Subscript[𝒟, 2], 1 / 2] == Median[Subscript[𝒟, 2]]InverseSurvivalFunctionについても同様である：
InverseSurvivalFunction[Subscript[𝒟, 1], 1 / 2] == Median[Subscript[𝒟, 1]]InverseSurvivalFunction[Subscript[𝒟, 2], 1 / 2] == Median[Subscript[𝒟, 2]]連続分布の場合はCDF[dist,Median[dist]]=1/2である：
𝒩 = NormalDistribution[];CDF[𝒩, Median[𝒩]]SurvivalFunctionについても同様である：
SurvivalFunction[𝒩, Median[𝒩]]𝒢 = GeometricDistribution[1 / 12];CDF[𝒢, Median[𝒢]]N[%]考えられる問題 (2)
Medianは数値を必要とする：
Median[{a, b, c}]
Quantileを介して計算されたデータの中央値は常にMedianと一致するわけではない：
data = RandomReal[10, 20];Quantile[data, 1 / 2]Median[data]%% - %Quantileで線形補間パラメータを指定する：
Quantile[data, 1 / 2, {{1 / 2, 0}, {0, 1}}]%%% - %おもしろい例題 (1)
20個，100個，300個のサンプルについてのMedian推定値の分布：
Median[ExponentialDistribution[0.9]]SmoothHistogram[Table[Median[RandomVariate[ExponentialDistribution[0.9], {s, 1000}]], {s, {20, 100, 300}}], Filling -> Axis, PlotLegends -> {20, 100, 300}, PlotRange -> {{0, 2}, Automatic}]
Wolfram Research (2003), Median, Wolfram言語関数， https://reference.wolfram.com/language/ref/Median.html （2024年に更新）.
テキスト
Wolfram Research (2003), Median, Wolfram言語関数， https://reference.wolfram.com/language/ref/Median.html （2024年に更新）.
CMS
Wolfram Language. 2003. "Median." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/Median.html.
APA
Wolfram Language. (2003). Median. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Median.html