Wolfram 语言与系统参考资料中心

AngularGauge

AngularGauge[value]

绘制一个仪表，在 0 到 1 范围内显示 value.

AngularGauge[value,{min,max}]

绘制一个仪表，在 min 到 max 范围内显示 value.

AngularGauge[Dynamic[value],…]

允许利用仪表交互地设置 value.

AngularGauge[{value₁,value₂,…},…]

绘制一个显示多个值的仪表.

范例

打开所有单元关闭所有单元

基本范例 (4)

生成一个显示特定值的千分表：

Wolfram Language code: AngularGauge[42, {0, 100}]

用带单位的值生成一个仪表：

Wolfram Language code: AngularGauge[["68 m/s"], {["0 m/s"], ["100 m/s"]}, GaugeLabels -> "Unit"]

生成一个显示多个值的千分表：

Wolfram Language code: AngularGauge[{15, 42, 63, 88}, {0, 100}]

生成一个具有交互式值的千分表：

Wolfram Language code: DynamicModule[{y = 0}, AngularGauge[Dynamic[y], {0, 100}]]

范围 (22)

数据和布局 (7)

数据值被限制在尺度范围内：

Wolfram Language code: AngularGauge[{-500, 1, 8, 14.68}, {0, 10}]

非实数数据被认为是缺失的，并通常显示为仪表的最小值：

Wolfram Language code:

Table[AngularGauge[a, {0, 10}], 
	{a, {2 + 2I, "Hi"}}]

所指定的 min 和 max 值将被排序，从而保证列表中较小的数值对应的总是 min：

Wolfram Language code: AngularGauge[42, {100, 0}]

用带单位的值生成一个仪表：

Wolfram Language code: AngularGauge[["68 m/s"], {["0 m/s"], ["100 m/s"]}, GaugeLabels -> "Unit"]

用 TargetUnits 指定所显示的单位：

Wolfram Language code:

AngularGauge[["68 m/s"], {["0 m/s"], ["100 m/s"]}, GaugeLabels -> "Unit", TargetUnits -> "Kilometers" / "Hours"]

改变标度的位置：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> Left]

显示一个半圆形的仪表：

Wolfram Language code: AngularGauge[88, {0, 100}, ScaleOrigin -> {π, 0}]

使用 Dynamic 生成互动仪表：

Wolfram Language code:

DynamicModule[{x}, Column[{AngularGauge[Dynamic[x], GaugeLabels -> Automatic], Slider[Dynamic[x]], Button["Reset", x = 0]}]]

样式化与外观 (9)

使用主题控制全局外观：

Wolfram Language code: AngularGauge[42, {0, 100}, PlotTheme -> "Business"]

使用显式样式作为指针：

Wolfram Language code: AngularGauge[{2, 17, 42, 88}, {0, 100}, GaugeStyle -> {Red, Green, Blue, Yellow}]

使用 ColorData 的任意梯度的或索引的颜色方案，设定指针的样式：

Wolfram Language code: Table[AngularGauge[{2, 17, 42, 88}, {0, 100}, GaugeStyle -> f], {f, {61, "Pastel"}}]

改变指针的类型：

Wolfram Language code: Table[AngularGauge[42, {0, 100}, GaugeMarkers -> f], {f, {"BezelBevelNeedle", "ShinyHubNeedle"}}]

改变指针的位置：

Wolfram Language code:

Table[AngularGauge[42, {0, 100}, GaugeMarkers -> Placed[Automatic, f]], {f, {"Center", "InsideScale", "OutsideScale", "Frame", "DivisionCenter", "ScaleRange"}}]

使用任意的图形或图片作为指针：

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeMarkers -> Placed[[image], #]]& /@ {"InsideScale", "DivisionCenter"}

改变仪表面的样式：

Wolfram Language code: Table[AngularGauge[42, {0, 100}, GaugeFaceStyle -> c], {c, {LightGray, LightOrange}}]

改变仪表四周框架的样式：

Wolfram Language code: Table[AngularGauge[42, {0, 100}, GaugeFrameStyle -> c], {c, {Black, LightOrange}}]

指定表盘上标度所要着色的范围：

Wolfram Language code: AngularGauge[20, {0, 100}, ScaleRanges -> {{50, 60}, {60, 70}, {70, 80}, {80, 100}}]

添加标签 (6)

使用 GaugeLabels 为表盘添加标签：

Wolfram Language code: AngularGauge[88, {0, 100}, GaugeLabels -> "MPH"]

添加显示的标度值：

Wolfram Language code: AngularGauge[9, {0, 10}, GaugeLabels -> "Value"]

显示仪表的单位：

Wolfram Language code: AngularGauge[Quantity[9, "Feet"], {0, 10}, GaugeLabels -> "Unit"]

显示单位和标度值：

Wolfram Language code: AngularGauge[Quantity[9, "Feet"], {0, 10}, GaugeLabels -> Full]

使用 Placed 改变标签在仪表表盘的位置：

Wolfram Language code: AngularGauge[86, {0, 100}, GaugeLabels -> Placed[ "% Complete", Above]]

使用列表指定多个标签：

Wolfram Language code: AngularGauge[68.2, {0, 100}, GaugeLabels -> {"Tank Pressure", "Value"}]

选项 (87)

AspectRatio (2)

默认情况下，AspectRatio 自动给出完美的圆：

Wolfram Language code: AngularGauge[60, {0, 100}]

使用固定比率来改变仪表的形状：

Wolfram Language code: AngularGauge[60, {0, 100}, AspectRatio -> 1 / 2]

Background (1)

插入仪表后面的背景色：

Wolfram Language code: AngularGauge[42, {0, 100}, Background -> LightBlue]

使用 GaugeFaceStyle 设置仪表面的样式：

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeFaceStyle -> LightBlue]

Frame (4)

AngularGauge 默认情况下不使用边框：

Wolfram Language code: AngularGauge[42, {0, 100}]

设置 FrameTrue 在绘图周围绘制边框：

Wolfram Language code: AngularGauge[42, {0, 100}, Frame -> True]

在左边和右边绘制边框：

Wolfram Language code: AngularGauge[42, {0, 100}, Frame -> {{True, True}, {False, False}}]

在左边和底边绘制边框：

Wolfram Language code: AngularGauge[42, {0, 100}, Frame -> {{True, False}, {True, False}}]

FrameStyle (2)

指定边框的样式：

Wolfram Language code: AngularGauge[42, {0, 100}, Frame -> True, FrameStyle -> Directive[StandardBlue, Thick]]

指定每条边框边的样式：

Wolfram Language code:

AngularGauge[42, {0, 100}, Frame -> True, FrameStyle -> {{Directive[Green, Thick], Red}, {Directive[Gray, Thick], Blue}}]

GaugeFaceElementFunction (3)

列出 GaugeFaceElementFunction 的内置设置：

Wolfram Language code: ChartElementData["AngularGauge", "Face"]

使用面板 ▶ 图表元素方案得到更详尽的设置：

Wolfram Language code:

Table[AngularGauge[42, {0, 100}, GaugeFrameStyle -> None, GaugeFaceStyle -> LightBlue, GaugeFaceElementFunction -> f, PlotLabel -> f], {f, {"GlassSector", "OscillatingSector"}}]

编写一个自定义的 GaugeFaceElementFunction：

Wolfram Language code:

f[{{θ1_, θ2_}, {r1_, r2_}}, __] := First[ParametricPlot[(Max[r, 0.65 + 0.1Abs[Cos[θ ^ 1.3]]Sin[16θ]]){ Cos[θ], Sin[θ]}, {θ, θ1, θ2}, {r, r1, r2}, Mesh -> None, PlotPoints -> {30, 3}, PlotStyle -> Directive[Opacity[1], LightGray], BoundaryStyle -> Gray]]

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeFrameStyle -> None, GaugeFaceElementFunction -> f]

GaugeFaceStyle (3)

指定仪表面的样式：

Wolfram Language code: Table[AngularGauge[42, {0, 100}, GaugeFaceStyle -> c], {c, {LightGray, LightOrange}}]

使用 None 关闭表面：

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeFaceStyle -> None, Background -> LightBlue]

使用 Texture 作为仪表面：

Wolfram Language code: AngularGauge[42, {0, 100}, TicksStyle -> Black, GaugeFaceStyle -> Texture[ExampleData[{"ColorTexture", "Amboyna"}]]]

Wolfram Language code:

AngularGauge[42, {0, 100}, TicksStyle -> Black, GaugeFaceStyle -> Texture[ImageCrop[Graphics3D[Sphere[], Boxed -> False]]]]

GaugeFrameElementFunction (3)

列出 GaugeFrameElementFunction 的内置设置：

Wolfram Language code: ChartElementData["AngularGauge", "Frame"]

使用面板 ▶ 图表元素方案得到更详尽的设置：

Wolfram Language code: Table[AngularGauge[42, {0, 100}, GaugeFrameElementFunction -> f, PlotLabel -> f], {f, {"BezelSector", "GlassSector"}}]

构建一个自定义的渲染函数：

Wolfram Language code:

f[{{tmin_, tmax_}, {rmin_, rmax_}}, ___] := Module[{inpts, outpts}, 
	inpts = Array[rmin{Cos[2π # / 100], Sin[2π # / 100]}&, 100];
	outpts = Array[rmax{Cos[2π # / 100], Sin[2π # / 100]}&, 100];
	{EdgeForm[Directive[Thick, Dashed, Gray]], LightGray, FilledCurve[{{Line[inpts]}, {Line[outpts]}}]}]

Wolfram Language code: AngularGauge[5.5, {0, 10}, GaugeFrameElementFunction -> f]

GaugeFrameSize (3)

使仪表框具有与仪表面尺寸呈一定比例的显式宽度：

Wolfram Language code:

{AngularGauge[42, {0, 100}, GaugeFrameSize -> .4], 
	AngularGauge[42, {0, 100}, GaugeFrameSize -> .05]}

使用 None 去掉表框：

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeFrameSize -> None]

使用已命名的尺寸指定仪表框大小：

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeFrameSize -> #]& /@ {Tiny, Small , Medium, Large}

GaugeFrameStyle (1)

使用指令改变对仪表框的渲染：

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeFrameStyle -> #]& /@ {Black, LightOrange}

GaugeLabels (10)

将值作为标签显示：

Wolfram Language code: AngularGauge[55, {0, 100}, GaugeLabels -> Automatic]

指定标签：

Wolfram Language code: AngularGauge[55, {0, 100}, GaugeLabels -> Style["", 24]]

标签可以是任意表达式：

Wolfram Language code: Table[AngularGauge[55, {0, 100}, GaugeLabels -> label], {label, {Sqrt[x^x], [image], [image]}}]

如果单位存在，可以作为标签添加到仪表：

Wolfram Language code:

{AngularGauge[42, {0, 100}, TargetUnits -> "psi", GaugeLabels -> "Unit"], AngularGauge[Quantity[6.5, "Feet"], {0, 10}, GaugeLabels -> "Unit"]}

使用 Placed 控制标签的位置：

Wolfram Language code: Table[AngularGauge[9, {0, 10}, GaugeLabels -> Placed["Value", p]], {p, {Left, Top, Right}}]

将标签放置在沿仪表的值处：

Wolfram Language code: Table[AngularGauge[9, {0, 10}, GaugeLabels -> Placed["Value", {p, {0.5, 0.5}}]], {p, {0, 5, 10}}]

利用按比例缩放的坐标系统，沿标度放置标签：

Wolfram Language code: Table[AngularGauge[9, {0, 10}, GaugeLabels -> Placed["Value", {Scaled[p], {0.5, 0.5}}]], {p, {0, 1 / 2, 1}}]

在整个仪表上使用按比例缩放的坐标系统：

Wolfram Language code: Table[AngularGauge[9, {0, 10}, GaugeLabels -> Placed["Value", p]], {p, {{0.35, 0.5}, {0.1, 0.9}, {0.5, 0.65}}}]

将所有标签放置在标度中央，并变化标签以内的坐标：

Wolfram Language code:

Table[AngularGauge[9, {0, 10}, GaugeLabels  -> Placed["Value", {Scaled[0.5], p}]], {p, {{0.5, 0}, {0.5, 1}, {0.5, 2.75}}}]

使用列表指定多个标签：

Wolfram Language code:

AngularGauge[9, {0, 10}, TargetUnits -> "RPM", GaugeLabels -> {"×1000", 
    "Unit", "Value"}]

GaugeMarkers (8)

显示指针或不显示指针：

Wolfram Language code: Table[AngularGauge[42, {0, 100}, GaugeMarkers -> typ], {typ, {Automatic, None}}]

列出 GaugeMarkers 的内置设置：

Wolfram Language code: ChartElementData["AngularGauge", "Markers"]

使用面板 ▶ 图表元素方案得到更详尽的设置：

Wolfram Language code:

Table[AngularGauge[42, {0, 100}, GaugeMarkers -> typ], {typ, {"BevelNeedle", "TwoToneNeedle", "BezelBevelNeedle", "ShinyHubNeedle"}}]

使用图像或图形作为指针：

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeMarkers -> [image]]

使用 Placed 改变指针的位置：

Wolfram Language code:

Table[AngularGauge[42, {0, 100}, GaugeMarkers -> Placed["PolarMarker", loc]], {loc, {"InsideScale", "OutsideScale", "Scale", "Frame"}}]

通过填充一个累计栏来标注值：

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeMarkers -> Placed[Automatic, "ScaleRange"]]

填充弧线段来标注值，弧线段以分度值为中心：

Wolfram Language code:

{AngularGauge[42, {0, 100}, GaugeMarkers -> Placed[Automatic, "DivisionCenter"]], 
	AngularGauge[42, {0, 100}, GaugeMarkers -> Placed[Automatic, "DivisionCenter"], TicksStyle -> Gray]}

当值被四舍五入到分度值时，顺序指针被激活：

Wolfram Language code:

{AngularGauge[94.99, {0, 100}, ScaleDivisions -> {5, 2}, TicksStyle -> Gray, GaugeMarkers -> Placed[Automatic, "DivisionCenter"]], AngularGauge[95, {0, 100}, ScaleDivisions -> {5, 2}, TicksStyle -> Gray, GaugeMarkers -> Placed[Automatic, "DivisionCenter"]]}

填充分度值之间的弧线段：

Wolfram Language code:

{AngularGauge[42, {0, 100}, GaugeMarkers -> Placed[Automatic, "DivisionInterval"]], 
	AngularGauge[42, {0, 100}, GaugeMarkers -> Placed[Automatic, "DivisionInterval"], TicksStyle -> Gray]}

当值大于或等于分度值时，顺序指针被激活：

Wolfram Language code:

{AngularGauge[99.99, {0, 100}, ScaleDivisions -> {5, 2}, TicksStyle -> Gray, GaugeMarkers -> Placed[Automatic, "DivisionInterval"]], AngularGauge[100, {0, 100}, ScaleDivisions -> {5, 2}, TicksStyle -> Gray, GaugeMarkers -> Placed[Automatic, "DivisionInterval"]]}

使用图像或图形作为累计式指针：

Wolfram Language code: AngularGauge[42, {0, 100}, GaugeMarkers -> Placed[[image], "DivisionInterval"]]

GaugeStyle (5)

设置仪表指针的样式：

Wolfram Language code: Table[AngularGauge[42, {0, 100}, GaugeStyle -> s], {s, {Red, Darker[Blue]}}]

默认情况下，对多个标记选择不同的样式：

Wolfram Language code: AngularGauge[{10, 27, 45, 62, 80, 97}, {0, 100}]

指定样式列表：

Wolfram Language code: AngularGauge[{10, 27, 45, 62, 80, 97}, {0, 100}, GaugeStyle -> {Red, Orange, Yellow, Green, Blue, Purple}]

使用 ColorData 中的梯度或索引的色彩方案：

Wolfram Language code: Table[AngularGauge[{10, 27, 45, 62, 80, 97}, {0, 100}, GaugeStyle -> s], {s, {"BlueGreenYellow", 24}}]

指定累计式指针在仪表值范围内的样式：

Wolfram Language code: Table[AngularGauge[42, {0, 100}, GaugeMarkers -> p, GaugeStyle -> Blue], {p, {"DivisionCenter", "ScaleRange"}}]

指定在仪表值范围外的其他指针样式：

Wolfram Language code:

Table[AngularGauge[42, {0, 100}, GaugeMarkers -> p, GaugeStyle -> {Blue, Lighter[Blue, 0.7]}], {p, {"DivisionCenter", "ScaleRange"}}]

用 None 指定不使用任何样式：

Wolfram Language code: Table[AngularGauge[42, {0, 100}, GaugeMarkers -> p, GaugeStyle -> {Blue, None}], {p, {"DivisionCenter", "ScaleRange"}}]

ImageSize (7)

使用有名称的尺寸如 Tiny、Small、Medium 和 Large：

Wolfram Language code: {AngularGauge[60, {0, 100}, ImageSize -> Tiny], AngularGauge[60, {0, 100}, ImageSize -> Small]}

指定绘图的宽度：

Wolfram Language code: {AngularGauge[60, {0, 100}, ImageSize -> 150], AngularGauge[60, {0, 100}, AspectRatio -> 1.5, ImageSize -> 150]}

指定绘图的高度：

Wolfram Language code:

{AngularGauge[60, {0, 100}, ImageSize -> {Automatic, 150}], AngularGauge[60, {0, 100}, AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

指定图形的宽度和高度，必要时用空白填充：

Wolfram Language code: AngularGauge[60, {0, 100}, ImageSize -> {200, 200}, Background -> LightBlue]

使用最大宽度和高度：

Wolfram Language code:

{AngularGauge[60, {0, 100}, ImageSize -> {UpTo[150], UpTo[100]}], AngularGauge[60, {0, 100}, AspectRatio -> 1.5, ImageSize -> {UpTo[150], UpTo[100]}]}

设置 ImageSizeFull 可填充对象中的可用空间：

Wolfram Language code: Framed[Pane[AngularGauge[60, {0, 100}, ImageSize -> Full, Background -> LightBlue], {200, 100}]]

将图像大小指定为可用空间的一个比例：

Wolfram Language code: Framed[Pane[AngularGauge[60, {0, 100}, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> LightBlue], {200, 100}]]

LabelStyle (1)

设定标签的样式：

Wolfram Language code: AngularGauge[42, {0, 100}, LabelStyle -> {18, Blue}]

PerformanceGoal (2)

生成一个仪表，在仪表指针上带有工具提示：

Wolfram Language code: AngularGauge[{2, 5.5, 9}, {0, 10}, PerformanceGoal -> "Quality"]

通过禁用互动行为来强化性能：

Wolfram Language code: AngularGauge[{2, 5.5, 9}, {0, 10}, PerformanceGoal -> "Speed"]

PlotTheme (4)

使用不同底座主题创建仪表：

Wolfram Language code:

Multicolumn[Table[Labeled[AngularGauge[7, {0, 10}, PlotTheme -> t, ImageSize -> 125], t], {t, {"Business", "Detailed", "Marketing", "Minimal", "Monochrome", "Scientific", "Web", "Classic"}}]]

将底座主题与 "GaugeHalf" 特征主题合并：

Wolfram Language code:

Multicolumn[Table[Labeled[AngularGauge[7, {0, 10}, PlotTheme -> {t, "GaugeHalf"}, ImageSize -> 125], t], {t, {"Business", "Detailed", "Marketing", "Minimal", "Monochrome", "Scientific", "Web", "Classic"}}]]

将量程原点与 "Marketing" 主题合并：

Wolfram Language code: AngularGauge[37, {0, 100}, PlotTheme -> "Marketing", ScaleOrigin -> {6Pi / 5, -Pi / 5}]

"Sparkline" 主题适合周围文本中的仪表：

Wolfram Language code: gauge = AngularGauge[0.54, PlotTheme -> "Sparkline"]

Wolfram Language code: TextCell[Row[{"Sparkline gauges ", gauge, " match the surrounding text size."}], FontFamily -> "Arial", FontSize -> 32]

ScaleDivisions (2)

指定分度的总数：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleDivisions -> 10]

指定主要和次要分度的数目：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleDivisions -> {5, 4}]

ScaleOrigin (4)

使用 ScaleOrigin 指定标度的弧度位置：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> .75]

用相对位置作为标度的中心：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> Left]

指定标度的起始和终止角度：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> {π, -π / 2}]

改变端点次序，使标度方向逆转：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> {-π / 2, π}]

改变端点，以使用标度的对面弧形：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> {π, 3π / 2}, ScalePadding -> All]

改变端点次序，使标度方向逆转：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> {3π / 2, π}, ScalePadding -> All]

指定标度的弧度和角度位置：

Wolfram Language code:

Table[AngularGauge[42, {0, 100}, ScaleOrigin -> f, ScalePadding -> All, PlotLabel -> f], {f, {{Left, .75}, {{π, -Pi / 2}, 1}}}]

ScalePadding (5)

使用自动确定的角填充：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> {0, π / 2}, ScalePadding -> Automatic]

完全填充，以保证一个“可观”的表盘形状：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> {π / 4, 3π / 4}, ScalePadding -> Full]

不在标度周围进行角填充：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> {0, π}, ScalePadding -> None]

指定一个固定的角填充：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> {0, π}, ScalePadding -> π / 12]

在两侧指定不同的角填充：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleOrigin -> {0, π / 2}, ScalePadding -> {π / 20, 11π / 20}]

ScaleRanges (7)

突出显示标度上某一范围的值：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> {80, 100}]

指定多个范围：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> {{50, 75}, {75, 90}, {90, 100}}]

样式化标度后面的整个区域：

Wolfram Language code:

AngularGauge[42, {0, 100}, ScaleRangeStyle -> Directive[White, EdgeForm[Black]], GaugeFrameStyle -> None, GaugeMarkers -> #, ScaleRanges -> All]& /@ {Automatic, "DivisionCenter"}

范围不必是连续的或不同的：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> {{0, 25}, {50, 75}, {75, 100}, {65, 85}}]

使用 range->style 将样式与范围直接联系：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> {{0, 33} -> Green, {33, 66} -> Yellow, {66, 100} -> Red}]

ScaleRanges 在仪表面的前方出现：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> All, GaugeFaceStyle -> LightGray]

变化标度范围的宽度：

Wolfram Language code: AngularGauge[17, {0, 100}, ScaleRanges -> {{{0, 33}, .1}, {{33, 66}, .1}, {{66, 100}, .1}}, ScaleRangeStyle -> 24]

改变每个刻度范围的宽度：

Wolfram Language code:

AngularGauge[17, {0, 100}, ScaleRanges -> {{{0, 33}, {0, 0.1}}, {{33, 66}, {0, 0.2}}, {{66, 100}, {0, 0.3}}}, ScaleRangeStyle -> 24]

ScaleRangeStyle (8)

在默认情况下，标度范围的样式基于指针颜色：

Wolfram Language code:

AngularGauge[42, {0, 100}, GaugeStyle -> #, ScaleRanges -> {{50, 70}, {70, 80}, {80, 90}, {90, 100}}]& /@ {Automatic, Orange}

将一个样式应用于各个范围：

Wolfram Language code:

AngularGauge[42, {0, 100}, ScaleRanges -> {{50, 70}, {70, 80}, {80, 90}, {90, 100}}, AxesStyle -> None, ScaleRangeStyle -> EdgeForm[{Darker@Gray}]]

使用一个指令列表分别对每个范围进行样式化：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> {{70, 80}, {80, 90}, {90, 100}}, ScaleRangeStyle -> {Yellow, Orange, Red}]

样式在必要时将循环使用：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> Table[{i, i + 10}, {i, 0, 100, 10}], ScaleRangeStyle -> {Yellow, Orange}]

使用 ScaleRangeStyle->{None,style} 将样式仅应用于标度：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> {80, 100}, ScaleRangeStyle -> {None, Red}]

将样式应用于所有范围的背景和前景：

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> {{0, 20}, {80, 100}}, ScaleRangeStyle -> {{LightBlue, Blue}, {LightRed, Red}}]

利用内置色彩方案为尺度范围着色：

Wolfram Language code:

Table[AngularGauge[42, {0, 100}, ScaleRanges -> {{0, 20}, {20, 50}, {50, 80}, {80, 100}}, ScaleRangeStyle -> f], {f, {"BlueGreenYellow", 24}}]

定义一个一维色彩函数：

Wolfram Language code: CoolColor[ z_ ] := RGBColor[1 - z, z, 1];

Wolfram Language code: AngularGauge[42, {0, 100}, ScaleRanges -> {{0, 20}, {20, 50}, {50, 80}, {80, 100}}, ScaleRangeStyle -> CoolColor]

TargetUnits (2)

在默认情况下，单位自动确定：

Wolfram Language code: AngularGauge[["43 m"], {["0m"], ["50m"]}, GaugeLabels -> "Unit"]

指定所显示的单位：

Wolfram Language code: AngularGauge[["43 m"], {["0m"], ["50m"]}, GaugeLabels -> "Unit", TargetUnits -> "Feet"]

应用 (6)

将仪表用作 Manipulate 的控件：

Wolfram Language code: Manipulate[Plot[Sin[a x], {x, 0, 4Pi}], {{a, 1}, 0, 4, AngularGauge[##, ImageSize -> 125]&}, ControlPlacement -> Left]

可视化连续积分的叶数：

Wolfram Language code: AngularGauge[Dynamic[exp], {0, 300}]

Wolfram Language code: Do[(Pause[.4];exp = LeafCount[Integrate[1 / (x ^ n - 1), x]];), {n, 10}];

监视进程使用的内存，用使用的最大内存作为指标：

Wolfram Language code:

AngularGauge[{MemoryInUse[], MaxMemoryUsed[]} / 10. ^ 9, {0, 4}, GaugeMarkers -> {"DivisionInterval", "Frame"}, GaugeFrameSize -> 0.25, GaugeStyle -> {{Green, None}, Red}]

监视积分微分方程的进度：

Wolfram Language code: AngularGauge[Dynamic[t], {0, 30}, PlotLabel -> "Currently estimating x=", GaugeStyle -> Black]

Wolfram Language code: sol = NDSolve[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, EvaluationMonitor :> (Pause[0.02];(t = x))]

可视化惰性气体的性质：

Wolfram Language code:

Partition[Table[Grid[{{Style[element, "Section"], SpanFromLeft}, {AngularGauge[ElementData[element, "AtomicWeight"], {0, 200}, GaugeLabels -> "AMU", PlotLabel -> "Atomic Weight", ImageSize -> 130], 
	ThermometerGauge[ElementData[element, "CriticalTemperature"], {0, 500}, ImageSize -> {75, 300}, GaugeLabels -> Placed[ Rotate["Critical Temperature (K)", π / 2], {.1, .5}]]}, 
	{AngularGauge[ElementData[element, "CriticalPressure"], {0, 10}, GaugeLabels -> Placed["Mega pascals", {.5, .35}], PlotLabel -> "Critical Pressure", ImageSize -> 130], SpanFromAbove}}, Frame -> True, Alignment -> Bottom], {element, ElementData["NobleGas"][[1 ;; 6]]}], 2]//Grid

实现多项式前两阶导数的可视化：

Wolfram Language code:

Manipulate[With[{f = Function[x, x ^ 3 + 3x ^ 2 - 3x - 1]}, 
	Column[{Row[{AngularGauge[(D[f[x], {x, 1}] /. x -> p), {-20, 20}, GaugeLabels -> {Placed["SuperscriptBox[1, st] Derivative", {.5, .7}], Automatic}], 
	AngularGauge[(D[f[x], {x, 2}] /. x -> p), {-20, 20}, GaugeLabels -> {Placed["SuperscriptBox[2, nd] Derivative", {.5, .7}], Automatic}]}], 
	Plot[f[t], {t, -4, 2}, Epilog -> {PointSize[Large], Red, Point[{p, f[p]}]}, ImageSize -> Medium]}, Center]], {{p, -3.5}, -4, 2}]

Top

	None	无仪表标签
	Automatic	包括作为标签的单位
	Full	包括作为标签的单位和值
	All	包括作为标签的所有值
	"Value"	包括作为标签的值
	"Unit"	包括作为标签的单位
	label	用 label 作为标签
	Placed[label,pos]	将 label 放在位置 pos
	{label₁,label₂,…}	使用多个标签

	Top,Bottom,Left,Right,Center	仪表面以内的位置
	b_s	沿标度的位置
	Scaled[b_s]	沿标度经比例缩放的位置
	{b_x,b_y}	仪表中经比例缩放的位置 {b_x,b_y}
	{pos,{l_x,l_y}}	仪表一般位置 pos 处的标签中经比例缩放的位置 {l_x,l_y}

	r	标度半径
	Left,Right,Bottom,Top	标度的中心在哪边
	{θ_min,θ_max}	标度的 min 和 max 的角位置
	{angle,r}	标度的角度和径向原点

	p	在标度两端的角填充 p
	{p_min,p_max}	在标度之前填充 p_min，之后填充 p_max
	None	标度周围无填充
	Automatic	自动确定填充
	Full	填充至圆的最近的弦
	All	填充标度，成为一个完整的圆

AlignmentPoint	Center	在图形内对齐的缺省点
AspectRatio	Automatic	高与宽的比
Axes	False	是否绘制轴
AxesLabel	None	坐标轴标签
AxesOrigin	Automatic	坐标轴原点
AxesStyle	{}	坐标轴样式指定
Background	None	绘图的背景色
BaselinePosition	Automatic	如何与环绕文本基线对齐
BaseStyle	{}	图形的基本样式指定
ContentSelectable	Automatic	是否允许进行内容选择
CoordinatesToolOptions	Automatic	坐标工具的详细行为
Epilog	{}	主图形之后执行的图形指令
FormatType	TraditionalForm	文本的缺省样式类型
Frame	False	是否在图形周围放置边框
FrameLabel	None	边框标签
FrameStyle	{}	边框的样式指定
FrameTicks	Automatic	边框刻度
FrameTicksStyle	{}	边框刻度的样式指定
GaugeFaceElementFunction	Automatic	绘制仪表面的函数
GaugeFaceStyle	Automatic	仪表面的样式
GaugeFrameElementFunction	Automatic	绘制仪表框的函数
GaugeFrameSize	Automatic	仪表框的大小
GaugeFrameStyle	Automatic	仪表框的样式
GaugeLabels	None	仪表的标签
GaugeMarkers	Automatic	指针的外观
GaugeStyle	Automatic	仪表指针的样式
GridLines	None	绘制的网格线
GridLinesStyle	{}	网格线的样式指定
ImageMargins	0.	图形周围的边幅
ImagePadding	All	为标签等额外填充内容
ImageSize	Automatic	图形的绝对尺寸
LabelStyle	{}	标签的样式指定
Method	Automatic	所用方法
PerformanceGoal	$PerformanceGoal	优化的目标
PlotLabel	None	图形的一个整体标签
PlotRange	All	图形值的范围
PlotRangeClipping	False	是否在图形范围剪切
PlotRangePadding	Automatic	填充图形值范围的程度
PlotRegion	Automatic	填充的最后显示区域
PlotTheme	$PlotTheme	绘制仪表所用的主题
PreserveImageOptions	Automatic	当显示相同图形的新版本时，是否保存图形选项
Prolog	{}	主图形之前执行的图形指令
RotateLabel	True	是否在边框上旋转 y 标签
ScaleDivisions	Automatic	刻度的数量和分布
ScaleOrigin	Automatic	在仪表中放置标度的位置
ScalePadding	Automatic	如何绘制标度周围的空间
ScaleRanges	None	标度各范围的样式
ScaleRangeStyle	Automatic	如何绘制标度范围
ScalingFunctions	None	仪表的尺度函数
TargetUnits	Automatic	仪表中所显示的单位
Ticks	Automatic	坐标轴标记
TicksStyle	{}	坐标轴标记的样式指定

	"Center"	表盘中心
	"DivisionCenter"	以分度为中心的累计标度
	"DivisionInterval"	位于分度之间的累计标度
	"Scale"	标度区域以内
	"OutsideScale"	标度区域以外
	"InsideScale"	标度区域内部
	"ScaleRange"	标度区域以内的累计标度
	"Frame"	表框以内

AngularGauge

更多信息和选项

所有选项的列表

范例

基本范例 (4)

范围 (22)

数据和布局 (7)

样式化与外观 (9)

添加标签 (6)

选项 (87)

AspectRatio (2)

Background (1)

Frame (4)

FrameStyle (2)

GaugeFaceElementFunction (3)

GaugeFaceStyle (3)

GaugeFrameElementFunction (3)

GaugeFrameSize (3)

GaugeFrameStyle (1)

GaugeLabels (10)

GaugeMarkers (8)

GaugeStyle (5)

ImageSize (7)

LabelStyle (1)

PerformanceGoal (2)

PlotTheme (4)

ScaleDivisions (2)

ScaleOrigin (4)

ScalePadding (5)

ScaleRanges (7)

ScaleRangeStyle (8)

TargetUnits (2)

应用 (6)

参见

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX