Wolfram 语言与系统参考资料中心

AnatomyPlot3D

AnatomyPlot3D[primitives,options]

表示一个三维图形图像，可用于解剖学条目和三维图形基元和指令.

范例

打开所有单元关闭所有单元

基本范例 (5)

显示基础条目：

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftFemur"]]

Wolfram Language code: AnatomyPlot3D[Entity["AnimalAnatomicalStructure", "LeftFemur::CanisLupusFamiliaris::4t62p"]]

显示复杂条目：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "RightHand"]}]

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}]

条目的颜色和样式：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftClavicle"], StandardRed, Entity["AnatomicalStructure", "LeftScapula"]}]

为样式效果使用主题：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "RightHand"]}, PlotTheme -> "Business"]

在任意图形基元中使用实体：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"], AbsoluteThickness[2], StandardBlue, Arrow[{Entity["AnatomicalStructure", "DistalPhalanxOfLeftThumb"], Entity["AnatomicalStructure", "DistalPhalanxOfLeftIndexFinger"]}]}]

范围 (11)

上色和样式 (3)

可以对所有条目都做同一样式的上色：

Wolfram Language code: AnatomyPlot3D[{StandardBlue, Entity["AnatomicalStructure", "LeftArm"]}]

下列范例说明，也可操作诸如肱二头肌的“中等”结构，尽管这些结构由更小的微成分组成：

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> StandardGreen|>], Entity["AnatomicalStructure", "LeftArm"]}]

下列范例说明，你也可以分别为更低等级的微结构指定样式：

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "LongHeadOfLeftBicepsBrachii"] -> StandardGreen, Entity["AnatomicalStructure", "ShortHeadOfLeftBicepsBrachii"] -> StandardBlue|>], Entity["AnatomicalStructure", "LeftArm"]}]

下列范例说明，你可以给所有对象都上同一个颜色，但肌肉（或其他条目）除外，这些结构的颜色不同：

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|_ -> StandardRed, Entity["AnatomicalStructure", "Muscle"] -> StandardBlue|>], Entity["AnatomicalStructure", "LeftArm"]}]

没有参数的话，AnatomyForm 的表现与 FaceForm[] 一样：

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[], EdgeForm[StandardBlue], Entity["AnatomicalStructure", "SeventhCervicalVertebra"]}]

AnatomyForm["Natural"] 忽略更早的指令，将样式储存为其原始状态：

Wolfram Language code:

AnatomyPlot3D[{StandardRed, Entity["AnatomicalStructure", "SeventhCervicalVertebra"], AnatomyStyling["Natural"], Entity["AnatomicalStructure", "FirstThoracicVertebra"]}]

基元 (6)

绘制条目间的线：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"], Entity["AnatomicalStructure", "RightHand"], StandardRed, Line[{Entity["AnatomicalStructure", "LeftHand"], Entity["AnatomicalStructure", "RightHand"]}]}]

绘制条目中的箭头：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "SkeletonOfRightHand"], StandardRed, Arrow[{{-175, -130, 758}, Entity["AnatomicalStructure", "RightFifthMetacarpalBone"]}, 5], Text["5th metacarpal", {-175, -130, 758}, {0, -1}]}]

绘制条目中的立方体：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "HipBone"], Entity["AnatomicalStructure", "Scapula"], Opacity[.5, StandardRed], Cuboid[Entity["AnatomicalStructure", "LeftHipBone"], Entity["AnatomicalStructure", "RightScapula"]]}]

绘制条目中的球体：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "SkeletonOfLeftUpperLimb"], Opacity[.5], Sphere[Entity["AnatomicalStructure", "LeftElbow"], 50]}]

绘制条目中的圆柱体：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHumerus"], Entity["AnatomicalStructure", "LeftHand"], Opacity[.3], Cylinder[{Entity["AnatomicalStructure", "LeftElbow"], Entity["AnatomicalStructure", "LeftWrist"]}, 20]}]

绘制条目中的管道：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftClavicle"], Entity["AnatomicalStructure", "LeftScapula"], Entity["AnatomicalStructure", "LeftHand"], StandardRed, Tube[{Entity["AnatomicalStructure", "LeftShoulder"], Entity["AnatomicalStructure", "LeftElbow"], Entity["AnatomicalStructure", "LeftWrist"]}, 10]}]

为次结构（subpart）添加标签 (1)

使用文本对此结构添加标签：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "SetOfCervicalVertebrae"]}] /. Annotation[x_, y_] :> {x, LightDarkSwitched[Black, White], Text[y["Name"], y["Entity"]["RegionCentroid"] + {45, 0, 0}, {-1, 0}]}

切割层次 (1)

对解剖学结构使用一个剪切平面：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "Aorta"], ClipPlanes -> {InfinitePlane[{{-3, -123, 1226}, {17, -143, 1226}, {-3, -143, 1206}}]}, Entity["AnatomicalStructure", "Heart"]}, PlotRange -> Entity["AnatomicalStructure", "Heart"]]

对解剖学结构使用多个剪切平面：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"], ClipPlanesStyle -> {Directive[Opacity[.3], StandardRed], Directive[Opacity[.3], StandardBlue]}, ClipPlanes -> {InfinitePlane[{{273 - 20, -146, 725}, {273 - 20, -146 - 20, 725}, {273, -146 - 20, 725}}], InfinitePlane[{{273 + 20, -146 - 20, 735}, {273 + 20, -146, 735 - 20}, {273, -146 - 20, 735 - 20}}]}, Entity["AnatomicalStructure", "SkinOfLeftHand"]}, Boxed -> True, Axes -> True]

选项 (29)

AnatomySkinStyle (3)

解剖学结构条目自动包括最近的皮肤次结构：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftFemur"], Entity["AnatomicalStructure", "RightFemur"]}, AnatomySkinStyle -> Automatic]

可以复写默认样式：

Wolfram Language code:

AnatomyPlot3D[{StandardRed, Entity["AnatomicalStructure", "PituitaryGland"]}, AnatomySkinStyle -> Directive[StandardBlue, Opacity[.3]], ViewPoint -> Left]

默认行为中，不包括任何皮肤次结构：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftFemur"]}, AnatomySkinStyle -> None]

Axes (3)

默认情况下为 AnatomyPlot3D 绘制 Axes：

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}]

设置 AxesTrue 可绘制轴：

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True]

单独显示每条轴：

Wolfram Language code:

{AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, PlotLabel -> "X axis", Axes -> {True, False, False}], AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, PlotLabel -> "Y axis", Axes -> {False, True, False}], AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, PlotLabel -> "Z axis", Axes -> {False, False, True}]}

AxesLabel (3)

默认情况下不绘制坐标轴标签：

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True]

在轴上放置标签：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True, AxesLabel -> z]

指定轴标签：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True, AxesLabel -> {x, y, z}]

AxesOrigin (2)

自动确定轴的位置：

Wolfram Language code: AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True]

为轴指定一个明确的原点：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnimalAnatomicalStructure", "LeftForefoot::CanisLupusFamiliaris::4t62p"]}, Axes -> True, AxesOrigin -> {0, 0, -100}]

AxesStyle (4)

改变轴的样式：

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "LeftHand"], Axes -> 
	True, AxesStyle -> StandardRed]

为每条轴指定样式：

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "LeftHand"], Axes -> 
	True, AxesStyle -> {Directive[Thick, StandardRed], Directive[Thick, StandardBlue], Directive[Thick, StandardGreen]}]

刻度和轴使用不同样式：

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "LeftHand"], Axes -> 
	True, AxesStyle -> StandardBlue, TicksStyle -> StandardRed]

标签和轴使用不同样式：

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "LeftHand"], Axes -> 
	True, AxesStyle -> StandardPurple, LabelStyle -> StandardRed]

Method (2)

默认情况下可显示提示条，可通过 "Tooltips" 禁用：

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftIndexFinger"], Method -> {"Tooltips" -> False}]

对于某些 PlotTheme，默认情况下禁用工具条，可通过 "Tooltips" 启用：

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftIndexFinger"], PlotTheme -> "Minimal", Method -> {"Tooltips" -> True}]

默认情况下，一些结构周围可能有空白区域：

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftFoot"]]

可通过 "ShrinkWrap" 最小化这些 3D 结构周围的白色区域：

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "LeftFoot"], Method -> {"ShrinkWrap" -> True}]

PlotRange (1)

将 PlotRange 限制到指定条目，填充范围为 50 mm：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftFemur"], Entity["AnatomicalStructure", "LeftTibia"], Entity["AnatomicalStructure", "LeftFibula"], Entity["AnatomicalStructure", "LeftPatella"]}, PlotRange -> Entity["AnatomicalStructure", "LeftPatella"], PlotRangePadding -> 50]

PlotTheme (2)

经典教科书插图：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic"]

通过工具提示和单个颜色识别子部分：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Scientific"]

用平面阴影和最小细节来说明：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Minimal"]

历史的棕褐色调：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Vintage"]

透明的外观，强调骨骼，与x射线类似：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "XRay"]

通过将默认骨骼颜色与透明主题相结合来突出显示骨骼：

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|EntityClass["AnatomicalStructure", "Bones"] -> "Natural"|>], Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> {"Transparent", Hue[.58]}]

SphericalRegion (1)

默认情况下，渲染的场景以边界框的中心为中心：

Wolfram Language code: AnatomyPlot3D[Entity["AnatomicalStructure", "RightFoot"]]

SphericalRegion 可用于在特定场景元素周围重新定位场景，并将视图限制在元素的边界球体内：

Wolfram Language code:

AnatomyPlot3D[Entity["AnatomicalStructure", "RightFoot"], SphericalRegion -> Entity["AnatomicalStructure", "RightThirdMetatarsalBone"]]

Ticks (4)

刻度线会自动放置在每个绘图中：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True]

设置 TicksNone 则不会绘制任何刻度标记：

Wolfram Language code: AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> None]

将刻度标记放置于特定位置：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> {{220, 250, 300}, {-100, -120, -150}, {650, 700, 800}}]

使用指定标签在指定位置绘制刻度线：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> {{{220, a}, {250, b}, {300, c}}, {{-100, d}, {-120, e}, {-150, f}}, {{650, g}, {700, h}, {800, i}}}]

TicksStyle (4)

指定整体刻度样式，包括刻度标签：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, TicksStyle -> Directive[Bold, StandardRed]]

为每个轴指定刻度样式：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, TicksStyle -> {Directive[StandardPurple, Bold], Directive[Bold, StandardRed], Directive[Bold, StandardBlue]}]

指定按比例缩放长度的刻度线：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> {{{220, a, .1}, {250, b, .1}, {300, c, .1}}, {{-100, d, .2}, {-120, e, .2}, {-150, f, .2}}, {{650, g, .15}, {700, h, .15}, {800, i, .15}}}]

使用位置、长度、标签和样式自定义每个刻度：

Wolfram Language code:

AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftHand"]}, PlotTheme -> "Classic", Axes -> True, Ticks -> {{{220, a, .1, Directive[StandardRed]}, {250, b, .1, Directive[StandardRed]}, {300, c, .1, Directive[StandardRed]}}, {{-100, d, .2, Directive[StandardBlue, Thick]}, {-120, e, .2, Directive[StandardBlue, Thick]}, {-150, f, .2, Directive[StandardBlue, Thick]}}, {{650, g, .15, Directive[StandardBlue]}, {700, h, .15, Directive[StandardBlue]}, {800, i, .15, Directive[StandardBlue]}}}]

应用 (1)

通过使用解剖结构的区域属性可以自动标记更多的子部分：

Wolfram Language code:

anatomyCallouts[entities_, callouts_List] := Module[{scene, pr, sc, sr, cr}, 
	pr = PlotRange /. AbsoluteOptions[scene = AnatomyPlot3D[{entities}], PlotRange];{sc, sr} = {Mean /@ pr, Norm[Subtract@@@pr] / 2};
	cr = Rule@@@AnatomyData[callouts, {"Name", "RegionCentroid"}];
	Show[scene, Graphics3D[{Red, Line[{#[[2]], sr Normalize[(#[[2]] - sc)] + sc}]& /@ cr, Black, Inset[Style[#[[1]], Bold, 16], 1.1sr Normalize[(#[[2]] - sc)] + sc, Background -> GrayLevel[.95]]& /@ cr}], ImageSize -> {500, 400}]]

Wolfram Language code:

anatomyCallouts[{Entity["AnatomicalStructure", "Skull"]}, {Entity["AnatomicalStructure", "FrontalBone"], Entity["AnatomicalStructure", "OccipitalBone"], Entity["AnatomicalStructure", "RightTemporalBone"], Entity["AnatomicalStructure", "RightParietalBone"], Entity["AnatomicalStructure", "LeftParietalBone"], Entity["AnatomicalStructure", "LeftTemporalBone"]}]

属性和关系 (1)

该模型与 AnatomyPlot3D 一起使用，它与从 EntityValue 的 "Graphics3D" 属性中获取的模型一样：

Wolfram Language code: model = Entity["AnatomicalStructure", "HipBone"]["Graphics3D"]

该模型的结构中，每个次结构都有一个 Annotation，在添加标签和保持其他引用中很有用：

Wolfram Language code: Cases[model, _Annotation, ∞] /. Annotation[body_, ann_] :> Inactive[Annotation][Graphics3D[body], ann]

巧妙范例 (4)

使用 Overlay 将解剖结构放置在皮肤轮廓上：

Wolfram Language code:

Block[{opts = {PlotRange -> Entity["AnatomicalStructure", "Skin"], ViewAngle -> 14°, ViewCenter -> {.5, 0, .7}}}, Overlay[{AnatomyPlot3D[{AnatomyStyling[{Directive[Lighting -> {{"Ambient", White}}, GrayLevel[.3]]}], Entity["AnatomicalStructure", "Skin"]}, Background -> GrayLevel[.2], opts], AnatomyPlot3D[{Entity["AnatomicalStructure", "AlimentarySystem"]}, opts]}]]

在透明结构中定位子部件时控制 Opacity：

Wolfram Language code:

AnatomyPlot3D[{AnatomyStyling[<|_ -> Opacity[.15], Entity["AnatomicalStructure", "TricuspidValve"] -> White|>], Entity["AnatomicalStructure", "Heart"]}, PlotTheme -> {"Transparent", StandardRed}]

对解剖学结构使用 Rotate：

Wolfram Language code:

Manipulate[AnatomyPlot3D[{Entity["AnatomicalStructure", "Neurocranium"], Entity["AnatomicalStructure", "ZygomaticBone"], Entity["AnatomicalStructure", "SphenoidBone"], Entity["AnatomicalStructure", "NasalBone"], Entity["AnatomicalStructure", "Maxilla"], Entity["AnatomicalStructure", "MaxillaryDentition"], Rotate[{Entity["AnatomicalStructure", "Mandible"], Entity["AnatomicalStructure", "MandibularDentition"]}, Dynamic[t Degree], {1, 0, 0}, {0.33, -106., 1470.}]}, SphericalRegion -> True, PlotRange -> Entity["AnatomicalStructure", "Skull"], PlotRangePadding -> 20], {t, 0, 20}, SynchronousUpdating -> False]

在场景中对特定对象使用 ClipPlanes：

Wolfram Language code:

Manipulate[
	AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftUpperLimb"], ClipPlanes -> Dynamic[{InfinitePlane[{{0, -300, z}, {300, -300, z + 200}, {200, 0, z}}]}], Entity["AnatomicalStructure", "SkinOfLeftUpperLimb"]}], 
	{z, 400, 1400}, SynchronousUpdating -> False
	]

Top

Boxed	False	是否绘制边界箱
Lighting	"Neutral"	模拟使用的光源
PlotTheme	$PlotTheme	绘制的整体主题
AnatomySkinStyle	None	自动使用的样式，包括最近的皮肤部分
ViewPoint	{0,-1.9,0}	查看位置

		"Business"	一个大胆、现代的设计
		"Detailed"	使用标记的轴和网格线来识别尺寸
		"Marketing"	适合市场需求的优雅设计
		"Minimal"	带有最小细节的平面阴影
		"Monochrome"	单色设计
		"Scientific"	由工具提示识别的单独的彩色部分
		"Web"	适合网络的明亮阴影和颜色
		"Classic"	历史暗色

		"Transparent"	灰色透明度
		{"Transparent",color}	彩色透明度
		"Vintage"	棕褐色色调说明性设计
		"XRay"	强调骨骼的灰色透明度

		"BoldColor"	12 种鲜明的颜色
		"CoolColor"	8 种冷色
		"DarkColor"	8 种暗色
		"NeonColor"	8 种霓虹色
		"PastelColor"	8 种柔和色
		"RoyalColor"	8 种皇家颜色
		"VibrantColor"	10 种鲜艳的颜色
		"WarmColor"	8 种暖色

AlignmentPoint	Center	在图形内对齐的缺省点
AnatomySkinStyle	None	自动使用的样式，包括最近的皮肤部分
AspectRatio	Automatic	高与宽的比
Axes	False	是否绘制轴
AxesEdge	Automatic	在哪条边上放置轴
AxesLabel	None	坐标轴标签
AxesOrigin	Automatic	坐标轴交叉的位置
AxesStyle	{}	指定坐标轴样式的图形指令
Background	None	图形背景色
BaselinePosition	Automatic	如何与环绕文本基线对齐
BaseStyle	{}	图形的基本样式指定
Boxed	False	是否绘制边界箱
BoxRatios	Automatic	绑定的三维盒框比例
BoxStyle	{}	盒框的样式指定
ClipPlanes	None	剪切平面
ClipPlanesStyle	Automatic	剪切平面的样式指定
ContentSelectable	Automatic	是否允许内容选择
ControllerLinking	False	连接到外部旋转控制器的时间
ControllerPath	Automatic	尝试使用的外部控制器
Epilog	{}	在主图形显示后显示的二维图形基元
FaceGrids	None	在边框上绘制的网格线
FaceGridsStyle	{}	网格面的样式指定
FormatType	TraditionalForm	文本的缺省格式类型
ImageMargins	0.	图形周围预留的边幅
ImagePadding	All	允许为标签等设置的填充范围
ImageSize	Automatic	渲染图形的绝对尺寸
LabelStyle	{}	标签的样式指定
Lighting	"Neutral"	模拟使用的光源
Method	Automatic	使用的三维图形方法的详细信息
PlotLabel	None	图形的标签
PlotRange	All	包含值的范围
PlotRangePadding	Automatic	值域范围填充的程度
PlotRegion	Automatic	要填充的最终显示区域
PlotTheme	$PlotTheme	绘制的整体主题
PreserveImageOptions	Automatic	当显示相同图形的一个新版本时，是否保留图像选项
Prolog	{}	在主图形之前渲染的二维图形基元
RotationAction	"Fit"	互动旋转后渲染的方式
SphericalRegion	Automatic	是否将外切球体调整适合最后显示区域
Ticks	Automatic	指定刻度
TicksStyle	{}	刻度的样式指定
TouchscreenAutoZoom	False	当在一个触摸屏上激活时，是否放大为全屏
ViewAngle	Automatic	视图的角度
ViewCenter	Automatic	在中心显示的点
ViewMatrix	Automatic	显式转换矩阵
ViewPoint	{0,-1.9,0}	查看位置
ViewProjection	Automatic	用于渲染远离观察者的对象的投影方法
ViewRange	All	要包含的观察距离范围
ViewVector	Automatic	模拟相机的位置和方向
ViewVertical	{0,0,1}	垂直的方向

AnatomyPlot3D

更多信息和选项

所有选项的列表

范例

基本范例 (5)

范围 (11)

上色和样式 (3)

基元 (6)

为次结构（subpart）添加标签 (1)

切割层次 (1)

选项 (29)

AnatomySkinStyle (3)

Axes (3)

AxesLabel (3)

AxesOrigin (2)

AxesStyle (4)

Method (2)

PlotRange (1)

PlotTheme (2)

SphericalRegion (1)

Ticks (4)

TicksStyle (4)

应用 (1)

属性和关系 (1)

巧妙范例 (4)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX