WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Audio[file]

指定のファイルに保存されている音声を表す．

Audio[url]

指定のURLに保存されている音声を表す．

Audio[data]

配列 data でサンプルが与えられる音声を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
音声の生成  
オプション  
Appearance  
AudioLabel  
AudioOutputDevice  
MetaInformation  
SampleRate  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
関連するワークフロー
履歴
引用書式

Audio

Audio[file]

指定のファイルに保存されている音声を表す．

Audio[url]

指定のURLに保存されている音声を表す．

Audio[data]

配列 data でサンプルが与えられる音声を表す．

詳細とオプション

  • Audioは，音声プレーヤーとして表示される，関数の入出力となりうるオブジェクトである．
  • 音声データは，メモリ，ローカルファイルあるいはリモートファイルに保存できる．保存したものは再生や処理のためにストリーミングできる．
  • Use the "Store in notebook"ボタンあるいはToMemory関数を使ってアウトオブメモリAudioオブジェクトをノートブックに永久的に保存する． »
  • サポートされるファイル形式には，AIFF，FLAC，MP3，MP4，Ogg，QuickTime，WAVがある．
  • 次は，Audioの可能な外部ソースである．
  • File[…]ローカルファイルのデータ
    CloudObject[…]パブリックまたはプライベートのクラウドオブジェクトのデータ
    LocalObject[…]ローカルオブジェクトのデータ
    URL[…]URLのデータ
  • 外部ソースからAudioオブジェクトを作る場合は，表されるオブジェクトのバイト数もそれを含むノートブックもより小さくなる．
  • Audio[data]では，データは以下のいずれかである．
  • {v1,v2,…}モノラル音声のサンプル値
    {{v11,v12,…},{v21,v22,…},…}チャンネル i に対応する値 vijのある，多チャンネル音声のサンプル値
  • 入力配列 data は，List，NumericArray，SparseArray等で与えられる．
  • Audio[data]では，data の行は結果の音声のチャンネルであるとみなされる．
  • デフォルトで，44100Hzのサンプリングレートが仮定される．SampleRateオプションを使うとこれ以外のサンプリングレートが指定できる．
  • Audio[Sound[…]]は，必要に応じてSoundNoteプリミティブをサンプリングして，サウンドを音声オブジェクトに変換する．
  • Audio[MusicScore[…]]は，必要に応じて記号的な音楽プリミティブをサンプリングすることで，サウンドを音声オブジェクトに変換する．
  • Audio[Video[…]]は，Audioがサポートするファイル形式の最初の音声トラックを参照するAudioオブジェクトを作成する．
  • Audio[data,"type"]を使ってタイプの異なる音声オブジェクトを作ることができる．data の値は丸めや切取りによって強制的に指定のタイプにされる．デフォルトでは"Real32"が仮定される．
  • "type"の可能な設定:
  • "SignedInteger8"からまでの符号付8ビット整数
    "SignedInteger16"からまでの符号付16ビット整数
    "SignedInteger32"からまでの符号付32ビット整数
    "Real32"単精度実数（32ビット）
    "Real64"倍精度実数（64ビット）
  • Audioは，AtomQのような関数には，パターンマッチングの目的で生のオブジェクトとして扱われる．
  • 指定可能なオプション
  • Appearance Automatic生成されたプレーヤーの外観
    AnnotationRulesNone名前付き注釈のリスト
    AudioChannelAssignmentAutomatic出力にどのように音声チャンネルを割り当てるか
    AudioOutputDevice $DefaultAudioOutputDevice再生に使用する音声出力デバイス
    AudioLabel Automatic音声オブジェクトに表示するラベル
    MetaInformation 音声と関連付けられたメタ情報
    SampleRate Automaticサンプリングレート
    SoundVolume1音量
  • Appearanceの可能な設定には，"Minimal"，"Basic"，"Detailed"がある．
  • AudioのInformationには次の特性が含まれることがある．
  • "Channels"音声チャンネルの数
    "DataType"もとになっているデータタイプ
    "Duration"音声信号の持続時間
    "Length"音声サンプルの数
    "ResourcePath"音声ファイルへのパス
    "SampleRate"サンプリングレート

例題

すべて開く すべて閉じる

例  (2)

ローカルファイルにリンクされた音声オブジェクト：

Wolfram Language code: Audio[File["ExampleData/car.mp3"]]

音声の波形プロット：

Wolfram Language code: AudioPlot[%]

単純に数を掛けることで音声信号を減衰させる：

Wolfram Language code: .2Audio["ExampleData/car.mp3"]//AudioPlot

スコープ  (12)

基本的な用法  (6)

ファイルからAudioオブジェクトをインポートする：

Wolfram Language code: Import["ExampleData/car.mp3", "Audio"]

ローカルファイルにリンクしている音声オブジェクト：

Wolfram Language code: Audio["ExampleData/car.mp3"]

URLにリンクしている音声オブジェクト：

Wolfram Language code: Audio["http://exampledata.wolfram.com/bach.mp3"]

CloudObjectに接続された音声オブジェクト：

Wolfram Language code: Audio[CloudObject["https://www.wolframcloud.com/obj/documentation/rule30"]]

動画ファイルの音声トラック：

Wolfram Language code: Audio["ExampleData/Caminandes.mp4"]

アウトオブメモリAudioオブジェクトをノートブックに保存する：

Wolfram Language code: ToMemory[\!\(\*AudioBox["![Embedded Audio Player](audio://content-vxgua)"]\)]

音声の生成  (6)

データ値のリストからモノラルの音声信号を作る：

Wolfram Language code: Audio[Array[Sin[2π 1200 #]&, 44100, {0, 1}]]
Wolfram Language code: AudioChannels[%]

ステレオ音声サンプルを作る：

Wolfram Language code: a = Audio[Transpose@Array[{Sin[2π 1200 #], Sin[2π 500 #]}&, 44100, {0, 1}]]
Wolfram Language code: AudioChannels[a]

SoundオブジェクトをAudioに変換する：

Wolfram Language code: Audio[Sound[«1»]]

音符を含むSoundオブジェクトを変換する：

Wolfram Language code: Audio[Sound[{SoundNote[0, 1.75, "Trumpet"], SoundNote[7, 1.75, "Trumpet"], SoundNote[12, 1.75, "Trumpet"]}]]

MusicScoreオブジェクトをAudioに変換する：

Wolfram Language code: Audio[MusicScore[{"C", "G", "A", "D"}]]

タイプ"SignedInteger8"の音声信号を作る：

Wolfram Language code: Audio[RandomInteger[{-128, 127}, 44100], "SignedInteger8"]
Wolfram Language code: AudioType[%]

音声タイプを8ビット符号付整数から32ビット実数に変換する：

Wolfram Language code: a = Audio[RandomInteger[{-128, 127}, 44100], "SignedInteger8"];
Wolfram Language code: res = Audio[a, "Real32"];
Wolfram Language code: AudioType /@ {a, res}

オプション  (5)

Appearance  (1)

デフォルトで，基本GUIが表示される：

Wolfram Language code: Audio["ExampleData/car.mp3"]

最小のGUIを表示する：

Wolfram Language code: Audio["ExampleData/car.mp3", Appearance -> "Minimal"]

詳しいGUIを表示する：

Wolfram Language code: Audio["ExampleData/car.mp3", Appearance -> "Detailed"]

AudioLabel  (1)

デフォルトで，音声タイプによって自動ラベルが使われる：

Wolfram Language code: Audio["ExampleData/car.mp3"]

カスタムラベルをGUIに表示する：

Wolfram Language code: Audio["ExampleData/car.mp3", AudioLabel -> "my audio"]

AudioOutputDevice  (1)

デフォルトで，再生には$DefaultAudioOutputDeviceが使われる：

Wolfram Language code: AudioGenerator["Sin"]//Options
Wolfram Language code: $DefaultAudioOutputDevice
Wolfram Language code: AudioGenerator["Sin", AudioOutputDevice -> "Logitech USB Headset H340"]//Options

使用可能なデバイスのリストをチェックする：

Wolfram Language code: $AudioOutputDevices

オペレーティングシステムがデフォルトとして指定しているデバイスを使う：

Wolfram Language code: AudioGenerator["Sin", AudioOutputDevice -> "System Setting"]//Options

MetaInformation  (1)

カスタムのメタ情報を音声オブジェクトに加える：

Wolfram Language code: a = Audio[RandomInteger[{-128, 127}, 44100], "SignedInteger8", MetaInformation -> {"Owner" -> "John"}]

Optionsを使ってメタ情報を取り出す：

Wolfram Language code: Options[%, MetaInformation]

SampleRate  (1)

デフォルトで，44.1kHzのサンプルレートが仮定される：

Wolfram Language code: data = RandomReal[{-1, 1}, 44100];
Wolfram Language code: Audio[data, SampleRate -> 44100]

別のサンプルレートを指定する：

Wolfram Language code: Audio[data, SampleRate -> 22050]

特性と関係  (7)

AudioQを使って有効な音声の式かどうかをチェックする：

Wolfram Language code: AudioQ[\!\(\*AudioBox["![Audio Player: ExampleData/car.mp3](audio://content-3g99c)"]\)]
Wolfram Language code: AudioQ[Audio[x]]

Audioオブジェクトは原子的で，分割できない：

Wolfram Language code: AtomQ[\!\(\*AudioBox["![Audio Player: ExampleData/car.mp3](audio://content-3g99c)"]\)]

音声タイプが違えばビット深度も異なる．圧縮のためにより小さいビット深度を使う：

Wolfram Language code: a = Import["ExampleData/car.mp3", "Audio"];
Wolfram Language code: types = {"SignedInteger8", "SignedInteger16", "SignedInteger32", "Real32", "Real"}; TextGrid[Table[{t, ByteCount@Audio[a, t]}, {t, types}], Dividers -> {False, Center}, Alignment -> Left, Spacings -> {3, .5}]

Audio[file]とAudio[url]はもとになっているデータをメモリにインポートしない：

Wolfram Language code: a = Audio["ExampleData/car.mp3"];

生成されたプレーヤーのByteCountを取り出す：

Wolfram Language code: ByteCount[%]

もとのファイルのバイト数と比較する：

Wolfram Language code: FileByteCount[FindFile["ExampleData/car.mp3"]]

ToMemoryを使ってアウトオブコア音声オブジェクトのデータをメモリに入れる：

Wolfram Language code: ByteCount[a = Audio["ExampleData/car.mp3"]]
Wolfram Language code: ByteCount[ToMemory[a]]

AudioGeneratorを使ってさまざまな振動とノイズを作る：

Wolfram Language code: AudioGenerator["Sin"]
Wolfram Language code: AudioPlot[%, PlotRange -> .1]

ピンクノイズを作る：

Wolfram Language code: AudioGenerator["Pink"]
Wolfram Language code: AudioPlot[%]

AudioPlotを使って音声オブジェクトの波形を可視化する：

Wolfram Language code: AudioPlot[Audio["ExampleData/car.mp3"]]

おもしろい例題  (1)

ビットごとの操作のみを使って複雑な音声信号を作る：

Wolfram Language code: f[t_] := t * BitAnd[BitOr[BitShiftRight[t, 12], BitShiftRight[t, 8]], BitAnd[63, BitShiftRight[t, 4]]]
Wolfram Language code: Audio[Table[f[t], {t, 0, 100000}], "SignedInteger8", SampleRate -> 8000]
Wolfram Research (2016), Audio, Wolfram言語関数， https://reference.wolfram.com/language/ref/Audio.html （2020年に更新）.

テキスト

Wolfram Research (2016), Audio, Wolfram言語関数， https://reference.wolfram.com/language/ref/Audio.html （2020年に更新）.

CMS

Wolfram Language. 2016. "Audio." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/Audio.html.

APA

Wolfram Language. (2016). Audio. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Audio.html

BibTeX

@misc{reference.wolfram_2026_audio, author="Wolfram Research", title="{Audio}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/Audio.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_audio, organization={Wolfram Research}, title={Audio}, year={2020}, url={https://reference.wolfram.com/language/ref/Audio.html}, note=[Accessed: 13-September-2026]}