WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

SendMail[body]

body からなるメールを$CloudUserIDで指定されたアドレスへ送信する．

SendMail[{"subject"}]

指定された件名で本文のないメールを送信する．

SendMail[{"subject",body}]

指定された件名と本文でメールを送信する．

SendMail[{"subject",body,att}]

添付ファイル att のあるメールを送信する．

SendMail["to",content]

指定されたアドレスにメールを送信する．

SendMail[{"to1","to2",…},content]

複数のアドレスにメールを送信する．

SendMail[{{"to1",…},{"cc1",…}},content]

Cc:アドレスとして cciを含む．

SendMail[{{"to1",…},{"cc1",…},{"bcc1",…}},content]

Bcc:アドレスとして bcciを含む．

SendMail[assoc]

連想 assoc で指定された要素のあるメールを送信する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アカウントの設定  
基本的な用法  
コンテンツ  
テキストのみ  
テキストとHTML  
そのほかの式  
添付書類  
受信者  
オプション  
MailAddressValidation  
MailSettings  
サーバとアカウントの設定  
自動Ccと自動Bcc  
署名  
その他のメッセージ設定  
アプリケーション  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

SendMail

SendMail[body]

body からなるメールを$CloudUserIDで指定されたアドレスへ送信する．

SendMail[{"subject"}]

指定された件名で本文のないメールを送信する．

SendMail[{"subject",body}]

指定された件名と本文でメールを送信する．

SendMail[{"subject",body,att}]

添付ファイル att のあるメールを送信する．

SendMail["to",content]

指定されたアドレスにメールを送信する．

SendMail[{"to1","to2",…},content]

複数のアドレスにメールを送信する．

SendMail[{{"to1",…},{"cc1",…}},content]

Cc:アドレスとして cciを含む．

SendMail[{{"to1",…},{"cc1",…},{"bcc1",…}},content]

Bcc:アドレスとして bcciを含む．

SendMail[assoc]

連想 assoc で指定された要素のあるメールを送信する．

詳細とオプション

  • SendMailは，指定された電子メールを全受信者に向けて送信しようと試み，SuccessまたはFailureを返す．
  • 電子メールのアドレスは文字列として与えられる．
  • メッセージ本文は文字列，式，式のリストでもよい．
  • SendMailは，次のタイプの式を独立した部分として自動的にメッセージに埋め込む．
  • EmbeddedHTML["string"]本文に埋め込まれたハイパーリンク
    Hyperlink[…]HTMLの本文部分
    CloudObject[…]URLが埋め込まれたクラウドオブジェクト
    Image[…],Graphics[…],…GIFファイル
    Audio[…], Sound[…]WAVファイル
    Dataset[…], TimeSeries[…],…CSVファイル
    NotebookObject[…].nbファイル
    XMLObject[…]XMLファイル
    InputForm[expr]Wolfram言語コードの.wlファイル
    ExportForm[expr,"fmt"]"fmt"で指定された形式のファイル
    exprexpr のフォーマットされた形のラスタ画像ファイル
    {expr1,expr2,…}電子メールの連続する本文部分
  • SendMailはメッセージ中に現れる任意の特殊文字を扱うのに適切な符号化を使う．
  • デスクトップシステムでは，SendMailはユーザのある種のメール設定を必要とする．これらは，ノートブックフロントエンドの「環境設定」▶「インターネットとメール」▶「メール設定」から，あるいはSetOptions[SendMail,MailSettings]を使って定義することができる．SendMailはこれらの設定が提供されていない場合はWolfram Cloudを介してメールを送ろうとする． »
  • Wolfram Cloudでは，電子メールは常にWolfram Cloudサーバから中継される．
  • SendMail[assoc]の連想 assoc は，次の基本要素を含むことができる．
  • "To"{}主受信者の電子メールアドレス
    "Cc"{}従受信者の電子メールアドレス
    "Bcc"{}隠れ受信者の電子メールアドレス
    "Subject"Noneメッセージの件名
    "Body"Noneメッセージ本文
    "TextBody"Noneテキストクライアント用の追加的メッセージ本文
    "HTMLBody"NoneHTMLクライアント用の追加メッセージ本文
    "AttachedExpressions"{}添付書類として送る式
    "AttachedFiles"{}添付書類として送るファイル
    "Priority"Automatic電子メールの優先順位
    "ReturnReceipt"None受取り証明の送り先
  • 指定された"Body"は，メッセージの"TextBody"と"HTMLBody"の前に入れられる．
  • "AttachedExpressions"->"file1"->expr1,…とすると，各式 expriがファイル名 fileiで添付される．
  • "Priority"の設定には，"High"，"Normal"，"Low"，または，1（高い）から 5（低い）までがある．
  • "ReturnReceipt"->Automaticとすると送信者に受取り証明が送られる．"ReturnReceipt"->Noneの場合は，受取り証明は送られない．"ReturnReceipt"->"address"とすると指定されたアドレスに受取り証明が送られる．
  • 連想 assoc は次の追加的要素を含むことができる．これらはオプションMailSettingsの設定で与えることもできる．
  • "AutoBcc"None自動隠れ受信者
    "AutoCc"None自動従受信者
    "FromAddress"Automatic送信者の電子メールアドレス
    "FromName"None送信者の氏名
    "ReplyTo"None推奨される返信用アドレス
    "Signature"None本文の最後に追加するテキスト
  • 電子メールの接続に関連する次の要素もまた連想 assoc あるいはMailSettingsの設定で与えることができる．
  • "EncryptionProtocol"Automatic電子メールの暗号化プロトコル
    "Password"Automaticユーザのパスワード
    "PortNumber"Automaticサーバのボート番号（複数可）
    "Server"Automaticサーバのホスト名またはIPアドレス
    "ServerAuthentication"Automaticサーバの認証を検証するかどうか，検証するとしたらどのように行うか
    "Username"$Usernameユーザのログイン名
  • "EncryptionProtocol"の可能な設定には，"SSL"，"TLS"，"StartTLS"，Noneがある．Automaticと設定すると，使用中のサーバに基づいて符号化が選ばれる．
  • "Password"は，一般に，パスワードの確認が必要とされない場合はNoneに，パスワードがインタラクティブなダイアログで入力される場合はAutomaticに設定される．パスワードをテキスト文字列で与えることも可能である．
  • 電子メールの信用証明は，"Password"のインタラクティブなダイアログを使って任意で保存することができる．信用証明はコンピュータのハードドライブに保存されたキーを使って暗号化される．暗号化された信用証明はWolfram Cloudに送信され，ユーザがWolfram IDを使って認証されて始めてアクセスできるようになる．
  • SendMailには次のオプションを使うことができる．
  • MailAddressValidation Automaticアドレス検証のための関数
    MailSettings Automaticメール設定の連想
  • MailAddressValidationの設定は送信者および受信者の全アドレスに適用される．いずれかのアドレスで検証が失敗すると，SendMailはいかなるメールも送信しない．

例題

すべて開く すべて閉じる

例  (2)

指定された受信者にテキストメールを送る：

Wolfram Language code: SendMail["wlmailtest@wolfram.com", "Here is the body of the message."]

指定された受信者に任意の式を送る：

Wolfram Language code: SendMail["wlmailtest@wolfram.com", Graphics[Circle[]]]

スコープ  (38)

アカウントの設定  (2)

環境設定ダイアログのインターネットとメールタブで送信メールの設定をする：

SetOptionsを使ってデフォルトのパラメータを設定する：

Wolfram Language code: SetOptions[SendMail, MailSettings -> <|"Server" -> "myserver.wolfram.com", "EncryptionProtocol" -> "SSL", "PortNumber" -> 465|>]

基本的な用法  (12)

指定された受信者にテキストメールを送る：

Wolfram Language code: SendMail["wlmailtest@wolfram.com", {"Subject", "Body"}]

$CloudUserIDにテキストメールを送る：

Wolfram Language code: SendMail["Here is the body of the message."]

$CloudUserIDにHTMLメールを送る：

Wolfram Language code: SendMail[EmbeddedHTML["<html><body><font color=\"blue\">Here is an HTML message.</font></body></html>"]]

指定された件名の電子メールを$CloudUserIDに送る：

Wolfram Language code: SendMail[{"Here is the subject of the message."}]

件名と本文がある電子メールを$CloudUserIDに送る：

Wolfram Language code: SendMail[{"Here is the subject of the message.", "Here is the body of the message."}]

件名，本文，添付ファイルがある電子メールを$CloudUserIDに送る：

Wolfram Language code: SendMail[{"Here is the subject of the message.", "Here is the body of the message.", Export["image.jpg", ExampleData[{"TestImage", "House"}]]}]

電子メールを複数の受信者に送る：

Wolfram Language code: SendMail[{"wlmailtest@wolfram.com", "wlmailtest2@wolfram.com"}, "This is the body of the message."]

ToフィールドとCcフィールドの複数の受信者に電子メールを送る：

Wolfram Language code: SendMail[{{"wlmailtest@wolfram.com", "wlmailtest2@wolfram.com"}, {"wlmailtestCc@wolfram.com", "wlmailtestCc2@wolfram.com"}}, "This is the body of the message."]

Toフィールド，Ccフィールド，Bccフィールドの複数の受信者に電子メールを送る：

Wolfram Language code: SendMail[{{"wlmailtest@wolfram.com", "wlmailtest2@wolfram.com"}, {"wlmailtestCc@wolfram.com", "wlmailtestCc2@wolfram.com"}, {"wlmailtestBcc@wolfram.com", "wlmailtestBcc2@wolfram.com"}}, "This is the body of the message."]

テキストとHTMLが交互になったメールを送る：

Wolfram Language code: SendMail[<| "TextBody" -> "Here is the text version of the mail.", "HTMLBody" -> EmbeddedHTML["<html><body><font color=\"blue\">Here is the HTML version of the mail.</font></body></html>"]|>]

任意の式を送る：

Wolfram Language code: SendMail[\!\(\*AudioBox["![Audio Player: ExampleData/car.mp3](audio://content-si5a9)"]\)]

Associationを使って受信者とメールのコンテンツを指定する：

Wolfram Language code: SendMail[<| "To" -> "wlmailtest@wolfram.com", "Subject" -> "Subject line", "Body" -> "Here is the body of the message."|>]

コンテンツ  (18)

テキストのみ  (3)

テキスト本文だけのメールを送る：

Wolfram Language code: SendMail["Here is the body of the message."]

件名だけで本文がないメールを送る：

Wolfram Language code: SendMail[{"Subject line"}]

件名があるテキストメールを送る：

Wolfram Language code: SendMail[{"Subject line", "Here is the body of the message."}]

テキストとHTML  (3)

HTMLメールを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> EmbeddedHTML["<html><body><font color=\"blue\">Here is an HTML email.</font></body></html>"]|>]

テキストとHTMLが交互になったメールを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "TextBody" -> "Here is the text version of the email.", "HTMLBody" -> EmbeddedHTML["<html><body><font color=\"blue\">Here is the HTML version of the email.</font></body></html>"]|>]

テキストとHTMLが混合した本文のメールを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> {"Here is the text part of the email.", EmbeddedHTML["<html><body><font color=\"blue\">Here is the HTML part of the email.</font></body></html>"]}|>]

そのほかの式  (9)

Hyperlinkのあるメールを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> Hyperlink["Wolfram", "http://wolfram.com"]|>]

Wolfram言語のクラウドオブジェクトを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> CloudObject[]|>]

Imageオブジェクトを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> [image]|>]

AudioオブジェクトをWAVファイルとして送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> \!\(\*AudioBox["![Embedded Audio Player](audio://content-ovab0)"]\)|>]

TimeSeriesオブジェクトをCSVファイルとして送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> TimeSeries[FinancialData["MSFT", "Jan. 1, 2018"]]|>]

ノートブックオブジェクトを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> InputNotebook[]|>]

任意の式のInputFormを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> InputForm[Integrate[1 / (x ^ 3 + 1), {x, 0, 1}]]|>]

任意の式のExportFormを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> ExportForm[Graphics[Disk[]], "GIF"]|>]

任意の式のリストを送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> {"Some text", [image], QuantityArray[{2.3, 1.5}, "Meters"]}|>]

添付書類  (3)

添付書類があるメールを送る：

Wolfram Language code: SendMail[{"Subject", "Body", Export["image.jpg", ExampleData[{"TestImage", "House"}]]}]

メールにローカルファイルを添付する：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "AttachedFiles" -> File[FindFile["ExampleData/car.mp3"]]|>]

任意の式を添付書類として特定の受信者に送る：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "AttachedExpressions" -> Plot[{Callout[Log[x] Sin[x], "max", Above], Log[x] Cos[x]}, {x, 0, 2 π}]|>]

受信者  (6)

指定された受信者へメールを送信する：

Wolfram Language code: SendMail["wlmailtest@wolfram.com", {"Subject", "Body text.", Export["mandrill.jpg", ExampleData[{"TestImage", "Mandrill"}]]}]

受信者は名前と電子メールアドレスで指定できる：

Wolfram Language code: SendMail["Mail Test <wlmailtest@wolfram.com>", {"Subject", "Body text.", Export["mandrill.jpg", ExampleData[{"TestImage", "Mandrill"}]]}]

Toの受信者を指定する：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Body" -> "Here is the body of the message."|>]

複数の受信者にメールを送信する：

Wolfram Language code: SendMail[<|"To" -> {"wlmailtest@wolfram.com", "wlmailtest2@wolfram.com"}, "Body" -> "Here is the body of the message."|>]

ToとCcの受信者を指定する：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Cc" -> "wlmailtestCc@wolfram.com", "Body" -> "Here is the body of the message."|>]

Bccの受信者を指定する：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com", "Bcc" -> "wlmailtestBcc@wolfram.com", "Body" -> "Here is the body of the message."|>]

オプション  (9)

MailAddressValidation  (2)

送信前にすべてのメールアドレスを認証する関数を指定する：

Wolfram Language code: SendMail[<|"To" -> "to@wolframsendmail.com"|>, MailAddressValidation -> (True&)]

送信前にすべてのメールアドレスを承認する関数を指定する：

Wolfram Language code: SendMail[<|"To" -> "to@blah.com"|>, MailAddressValidation -> (StringEndsQ[#, "wolframsendmail.com"]&)]

MailSettings  (7)

サーバとアカウントの設定  (2)

送信，メールサーバと認証情報を指定する：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com"|>, MailSettings -> <|"Server" -> "mail.wolfram.com", "UserName" -> "wlmailtest", "Password" -> "XXXXXXXX"|>]

メールが誰からであるかを指定する：

Wolfram Language code: SendMail[<|"To" -> "wlmailtest@wolfram.com"|>, MailSettings -> <|"FromAddress" -> "wlmailtest@wolfram.com", "FromName" -> "Documentation Project"|>]

自動Ccと自動Bcc  (2)

2番目の受信者を自動的にCcにする：

Wolfram Language code: SendMail[<|"To" -> "to@wolframsendmail.com"|>, MailSettings -> <|"AutoCc" -> "to2@wolframsendmail.com"|>]

2番目の受信者を自動的にBccにする：

Wolfram Language code: SendMail[<|"To" -> "to@wolframsendmail.com"|>, MailSettings -> <|"AutoBcc" -> "to2@wolframsendmail.com"|>]

自動Ccと自動Bccは，「環境設定」ダイアログの「インターネットとメール」タブを使っても設定できる．

署名  (1)

メッセージ本体の末尾に署名を加える：

Wolfram Language code: SendMail[<|"To" -> "to@wolframsendmail.com"|>, MailSettings -> <|"Signature" :> StringJoin["Lucky number: ", ToString[RandomInteger[{1, 50}]]]|>]

その他のメッセージ設定  (2)

優先順位を高くしてメッセージを送る：

Wolfram Language code: SendMail[<|"To" -> "to@wolframsendmail.com", "Priority" -> "High"|>]

指定した電子メールアドレスに受取り証明を要求する：

Wolfram Language code: SendMail[<|"To" -> "to@wolframsendmail.com", "ReturnReceipt" -> "to2@wolframsendmail.com"|>]

アプリケーション  (1)

計算の終了時に通知メールを送る：

Wolfram Language code: Print[res = AbsoluteTiming[N[10000000!, 5]]]; SendMail[<|"To" -> "wlmailtest@wolfram.com", "Subject" -> "Calculation Done", "Body" -> {"AbsoluteTiming: " <> ToString@res[[1]] <> " ", res}|> ]
Wolfram Research (2008), SendMail, Wolfram言語関数， https://reference.wolfram.com/language/ref/SendMail.html （2020年に更新）.

テキスト

Wolfram Research (2008), SendMail, Wolfram言語関数， https://reference.wolfram.com/language/ref/SendMail.html （2020年に更新）.

CMS

Wolfram Language. 2008. "SendMail." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/SendMail.html.

APA

Wolfram Language. (2008). SendMail. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SendMail.html

BibTeX

@misc{reference.wolfram_2026_sendmail, author="Wolfram Research", title="{SendMail}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/SendMail.html}", note=[Accessed: 30-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_sendmail, organization={Wolfram Research}, title={SendMail}, year={2020}, url={https://reference.wolfram.com/language/ref/SendMail.html}, note=[Accessed: 30-June-2026]}