WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

HighlightImage[image,roi]

image 内の関心領域 roi の指定された部分をハイライトする．

HighlightImage[image,{roi1,roi2,…}]

複数の関心領域 roiiをハイライトする．

HighlightImage[image,{…,w[roii],…}]

記号ラッパー w で定義された特徴を使ってハイライトする．

HighlightImage[image,fg,bgstyle]

スタイル bgstyle をすべての関心領域の補集合に適用する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
領域  
点領域  
曲線領域  
面領域  
ラベル行列  
他のグラフィックス要素  
スタイリング  
領域のスタイリング  
背景のスタイリング  
ラベルと凡例  
ラッパー  
オプション  
DataRange  
GridLines  
ImageLabels  
ImageLegends  
PlotRange  
アプリケーション  
インタラクティブな例題  
関連項目
関連するガイド
履歴
引用書式

HighlightImage

HighlightImage[image,roi]

image 内の関心領域 roi の指定された部分をハイライトする．

HighlightImage[image,{roi1,roi2,…}]

複数の関心領域 roiiをハイライトする．

HighlightImage[image,{…,w[roii],…}]

記号ラッパー w で定義された特徴を使ってハイライトする．

HighlightImage[image,fg,bgstyle]

スタイル bgstyle をすべての関心領域の補集合に適用する．

詳細とオプション

  • HighlightImageを使って画像中の特定の領域あるいは特徴をハイライトすることができる．ハイライトされた領域はGraphicsオブジェクトとして返される．
  • 関心領域 roi は以下のいずれでもよい．
  • {{x1,y1},…}画像の位置のリスト
    region2D幾何学領域（Point，Line，Disk等）
    labelmatrix画像の成分を指定する2Dラベル行列
    maskimageImageオブジェクトの非零の画素
    graphicsGraphicsオブジェクト
    f関数 f によって返された範囲
    <|label1->roi1, …|>ラベルが付けられた範囲の連想
  • ラベル付きの連想<|label1->roi1, …|> 内のラベルはラベルと凡例の作成に使われる．
  • デフォルトで，DataRange->Fullが使われ，位置{xi,yi}および幾何学領域は標準的な画像座標系であると想定される．
  • 次のラッパー w を使うことができる．
  • Annotation[roi,label]注釈を与える
    Button[roi,action]要素がクリックされたときに実行するアクションを定義する
    EventHandler[roi,…]要素の一般的なイベントハンドラを定義する
    Hyperlink[roi,uri]要素をハイパーリンクにする
    ImageMarker[roi,…]画像マーカー，roi のメドイドにマーカーを置く
    Labeled[roii,…]roi のメドイドにマーカーを置く
    Legended[roi,lbl]ラベル lbl を凡例に含める
    PopupWindow[roi,cont]要素にポップアップウィンドウを付ける
    StatusArea[roi,label]要素の上にマウスが来たときにステータスエリアに表示する
    Style[roi,opts]指定のスタイルを使って要素を示す
    Tooltip[roi,label]要素の任意のツールチップを付ける
  • HighlightImage[image,{…,style,roi,…}]を使って領域 roi の style を指定する．
  • 以下は，基本的な style 指定である．
  • Automaticハイライトの方法を自動選択する
    colorc色指定（RGBColor，LABColor等）
    directive有効な任意のグラフィックス指示子（PointSize，Thickness等）
  • デフォルトで，最適なハイライトスタイルが使われる．
  • その他の style 指定
  • "Blur",{"Blur",r}範囲 r の近傍を使ってぼかす
    "Boundary",{"Boundary",t}太さ t を使って境界をハイライトする
  • 関心領域とスタイルのネストしたリストを与えることができる．スタイル指定はそれを含むリストの終りまでしか効果を持たない．
  • 背景は全関心領域の補集合であるとみなされる．次の bgstyle 指定を使うことができる．
  • "Blur",
    {"Blur",r}    		範囲 r の近傍を使ってぼかす
    "Darken",{"Darken",a}黒と混ぜ合せる（デフォルト ）
    "Lighten",{"Lighten",a}白と混ぜ合せる（デフォルト ）
    "Desaturate",{"Desaturate",s}彩度を減じる
    "Remove"背景を透過的にする
    {"Remove",color}背景を color で置換する
    ff を背景で実行する
  • 明示的な bgstyle では，前景の不透明度は0に設定される．Opacity[α]を使ってこれとは異なる前景の不透明度を指定する．
  • HighlightImageには，Graphicsの全オプションに以下の追加・変更を加えたものが使える． [全オプションのリスト]
  • DataRange Fullもとの画像の座標範囲
    ImageLabels Automatic関心領域のラベルの付け方
    ImageLegends None凡例の加え方
    PlotRange Automatic含める画像範囲
    PlotRangePaddingNone値の範囲をどのくらい充填するか
  • 以下は，ImageLabelsおよびImageLegendsの可能な設定である．
  • {lbl1,lbl2,…}roiiに明示的な lbliを使う
    Automatic自動的なラベル付けと凡例作成
    Noneラベルや凡例は使わない
    "Expressions"任意の関数 f を使う
  • DataRangeのよく使われる設定
  • Automatic{{0,1},{0,h/w}}
    Full{{0,w},{0,h}}
    {{left,right},{bottom,top}}2Dの明示的な座標範囲
  • 次は，PlotRangeのよく使われる設定である．
  • Allすべての点を含む
    AutomaticDataRangeの設定と同じ
    {{left,right},{bottom,top}}明示的な座標範囲

    • 全オプションのリスト

例題

すべて開く すべて閉じる

例  (3)

画像のコーナーをハイライトする：

Wolfram Language code: i = [image];
Wolfram Language code: HighlightImage[i, ImageCorners[i, 1, .001, 5]]

画像の残りの部分をハイライトしないことで，関心領域をハイライトする：

Wolfram Language code: i = [image]; HighlightImage[i, FindFaces[i], "Darken"]

関心領域をハイライトする：

Wolfram Language code: HighlightImage[[image], [image]]

スコープ  (23)

領域  (8)

点領域  (1)

点のリストをハイライトする：

Wolfram Language code: img = [image];
Wolfram Language code: region = ImageKeypoints[img, MaxFeatures -> 20]

位置のリストを使う：

Wolfram Language code: HighlightImage[img, region]

明示的なPointラッパーを使う：

Wolfram Language code: HighlightImage[img, Point[region]]

ImageMarkerラッパーを使う：

Wolfram Language code: HighlightImage[img, ImageMarker[region]]

マーカーを指定する：

Wolfram Language code: HighlightImage[img, ImageMarker[region, "Circle"]]

曲線領域  (1)

一次元の領域をハイライトする：

Wolfram Language code: img = [image]; region = ImageLines[EdgeDetect[img], .1, .1]
Wolfram Language code: HighlightImage[img, region]

面領域  (3)

Wolfram Language code: img = [image];

Imageオブジェクトを領域として使う：

Wolfram Language code: HighlightImage[img, [image]]

Graphicsプリミティブを使って何をハイライトするかを説明する：

Wolfram Language code: HighlightImage[img, Disk[{125, 75}, 35]]

Graphicsオブジェクトを領域として使う：

Wolfram Language code: HighlightImage[img, Graphics[Disk[{125, 75}, 35]]]

幾何学領域を使って何をハイライトするかを説明する：

Wolfram Language code: ℛ = ImplicitRegion[(x - 125)^2 + (y - 75)^2 ≤ 35^2, {x, y}];
Wolfram Language code: HighlightImage[img, ℛ]

関心領域は任意の関数で生成したGraphicsオブジェクトでもよい：

Wolfram Language code: img = [image]; region = ImplicitRegion[x ^ 2 + y ^ 3 < 2, {{x, -2, 2}, {y, -2, 2}}]
Wolfram Language code: Region[region]
Wolfram Language code: HighlightImage[img, {Transparent, region}, "Darken", DataRange -> {{-2, 2}, {-2, 2}}]

領域が画像として与えられた場合，それは常に2D領域であると仮定される：

Wolfram Language code: img = [image]; region = Binarize[img]
Wolfram Language code: HighlightImage[img, {RGBColor[0, 0, 1, 1], region}]

境界を除いて検出された画素のみをハイライトする：

Wolfram Language code: HighlightImage[img, {RGBColor[0, 0, 1, 1], EdgeForm[], region}]

結果を厳密な画素ごとの色置換と比較する：

Wolfram Language code: ImageDistance[ Rasterize[Style[%, Antialiasing -> False], ImageResolution -> 72], ReplacePixelValue[img, region -> RGBColor[0, 0, 1]] ]

ラベル行列  (2)

バイナリ画像の連結成分をハイライトする：

Wolfram Language code: HighlightImage[[image], MorphologicalComponents]

流域分割を行なった後の画像の断片をハイライトする：

Wolfram Language code: img = [image];
Wolfram Language code: markers = MaxDetect[GaussianFilter[img, 25], Padding -> 1]; c = WatershedComponents[GradientFilter[img, 3], markers];

すべての成分をハイライトする：

Wolfram Language code: HighlightImage[img, c]

境界成分を削除して残りをハイライトする：

Wolfram Language code: HighlightImage[img, DeleteBorderComponents[c]]

他のグラフィックス要素  (1)

Insetを使う：

Wolfram Language code: i = [image];
Wolfram Language code: HighlightImage[i, {Opacity[1], Inset[Graphics3D[{Red, Cone[]}], {140, 100}]}]

Text要素を使う：

Wolfram Language code: HighlightImage[i, {Opacity[1], Text[Style["Hello", 32], {140, 100}]}]

スタイリング  (15)

領域のスタイリング  (3)

ハイライトする色を指定する：

Wolfram Language code: img = [image]; HighlightImage[img, {Yellow, mask = Binarize[img, .5]}]

一色で領域をハイライトする：

Wolfram Language code: HighlightImage[img, {Opacity[1], Yellow, mask}]

領域の境界をハイライトする：

Wolfram Language code: img = [image];region = FillingTransform@Binarize[img, .1]
Wolfram Language code: HighlightImage[[image], {"Boundary", region}]

Graphics指示子を使って領域をカスタマイズする：

Wolfram Language code: i = [image]; xy = ImageKeypoints[i, MaxFeatures -> 20]; HighlightImage[i, {GrayLevel[.5, .3], EdgeForm[{Green, Opacity[1]}], Disk[#, 10]& /@ xy}]

背景のスタイリング  (6)

背景の明度を減じて画像をハイライトする：

Wolfram Language code: i = [image];r = Rectangle[{100, 10}, {170, 90}]; HighlightImage[i, r, "Darken"]

背景の明度を増して画像をハイライトする：

Wolfram Language code: i = [image];r = Rectangle[{100, 10}, {170, 90}]; HighlightImage[i, r, "Lighten"]

背景をグレースケールに変換して関心領域をハイライトする：

Wolfram Language code: i = [image];r = Rectangle[{100, 10}, {170, 90}]; HighlightImage[i, r, "Desaturate"]

特定の彩度を使う：

Wolfram Language code: HighlightImage[i, r, {"Desaturate", .8}]

背景をぼかして前景をハイライトする：

Wolfram Language code: i = [image];r = Rectangle[{100, 10}, {170, 90}]; HighlightImage[i, r, "Blur"]

カスタム関数を使って背景をハイライトする：

Wolfram Language code: i = [image];r = Rectangle[{100, 10}, {170, 90}]; HighlightImage[i, r, # / 2&]

背景を削除する：

Wolfram Language code: i = [image];r = Rectangle[{100, 10}, {170, 90}]; HighlightImage[i, r, "Remove"]

削除した背景を特定の色で置換する：

Wolfram Language code: HighlightImage[i, r, {"Remove", GrayLevel[.3]}]

ラベルと凡例  (5)

画像の顔にラベルを付ける：

Wolfram Language code: i = [image];
Wolfram Language code: HighlightImage[i, {Labeled[Rectangle[{82, 124}, {127, 191}], "mom"], Labeled[Rectangle[{172, 104}, {214, 154}], "baby"]}]

顔を検出し，推定年齢でラベルを付ける：

Wolfram Language code: i = [image];
Wolfram Language code: HighlightImage[i, MapThread[Labeled, {FindFaces[i], FacialFeatures[i, "Age"]}]]

各点のデータ集合のラベルを指定する：

Wolfram Language code: i = [image];
Wolfram Language code: HighlightImage[i, { Green, Labeled[ImageCorners[i, 1, .001, 5], "corners"], Red, Labeled[ImageKeypoints[i, MaxFeatures -> 50], "keypoints", Top] }]

指定されたラベルを使って凡例を作成する：

Wolfram Language code: i = [image]; HighlightImage[i, { Green, Legended[ImageCorners[i, 1, .001, 5], "corners"], Red, Legended[ImageKeypoints[i, MaxFeatures -> 50], "keypoints"]}]

2つの画像の断片をハイライトしてラベルを付ける：

Wolfram Language code: HighlightImage[[image], Thread@Labeled[{[image], [image]}, {"seg 1", "seg 2"}]]

ラッパー  (1)

関心点にツールチップを加える：

Wolfram Language code: i = [image];

キーポイントの位置と強さを計算する：

Wolfram Language code: (data = ImageKeypoints[i, {"Position", "Strength"}])//Short
Wolfram Language code: HighlightImage[i, MapThread[Tooltip, Transpose[data]]]

オプション  (7)

DataRange  (1)

デフォルトのデータ範囲は画像の次元によって決定される：

Wolfram Language code: img = RandomImage[1, {5, 3}]; center = {.5, .5}; region = {Blue, EdgeForm[], Disk[center, .5], Red, Point[center]};
Wolfram Language code: HighlightImage[img, region, ImageSize -> Small, Frame -> True]

以下はDataRange->Fullに等しい：

Wolfram Language code: HighlightImage[img, {EdgeForm[], region}, ImageSize -> Small, Frame -> True, DataRange -> Full]

軸上の正規化された範囲にDataRange->Automaticを使う：

Wolfram Language code: HighlightImage[img, {EdgeForm[], region}, ImageSize -> Small, Frame -> True, DataRange -> Automatic]

カスタム範囲を使う：

Wolfram Language code: HighlightImage[img, {EdgeForm[], region}, ImageSize -> Small, Frame -> True, DataRange -> {{0, 1}, {0, 1}}]

GridLines  (1)

デフォルトで，格子線は示されない：

Wolfram Language code: img = [image];points = ImageCorners[img, 1, .001, 5];
Wolfram Language code: HighlightImage[img, points]

格子線を示す：

Wolfram Language code: HighlightImage[img, ImageCorners[img, 1, .001, 5], GridLines -> Automatic, GridLinesStyle -> Orange]

示す格子線を指定する：

Wolfram Language code: HighlightImage[img, ImageCorners[img, 1, .001, 5], GridLines -> {Range[0, 250, 20], Range[0, 200, 20]}, GridLinesStyle -> Orange]

ImageLabels  (2)

デフォルトでは，ハイライトされた領域にはラベルは付けられない：

Wolfram Language code: i = [image];
Wolfram Language code: HighlightImage[i, {Rectangle[{6., 81.}, {103., 128.}], Rectangle[{206., 92.}, {348., 151.}]}]

ImageLabels{"lbl1","lbl2",…}を使って各領域のラベルを定義する：

Wolfram Language code: HighlightImage[i, {Rectangle[{6, 70}, {100, 130}], Rectangle[{200, 90}, {360, 150}]}, ImageLabels -> {"Little Ararat", "Greater Ararat"}]

連想キーが自動的にラベルとして使われる：

Wolfram Language code: i = [image]; boxes = ImageBoundingBoxes[i]
Wolfram Language code: HighlightImage[i, boxes]

ImageLabelsNoneを使って自動的なラベル付けを無効にする：

Wolfram Language code: HighlightImage[i, boxes, ImageLabels -> None]

ImageLegends  (2)

ImageLegends{"lbl1","lbl2",…}を使って各領域のラベルを定義する：

Wolfram Language code: i = [image];
Wolfram Language code: HighlightImage[i, {Rectangle[{6, 70}, {100, 130}], Rectangle[{200, 90}, {360, 150}]}, ImageLegends -> {"Little Ararat", "Greater Ararat"}]

凡例は，まず領域の深さをスキャンすることでマッチされる：

Wolfram Language code: HighlightImage[i, {{Rectangle[{6, 70}, {100, 130}], Rectangle[{200, 90}, {360, 150}]}, Rectangle[{257., 53.}, {354., 98.}]}, ImageLegends -> {"Little Ararat", "Greater Ararat", "Monastery"}]

連想キーが自動的にラベルとして使われる：

Wolfram Language code: i = [image]; boxes = ImageBoundingBoxes[i]
Wolfram Language code: HighlightImage[i, boxes]

ImageLegendsAutomaticを使って自動凡例付けを有効にする：

Wolfram Language code: HighlightImage[i, boxes, ImageLegends -> All]

ImageLabelsNoneを使ってラベル付けを無効にする：

Wolfram Language code: HighlightImage[i, boxes, ImageLegends -> All, ImageLabels -> None]

PlotRange  (1)

デフォルトのプロット範囲は画像の次元で決定される：

Wolfram Language code: img = [image];
Wolfram Language code: HighlightImage[img, {Disk[{250, 120}, 10], Rectangle[{-20, -20}, {20, 20}]}]
Wolfram Language code: Options[%, PlotRange]
Wolfram Language code: ImageDimensions[img]

PlotRange->Allを使って全領域を見る：

Wolfram Language code: HighlightImage[img, {Disk[{250, 120}, 10], Rectangle[{-20, -20}, {20, 20}]}, PlotRange -> All]

カスタム範囲を使う：

Wolfram Language code: HighlightImage[img, {Disk[{250, 120}, 10], Rectangle[{-20, -20}, {20, 20}]}, PlotRange -> {{-20, 150}, {-20, 150}}]

アプリケーション  (5)

画像中の顔をぼかす：

Wolfram Language code: img = [image]; faces = FindFaces[img]; HighlightImage[img, {"Blur", faces}]

ニューラルネットワークを使って画像にセマンティックセグメンテーションを施し，可視化する：

Wolfram Language code: net = NetModel["Dilated ResNet-22 Trained on Cityscapes Data"];
Wolfram Language code: labels = {"road", "sidewalk", "building", "wall", "fence", "pole", "traffic light", "traffic sign", "vegetation", "terrain", "sky", "person", "rider", "car", "truck", "bus", "train", "motorcycle", "bicycle"};

任意の画像次元に使うことができる評価器関数を定義する：

Wolfram Language code: netevaluate[img_] := NetReplacePart[net, {{"input_0", "ImageSize"} -> ImageDimensions[img]}][img]

画像を分割する：

Wolfram Language code: mask = netevaluate[scene = [image]];

ラベルが付いた断片をハイライトする：

Wolfram Language code: HighlightImage[scene, {Opacity[.5], Labeled[mask, labels]}, ImageSize -> Medium]

断片をハイライトし，凡例を使ってラベルを表示する：

Wolfram Language code: HighlightImage[scene, {Opacity[.5], Legended[mask, labels]}, ImageSize -> Medium]

強いコーナーと弱いコーナーをスタイルを変えてハイライトする：

Wolfram Language code: img = [image]; strong = ImageCorners[img, 1, .005, 10]; weak = Complement[ImageCorners[img, 1, .0005], strong]; HighlightImage[img, {AbsolutePointSize[3], Red, Legended[weak, "weak"], Green, AbsolutePointSize[10], Legended[strong, "strong"]}]

画像を分割し，円板の中心をマーカーでハイライトする：

Wolfram Language code: img = [image]; disks = Pruning[FillingTransform@DeleteSmallComponents@Binarize[img, {0, .83}]]
Wolfram Language code: HighlightImage[[image], ImageMarker[disks]]

複数の関心領域をハイライトする：

Wolfram Language code: i = [image];
Wolfram Language code: HighlightImage[i, {Blue, EdgeDetect[i], Red, ImageLines[GradientFilter[i, 2], MaxFeatures -> 10], Green, ImageKeypoints[i, MaxFeatures -> 20]}]

インタラクティブな例題  (1)

風景にインタラクティブなスポットライトを適用する：

Wolfram Language code: DynamicModule[ {img = [image], dims, pt}, dims = ImageDimensions[img]; pt = dims / 2; LocatorPane[ Dynamic[pt], Dynamic[ HighlightImage[ img, {Transparent, Disk[pt, GeometricMean[dims] / 6]}, "Darken"] ], Appearance -> None ] ]
Wolfram Research (2012), HighlightImage, Wolfram言語関数， https://reference.wolfram.com/language/ref/HighlightImage.html （2021年に更新）.

テキスト

Wolfram Research (2012), HighlightImage, Wolfram言語関数， https://reference.wolfram.com/language/ref/HighlightImage.html （2021年に更新）.

CMS

Wolfram Language. 2012. "HighlightImage." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/HighlightImage.html.

APA

Wolfram Language. (2012). HighlightImage. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HighlightImage.html

BibTeX

@misc{reference.wolfram_2026_highlightimage, author="Wolfram Research", title="{HighlightImage}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/HighlightImage.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_highlightimage, organization={Wolfram Research}, title={HighlightImage}, year={2021}, url={https://reference.wolfram.com/language/ref/HighlightImage.html}, note=[Accessed: 03-November-2026]}