Wolfram 语言与系统参考资料中心

MultinomialDistribution

MultinomialDistribution[n,{p₁,p₂,…,p_m}]

表示试验次数为 n、概率为 p_i 的多项分布.

背景

MultinomialDistribution[n,{p₁,p₂,…,p_m}] 表示一个支持在的子集上的一个离散多元统计分布，这个子集是由满足和并且每个第个（单变量）边际分布对有 BinomialDistribution 的整数构成的所有元组组成的. 换言之，各个变量对满足 x_jBinomialDistribution[n,p_j]. 这个多项分布由正整数 n 和满足的非负实数参数化，这些参数共同定义分布的相关均值、方差和协方差.
多项分布对从类型 i 表示总体的百分之 p_i 的集合中有替换地进行 n 次抽取的情境进行建模. 这可以图像化为一个从含有 m 种不同的球并且其中 i 类球的百分比为 p_i （）的瓮中有替换地取出 n 个球的瓮模型. 这个多项分布由法国数学家 Pierre Raymond de Montmort 于1708年的论文中首次分析，使之成为最早研究的多变量概率分布之一. 此后它成为研究包括粒子物理学中的分子运动论和会计学中的高估在内的多种不同现象的工具. 它也被广泛应用于相依表、电讯建模、流行病学和光子计数的分析中.
RandomVariate 可用于从一个多项分布中给出一个或多个机器精度或任意精度（后者通过 WorkingPrecision 选项）伪随机变量. Distributed[x,MultinomialDistribution[n,{p₁,p₂,…,p_m}]] ，更简洁地写作 xMultinomialDistribution[n,{p₁,p₂,…,p_m}]，可用于断言随机变量 x 符合多项分布. 这样的断言即可用于如 Probability、 NProbability、 Expectation 和 NExpectation 等函数.
多项分布的概率密度和累积分布函数可以通过 PDF[MultinomialDistribution[n,{p₁,p₂,…,p_m}]] 和 CDF[MultinomialDistribution[n,{p₁,p₂,…,p_m}]] 给出. 均值、中位数、方差、协方差、原始矩和中心矩可以分别通过 Mean、 Median、 Variance、 Covariance、 Moment 和 CentralMoment 给出.
DistributionFitTest 可用于测试给定数据集是否符合多项分布， EstimatedDistribution 可用于从给定数据中估计多项参数分布，而 FindDistributionParameters 可用于拟合数据至一个多项分布. ProbabilityPlot 可用于生成给定数据的 CDF 对符号化多项分布的 CDF 的图像，而 QuantilePlot 可用于生成给定数据的分位数对符号化多项分布的分位数的图像.
TransformedDistribution 可用于表示一个变形多项分布，CensoredDistribution 可用于表示上限和下限值之间的删节值的分布，而 TruncatedDistribution 可用于表示上限和下限值之间的截尾值的分布. CopulaDistribution 可用于构建包含多项分布的更高维分布，而 ProductDistribution 可用于计算涉及多项分布的有独立组分分布的联合分布.
MultinomialDistribution 与其他一些分布有关. 如上所述 MultinomialDistribution 与 BinomialDistribution 相关，MultinomialDistribution 的每个一维边际 PDF 都有 BinomialDistribution 而多变量边际不化简至指定的分布. MultivariateHypergeometricDistribution 的瓮模型的分布模型的抽取不包含替换，就此意义而言 MultinomialDistribution 的瓮模型与 MultivariateHypergeometricDistribution 的瓮模型有关. 由于其与单变量 BinomialDistribution 的关系，它与与 BernoulliDistribution、 NormalDistribution、 PoissonDistribution、 BetaBinomialDistribution 和 NegativeBinomialDistribution 有关.

范例

打开所有单元关闭所有单元

基本范例 (4)

概率质量函数：

Wolfram Language code:

Table[DiscretePlot3D[PDF[MultinomialDistribution[n, {0.6, 0.4}], {x, y}], {y, 0, n}, {x, 0, n}, PlotLabel -> Row[{"n = ", n}], ExtentSize -> 0.5], {n, {3, 6, 9, 12}}]

Wolfram Language code: PDF[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2]}], {x, y}]

Wolfram Language code: PDF[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {x, y, z}]

累积分布函数：

Wolfram Language code:

Table[DiscretePlot3D[CDF[MultinomialDistribution[n, {0.6, 0.4}], {x, y}], {x, 0, n}, {y, 0, n}, PlotLabel -> Row[{"n = ", n}], ExtentSize -> Right], {n, {3, 6, 9, 12}}]

均值和方差：

Wolfram Language code: Mean[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2]}]]

Wolfram Language code: Variance[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2]}]]

协方差：

Wolfram Language code: Covariance[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2]}]]//MatrixForm

范围 (8)

从多项分布生成一个伪随机向量样本：

Wolfram Language code: sample = RandomVariate[𝒹 = MultinomialDistribution[10, {0.3, 0.7}], 10 ^ 4];

Wolfram Language code:

{Histogram3D[sample, {-0.5, 10.5, 1}, "PDF", ColorFunction -> "Rainbow"], DiscretePlot3D[PDF[𝒹, {x, y}], {x, 0, 10}, {y, 0, 10}, ColorFunction -> "Rainbow", ExtentSize -> 1]}

分布参数估计：

Wolfram Language code: sample = RandomVariate[MultinomialDistribution[20, {0.2, 0.3, 0.5}], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code: e𝒟 = EstimatedDistribution[sample, MultinomialDistribution[n, {p1, p2, p3}]]

拟合优度检验：

Wolfram Language code: PearsonChiSquareTest[sample, MultinomialDistribution[n, {p1, p2, p3}]]

偏度：

Wolfram Language code: Skewness[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2]}]]

Wolfram Language code: Limit[Skewness[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2]}]], n -> ∞]

峰度：

Wolfram Language code: Kurtosis[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2]}]]

Wolfram Language code: Limit[Kurtosis[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2]}]], n -> ∞]

应用 (5)

在一次竞选中，有两位候选人，其中获胜者由简单的多数得票率决定. 这里有个选民，他们把票投给1号候选人的概率是而投给2号候选人的概率是，其中，这样使得一个选民可能不投给任何候选人. 当，，两位候选人得票相同的概率是：

Wolfram Language code: 𝒟 = MultinomialDistribution[100 - 1, {0.4, 0.4, 1 - 0.4 - 0.4}];

Wolfram Language code: Probability[x == y, {x, y, z}𝒟]

获胜者比失败者多一票的概率是：

Wolfram Language code: Probability[Abs[x - y] == 1, {x, y, z}𝒟]

1号候选人赢得选举的概率：

Wolfram Language code: Probability[x > y, {x, y, z}𝒟]

下一次选举的可能结果是：

Wolfram Language code: RandomVariate[𝒟]

一次选举的平均结果：

Wolfram Language code: Mean[𝒟]

在3个容器中分配5个球，每个容器具有相同的概率被选中. 求没有容器是空的概率：

Wolfram Language code:

Probability[Subscript[x, 1] > 0 && Subscript[x, 2] > 0 && Subscript[x, 3] > 0, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}MultinomialDistribution[5, {1 / 3, 1 / 3, 1 / 3}]]

使用 SurvivalFunction 计算相同的概率：

Wolfram Language code: SurvivalFunction[MultinomialDistribution[5, {1 / 3, 1 / 3, 1 / 3}], {0, 0, 0}]

在相同的概率下，把个球分配给个容器. 求对于和的不同值，不存在空容器的概率：

Wolfram Language code:

ballprob[n_Integer, m_Integer] := SurvivalFunction[MultinomialDistribution[n, ConstantArray[1 / m, {m}]], ConstantArray[0, {m}]]

Wolfram Language code: DiscretePlot3D[Evaluate@ballprob[n, m], {n, 7}, {m, 2, 7}, ExtentSize -> 1 / 2, ViewPoint -> {1, 1, 1}]

在电话客户服务中心，其中三件事可能会发生：线路繁忙的概率为0.4，错误来电的概率为0.1，或来电者与代理连接成功. 求对于一个来电者致电6次，4次获得繁忙信号，2次直接连接到代理人的概率：

Wolfram Language code: 𝒟 = MultinomialDistribution[6, {0.4, 0.1, 0.5}];

Wolfram Language code: PDF[𝒟, {4, 0, 2}]

求来电者致电6次，至少2次错误来电的概率：

Wolfram Language code: SurvivalFunction[𝒟, {0, 2, 0}]

模拟在不同时间发生的6个呼叫请求：

Wolfram Language code: RandomVariate[𝒟]

在某个城市，911接到的所有电话中，其中有30%要求救护车，15%要求救火，剩下的是要求警察. 求在接下来的10个紧急呼叫中，2个要求救护车，1个要求救火，7个要求警察的概率：

Wolfram Language code: 𝒟 = MultinomialDistribution[10, {.3, .15, .55}];

Wolfram Language code: PDF[𝒟, {2, 1, 7}]

模拟在接下来100个呼叫中，各种不同要求的分布：

Wolfram Language code: Total@RandomVariate[𝒟, 10]

将多变量 Pólya 分布定义为负多项分布的参数混合：

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[NegativeMultinomialDistribution[10, {p1, p2}], {p1, p2}DirichletDistribution[{1, 2, 3}]];

Wolfram Language code: pdf = PDF[𝒟, {x, y}]

Wolfram Language code: DiscretePlot3D[pdf, {x, 0, 10}, {y, 0, 10}, ExtentSize -> 1 / 2]

属性和关系 (3)

与其他分布的关系：

双变量多项分布是 BinomialDistribution：

Wolfram Language code: PDF[MultinomialDistribution[n, {p, 1 - p}], {x, n - x}]

Wolfram Language code: PDF[BinomialDistribution[n, p], x]

Wolfram Language code: % - %%//FullSimplify

单变量多项分布是经过平移的 BernoulliDistribution：

Wolfram Language code: PDF[MultinomialDistribution[n, {1}], {x}]//FullSimplify[#, n ≥ 0]&

Wolfram Language code: PDF[TransformedDistribution[u + n - 1, uBernoulliDistribution[1], Assumptions -> n ≥ 0], x]//FullSimplify

可能存在的问题 (2)

MultinomialDistribution 在 n 不是正整数时无定义：

Wolfram Language code: Mean[MultinomialDistribution[-2, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3], Subscript[p, 4]}]]

MultinomialDistribution 在 p 的元素之和不为1时无定义：

Wolfram Language code: Mean[MultinomialDistribution[n, {1 / 2, 2}]]

将无效参数代入符号式输出中将给出无意义的结果：

Wolfram Language code:

Mean[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}]] /. {n -> -5, Subscript[p, 1] -> 1 / 2, Subscript[p, 2] -> 2, Subscript[p, 3] -> I}

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

MultinomialDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (5)

属性和关系 (3)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

MultinomialDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (5)

属性和关系 (3)

可能存在的问题 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX