WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター
Background

Background

背景の彩色を指定するオプションである．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

Background

Background

背景の彩色を指定するオプションである．

詳細

  • Backgroundの設定には，任意の色あるいは不透明度指定が使える．
  • Backgroundは，Graphics，Plot，Text，Panel，Button，Cell等の関数のオプションとして使われる．
  • 一般にオブジェクトにBackground->color のオプションがあると，オブジェクトによって定義された領域全般で指定された色が背景色として使われる．
  • Style[expr,Background->color]は，expr の境界ボックスで定義された領域でのみ color が背景色として使われるように指定する．
  • Gridのような構文では，Itemを使って，特定の項目について背景が範囲全体を埋めるように指定することができる．
  • トップレベルのセルの中では，背景はセル枠の内部領域に対してのみ使われる．セルの背景色が周囲とマッチしない場合は，セル枠が描かれていなくてもセルにはセルの余白が含まれる．インラインや添付等として表示されたセルは同様の影響は受けない． »
  • Background->Noneは，背景を使わないように指定するので，実質的に背景は透過的になる．
  • Background->Automaticは，使用されている特定のオブジェクトあるいはウィンドウについてのシステムの外観に従う背景を使うように指定する．Insetの場合，Background->Automaticは，それが使われているグラフィックスの背景を使うように指定する．
  • Grid，Column，Rowのようなオブジェクトでは，Backgroundの設定は個々の列，行，要素等の背景を指定したリストでもよい．
  • DatasetのBackgroundの設定は，色を返す純関数 f でよい．設定は f[value,position,dataset]で与えられる．data はデータ集合の第1引数である．

例題

すべて開く すべて閉じる

例  (2)

式の後ろに背景色を入れる：

Wolfram Language code: Style[{a, b, c}, Background -> Orange]

グラフィックスの背景：

Wolfram Language code: Graphics[{Circle[]}, Background -> Brown]
Wolfram Language code: Graphics3D[{Opacity[.5], Sphere[]}, Background -> Pink]

スコープ  (4)

ピンク色の背景で格子を描く：

Wolfram Language code: Grid[Table[x, {4}, {7}], Background -> Pink]

有効な任意の色指示子を使うことができる：

Wolfram Language code: Table[ExpressionCell["abc", Background -> col], {col, {RGBColor[1, 1, 0], Hue[.5, .3, .1], GrayLevel[.5], LABColor[1, .4, .8], XYZColor[.6, .9, .2]}}]

LightDarkSwitchedを使うことで，ライトモードとダークモードで異なる色が指定できる：

Wolfram Language code: Graphics[Disk[], Background -> LightDarkSwitched[LightGreen, Purple]]

第1要素を茶色の背景で描く：

Wolfram Language code: Grid[{{Item[a, Background -> Brown], b}, {c, d}}]

一般化と拡張  (5)

最初と2番目の水平位置にオレンジ色とマジェンタ色の背景を施す：

Wolfram Language code: Grid[Table[x, {4}, {7}], Background -> {{Orange, Magenta}, None}]

最初と最後の水平位置にオレンジ色とマジェンタ色の背景を施す：

Wolfram Language code: Grid[Table[x, {4}, {7}], Background -> {{Orange, {}, Magenta}, None}]

最初と2番目の垂直位置にオレンジ色とマジェンタ色の背景を施す：

Wolfram Language code: Grid[Table[x, {4}, {7}], Background -> {None, {Orange, Magenta}}]

茶色と灰色の背景を交互にする：

Wolfram Language code: Grid[Table[x, {4}, {7}], Background -> {{{Brown, Gray}}, None}]

背景色を交互にし，最初と最後の位置にピンク色を重ねる：

Wolfram Language code: Grid[Table[x, {4}, {7}], Background -> {{{{Brown, Gray}}, {1 -> Pink, -1 -> Pink}}, None}]

格子の小区域に背景色を設定する：

Wolfram Language code: Grid[Table[x, {4}, {7}], Background -> {None, None, {{{1, 3}, {2, 4}} -> Pink}}]

Dataset内の値で背景に彩色する：

Wolfram Language code: Dataset[Take[...], Background -> {"age" -> (If[# > 9, Pink, Automatic]&)}]

アプリケーション  (3)

行の背景色を交互に使った表を示す：

Wolfram Language code: Grid[Table[Binomial[n, k], {n, 15}, {k, 15}], Background -> {None, {{Brown, Gray}}}]

Datasetの各列の最大値をハイライトする：

Wolfram Language code: Dataset[Table[RandomReal[], {5}, {3}], Background -> (If[# === Max[#3[[All, #2[[2]]]]], Orange, Automatic]&)]

値の格子を色分け図として表示する：

Wolfram Language code: Dataset[Table[x y / 25., {x, 5}, {y, 5}], Background -> (LightDarkSwitched[Hue[1, #]]&)]

特性と関係  (2)

透過的オブジェクトを通して背景色を見ることができる：

Wolfram Language code: {Graphics[{Opacity[0.5], Red, Disk[]}], Graphics[{Opacity[0.5], Red, Disk[]}, Background -> Yellow]}

対照的な背景色を持ち，CellFrameMarginsを使ってセル枠が描かれていないセル：

Wolfram Language code: CellPrint[ExpressionCell["abc", "Print", CellFrameMargins -> 20, Background -> Gray]]

周囲とマッチする背景色は，セル枠が存在する場合にのみCellFrameMarginsを使う：

Wolfram Language code: CellPrint[ExpressionCell["abc", "Print", CellFrameMargins -> 20, Background -> ThemeColor["Background"]]]
Wolfram Language code: CellPrint[ExpressionCell["abc", "Print", CellFrameMargins -> 20, Background -> ThemeColor["Background"], CellFrame -> True]]

BackgroundNoneはマッチする背景色として扱われる：

Wolfram Language code: CellPrint[ExpressionCell["abc", "Print", CellFrameMargins -> 20, Background -> None]]

CellFrameMarginsは，インラインセル，添付セル，浮遊セル等として表示されるセルに対しては使われない：

Wolfram Language code: Row[{1, ExpressionCell[2, Background -> Gray], 3}]

考えられる問題  (1)

背景色の中には，ライトモードではデフォルトのフォント色とのコントラストがよくなるがダークモードではコントラストが悪くなるものがある：

Wolfram Language code: ExpressionCell["light mode contrast", Background -> Yellow]

そのような場合には，LightDarkSwitchedで色を包み込むとよい：

Wolfram Language code: ExpressionCell["light mode contrast", Background -> LightDarkSwitched[Yellow]]

また，ダークモードではコントラストがよくなるがライトモードでは悪くなる色もある：

Wolfram Language code: ExpressionCell["light mode contrast", Background -> Purple]

このようなことは，第1引数としてLightDarkSwitchedおよびAutomaticを使うことで解消される：

Wolfram Language code: ExpressionCell["light mode contrast", Background -> LightDarkSwitched[Automatic, Purple]]

おもしろい例題  (1)

3Dオブジェクトを黒い背景で示す：

Wolfram Language code: ContourPlot3D[x ^ 4 + y ^ 4 + z ^ 4 - (x ^ 2 + y ^ 2 + z ^ 2) == -1 / 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> 15, MeshFunctions -> {#1^2 + #2^2 + #3^2&}, MeshShading -> {None, Directive[Blue, Specularity[White, 50]], None, Directive[Yellow, Specularity[White, 50]]}, PlotPoints -> 35, MeshStyle -> Opacity[.3], Axes -> False, Boxed -> False, Background -> Black]
Wolfram Research (1991), Background, Wolfram言語関数， https://reference.wolfram.com/language/ref/Background.html （2020年に更新）.

テキスト

Wolfram Research (1991), Background, Wolfram言語関数， https://reference.wolfram.com/language/ref/Background.html （2020年に更新）.

CMS

Wolfram Language. 1991. "Background." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/Background.html.

APA

Wolfram Language. (1991). Background. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Background.html

BibTeX

@misc{reference.wolfram_2026_background, author="Wolfram Research", title="{Background}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/Background.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_background, organization={Wolfram Research}, title={Background}, year={2020}, url={https://reference.wolfram.com/language/ref/Background.html}, note=[Accessed: 12-September-2026]}