WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ListStreamPlot3D[varr]

ベクトルの配列として与えられたベクトル場についての流線をプロットする．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
サンプリング  
プレゼンテーション  
オプション  
Axes  
AxesLabel  
AxesOrigin  
Show More Show More
AxesStyle  
BoxRatios  
DataRange  
ImageSize  
PlotLegends  
PlotTheme  
RegionBoundaryStyle  
RegionFunction  
ScalingFunctions  
StreamColorFunction  
StreamColorFunctionScaling  
StreamMarkers  
StreamPoints  
StreamScale  
StreamStyle  
Ticks  
TicksStyle  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ListStreamPlot3D

ListStreamPlot3D[varr]

ベクトルの配列として与えられたベクトル場についての流線をプロットする．

詳細とオプション

例題

すべて開く すべて閉じる

例  (4)

指定されたベクトル集合から補間されたベクトル場をプロットする：

Wolfram Language code: ListStreamPlot3D[Table[{z, -x, y}, {x, -1, 1, .1}, {y, -1, 1, .1}, {z, -1, 1, .1}]]

場の強度を示す凡例を含める：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {x, -1, 1, .1}, {y, -1, 1, .1}, {z, -1, 1, .1}], PlotLegends -> Automatic]

流線を表すのに管を使う：

Wolfram Language code: ListStreamPlot3D[Table[{x, y + z, z}, {x, -1, 1, .1}, {y, -1, 1, .1}, {z, -1, 1, .1}], StreamMarkers -> "Tube"]

データ範囲を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, .1}, {y, -1, 1, .1}, {z, -1, 1, .1}], DataRange -> {{-1, 1}, {-1, 1}, {-1, 1}}]

スコープ  (12)

サンプリング  (3)

流線のためにシード点の密度を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{2 , -Sin[π x], -x}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamPoints -> Coarse]

流線のために特定のシード点を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{2 , -Sin[π x], -x}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamPoints -> RandomReal[{1, 20}, {30, 3}]]

指定領域上に流線をプロットする：

Wolfram Language code: ListStreamPlot3D[Table[{2 , -Sin[π x], -x}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], RegionFunction -> Function[{x, y, z}, y ≥ x]]

プレゼンテーション  (9)

デフォルトで，流線は線として描画される：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]

3Dの管を使って流線を描画する：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Tube"]

平らなリボンを使う：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Ribbon"]

流線マーカーの「矢印」バージョンを使って流線に沿った流れの方向を示す：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow"]

管の上の矢印：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow3D"]

リボンは，流線の頭を先細りにし，尾を切り欠くことによって矢印に変えられる：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "ArrowRibbon"]

流線に単一の色を使う：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamColorFunction -> None, StreamStyle -> RGBColor[0.09, 0.76, 0.65], StreamMarkers -> "Tube"]

流線に名前付きの色勾配を使う：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamColorFunction -> "Rainbow"]

場の大きさについての凡例を含める：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], PlotLegends -> Automatic]

StreamScaleを使って流線をより短い複数の線分に分割する：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamScale -> 0.1]
Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamScale -> 0.2]

各線分の点の数を増やし，マーカーの縦横比も増す：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow", StreamScale -> {Full, 20, 0.2}]

テーマを使う：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], PlotTheme -> "Marketing"]

z 方向に対数スケールを使う：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ScalingFunctions -> {None, None, "Log"}]

オプション  (75)

Axes  (3)

デフォルトで，Axesが描かれる：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]

AxesFalseとして軸が描かれないようにする：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], Axes -> False]

各軸を別々に描画する：

Wolfram Language code: {ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], Axes -> {True, False, False}], ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], Axes -> {False, True, False}], ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], Axes -> {False, False, True}]}

AxesLabel  (4)

デフォルトで，軸ラベルは描かれない：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]

軸上にラベルを置く：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AxesLabel -> z]

軸ラベルを指定する：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AxesLabel -> {x, y, z}]

単位をラベルとして使う：

Wolfram Language code: ListStreamPlot3D[QuantityArray[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], "Meters"], AxesLabel -> Automatic]

AxesOrigin  (2)

軸の位置は自動的に決定される：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]

軸の原点を明示的に指定する：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AxesOrigin -> {1, 10, 10}]

AxesStyle  (4)

軸のスタイルを変える：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AxesStyle -> StandardRed]

各軸のスタイルを指定する：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AxesStyle -> {{Thick, StandardBrown}, {Thick, StandardBlue}, {Thick, StandardGreen}}]

U目盛と軸に異なるスタイルを使う：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AxesStyle -> StandardGreen, TicksStyle -> StandardGray]

ラベルと軸に異なるスタイルを使う：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AxesStyle -> StandardGreen, LabelStyle -> StandardGray]

BoxRatios  (2)

デフォルトで，BoxRatiosはAutomaticに設定されている：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]

ボックスの x 方向の長さを2倍にする：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], BoxRatios -> {2, 1, 1}]

DataRange  (2)

デフォルトで，データ範囲はデータ配列の指標範囲であるとみなされる：

Wolfram Language code: ListStreamPlot3D[Table[{x - y, y - z, z - x}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]

領域についてデータ範囲を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{x - y, y - z, z - x}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], DataRange -> {{-2, 2}, {-1, 1}, {-1, 1}}]

ImageSize  (7)

Tiny，Small，Medium，Largeのような名前付きのサイズを使う：

Wolfram Language code: {ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ImageSize -> Tiny], ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ImageSize -> Small]}

プロットの幅を指定する：

Wolfram Language code: {ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ImageSize -> 150], ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AspectRatio -> 1.5, ImageSize -> 150]}

プロットの高さを指定する：

Wolfram Language code: {ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ImageSize -> {Automatic, 150}], ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

特定のサイズまでの幅と高さを許容する：

Wolfram Language code: {ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ImageSize -> UpTo[200]], ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AspectRatio -> 2, ImageSize -> UpTo[200]]}

グラフィックスの幅と高さを指定して，必要な場合はスペースで充填する：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ImageSize -> {200, 300}, Background -> StandardBlue]

AspectRatioFullと設定すると，使用可能なスペースが塗り潰される：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AspectRatio -> Full, ImageSize -> {200, 300}, Background -> StandardBlue]

幅と高さに最大サイズを使う：

Wolfram Language code: {ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ImageSize -> {UpTo[150], UpTo[100]}], ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

ImageSizeFullを使ってオブジェクト内の使用可能なスペースを塗り潰す：

Wolfram Language code: Framed[Pane[ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ImageSize -> Full, Background -> StandardBlue], {200, 100}]]

画像サイズを使用可能なスペースとの割合で指定する：

Wolfram Language code: Framed[Pane[ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -2, 2, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> StandardBlue], {200, 200}]]

PlotLegends  (3)

デフォルトで，凡例は含まれない：

Wolfram Language code: ListStreamPlot3D[Table[{1 - x, y - x, z - y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]

ベクトル場のノルムを示す凡例を含める：

Wolfram Language code: ListStreamPlot3D[Table[{1 - x, y - x, z - y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], PlotLegends -> Automatic]

凡例の場所を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{1 - x, y - x, z - y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], PlotLegends -> Placed[Automatic, Left]]

PlotTheme  (1)

テーマを指定する：

Wolfram Language code: ListStreamPlot3D[Table[{x, 2y, 3z}, {x, -3, 3, 0.5}, {y, -3, 3, 0.5}, {z, -3, 3, 0.5}], PlotTheme -> "Marketing"]

RegionBoundaryStyle  (4)

RegionFunctionで定義された範囲を表示する：

Wolfram Language code: ListStreamPlot3D[Table[{1, -z, y}, {x, -2, 2, 0.5}, {y, -2, 2, 0.5}, {z, -2, 2, 0.5}], RegionFunction -> Function[{x, y, z, vx, vy, vz, n}, n < 2]]

Noneを使って境界を表示しないようにする：

Wolfram Language code: ListStreamPlot3D[Table[{1, -z, y}, {x, -2, 2, 0.5}, {y, -2, 2, 0.5}, {z, -2, 2, 0.5}], RegionFunction -> Function[{x, y, z, vx, vy, vz, n}, n < 2], RegionBoundaryStyle -> None]

領域の境界の色を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{1, -z, y}, {x, -2, 2, 0.5}, {y, -2, 2, 0.5}, {z, -2, 2, 0.5}], RegionFunction -> Function[{x, y, z, vx, vy, vz, n}, n < 2], RegionBoundaryStyle -> Yellow]

完全な長方形領域の境界は表示されない：

Wolfram Language code: ListStreamPlot3D[Table[{1, -z, y}, {x, -2, 2, 0.5}, {y, -2, 2, 0.5}, {z, -2, 2, 0.5}]]

RegionFunction  (4)

限定された領域内で流線をプロットする：

Wolfram Language code: ListStreamPlot3D[Table[{y, -x, 3}, {x, -5, 5}, {y, -5, 5}, {z, -5, 5}], RegionFunction -> Function[{x, y, z, vx, vy, vz, n}, vx vy ≥ 0]]

場の大きさが与えられた閾値を超えるところにのみ流れをプロットする：

Wolfram Language code: ListStreamPlot3D[Table[{y, -x, 3}, {x, -5, 5}, {y, -5, 5}, {z, -5, 5}], RegionFunction -> Function[{x, y, z, vx, vy, vz, n}, n ≥ 5]]

領域関数は，一般に，7つの引数に依存する：

Wolfram Language code: ListStreamPlot3D[Table[{y, -x, 3}, {x, -5, 5}, {y, -5, 5}, {z, -5, 5}], RegionFunction -> Function[{x, y, z, vx, vy, vz, n}, 3n ≥ x + y]]

RegionBoundaryStyleNoneを使って境界を表示しないようにする：

Wolfram Language code: ListStreamPlot3D[Table[{y, -x, 3}, {x, -5, 5}, {y, -5, 5}, {z, -5, 5}], RegionFunction -> Function[{x, y, z, vx, vy, vz, n}, n ≥ 5], RegionBoundaryStyle -> None]

ScalingFunctions  (3)

デフォルトでは線形スケールが使われる：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]

z 方向に対数スケールを使う：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ScalingFunctions -> {None, None, "Log"}]

z 方向の向きを逆にする：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1 + 2y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], ScalingFunctions -> {None, None, "Reverse"}]

StreamColorFunction  (4)

流れにそのノルムで彩色する：

Wolfram Language code: ListStreamPlot3D[Table[{3x, 2y, z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamColorFunction -> Hue]

ColorDataからの任意の名前付き色勾配を使う：

Wolfram Language code: ListStreamPlot3D[Table[{3x, 2y, z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamColorFunction -> "Rainbow"]

流線にその x 値に従って彩色する：

Wolfram Language code: ListStreamPlot3D[Table[{3x, 2y, z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamColorFunction -> Function[{x, y, z, vx, vy, vz, n}, Hue[x]]]

StreamColorFunctionScalingFalseを使ってスケールされていない値を得る：

Wolfram Language code: ListStreamPlot3D[Table[{3x, 2y, z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamColorFunction -> "Rainbow", StreamColorFunctionScaling -> False]

StreamColorFunctionScaling  (2)

デフォルトで，スケールされた値が使われる：

Wolfram Language code: ListStreamPlot3D[Table[{y, -x, E^z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamColorFunction -> "Pastel", PlotLegends -> Automatic]

StreamColorFunctionScalingFalseを使ってスケールされていない値を得る：

Wolfram Language code: ListStreamPlot3D[Table[{y, -x, E^z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamColorFunction -> "Pastel", PlotLegends -> Automatic, StreamColorFunctionScaling -> False]

StreamMarkers  (5)

デフォルトで，線が使われる：

Wolfram Language code: ListStreamPlot3D[Table[{E^x, E^y, -3}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]

流線を管として描画する：

Wolfram Language code: ListStreamPlot3D[Table[{E^x, E^y, -3}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Tube"]

流線を平たいリボンとして描画する：

Wolfram Language code: ListStreamPlot3D[Table[{E^x, E^y, -3}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Ribbon"]

"Arrow"流れマーカーは，流線を自動的により短い線分に分割する：

Wolfram Language code: ListStreamPlot3D[Table[{E^x, E^y, -3}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow"]

3Dの鏃を管に使う：

Wolfram Language code: ListStreamPlot3D[Table[{E^x, E^y, -3}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow3D"]

向きがあるリボンを使う：

Wolfram Language code: ListStreamPlot3D[Table[{E^x, E^y, -3}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "ArrowRibbon"]

線分に分割されたマーカーを連続的にする：

Wolfram Language code: ListStreamPlot3D[Table[{E^x, E^y, -3}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow3D", StreamScale -> Full]

連続するマーカーを線分に分割する：

Wolfram Language code: ListStreamPlot3D[Table[{E^x, E^y, -3}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Ribbon", StreamScale -> 0.1]

StreamPoints  (4)

自動的に決定された流れの点を使って曲線にシードする：

Wolfram Language code: ListStreamPlot3D[Table[{1, -E^-y, E^z}, {x, -2, 2, 0.1}, {y, -2, 2, 0.1}, {z, -2, 2, 0.1}]]

流線の最大数を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{1, -E^-y, E^z}, {x, -2, 2, 0.1}, {y, -2, 2, 0.1}, {z, -2, 2, 0.1}], StreamPoints -> 40]

流れに特定のシード点を与える：

Wolfram Language code: ListStreamPlot3D[Table[{1, -E^-y, E^z}, {x, -2, 2, 0.1}, {y, -2, 2, 0.1}, {z, -2, 2, 0.1}], StreamPoints -> RandomReal[{1, 40}, {20, 3}]]

間隔が疎らな流線を使う：

Wolfram Language code: ListStreamPlot3D[Table[{1, -E^-y, E^z}, {x, -2, 2, 0.1}, {y, -2, 2, 0.1}, {z, -2, 2, 0.1}], StreamPoints -> Coarse]

より狭い間隔の流線を使う：

Wolfram Language code: ListStreamPlot3D[Table[{1, -E^-y, E^z}, {x, -2, 2, 0.1}, {y, -2, 2, 0.1}, {z, -2, 2, 0.1}], StreamPoints -> Fine]

StreamScale  (9)

分割されたマーカーにはデフォルトの長さ，点の数，縦横比がある：

Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow"]

線分の長さを変える：

Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow", StreamScale -> 0.2]

各線分のサンプル点の数を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow", StreamScale -> {0.2, 2}]

流れマーカーの縦横比を変える：

Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow", StreamScale -> {0.2, 2, 0.2}]

分割されたマーカーを連続的にする：

Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow", StreamScale -> Full]

連続的なマーカーを線分に分割する：

Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Ribbon", StreamScale -> 0.2]

縦横比はリボンや管の太さを制御する：

Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "ArrowRibbon", StreamScale -> {Automatic, Automatic, 0.05}]
Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Ribbon", StreamScale -> {Automatic, Automatic, 0.05}]
Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Tube", StreamScale -> {Automatic, Automatic, 0.05}]

縦横比は鏃の大きさを制御する：

Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow", StreamScale -> {Automatic, Automatic, 0.2}]

各線分に3点使う：

Wolfram Language code: ListStreamPlot3D[Table[{y^2, -x^2, 2 - z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow", StreamScale -> {0.5, 3}]

StreamStyle  (3)

流線の外観を変える：

Wolfram Language code: ListStreamPlot3D[Table[{-y^2, x^2, 0.5}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamStyle -> Thickness[0.02]]

StreamColorFunctionはStreamStyleより優先順位が高い：

Wolfram Language code: ListStreamPlot3D[Table[{-y^2, x^2, 0.5}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamStyle -> Directive[Red, Dashing[{0.1, 0.02}]]]

StreamColorFunctionNoneを使ってStreamStyleで流線の色を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{-y^2, x^2, 0.5}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamStyle -> Directive[StandardRed, Dashing[{0.1, 0.02}]], StreamColorFunction -> None]

Ticks  (6)

目盛は各プロットに自動的に置かれる：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {z, -2, 2, 0.1}, {y, -2, 2, 0.1}, {x, -2, 2, 0.1}]]

TicksNoneを使って目盛を描かないようにする：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {z, -2, 2, 0.1}, {y, -2, 2, 0.1}, {x, -2, 2, 0.1}], Ticks -> None]

特定の位置に目盛を置く：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {z, -2, 2, 0.1}, {y, -2, 2, 0.1}, {x, -2, 2, 0.1}], Ticks -> {{5, 15, 25}, {5, 15, 25}, {5, 15, 25}}]

指定の位置に指定のラベルを付けて目盛を描く：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {z, -2, 2, 0.1}, {y, -2, 2, 0.1}, {x, -2, 2, 0.1}], Ticks -> {{{5, a}, {15, b}, {25, c}}, {{5, a}, {15, b}, {25, c}}, {{5, a}, {15, b}, {25, c}}}]

スケールされた長さの目盛を指定する：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {z, -2, 2, 0.1}, {y, -2, 2, 0.1}, {x, -2, 2, 0.1}], Ticks -> {{{5, a, .1}, {15, b, .1}, {25, c, .1}}, {{5, a, .05}, {15, b, .05}, {25, c, .05}}, {{5, a, .15}, {15, b, .15}, {25, c, .15}}}]

位置，長さ，ラベル，スタイルで各目盛をカスタマイズする：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {z, -2, 2, 0.1}, {y, -2, 2, 0.1}, {x, -2, 2, 0.1}], Ticks -> {{{5, a, .1, Directive[Red]}, {15, b, .1, Directive[Red, Thick]}, {25, c, .1, Directive[Red, Dashed, Thick]}}, {{5, a, .1, Directive[Blue]}, {15, b, .1, Directive[Blue, Thick]}, {25, c, .1, Directive[Blue, Dashed, Thick]}}, {{5, a, .1, Directive[Darker@Green]}, {15, b, .1, Directive[Darker@Green, Thick]}, {25, c, .1, Directive[Darker@Green, Dashed, Thick]}}}]

TicksStyle  (3)

デフォルトで，目盛と目盛ラベルには軸と同じスタイルが使われる：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {z, -2, 2, 0.1}, {y, -2, 2, 0.1}, {x, -2, 2, 0.1}], AxesStyle -> Directive[Thick, StandardRed]]

目盛の全体的なスタイルを目盛ラベルも含めて指定する：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {z, -2, 2, 0.1}, {y, -2, 2, 0.1}, {x, -2, 2, 0.1}], TicksStyle -> Directive[Bold, StandardRed]]

各軸の目盛スタイルを指定する：

Wolfram Language code: ListStreamPlot3D[Table[{x + y, y - z, x}, {z, -2, 2, 0.1}, {y, -2, 2, 0.1}, {x, -2, 2, 0.1}], TicksStyle -> {Directive[StandardGray, Bold], Directive[Bold, StandardRed], Directive[Bold, StandardBlue]}]

アプリケーション  (2)

等しい一定の電荷密度と反対の符号を持つ有限長の2本の細いワイヤーの影響下にある点のサンプリングで電場を数値的に計算する：

Wolfram Language code: data = Quiet@Table[If[Abs[x] == 1 && z == 0 && -2 ≤ y ≤ 2, {0, 0, 0}, NIntegrate[({x + 1, y - Y, z}/Norm[{x + 1, y - Y, z}]^3) - ({x - 1, y - Y, z}/Norm[{x - 1, y - Y, z}]^3), {Y, -2, 2}]], {x, -5, 5}, {y, -5, 5}, {z, -5, 5}];

正の電荷（黒）と負の電荷（赤）のワイヤーと一緒に電場を可視化する：

Wolfram Language code: Show[ListStreamPlot3D[data, StreamMarkers -> "Arrow", DataRange -> {{-5, 5}, {-5, 5}, {-5, 5}}, StreamColorFunction -> None, StreamStyle -> StandardBlue], Graphics3D[{Thickness[0.01], Line[{{-1, -2, 0}, {-1, 2, 0}}], StandardRed, Line[{{1, -2, 0}, {1, 2, 0}}]}]]

単位立方体内の時間依存の熱流を可視化する．単位立方体の温度が のときの定常状態熱方程式 について考える．ただし，以下に示すように，面で ，，，，の各面は断熱，面の半径0.3の円板を中心とする内部は ．円板の外は とする：

Wolfram Language code: cube = [image];

有限差分を使って熱方程式 を離散化する：

Wolfram Language code: n = 20; (* number of steps *) Δ = (1.0/n + 1); (* step size *) vars = Flatten[Table[u[i, j, k], {i, 1, n}, {j, 0, n + 1}, {k, 0, n + 1}]]; eqns = Flatten[Table[ u[i + 1, j, k] - 2u[i, j, k] + u[i - 1, j, k] + (* x direction *) u[i, j + 1, k] - 2u[i, j, k] + u[i, j - 1, k] + (* y direction *) u[i, j, k + 1] - 2u[i, j, k] + u[i, j, k - 1](* z direction *) == 0, {i, 1, n}, {j, 0, n + 1}, {k, 0, n + 1}]];

と の各面上の についての境界条件を指定する：

Wolfram Language code: u[0, _, _] := 1.0; u[n + 1, j_, k_] := If[(j Δ - 0.5)^2 + (k Δ - 0.5)^2 ≤ 0.3^2, 2, 0];

他の面の の断熱境界条件を指定する：

Wolfram Language code: u[i_, -1, k_] := u[i, 1, k];(* y=0 *) u[i_, n + 2, k_] := u[i, n, k]; (* y=1 *) u[i_, j_, -1] := u[i, j, 1]; (* z=0 *) u[i_, j_, n + 2] := u[i, j, n];(* z=1 *)

方程式系を解く：

Wolfram Language code: sol = Solve[eqns, vars][[1]]; temperatures = Table[u[i, j, k], {k, 0, n + 1}, {j, 0, n + 1}, {i, 0, n + 1}] /. sol;

有限差分を使って熱流束を近似する：

Wolfram Language code: heatflux = Table[-{(u[i + 1, j, k] - u[i - 1, j, k]/2Δ), (u[i, j + 1, k] - u[i, j - 1, k]/2Δ), (u[i, j, k + 1] - u[i, j, k - 1]/2Δ)} /. sol, {i, 1, n}, {j, 1, n}, {k, 1, n}];

面の流線についてシード点を生成する：

Wolfram Language code: sp1 = Flatten[Table[{0, y, z}, {y, 0.1, 0.9, 0.2}, {z, 0.1, 0.9, 0.2}], 1];

面の赤い円板内の流線についてシード点を生成する：

Wolfram Language code: sp2 = Flatten[Table[{1, 0.5 + r Cos[t], 0.5 + r Sin[t]}, {r, 0, 0.2, 0.1}, {t, 0, 2π - (π/5), (π/5)}], 1];

熱流を可視化する．境界温度は凡例で指定されており，立方体の空白の面は断熱されている：

Wolfram Language code: Show[ListStreamPlot3D[heatflux, DataRange -> {{0, 1}, {0, 1}, {0, 1}}, StreamPoints -> Join[sp1, sp2], StreamMarkers -> "Arrow3D", StreamScale -> Full, StreamColorFunction -> None, StreamStyle -> RGBColor[0.8675693999999999, 0.4915453999999999, 0.21120899999999998]], cube, Lighting -> "Neutral"]

特性と関係  (10)

StreamPlot3DとVectorPlot3Dを使って関数を可視化する：

Wolfram Language code: {StreamPlot3D[{z, -x, y}, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}], VectorPlot3D[{z, -x, y}, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}]}

StreamPlotおよびVectorPlotを使って関数を2Dで可視化する：

Wolfram Language code: {StreamPlot[{y - x, y}, {x, -3, 3}, {y, -3, 3}], VectorPlot[{y - x, y}, {x, -3, 3}, {y, -3, 3}]}

ListSliceVectorPlot3Dで曲面に沿ってベクトルをプロットする：

Wolfram Language code: data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2, z}, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}];
Wolfram Language code: ListSliceVectorPlot3D[data]

ListVectorPlot3Dを使って3Dの場を離散ベクトルとしてプロットする：

Wolfram Language code: data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2, z}, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}];
Wolfram Language code: ListVectorPlot3D[data]

2DベクトルのプロットにListVectorPlotに使う：

Wolfram Language code: data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}];
Wolfram Language code: ListVectorPlot[data]

ListStreamPlotを使ってベクトルではなく流線をプロットする：

Wolfram Language code: data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}];
Wolfram Language code: ListStreamPlot[data]

ListVectorDensityPlotまたはListStreamDensityPlotを使ってスカラー場の密度プロットを加える：

Wolfram Language code: data = Table[{{-1 - x ^ 2 + y, 1 + x - y ^ 2}, Abs[x] + Abs[y]}, {x, -3, 3}, {y, -3, 3}];
Wolfram Language code: {ListVectorDensityPlot[data], ListStreamDensityPlot[data]}

ListVectorDisplacementPlotを使って変位ベクトル場に関連付けられた領域の変形を可視化する：

Wolfram Language code: data2D = Table[{{x, y} = RandomReal[{-1, 1}, {2}], {y, x - x^3}}, {300}];
Wolfram Language code: data3D = Table[{{x, y, z} = RandomReal[{0, 1}, {3}], {y, x, -z}}, {300}];
Wolfram Language code: ListVectorDisplacementPlot[data2D, Disk[], VectorPoints -> Automatic]

ListVectorDisplacementPlot3Dを使って変形を3Dで可視化する：

Wolfram Language code: ListVectorDisplacementPlot3D[data3D, Cuboid[], VectorPoints -> "Boundary"]

ListLineIntegralConvolutionPlotを使ってベクトル場の線積分たたみ込みをプロットする：

Wolfram Language code: data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}];
Wolfram Language code: ListLineIntegralConvolutionPlot[data]

GeoVectorPlotを使って地図上にベクトルをプロットする：

Wolfram Language code: GeoVectorPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567}, {-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851}, {7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864}, { ... 904, "AngularDegrees"]}, {0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]}, {0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]}, {0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]

GeoStreamPlotを使ってベクトルの代りに流線をプロットする：

Wolfram Language code: GeoStreamPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567}, {-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851}, {7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864}, { ... 904, "AngularDegrees"]}, {0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]}, {0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]}, {0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]

考えられる問題  (2)

管のStreamMarkersはBoxRatiosで変形できる：

Wolfram Language code: data = Table[{2, -10 z - x y, 10 y - x z}, {x, -2π, 2π, π / 5}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}];
Wolfram Language code: ListStreamPlot3D[data, StreamMarkers -> "Tube", DataRange -> {{-2π, 2π}, {-1, 1}, {-1, 1}}]

BoxRatiosを注意深く調整して管の変形を防ぐ：

Wolfram Language code: ListStreamPlot3D[data, StreamMarkers -> "Tube", DataRange -> {{-2π, 2π}, {-1, 1}, {-1, 1}}, BoxRatios -> {2π, 1, 1}]

"Arrow"と"Arrow3D"の流れマーカーの色は矢印の先頭で決定されるので，長い矢印の場合は色の一貫性がなくなる：

Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}]]
Wolfram Language code: ListStreamPlot3D[Table[{x, y, 1}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}], StreamMarkers -> "Arrow3D", StreamScale -> Full]
Wolfram Research (2021), ListStreamPlot3D, Wolfram言語関数， https://reference.wolfram.com/language/ref/ListStreamPlot3D.html （2022年に更新）.

テキスト

Wolfram Research (2021), ListStreamPlot3D, Wolfram言語関数， https://reference.wolfram.com/language/ref/ListStreamPlot3D.html （2022年に更新）.

CMS

Wolfram Language. 2021. "ListStreamPlot3D." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/ListStreamPlot3D.html.

APA

Wolfram Language. (2021). ListStreamPlot3D. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ListStreamPlot3D.html

BibTeX

@misc{reference.wolfram_2026_liststreamplot3d, author="Wolfram Research", title="{ListStreamPlot3D}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ListStreamPlot3D.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_liststreamplot3d, organization={Wolfram Research}, title={ListStreamPlot3D}, year={2022}, url={https://reference.wolfram.com/language/ref/ListStreamPlot3D.html}, note=[Accessed: 03-November-2026]}